Loading...
1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * This is the infamous ld script for the 64 bits vdso
4 * library
5 */
6
7#include <asm/page.h>
8#include <asm/vdso.h>
9
10OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
11OUTPUT_ARCH(s390:64-bit)
12ENTRY(_start)
13
14SECTIONS
15{
16 PROVIDE(_vdso_data = . - __VVAR_PAGES * PAGE_SIZE);
17#ifdef CONFIG_TIME_NS
18 PROVIDE(_timens_data = _vdso_data + PAGE_SIZE);
19#endif
20 . = VDSO_LBASE + SIZEOF_HEADERS;
21
22 .hash : { *(.hash) } :text
23 .gnu.hash : { *(.gnu.hash) }
24 .dynsym : { *(.dynsym) }
25 .dynstr : { *(.dynstr) }
26 .gnu.version : { *(.gnu.version) }
27 .gnu.version_d : { *(.gnu.version_d) }
28 .gnu.version_r : { *(.gnu.version_r) }
29
30 .note : { *(.note.*) } :text :note
31
32 . = ALIGN(16);
33 .text : {
34 *(.text .stub .text.* .gnu.linkonce.t.*)
35 } :text
36 PROVIDE(__etext = .);
37 PROVIDE(_etext = .);
38 PROVIDE(etext = .);
39
40 /*
41 * Other stuff is appended to the text segment:
42 */
43 .rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
44 .rodata1 : { *(.rodata1) }
45
46 .dynamic : { *(.dynamic) } :text :dynamic
47
48 .eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr
49 .eh_frame : { KEEP (*(.eh_frame)) } :text
50 .gcc_except_table : { *(.gcc_except_table .gcc_except_table.*) }
51
52 .rela.dyn ALIGN(8) : { *(.rela.dyn) }
53 .got ALIGN(8) : { *(.got .toc) }
54 .got.plt ALIGN(8) : { *(.got.plt) }
55
56 _end = .;
57 PROVIDE(end = .);
58
59 /*
60 * Stabs debugging sections are here too.
61 */
62 .stab 0 : { *(.stab) }
63 .stabstr 0 : { *(.stabstr) }
64 .stab.excl 0 : { *(.stab.excl) }
65 .stab.exclstr 0 : { *(.stab.exclstr) }
66 .stab.index 0 : { *(.stab.index) }
67 .stab.indexstr 0 : { *(.stab.indexstr) }
68 .comment 0 : { *(.comment) }
69
70 /*
71 * DWARF debug sections.
72 * Symbols in the DWARF debugging sections are relative to the
73 * beginning of the section so we begin them at 0.
74 */
75 /* DWARF 1 */
76 .debug 0 : { *(.debug) }
77 .line 0 : { *(.line) }
78 /* GNU DWARF 1 extensions */
79 .debug_srcinfo 0 : { *(.debug_srcinfo) }
80 .debug_sfnames 0 : { *(.debug_sfnames) }
81 /* DWARF 1.1 and DWARF 2 */
82 .debug_aranges 0 : { *(.debug_aranges) }
83 .debug_pubnames 0 : { *(.debug_pubnames) }
84 /* DWARF 2 */
85 .debug_info 0 : { *(.debug_info .gnu.linkonce.wi.*) }
86 .debug_abbrev 0 : { *(.debug_abbrev) }
87 .debug_line 0 : { *(.debug_line) }
88 .debug_frame 0 : { *(.debug_frame) }
89 .debug_str 0 : { *(.debug_str) }
90 .debug_loc 0 : { *(.debug_loc) }
91 .debug_macinfo 0 : { *(.debug_macinfo) }
92 /* SGI/MIPS DWARF 2 extensions */
93 .debug_weaknames 0 : { *(.debug_weaknames) }
94 .debug_funcnames 0 : { *(.debug_funcnames) }
95 .debug_typenames 0 : { *(.debug_typenames) }
96 .debug_varnames 0 : { *(.debug_varnames) }
97 /* DWARF 3 */
98 .debug_pubtypes 0 : { *(.debug_pubtypes) }
99 .debug_ranges 0 : { *(.debug_ranges) }
100 .gnu.attributes 0 : { KEEP (*(.gnu.attributes)) }
101
102 /DISCARD/ : {
103 *(.note.GNU-stack)
104 *(.branch_lt)
105 *(.data .data.* .gnu.linkonce.d.* .sdata*)
106 *(.bss .sbss .dynbss .dynsbss)
107 }
108}
109
110/*
111 * Very old versions of ld do not recognize this name token; use the constant.
112 */
113#define PT_GNU_EH_FRAME 0x6474e550
114
115/*
116 * We must supply the ELF program headers explicitly to get just one
117 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
118 */
119PHDRS
120{
121 text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
122 dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
123 note PT_NOTE FLAGS(4); /* PF_R */
124 eh_frame_hdr PT_GNU_EH_FRAME;
125}
126
127/*
128 * This controls what symbols we export from the DSO.
129 */
130VERSION
131{
132 VDSO_VERSION_STRING {
133 global:
134 /*
135 * Has to be there for the kernel to find
136 */
137 __kernel_gettimeofday;
138 __kernel_clock_gettime;
139 __kernel_clock_getres;
140 __kernel_getcpu;
141 __kernel_restart_syscall;
142 __kernel_rt_sigreturn;
143 __kernel_sigreturn;
144 local: *;
145 };
146}
1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * This is the infamous ld script for the 64 bits vdso
4 * library
5 */
6
7#include <asm/page.h>
8#include <asm/vdso.h>
9
10OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
11OUTPUT_ARCH(s390:64-bit)
12ENTRY(_start)
13
14SECTIONS
15{
16 . = VDSO64_LBASE + SIZEOF_HEADERS;
17
18 .hash : { *(.hash) } :text
19 .gnu.hash : { *(.gnu.hash) }
20 .dynsym : { *(.dynsym) }
21 .dynstr : { *(.dynstr) }
22 .gnu.version : { *(.gnu.version) }
23 .gnu.version_d : { *(.gnu.version_d) }
24 .gnu.version_r : { *(.gnu.version_r) }
25
26 .note : { *(.note.*) } :text :note
27
28 . = ALIGN(16);
29 .text : {
30 *(.text .stub .text.* .gnu.linkonce.t.*)
31 } :text
32 PROVIDE(__etext = .);
33 PROVIDE(_etext = .);
34 PROVIDE(etext = .);
35
36 /*
37 * Other stuff is appended to the text segment:
38 */
39 .rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
40 .rodata1 : { *(.rodata1) }
41
42 .dynamic : { *(.dynamic) } :text :dynamic
43
44 .eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr
45 .eh_frame : { KEEP (*(.eh_frame)) } :text
46 .gcc_except_table : { *(.gcc_except_table .gcc_except_table.*) }
47
48 .rela.dyn ALIGN(8) : { *(.rela.dyn) }
49 .got ALIGN(8) : { *(.got .toc) }
50
51 _end = .;
52 PROVIDE(end = .);
53
54 /*
55 * Stabs debugging sections are here too.
56 */
57 .stab 0 : { *(.stab) }
58 .stabstr 0 : { *(.stabstr) }
59 .stab.excl 0 : { *(.stab.excl) }
60 .stab.exclstr 0 : { *(.stab.exclstr) }
61 .stab.index 0 : { *(.stab.index) }
62 .stab.indexstr 0 : { *(.stab.indexstr) }
63 .comment 0 : { *(.comment) }
64
65 /*
66 * DWARF debug sections.
67 * Symbols in the DWARF debugging sections are relative to the
68 * beginning of the section so we begin them at 0.
69 */
70 /* DWARF 1 */
71 .debug 0 : { *(.debug) }
72 .line 0 : { *(.line) }
73 /* GNU DWARF 1 extensions */
74 .debug_srcinfo 0 : { *(.debug_srcinfo) }
75 .debug_sfnames 0 : { *(.debug_sfnames) }
76 /* DWARF 1.1 and DWARF 2 */
77 .debug_aranges 0 : { *(.debug_aranges) }
78 .debug_pubnames 0 : { *(.debug_pubnames) }
79 /* DWARF 2 */
80 .debug_info 0 : { *(.debug_info .gnu.linkonce.wi.*) }
81 .debug_abbrev 0 : { *(.debug_abbrev) }
82 .debug_line 0 : { *(.debug_line) }
83 .debug_frame 0 : { *(.debug_frame) }
84 .debug_str 0 : { *(.debug_str) }
85 .debug_loc 0 : { *(.debug_loc) }
86 .debug_macinfo 0 : { *(.debug_macinfo) }
87 /* SGI/MIPS DWARF 2 extensions */
88 .debug_weaknames 0 : { *(.debug_weaknames) }
89 .debug_funcnames 0 : { *(.debug_funcnames) }
90 .debug_typenames 0 : { *(.debug_typenames) }
91 .debug_varnames 0 : { *(.debug_varnames) }
92 /* DWARF 3 */
93 .debug_pubtypes 0 : { *(.debug_pubtypes) }
94 .debug_ranges 0 : { *(.debug_ranges) }
95 .gnu.attributes 0 : { KEEP (*(.gnu.attributes)) }
96
97 . = ALIGN(PAGE_SIZE);
98 PROVIDE(_vdso_data = .);
99
100 /DISCARD/ : {
101 *(.note.GNU-stack)
102 *(.branch_lt)
103 *(.data .data.* .gnu.linkonce.d.* .sdata*)
104 *(.bss .sbss .dynbss .dynsbss)
105 }
106}
107
108/*
109 * Very old versions of ld do not recognize this name token; use the constant.
110 */
111#define PT_GNU_EH_FRAME 0x6474e550
112
113/*
114 * We must supply the ELF program headers explicitly to get just one
115 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
116 */
117PHDRS
118{
119 text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
120 dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
121 note PT_NOTE FLAGS(4); /* PF_R */
122 eh_frame_hdr PT_GNU_EH_FRAME;
123}
124
125/*
126 * This controls what symbols we export from the DSO.
127 */
128VERSION
129{
130 VDSO_VERSION_STRING {
131 global:
132 /*
133 * Has to be there for the kernel to find
134 */
135 __kernel_gettimeofday;
136 __kernel_clock_gettime;
137 __kernel_clock_getres;
138 __kernel_getcpu;
139
140 local: *;
141 };
142}