1/*
 2 * Common module linker script, always used when linking a module.
 3 * Archs are free to supply their own linker scripts.  ld will
 4 * combine them automatically.
 5 */
 6#ifdef CONFIG_UNWIND_TABLES
 7#define DISCARD_EH_FRAME
 8#else
 9#define DISCARD_EH_FRAME	*(.eh_frame)
10#endif
11
12SECTIONS {
13	/DISCARD/ : {
14		*(.discard)
15		*(.discard.*)
16		*(.export_symbol)
17	}
18
19	__ksymtab		0 : { *(SORT(___ksymtab+*)) }
20	__ksymtab_gpl		0 : { *(SORT(___ksymtab_gpl+*)) }
21	__kcrctab		0 : { *(SORT(___kcrctab+*)) }
22	__kcrctab_gpl		0 : { *(SORT(___kcrctab_gpl+*)) }
23
24	.ctors			0 : ALIGN(8) { *(SORT(.ctors.*)) *(.ctors) }
25	.init_array		0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) }
26
27	.altinstructions	0 : ALIGN(8) { KEEP(*(.altinstructions)) }
28	__bug_table		0 : ALIGN(8) { KEEP(*(__bug_table)) }
29	__jump_table		0 : ALIGN(8) { KEEP(*(__jump_table)) }
30
31	__patchable_function_entries : { *(__patchable_function_entries) }
32
33#ifdef CONFIG_ARCH_USES_CFI_TRAPS
34	__kcfi_traps 		: { KEEP(*(.kcfi_traps)) }
35#endif
36
37#ifdef CONFIG_LTO_CLANG
38	/*
39	 * With CONFIG_LTO_CLANG, LLD always enables -fdata-sections and
40	 * -ffunction-sections, which increases the size of the final module.
41	 * Merge the split sections in the final binary.
42	 */
43	.bss : {
44		*(.bss .bss.[0-9a-zA-Z_]*)
45		*(.bss..L*)
46	}
47
48	.data : {
49		*(.data .data.[0-9a-zA-Z_]*)
50		*(.data..L*)
51	}
52
53	.rodata : {
54		*(.rodata .rodata.[0-9a-zA-Z_]*)
55		*(.rodata..L*)
56	}
57#endif
58}
59
60/* bring in arch-specific sections */
61#include <asm/module.lds.h>