Loading...
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3
4# Check the stack usage of functions
5#
6# Copyright Joern Engel <joern@lazybastard.org>
7# Inspired by Linus Torvalds
8# Original idea maybe from Keith Owens
9# s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
10# Mips port by Juan Quintela <quintela@mandrakesoft.com>
11# Arm port by Holger Schurig
12# Random bits by Matt Mackall <mpm@selenic.com>
13# M68k port by Geert Uytterhoeven and Andreas Schwab
14# AArch64, PARISC ports by Kyle McMartin
15# sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk>
16# ppc64le port by Breno Leitao <leitao@debian.org>
17# riscv port by Wadim Mueller <wafgo01@gmail.com>
18# loongarch port by Youling Tang <tangyouling@kylinos.cn>
19#
20# Usage:
21# objdump -d vmlinux | scripts/checkstack.pl [arch] [min_stack]
22#
23# TODO : Port to all architectures (one regex per arch)
24
25use strict;
26
27# check for arch
28#
29# $re is used for two matches:
30# $& (whole re) matches the complete objdump line with the stack growth
31# $1 (first bracket) matches the size of the stack growth
32#
33# $dre is similar, but for dynamic stack redutions:
34# $& (whole re) matches the complete objdump line with the stack growth
35# $1 (first bracket) matches the dynamic amount of the stack growth
36#
37# $sub: subroutine for special handling to check stack usage.
38#
39# use anything else and feel the pain ;)
40my (@stack, $re, $dre, $sub, $x, $xs, $funcre, $min_stack);
41{
42 my $arch = shift;
43 if ($arch eq "") {
44 $arch = `uname -m`;
45 chomp($arch);
46 }
47
48 $min_stack = shift;
49 if ($min_stack eq "" || $min_stack !~ /^\d+$/) {
50 $min_stack = 512;
51 }
52
53 $x = "[0-9a-f]"; # hex character
54 $xs = "[0-9a-f ]"; # hex character or space
55 $funcre = qr/^$x* <(.*)>:$/;
56 if ($arch =~ '^(aarch|arm)64$') {
57 #ffffffc0006325cc: a9bb7bfd stp x29, x30, [sp, #-80]!
58 #a110: d11643ff sub sp, sp, #0x590
59 $re = qr/^.*stp.*sp, ?\#-([0-9]{1,8})\]\!/o;
60 $dre = qr/^.*sub.*sp, sp, #(0x$x{1,8})/o;
61 } elsif ($arch eq 'arm') {
62 #c0008ffc: e24dd064 sub sp, sp, #100 ; 0x64
63 $re = qr/.*sub.*sp, sp, #([0-9]{1,4})/o;
64 $sub = \&arm_push_handling;
65 } elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
66 #c0105234: 81 ec ac 05 00 00 sub $0x5ac,%esp
67 # or
68 # 2f60: 48 81 ec e8 05 00 00 sub $0x5e8,%rsp
69 $re = qr/^.*[as][du][db] \$(0x$x{1,8}),\%(e|r)sp$/o;
70 $dre = qr/^.*[as][du][db] (%.*),\%(e|r)sp$/o;
71 } elsif ($arch eq 'm68k') {
72 # 2b6c: 4e56 fb70 linkw %fp,#-1168
73 # 1df770: defc ffe4 addaw #-28,%sp
74 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
75 } elsif ($arch eq 'mips64') {
76 #8800402c: 67bdfff0 daddiu sp,sp,-16
77 $re = qr/.*daddiu.*sp,sp,-([0-9]{1,8})/o;
78 } elsif ($arch eq 'mips') {
79 #88003254: 27bdffe0 addiu sp,sp,-32
80 $re = qr/.*addiu.*sp,sp,-([0-9]{1,8})/o;
81 } elsif ($arch eq 'nios2') {
82 #25a8: defffb04 addi sp,sp,-20
83 $re = qr/.*addi.*sp,sp,-([0-9]{1,8})/o;
84 } elsif ($arch eq 'openrisc') {
85 # c000043c: 9c 21 fe f0 l.addi r1,r1,-272
86 $re = qr/.*l\.addi.*r1,r1,-([0-9]{1,8})/o;
87 } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
88 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
89 } elsif ($arch eq 'powerpc' || $arch =~ /^ppc(64)?(le)?$/ ) {
90 # powerpc : 94 21 ff 30 stwu r1,-208(r1)
91 # ppc64(le) : 81 ff 21 f8 stdu r1,-128(r1)
92 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
93 } elsif ($arch =~ /^s390x?$/) {
94 # 11160: a7 fb ff 60 aghi %r15,-160
95 # or
96 # 100092: e3 f0 ff c8 ff 71 lay %r15,-56(%r15)
97 $re = qr/.*(?:lay|ag?hi).*\%r15,-([0-9]+)(?:\(\%r15\))?$/o;
98 } elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
99 # f0019d10: 9d e3 bf 90 save %sp, -112, %sp
100 $re = qr/.*save.*%sp, -([0-9]{1,8}), %sp/o;
101 } elsif ($arch =~ /^riscv(64)?$/) {
102 #ffffffff8036e868: c2010113 addi sp,sp,-992
103 $re = qr/.*addi.*sp,sp,-([0-9]{1,8})/o;
104 } elsif ($arch =~ /^loongarch(32|64)?$/) {
105 #9000000000224708: 02ff4063 addi.d $sp, $sp, -48(0xfd0)
106 $re = qr/.*addi\..*sp, .*sp, -([0-9]{1,8}).*/o;
107 } else {
108 print("wrong or unknown architecture \"$arch\"\n");
109 exit
110 }
111}
112
113#
114# To count stack usage of push {*, fp, ip, lr, pc} instruction in ARM,
115# if FRAME POINTER is enabled.
116# e.g. c01f0d48: e92ddff0 push {r4, r5, r6, r7, r8, r9, sl, fp, ip, lr, pc}
117#
118sub arm_push_handling {
119 my $regex = qr/.*push.*fp, ip, lr, pc}/o;
120 my $size = 0;
121 my $line_arg = shift;
122
123 if ($line_arg =~ m/$regex/) {
124 $size = $line_arg =~ tr/,//;
125 $size = ($size + 1) * 4;
126 }
127
128 return $size;
129}
130
131#
132# main()
133#
134my ($func, $file, $lastslash, $total_size, $addr, $intro);
135
136$total_size = 0;
137
138while (my $line = <STDIN>) {
139 if ($line =~ m/$funcre/) {
140 $func = $1;
141 next if $line !~ m/^($x*)/;
142 if ($total_size > $min_stack) {
143 push @stack, "$intro$total_size\n";
144 }
145 $addr = "0x$1";
146 $intro = "$addr $func [$file]:";
147 my $padlen = 56 - length($intro);
148 while ($padlen > 0) {
149 $intro .= ' ';
150 $padlen -= 8;
151 }
152
153 $total_size = 0;
154 }
155 elsif ($line =~ m/(.*):\s*file format/) {
156 $file = $1;
157 $file =~ s/\.ko//;
158 $lastslash = rindex($file, "/");
159 if ($lastslash != -1) {
160 $file = substr($file, $lastslash + 1);
161 }
162 }
163 elsif ($line =~ m/$re/) {
164 my $size = $1;
165 $size = hex($size) if ($size =~ /^0x/);
166
167 if ($size > 0xf0000000) {
168 $size = - $size;
169 $size += 0x80000000;
170 $size += 0x80000000;
171 }
172 next if ($size > 0x10000000);
173
174 $total_size += $size;
175 }
176 elsif (defined $dre && $line =~ m/$dre/) {
177 my $size = $1;
178
179 $size = hex($size) if ($size =~ /^0x/);
180 $total_size += $size;
181 }
182 elsif (defined $sub) {
183 my $size = &$sub($line);
184
185 $total_size += $size;
186 }
187}
188if ($total_size > $min_stack) {
189 push @stack, "$intro$total_size\n";
190}
191
192# Sort output by size (last field) and function name if size is the same
193sub sort_lines {
194 my ($a, $b) = @_;
195
196 my $num_a = $1 if $a =~ /:\t*(\d+)$/;
197 my $num_b = $1 if $b =~ /:\t*(\d+)$/;
198 my $func_a = $1 if $a =~ / (.*):/;
199 my $func_b = $1 if $b =~ / (.*):/;
200
201 if ($num_a != $num_b) {
202 return $num_b <=> $num_a;
203 } else {
204 return $func_a cmp $func_b;
205 }
206}
207
208print sort { sort_lines($a, $b) } @stack;
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3
4# Check the stack usage of functions
5#
6# Copyright Joern Engel <joern@lazybastard.org>
7# Inspired by Linus Torvalds
8# Original idea maybe from Keith Owens
9# s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
10# Mips port by Juan Quintela <quintela@mandrakesoft.com>
11# IA64 port via Andreas Dilger
12# Arm port by Holger Schurig
13# sh64 port by Paul Mundt
14# Random bits by Matt Mackall <mpm@selenic.com>
15# M68k port by Geert Uytterhoeven and Andreas Schwab
16# AArch64, PARISC ports by Kyle McMartin
17# sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk>
18# ppc64le port by Breno Leitao <leitao@debian.org>
19# riscv port by Wadim Mueller <wafgo01@gmail.com>
20#
21# Usage:
22# objdump -d vmlinux | scripts/checkstack.pl [arch]
23#
24# TODO : Port to all architectures (one regex per arch)
25
26use strict;
27
28# check for arch
29#
30# $re is used for two matches:
31# $& (whole re) matches the complete objdump line with the stack growth
32# $1 (first bracket) matches the size of the stack growth
33#
34# $dre is similar, but for dynamic stack redutions:
35# $& (whole re) matches the complete objdump line with the stack growth
36# $1 (first bracket) matches the dynamic amount of the stack growth
37#
38# $sub: subroutine for special handling to check stack usage.
39#
40# use anything else and feel the pain ;)
41my (@stack, $re, $dre, $sub, $x, $xs, $funcre, $min_stack);
42{
43 my $arch = shift;
44 if ($arch eq "") {
45 $arch = `uname -m`;
46 chomp($arch);
47 }
48
49 $min_stack = shift;
50 if ($min_stack eq "" || $min_stack !~ /^\d+$/) {
51 $min_stack = 100;
52 }
53
54 $x = "[0-9a-f]"; # hex character
55 $xs = "[0-9a-f ]"; # hex character or space
56 $funcre = qr/^$x* <(.*)>:$/;
57 if ($arch =~ '^(aarch|arm)64$') {
58 #ffffffc0006325cc: a9bb7bfd stp x29, x30, [sp, #-80]!
59 #a110: d11643ff sub sp, sp, #0x590
60 $re = qr/^.*stp.*sp, \#-([0-9]{1,8})\]\!/o;
61 $dre = qr/^.*sub.*sp, sp, #(0x$x{1,8})/o;
62 } elsif ($arch eq 'arm') {
63 #c0008ffc: e24dd064 sub sp, sp, #100 ; 0x64
64 $re = qr/.*sub.*sp, sp, #([0-9]{1,4})/o;
65 $sub = \&arm_push_handling;
66 } elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
67 #c0105234: 81 ec ac 05 00 00 sub $0x5ac,%esp
68 # or
69 # 2f60: 48 81 ec e8 05 00 00 sub $0x5e8,%rsp
70 $re = qr/^.*[as][du][db] \$(0x$x{1,8}),\%(e|r)sp$/o;
71 $dre = qr/^.*[as][du][db] (%.*),\%(e|r)sp$/o;
72 } elsif ($arch eq 'ia64') {
73 #e0000000044011fc: 01 0f fc 8c adds r12=-384,r12
74 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
75 } elsif ($arch eq 'm68k') {
76 # 2b6c: 4e56 fb70 linkw %fp,#-1168
77 # 1df770: defc ffe4 addaw #-28,%sp
78 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
79 } elsif ($arch eq 'mips64') {
80 #8800402c: 67bdfff0 daddiu sp,sp,-16
81 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
82 } elsif ($arch eq 'mips') {
83 #88003254: 27bdffe0 addiu sp,sp,-32
84 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
85 } elsif ($arch eq 'nios2') {
86 #25a8: defffb04 addi sp,sp,-20
87 $re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
88 } elsif ($arch eq 'openrisc') {
89 # c000043c: 9c 21 fe f0 l.addi r1,r1,-272
90 $re = qr/.*l\.addi.*r1,r1,-(([0-9]{2}|[3-9])[0-9]{2})/o;
91 } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
92 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
93 } elsif ($arch eq 'powerpc' || $arch =~ /^ppc(64)?(le)?$/ ) {
94 # powerpc : 94 21 ff 30 stwu r1,-208(r1)
95 # ppc64(le) : 81 ff 21 f8 stdu r1,-128(r1)
96 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
97 } elsif ($arch =~ /^s390x?$/) {
98 # 11160: a7 fb ff 60 aghi %r15,-160
99 # or
100 # 100092: e3 f0 ff c8 ff 71 lay %r15,-56(%r15)
101 $re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})
102 (?:\(\%r15\))?$/ox;
103 } elsif ($arch =~ /^sh64$/) {
104 #XXX: we only check for the immediate case presently,
105 # though we will want to check for the movi/sub
106 # pair for larger users. -- PFM.
107 #a00048e0: d4fc40f0 addi.l r15,-240,r15
108 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
109 } elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
110 # f0019d10: 9d e3 bf 90 save %sp, -112, %sp
111 $re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
112 } elsif ($arch =~ /^riscv(64)?$/) {
113 #ffffffff8036e868: c2010113 addi sp,sp,-992
114 $re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
115 } else {
116 print("wrong or unknown architecture \"$arch\"\n");
117 exit
118 }
119}
120
121#
122# To count stack usage of push {*, fp, ip, lr, pc} instruction in ARM,
123# if FRAME POINTER is enabled.
124# e.g. c01f0d48: e92ddff0 push {r4, r5, r6, r7, r8, r9, sl, fp, ip, lr, pc}
125#
126sub arm_push_handling {
127 my $regex = qr/.*push.*fp, ip, lr, pc}/o;
128 my $size = 0;
129 my $line_arg = shift;
130
131 if ($line_arg =~ m/$regex/) {
132 $size = $line_arg =~ tr/,//;
133 $size = ($size + 1) * 4;
134 }
135
136 return $size;
137}
138
139#
140# main()
141#
142my ($func, $file, $lastslash, $total_size, $addr, $intro);
143
144$total_size = 0;
145
146while (my $line = <STDIN>) {
147 if ($line =~ m/$funcre/) {
148 $func = $1;
149 next if $line !~ m/^($xs*)/;
150 if ($total_size > $min_stack) {
151 push @stack, "$intro$total_size\n";
152 }
153
154 $addr = $1;
155 $addr =~ s/ /0/g;
156 $addr = "0x$addr";
157
158 $intro = "$addr $func [$file]:";
159 my $padlen = 56 - length($intro);
160 while ($padlen > 0) {
161 $intro .= ' ';
162 $padlen -= 8;
163 }
164
165 $total_size = 0;
166 }
167 elsif ($line =~ m/(.*):\s*file format/) {
168 $file = $1;
169 $file =~ s/\.ko//;
170 $lastslash = rindex($file, "/");
171 if ($lastslash != -1) {
172 $file = substr($file, $lastslash + 1);
173 }
174 }
175 elsif ($line =~ m/$re/) {
176 my $size = $1;
177 $size = hex($size) if ($size =~ /^0x/);
178
179 if ($size > 0xf0000000) {
180 $size = - $size;
181 $size += 0x80000000;
182 $size += 0x80000000;
183 }
184 next if ($size > 0x10000000);
185
186 $total_size += $size;
187 }
188 elsif (defined $dre && $line =~ m/$dre/) {
189 my $size = $1;
190
191 $size = hex($size) if ($size =~ /^0x/);
192 $total_size += $size;
193 }
194 elsif (defined $sub) {
195 my $size = &$sub($line);
196
197 $total_size += $size;
198 }
199}
200if ($total_size > $min_stack) {
201 push @stack, "$intro$total_size\n";
202}
203
204# Sort output by size (last field)
205print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack;