Loading...
1
2%option reentrant
3%option bison-bridge
4%option prefix="parse_events_"
5%option stack
6%option bison-locations
7%option yylineno
8%option reject
9
10%{
11#include <errno.h>
12#include <sys/types.h>
13#include <sys/stat.h>
14#include <unistd.h>
15#include "parse-events.h"
16#include "parse-events-bison.h"
17#include "evsel.h"
18
19char *parse_events_get_text(yyscan_t yyscanner);
20YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
21
22static int __value(YYSTYPE *yylval, char *str, int base, int token)
23{
24 u64 num;
25
26 errno = 0;
27 num = strtoull(str, NULL, base);
28 if (errno)
29 return PE_ERROR;
30
31 yylval->num = num;
32 return token;
33}
34
35static int value(yyscan_t scanner, int base)
36{
37 YYSTYPE *yylval = parse_events_get_lval(scanner);
38 char *text = parse_events_get_text(scanner);
39
40 return __value(yylval, text, base, PE_VALUE);
41}
42
43static int str(yyscan_t scanner, int token)
44{
45 YYSTYPE *yylval = parse_events_get_lval(scanner);
46 char *text = parse_events_get_text(scanner);
47
48 if (text[0] != '\'') {
49 yylval->str = strdup(text);
50 } else {
51 /*
52 * If a text tag specified on the command line
53 * contains opening single quite ' then it is
54 * expected that the tag ends with single quote
55 * as well, like this:
56 * name=\'CPU_CLK_UNHALTED.THREAD:cmask=1\'
57 * quotes need to be escaped to bypass shell
58 * processing.
59 */
60 yylval->str = strndup(&text[1], strlen(text) - 2);
61 }
62
63 return token;
64}
65
66static int lc_str(yyscan_t scanner, const struct parse_events_state *state)
67{
68 return str(scanner, state->match_legacy_cache_terms ? PE_LEGACY_CACHE : PE_NAME);
69}
70
71/*
72 * This function is called when the parser gets two kind of input:
73 *
74 * @cfg1 or @cfg2=config
75 *
76 * The leading '@' is stripped off before 'cfg1' and 'cfg2=config' are given to
77 * bison. In the latter case it is necessary to keep the string intact so that
78 * the PMU kernel driver can determine what configurable is associated to
79 * 'config'.
80 */
81static int drv_str(yyscan_t scanner, int token)
82{
83 YYSTYPE *yylval = parse_events_get_lval(scanner);
84 char *text = parse_events_get_text(scanner);
85
86 /* Strip off the '@' */
87 yylval->str = strdup(text + 1);
88 return token;
89}
90
91#define REWIND(__alloc) \
92do { \
93 YYSTYPE *__yylval = parse_events_get_lval(yyscanner); \
94 char *text = parse_events_get_text(yyscanner); \
95 \
96 if (__alloc) \
97 __yylval->str = strdup(text); \
98 \
99 yycolumn -= strlen(text); \
100 yyless(0); \
101} while (0)
102
103static int sym(yyscan_t scanner, int type, int config)
104{
105 YYSTYPE *yylval = parse_events_get_lval(scanner);
106
107 yylval->num = (type << 16) + config;
108 return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
109}
110
111static int tool(yyscan_t scanner, enum perf_tool_event event)
112{
113 YYSTYPE *yylval = parse_events_get_lval(scanner);
114
115 yylval->num = event;
116 return PE_VALUE_SYM_TOOL;
117}
118
119static int term(yyscan_t scanner, enum parse_events__term_type type)
120{
121 YYSTYPE *yylval = parse_events_get_lval(scanner);
122
123 yylval->term_type = type;
124 return PE_TERM;
125}
126
127static int hw_term(yyscan_t scanner, int config)
128{
129 YYSTYPE *yylval = parse_events_get_lval(scanner);
130 char *text = parse_events_get_text(scanner);
131
132 yylval->hardware_term.str = strdup(text);
133 yylval->hardware_term.num = PERF_TYPE_HARDWARE + config;
134 return PE_TERM_HW;
135}
136
137#define YY_USER_ACTION \
138do { \
139 yylloc->last_column = yylloc->first_column; \
140 yylloc->first_column = yycolumn; \
141 yycolumn += yyleng; \
142} while (0);
143
144#define USER_REJECT \
145 yycolumn -= yyleng; \
146 REJECT
147
148%}
149
150%x mem
151%s config
152%x event
153
154group [^,{}/]*[{][^}]*[}][^,{}/]*
155event_pmu [^,{}/]+[/][^/]*[/][^,{}/]*
156event [^,{}/]+
157
158num_dec [0-9]+
159num_hex 0x[a-fA-F0-9]{1,16}
160num_raw_hex [a-fA-F0-9]{1,16}
161name [a-zA-Z_*?\[\]][a-zA-Z0-9_*?.\[\]!\-]*
162name_tag [\'][a-zA-Z_*?\[\]][a-zA-Z0-9_*?\-,\.\[\]:=]*[\']
163name_minus [a-zA-Z_*?][a-zA-Z0-9\-_*?.:]*
164drv_cfg_term [a-zA-Z0-9_\.]+(=[a-zA-Z0-9_*?\.:]+)?
165/*
166 * If you add a modifier you need to update check_modifier().
167 * Also, the letters in modifier_event must not be in modifier_bp.
168 */
169modifier_event [ukhpPGHSDIWeb]+
170modifier_bp [rwx]{1,3}
171lc_type (L1-dcache|l1-d|l1d|L1-data|L1-icache|l1-i|l1i|L1-instruction|LLC|L2|dTLB|d-tlb|Data-TLB|iTLB|i-tlb|Instruction-TLB|branch|branches|bpu|btb|bpc|node)
172lc_op_result (load|loads|read|store|stores|write|prefetch|prefetches|speculative-read|speculative-load|refs|Reference|ops|access|misses|miss)
173digit [0-9]
174non_digit [^0-9]
175
176%%
177
178%{
179 struct parse_events_state *_parse_state = parse_events_get_extra(yyscanner);
180 {
181 int start_token = _parse_state->stoken;
182
183 if (start_token == PE_START_TERMS)
184 BEGIN(config);
185 else if (start_token == PE_START_EVENTS)
186 BEGIN(event);
187
188 if (start_token) {
189 _parse_state->stoken = 0;
190 /*
191 * The flex parser does not init locations variable
192 * via the scan_string interface, so we need do the
193 * init in here.
194 */
195 yycolumn = 0;
196 return start_token;
197 }
198 }
199%}
200
201<event>{
202
203{group} {
204 BEGIN(INITIAL);
205 REWIND(0);
206 }
207
208{event_pmu} |
209{event} {
210 BEGIN(INITIAL);
211 REWIND(1);
212 return PE_EVENT_NAME;
213 }
214
215<<EOF>> {
216 BEGIN(INITIAL);
217 REWIND(0);
218 }
219, {
220 return ',';
221 }
222}
223
224<config>{
225 /*
226 * Please update config_term_names when new static term is added.
227 */
228config { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
229config1 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
230config2 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
231config3 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG3); }
232name { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
233period { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
234freq { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
235branch_type { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
236time { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
237call-graph { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
238stack-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
239max-stack { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_MAX_STACK); }
240nr { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_MAX_EVENTS); }
241inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_INHERIT); }
242no-inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOINHERIT); }
243overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_OVERWRITE); }
244no-overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOOVERWRITE); }
245percore { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_PERCORE); }
246aux-output { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_AUX_OUTPUT); }
247aux-sample-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_AUX_SAMPLE_SIZE); }
248metric-id { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_METRIC_ID); }
249cpu-cycles|cycles { return hw_term(yyscanner, PERF_COUNT_HW_CPU_CYCLES); }
250stalled-cycles-frontend|idle-cycles-frontend { return hw_term(yyscanner, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
251stalled-cycles-backend|idle-cycles-backend { return hw_term(yyscanner, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
252instructions { return hw_term(yyscanner, PERF_COUNT_HW_INSTRUCTIONS); }
253cache-references { return hw_term(yyscanner, PERF_COUNT_HW_CACHE_REFERENCES); }
254cache-misses { return hw_term(yyscanner, PERF_COUNT_HW_CACHE_MISSES); }
255branch-instructions|branches { return hw_term(yyscanner, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
256branch-misses { return hw_term(yyscanner, PERF_COUNT_HW_BRANCH_MISSES); }
257bus-cycles { return hw_term(yyscanner, PERF_COUNT_HW_BUS_CYCLES); }
258ref-cycles { return hw_term(yyscanner, PERF_COUNT_HW_REF_CPU_CYCLES); }
259r{num_raw_hex} { return str(yyscanner, PE_RAW); }
260r0x{num_raw_hex} { return str(yyscanner, PE_RAW); }
261, { return ','; }
262"/" { BEGIN(INITIAL); return '/'; }
263{lc_type} { return lc_str(yyscanner, _parse_state); }
264{lc_type}-{lc_op_result} { return lc_str(yyscanner, _parse_state); }
265{lc_type}-{lc_op_result}-{lc_op_result} { return lc_str(yyscanner, _parse_state); }
266{name_minus} { return str(yyscanner, PE_NAME); }
267@{drv_cfg_term} { return drv_str(yyscanner, PE_DRV_CFG_TERM); }
268}
269
270<mem>{
271{modifier_bp} { return str(yyscanner, PE_MODIFIER_BP); }
272 /*
273 * The colon before memory access modifiers can get mixed up with the
274 * colon before event modifiers. Fortunately none of the option letters
275 * are the same, so trailing context can be used disambiguate the two
276 * cases.
277 */
278":"/{modifier_bp} { return PE_BP_COLON; }
279 /*
280 * The slash before memory length can get mixed up with the slash before
281 * config terms. Fortunately config terms do not start with a numeric
282 * digit, so trailing context can be used disambiguate the two cases.
283 */
284"/"/{digit} { return PE_BP_SLASH; }
285"/"/{non_digit} { BEGIN(config); return '/'; }
286{num_dec} { return value(yyscanner, 10); }
287{num_hex} { return value(yyscanner, 16); }
288 /*
289 * We need to separate 'mem:' scanner part, in order to get specific
290 * modifier bits parsed out. Otherwise we would need to handle PE_NAME
291 * and we'd need to parse it manually. During the escape from <mem>
292 * state we need to put the escaping char back, so we dont miss it.
293 */
294. { unput(*yytext); BEGIN(INITIAL); }
295 /*
296 * We destroy the scanner after reaching EOF,
297 * but anyway just to be sure get back to INIT state.
298 */
299<<EOF>> { BEGIN(INITIAL); }
300}
301
302cpu-cycles|cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
303stalled-cycles-frontend|idle-cycles-frontend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
304stalled-cycles-backend|idle-cycles-backend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
305instructions { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
306cache-references { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
307cache-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
308branch-instructions|branches { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
309branch-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
310bus-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
311ref-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
312cpu-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
313task-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
314page-faults|faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
315minor-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
316major-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
317context-switches|cs { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
318cpu-migrations|migrations { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
319alignment-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
320emulation-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
321dummy { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
322duration_time { return tool(yyscanner, PERF_TOOL_DURATION_TIME); }
323user_time { return tool(yyscanner, PERF_TOOL_USER_TIME); }
324system_time { return tool(yyscanner, PERF_TOOL_SYSTEM_TIME); }
325bpf-output { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_BPF_OUTPUT); }
326cgroup-switches { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CGROUP_SWITCHES); }
327
328{lc_type} { return str(yyscanner, PE_LEGACY_CACHE); }
329{lc_type}-{lc_op_result} { return str(yyscanner, PE_LEGACY_CACHE); }
330{lc_type}-{lc_op_result}-{lc_op_result} { return str(yyscanner, PE_LEGACY_CACHE); }
331mem: { BEGIN(mem); return PE_PREFIX_MEM; }
332r{num_raw_hex} { return str(yyscanner, PE_RAW); }
333{num_dec} { return value(yyscanner, 10); }
334{num_hex} { return value(yyscanner, 16); }
335
336{modifier_event} { return str(yyscanner, PE_MODIFIER_EVENT); }
337{name} { return str(yyscanner, PE_NAME); }
338{name_tag} { return str(yyscanner, PE_NAME); }
339"/" { BEGIN(config); return '/'; }
340, { BEGIN(event); return ','; }
341: { return ':'; }
342"{" { BEGIN(event); return '{'; }
343"}" { return '}'; }
344= { return '='; }
345\n { }
346. { }
347
348%%
349
350int parse_events_wrap(void *scanner __maybe_unused)
351{
352 return 1;
353}
1
2%option reentrant
3%option bison-bridge
4%option prefix="parse_events_"
5%option stack
6%option bison-locations
7%option yylineno
8
9%{
10#include <errno.h>
11#include "../perf.h"
12#include "parse-events.h"
13#include "parse-events-bison.h"
14
15char *parse_events_get_text(yyscan_t yyscanner);
16YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
17
18static int __value(YYSTYPE *yylval, char *str, int base, int token)
19{
20 u64 num;
21
22 errno = 0;
23 num = strtoull(str, NULL, base);
24 if (errno)
25 return PE_ERROR;
26
27 yylval->num = num;
28 return token;
29}
30
31static int value(yyscan_t scanner, int base)
32{
33 YYSTYPE *yylval = parse_events_get_lval(scanner);
34 char *text = parse_events_get_text(scanner);
35
36 return __value(yylval, text, base, PE_VALUE);
37}
38
39static int raw(yyscan_t scanner)
40{
41 YYSTYPE *yylval = parse_events_get_lval(scanner);
42 char *text = parse_events_get_text(scanner);
43
44 return __value(yylval, text + 1, 16, PE_RAW);
45}
46
47static int str(yyscan_t scanner, int token)
48{
49 YYSTYPE *yylval = parse_events_get_lval(scanner);
50 char *text = parse_events_get_text(scanner);
51
52 yylval->str = strdup(text);
53 return token;
54}
55
56#define REWIND(__alloc) \
57do { \
58 YYSTYPE *__yylval = parse_events_get_lval(yyscanner); \
59 char *text = parse_events_get_text(yyscanner); \
60 \
61 if (__alloc) \
62 __yylval->str = strdup(text); \
63 \
64 yycolumn -= strlen(text); \
65 yyless(0); \
66} while (0)
67
68static int pmu_str_check(yyscan_t scanner)
69{
70 YYSTYPE *yylval = parse_events_get_lval(scanner);
71 char *text = parse_events_get_text(scanner);
72
73 yylval->str = strdup(text);
74 switch (perf_pmu__parse_check(text)) {
75 case PMU_EVENT_SYMBOL_PREFIX:
76 return PE_PMU_EVENT_PRE;
77 case PMU_EVENT_SYMBOL_SUFFIX:
78 return PE_PMU_EVENT_SUF;
79 case PMU_EVENT_SYMBOL:
80 return PE_KERNEL_PMU_EVENT;
81 default:
82 return PE_NAME;
83 }
84}
85
86static int sym(yyscan_t scanner, int type, int config)
87{
88 YYSTYPE *yylval = parse_events_get_lval(scanner);
89
90 yylval->num = (type << 16) + config;
91 return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
92}
93
94static int term(yyscan_t scanner, int type)
95{
96 YYSTYPE *yylval = parse_events_get_lval(scanner);
97
98 yylval->num = type;
99 return PE_TERM;
100}
101
102#define YY_USER_ACTION \
103do { \
104 yylloc->last_column = yylloc->first_column; \
105 yylloc->first_column = yycolumn; \
106 yycolumn += yyleng; \
107} while (0);
108
109%}
110
111%x mem
112%s config
113%x event
114%x array
115
116group [^,{}/]*[{][^}]*[}][^,{}/]*
117event_pmu [^,{}/]+[/][^/]*[/][^,{}/]*
118event [^,{}/]+
119bpf_object .*\.(o|bpf)
120bpf_source .*\.c
121
122num_dec [0-9]+
123num_hex 0x[a-fA-F0-9]+
124num_raw_hex [a-fA-F0-9]+
125name [a-zA-Z_*?][a-zA-Z0-9_*?.]*
126name_minus [a-zA-Z_*?][a-zA-Z0-9\-_*?.:]*
127/* If you add a modifier you need to update check_modifier() */
128modifier_event [ukhpPGHSDI]+
129modifier_bp [rwx]{1,3}
130
131%%
132
133%{
134 {
135 int start_token;
136
137 start_token = parse_events_get_extra(yyscanner);
138
139 if (start_token == PE_START_TERMS)
140 BEGIN(config);
141 else if (start_token == PE_START_EVENTS)
142 BEGIN(event);
143
144 if (start_token) {
145 parse_events_set_extra(NULL, yyscanner);
146 /*
147 * The flex parser does not init locations variable
148 * via the scan_string interface, so we need do the
149 * init in here.
150 */
151 yycolumn = 0;
152 return start_token;
153 }
154 }
155%}
156
157<event>{
158
159{group} {
160 BEGIN(INITIAL);
161 REWIND(0);
162 }
163
164{event_pmu} |
165{bpf_object} |
166{bpf_source} |
167{event} {
168 BEGIN(INITIAL);
169 REWIND(1);
170 return PE_EVENT_NAME;
171 }
172
173<<EOF>> {
174 BEGIN(INITIAL);
175 REWIND(0);
176 }
177
178}
179
180<array>{
181"]" { BEGIN(config); return ']'; }
182{num_dec} { return value(yyscanner, 10); }
183{num_hex} { return value(yyscanner, 16); }
184, { return ','; }
185"\.\.\." { return PE_ARRAY_RANGE; }
186}
187
188<config>{
189 /*
190 * Please update config_term_names when new static term is added.
191 */
192config { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
193config1 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
194config2 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
195name { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
196period { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
197freq { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
198branch_type { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
199time { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
200call-graph { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
201stack-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
202inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_INHERIT); }
203no-inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOINHERIT); }
204, { return ','; }
205"/" { BEGIN(INITIAL); return '/'; }
206{name_minus} { return str(yyscanner, PE_NAME); }
207\[all\] { return PE_ARRAY_ALL; }
208"[" { BEGIN(array); return '['; }
209}
210
211<mem>{
212{modifier_bp} { return str(yyscanner, PE_MODIFIER_BP); }
213: { return ':'; }
214"/" { return '/'; }
215{num_dec} { return value(yyscanner, 10); }
216{num_hex} { return value(yyscanner, 16); }
217 /*
218 * We need to separate 'mem:' scanner part, in order to get specific
219 * modifier bits parsed out. Otherwise we would need to handle PE_NAME
220 * and we'd need to parse it manually. During the escape from <mem>
221 * state we need to put the escaping char back, so we dont miss it.
222 */
223. { unput(*yytext); BEGIN(INITIAL); }
224 /*
225 * We destroy the scanner after reaching EOF,
226 * but anyway just to be sure get back to INIT state.
227 */
228<<EOF>> { BEGIN(INITIAL); }
229}
230
231cpu-cycles|cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
232stalled-cycles-frontend|idle-cycles-frontend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
233stalled-cycles-backend|idle-cycles-backend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
234instructions { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
235cache-references { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
236cache-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
237branch-instructions|branches { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
238branch-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
239bus-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
240ref-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
241cpu-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
242task-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
243page-faults|faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
244minor-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
245major-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
246context-switches|cs { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
247cpu-migrations|migrations { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
248alignment-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
249emulation-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
250dummy { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
251bpf-output { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_BPF_OUTPUT); }
252
253 /*
254 * We have to handle the kernel PMU event cycles-ct/cycles-t/mem-loads/mem-stores separately.
255 * Because the prefix cycles is mixed up with cpu-cycles.
256 * loads and stores are mixed up with cache event
257 */
258cycles-ct { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
259cycles-t { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
260mem-loads { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
261mem-stores { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
262
263L1-dcache|l1-d|l1d|L1-data |
264L1-icache|l1-i|l1i|L1-instruction |
265LLC|L2 |
266dTLB|d-tlb|Data-TLB |
267iTLB|i-tlb|Instruction-TLB |
268branch|branches|bpu|btb|bpc |
269node { return str(yyscanner, PE_NAME_CACHE_TYPE); }
270
271load|loads|read |
272store|stores|write |
273prefetch|prefetches |
274speculative-read|speculative-load |
275refs|Reference|ops|access |
276misses|miss { return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }
277
278mem: { BEGIN(mem); return PE_PREFIX_MEM; }
279r{num_raw_hex} { return raw(yyscanner); }
280{num_dec} { return value(yyscanner, 10); }
281{num_hex} { return value(yyscanner, 16); }
282
283{modifier_event} { return str(yyscanner, PE_MODIFIER_EVENT); }
284{bpf_object} { return str(yyscanner, PE_BPF_OBJECT); }
285{bpf_source} { return str(yyscanner, PE_BPF_SOURCE); }
286{name} { return pmu_str_check(yyscanner); }
287"/" { BEGIN(config); return '/'; }
288- { return '-'; }
289, { BEGIN(event); return ','; }
290: { return ':'; }
291"{" { BEGIN(event); return '{'; }
292"}" { return '}'; }
293= { return '='; }
294\n { }
295. { }
296
297%%
298
299int parse_events_wrap(void *scanner __maybe_unused)
300{
301 return 1;
302}