Loading...
1/* SPDX-License-Identifier: GPL-2.0 */
2#include <asm/asm-offsets.h>
3#include <asm/thread_info.h>
4
5#define PAGE_SIZE _PAGE_SIZE
6
7/*
8 * Put .bss..swapper_pg_dir as the first thing in .bss. This will
9 * ensure that it has .bss alignment (64K).
10 */
11#define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
12
13/* Cavium Octeon should not have a separate PT_NOTE Program Header. */
14#ifndef CONFIG_CAVIUM_OCTEON_SOC
15#define EMITS_PT_NOTE
16#endif
17
18#define RUNTIME_DISCARD_EXIT
19
20#include <asm-generic/vmlinux.lds.h>
21
22#undef mips
23#define mips mips
24OUTPUT_ARCH(mips)
25ENTRY(kernel_entry)
26PHDRS {
27 text PT_LOAD FLAGS(7); /* RWX */
28#ifndef CONFIG_CAVIUM_OCTEON_SOC
29 note PT_NOTE FLAGS(4); /* R__ */
30#endif /* CAVIUM_OCTEON_SOC */
31}
32
33#ifdef CONFIG_32BIT
34 #ifdef CONFIG_CPU_LITTLE_ENDIAN
35 jiffies = jiffies_64;
36 #else
37 jiffies = jiffies_64 + 4;
38 #endif
39#else
40 jiffies = jiffies_64;
41#endif
42
43SECTIONS
44{
45#ifdef CONFIG_BOOT_ELF64
46 /* Read-only sections, merged into text segment: */
47 /* . = 0xc000000000000000; */
48
49 /* This is the value for an Origin kernel, taken from an IRIX kernel. */
50 /* . = 0xc00000000001c000; */
51
52 /* Set the vaddr for the text segment to a value
53 * >= 0xa800 0000 0001 9000 if no symmon is going to configured
54 * >= 0xa800 0000 0030 0000 otherwise
55 */
56
57 /* . = 0xa800000000300000; */
58 . = 0xffffffff80300000;
59#endif
60 . = LINKER_LOAD_ADDRESS;
61 /* read-only */
62 _text = .; /* Text and read-only data */
63 .text : {
64 HEAD_TEXT
65 TEXT_TEXT
66 SCHED_TEXT
67 LOCK_TEXT
68 KPROBES_TEXT
69 IRQENTRY_TEXT
70 SOFTIRQENTRY_TEXT
71 *(.fixup)
72 *(.gnu.warning)
73 . = ALIGN(16);
74 *(.got) /* Global offset table */
75 } :text = 0
76 _etext = .; /* End of text section */
77
78 EXCEPTION_TABLE(16)
79
80 /* Exception table for data bus errors */
81 __dbe_table : {
82 __start___dbe_table = .;
83 KEEP(*(__dbe_table))
84 __stop___dbe_table = .;
85 }
86
87 _sdata = .; /* Start of data section */
88 RO_DATA(4096)
89
90 /* writeable */
91 .data : { /* Data */
92 . = . + DATAOFFSET; /* for CONFIG_MAPPED_KERNEL */
93
94 INIT_TASK_DATA(THREAD_SIZE)
95 NOSAVE_DATA
96 PAGE_ALIGNED_DATA(PAGE_SIZE)
97 CACHELINE_ALIGNED_DATA(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
98 READ_MOSTLY_DATA(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
99 DATA_DATA
100 CONSTRUCTORS
101 }
102 BUG_TABLE
103 _gp = . + 0x8000;
104 .lit8 : {
105 *(.lit8)
106 }
107 .lit4 : {
108 *(.lit4)
109 }
110 /* We want the small data sections together, so single-instruction offsets
111 can access them all, and initialized data all before uninitialized, so
112 we can shorten the on-disk segment size. */
113 .sdata : {
114 *(.sdata)
115 }
116 _edata = .; /* End of data section */
117
118 /* will be freed after init */
119 . = ALIGN(PAGE_SIZE); /* Init code and data */
120 __init_begin = .;
121 INIT_TEXT_SECTION(PAGE_SIZE)
122 INIT_DATA_SECTION(16)
123
124 . = ALIGN(4);
125 .mips.machines.init : AT(ADDR(.mips.machines.init) - LOAD_OFFSET) {
126 __mips_machines_start = .;
127 KEEP(*(.mips.machines.init))
128 __mips_machines_end = .;
129 }
130
131 /* .exit.text is discarded at runtime, not link time, to deal with
132 * references from .rodata
133 */
134 .exit.text : {
135 EXIT_TEXT
136 }
137 .exit.data : {
138 EXIT_DATA
139 }
140#ifdef CONFIG_SMP
141 PERCPU_SECTION(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
142#endif
143
144 .rel.dyn : ALIGN(8) {
145 *(.rel)
146 *(.rel*)
147 }
148
149#ifdef CONFIG_MIPS_ELF_APPENDED_DTB
150 STRUCT_ALIGN();
151 .appended_dtb : AT(ADDR(.appended_dtb) - LOAD_OFFSET) {
152 *(.appended_dtb)
153 KEEP(*(.appended_dtb))
154 }
155#endif
156
157#ifdef CONFIG_RELOCATABLE
158 . = ALIGN(4);
159
160 .data.reloc : {
161 _relocation_start = .;
162 /*
163 * Space for relocation table
164 * This needs to be filled so that the
165 * relocs tool can overwrite the content.
166 * An invalid value is left at the start of the
167 * section to abort relocation if the table
168 * has not been filled in.
169 */
170 LONG(0xFFFFFFFF);
171 FILL(0);
172 . += CONFIG_RELOCATION_TABLE_SIZE - 4;
173 _relocation_end = .;
174 }
175#endif
176
177#ifdef CONFIG_MIPS_RAW_APPENDED_DTB
178 .fill : {
179 FILL(0);
180 BYTE(0);
181 STRUCT_ALIGN();
182 }
183 __appended_dtb = .;
184 /* leave space for appended DTB */
185 . += 0x100000;
186#endif
187 /*
188 * Align to 64K in attempt to eliminate holes before the
189 * .bss..swapper_pg_dir section at the start of .bss. This
190 * also satisfies PAGE_SIZE alignment as the largest page size
191 * allowed is 64K.
192 */
193 . = ALIGN(0x10000);
194 __init_end = .;
195 /* freed after init ends here */
196
197 /*
198 * Force .bss to 64K alignment so that .bss..swapper_pg_dir
199 * gets that alignment. .sbss should be empty, so there will be
200 * no holes after __init_end. */
201 BSS_SECTION(0, 0x10000, 8)
202
203 _end = . ;
204
205 /* These mark the ABI of the kernel for debuggers. */
206 .mdebug.abi32 : {
207 KEEP(*(.mdebug.abi32))
208 }
209 .mdebug.abi64 : {
210 KEEP(*(.mdebug.abi64))
211 }
212
213 /* This is the MIPS specific mdebug section. */
214 .mdebug : {
215 *(.mdebug)
216 }
217
218 STABS_DEBUG
219 DWARF_DEBUG
220 ELF_DETAILS
221
222 /* These must appear regardless of . */
223 .gptab.sdata : {
224 *(.gptab.data)
225 *(.gptab.sdata)
226 }
227 .gptab.sbss : {
228 *(.gptab.bss)
229 *(.gptab.sbss)
230 }
231
232 /* Sections to be discarded */
233 DISCARDS
234 /DISCARD/ : {
235 /* ABI crap starts here */
236 *(.MIPS.abiflags)
237 *(.MIPS.options)
238 *(.gnu.attributes)
239 *(.options)
240 *(.pdr)
241 *(.reginfo)
242 }
243}
1#include <asm/asm-offsets.h>
2#include <asm/thread_info.h>
3
4#define PAGE_SIZE _PAGE_SIZE
5
6/*
7 * Put .bss..swapper_pg_dir as the first thing in .bss. This will
8 * ensure that it has .bss alignment (64K).
9 */
10#define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
11
12#include <asm-generic/vmlinux.lds.h>
13
14#undef mips
15#define mips mips
16OUTPUT_ARCH(mips)
17ENTRY(kernel_entry)
18PHDRS {
19 text PT_LOAD FLAGS(7); /* RWX */
20#ifndef CONFIG_CAVIUM_OCTEON_SOC
21 note PT_NOTE FLAGS(4); /* R__ */
22#endif /* CAVIUM_OCTEON_SOC */
23}
24
25#ifdef CONFIG_32BIT
26 #ifdef CONFIG_CPU_LITTLE_ENDIAN
27 jiffies = jiffies_64;
28 #else
29 jiffies = jiffies_64 + 4;
30 #endif
31#else
32 jiffies = jiffies_64;
33#endif
34
35SECTIONS
36{
37#ifdef CONFIG_BOOT_ELF64
38 /* Read-only sections, merged into text segment: */
39 /* . = 0xc000000000000000; */
40
41 /* This is the value for an Origin kernel, taken from an IRIX kernel. */
42 /* . = 0xc00000000001c000; */
43
44 /* Set the vaddr for the text segment to a value
45 * >= 0xa800 0000 0001 9000 if no symmon is going to configured
46 * >= 0xa800 0000 0030 0000 otherwise
47 */
48
49 /* . = 0xa800000000300000; */
50 . = 0xffffffff80300000;
51#endif
52 . = VMLINUX_LOAD_ADDRESS;
53 /* read-only */
54 _text = .; /* Text and read-only data */
55 .text : {
56 TEXT_TEXT
57 SCHED_TEXT
58 CPUIDLE_TEXT
59 LOCK_TEXT
60 KPROBES_TEXT
61 IRQENTRY_TEXT
62 SOFTIRQENTRY_TEXT
63 *(.text.*)
64 *(.fixup)
65 *(.gnu.warning)
66 } :text = 0
67 _etext = .; /* End of text section */
68
69 EXCEPTION_TABLE(16)
70
71 /* Exception table for data bus errors */
72 __dbe_table : {
73 __start___dbe_table = .;
74 *(__dbe_table)
75 __stop___dbe_table = .;
76 }
77
78#ifdef CONFIG_CAVIUM_OCTEON_SOC
79#define NOTES_HEADER
80#else /* CONFIG_CAVIUM_OCTEON_SOC */
81#define NOTES_HEADER :note
82#endif /* CONFIG_CAVIUM_OCTEON_SOC */
83 NOTES :text NOTES_HEADER
84 .dummy : { *(.dummy) } :text
85
86 _sdata = .; /* Start of data section */
87 RODATA
88
89 /* writeable */
90 .data : { /* Data */
91 . = . + DATAOFFSET; /* for CONFIG_MAPPED_KERNEL */
92
93 INIT_TASK_DATA(THREAD_SIZE)
94 NOSAVE_DATA
95 CACHELINE_ALIGNED_DATA(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
96 READ_MOSTLY_DATA(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
97 DATA_DATA
98 CONSTRUCTORS
99 }
100 _gp = . + 0x8000;
101 .lit8 : {
102 *(.lit8)
103 }
104 .lit4 : {
105 *(.lit4)
106 }
107 /* We want the small data sections together, so single-instruction offsets
108 can access them all, and initialized data all before uninitialized, so
109 we can shorten the on-disk segment size. */
110 .sdata : {
111 *(.sdata)
112 }
113 _edata = .; /* End of data section */
114
115 /* will be freed after init */
116 . = ALIGN(PAGE_SIZE); /* Init code and data */
117 __init_begin = .;
118 INIT_TEXT_SECTION(PAGE_SIZE)
119 INIT_DATA_SECTION(16)
120
121 . = ALIGN(4);
122 .mips.machines.init : AT(ADDR(.mips.machines.init) - LOAD_OFFSET) {
123 __mips_machines_start = .;
124 *(.mips.machines.init)
125 __mips_machines_end = .;
126 }
127
128 /* .exit.text is discarded at runtime, not link time, to deal with
129 * references from .rodata
130 */
131 .exit.text : {
132 EXIT_TEXT
133 }
134 .exit.data : {
135 EXIT_DATA
136 }
137#ifdef CONFIG_SMP
138 PERCPU_SECTION(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
139#endif
140
141#ifdef CONFIG_RELOCATABLE
142 . = ALIGN(4);
143
144 .data.reloc : {
145 _relocation_start = .;
146 /*
147 * Space for relocation table
148 * This needs to be filled so that the
149 * relocs tool can overwrite the content.
150 * An invalid value is left at the start of the
151 * section to abort relocation if the table
152 * has not been filled in.
153 */
154 LONG(0xFFFFFFFF);
155 FILL(0);
156 . += CONFIG_RELOCATION_TABLE_SIZE - 4;
157 _relocation_end = .;
158 }
159#endif
160
161#ifdef CONFIG_MIPS_RAW_APPENDED_DTB
162 __appended_dtb = .;
163 /* leave space for appended DTB */
164 . += 0x100000;
165#elif defined(CONFIG_MIPS_ELF_APPENDED_DTB)
166 .appended_dtb : AT(ADDR(.appended_dtb) - LOAD_OFFSET) {
167 *(.appended_dtb)
168 KEEP(*(.appended_dtb))
169 }
170#endif
171 /*
172 * Align to 64K in attempt to eliminate holes before the
173 * .bss..swapper_pg_dir section at the start of .bss. This
174 * also satisfies PAGE_SIZE alignment as the largest page size
175 * allowed is 64K.
176 */
177 . = ALIGN(0x10000);
178 __init_end = .;
179 /* freed after init ends here */
180
181 /*
182 * Force .bss to 64K alignment so that .bss..swapper_pg_dir
183 * gets that alignment. .sbss should be empty, so there will be
184 * no holes after __init_end. */
185 BSS_SECTION(0, 0x10000, 0)
186
187 _end = . ;
188
189 /* These mark the ABI of the kernel for debuggers. */
190 .mdebug.abi32 : {
191 KEEP(*(.mdebug.abi32))
192 }
193 .mdebug.abi64 : {
194 KEEP(*(.mdebug.abi64))
195 }
196
197 /* This is the MIPS specific mdebug section. */
198 .mdebug : {
199 *(.mdebug)
200 }
201
202 STABS_DEBUG
203 DWARF_DEBUG
204
205 /* These must appear regardless of . */
206 .gptab.sdata : {
207 *(.gptab.data)
208 *(.gptab.sdata)
209 }
210 .gptab.sbss : {
211 *(.gptab.bss)
212 *(.gptab.sbss)
213 }
214
215 /* Sections to be discarded */
216 DISCARDS
217 /DISCARD/ : {
218 /* ABI crap starts here */
219 *(.MIPS.abiflags)
220 *(.MIPS.options)
221 *(.options)
222 *(.pdr)
223 *(.reginfo)
224 *(.eh_frame)
225 }
226}