Loading...
1/* SPDX-License-Identifier: GPL-2.0 */
2/* NGmemcpy.S: Niagara optimized memcpy.
3 *
4 * Copyright (C) 2006, 2007 David S. Miller (davem@davemloft.net)
5 */
6
7#ifdef __KERNEL__
8#include <linux/linkage.h>
9#include <asm/asi.h>
10#include <asm/thread_info.h>
11#define GLOBAL_SPARE %g7
12#define RESTORE_ASI(TMP) \
13 wr %g0, ASI_AIUS, %asi
14#else
15#define GLOBAL_SPARE %g5
16#define RESTORE_ASI(TMP) \
17 wr %g0, ASI_PNF, %asi
18#endif
19
20#ifdef __sparc_v9__
21#define SAVE_AMOUNT 128
22#else
23#define SAVE_AMOUNT 64
24#endif
25
26#ifndef STORE_ASI
27#define STORE_ASI ASI_BLK_INIT_QUAD_LDD_P
28#endif
29
30#ifndef EX_LD
31#define EX_LD(x,y) x
32#endif
33
34#ifndef EX_ST
35#define EX_ST(x,y) x
36#endif
37
38#ifndef LOAD
39#ifndef MEMCPY_DEBUG
40#define LOAD(type,addr,dest) type [addr], dest
41#else
42#define LOAD(type,addr,dest) type##a [addr] 0x80, dest
43#endif
44#endif
45
46#ifndef LOAD_TWIN
47#define LOAD_TWIN(addr_reg,dest0,dest1) \
48 ldda [addr_reg] ASI_BLK_INIT_QUAD_LDD_P, dest0
49#endif
50
51#ifndef STORE
52#define STORE(type,src,addr) type src, [addr]
53#endif
54
55#ifndef STORE_INIT
56#ifndef SIMULATE_NIAGARA_ON_NON_NIAGARA
57#define STORE_INIT(src,addr) stxa src, [addr] %asi
58#else
59#define STORE_INIT(src,addr) stx src, [addr + 0x00]
60#endif
61#endif
62
63#ifndef FUNC_NAME
64#define FUNC_NAME NGmemcpy
65#endif
66
67#ifndef PREAMBLE
68#define PREAMBLE
69#endif
70
71#ifndef XCC
72#define XCC xcc
73#endif
74
75 .register %g2,#scratch
76 .register %g3,#scratch
77
78 .text
79#ifndef EX_RETVAL
80#define EX_RETVAL(x) x
81__restore_asi:
82 ret
83 wr %g0, ASI_AIUS, %asi
84 restore
85ENTRY(NG_ret_i2_plus_i4_plus_1)
86 ba,pt %xcc, __restore_asi
87 add %i2, %i5, %i0
88ENDPROC(NG_ret_i2_plus_i4_plus_1)
89ENTRY(NG_ret_i2_plus_g1)
90 ba,pt %xcc, __restore_asi
91 add %i2, %g1, %i0
92ENDPROC(NG_ret_i2_plus_g1)
93ENTRY(NG_ret_i2_plus_g1_minus_8)
94 sub %g1, 8, %g1
95 ba,pt %xcc, __restore_asi
96 add %i2, %g1, %i0
97ENDPROC(NG_ret_i2_plus_g1_minus_8)
98ENTRY(NG_ret_i2_plus_g1_minus_16)
99 sub %g1, 16, %g1
100 ba,pt %xcc, __restore_asi
101 add %i2, %g1, %i0
102ENDPROC(NG_ret_i2_plus_g1_minus_16)
103ENTRY(NG_ret_i2_plus_g1_minus_24)
104 sub %g1, 24, %g1
105 ba,pt %xcc, __restore_asi
106 add %i2, %g1, %i0
107ENDPROC(NG_ret_i2_plus_g1_minus_24)
108ENTRY(NG_ret_i2_plus_g1_minus_32)
109 sub %g1, 32, %g1
110 ba,pt %xcc, __restore_asi
111 add %i2, %g1, %i0
112ENDPROC(NG_ret_i2_plus_g1_minus_32)
113ENTRY(NG_ret_i2_plus_g1_minus_40)
114 sub %g1, 40, %g1
115 ba,pt %xcc, __restore_asi
116 add %i2, %g1, %i0
117ENDPROC(NG_ret_i2_plus_g1_minus_40)
118ENTRY(NG_ret_i2_plus_g1_minus_48)
119 sub %g1, 48, %g1
120 ba,pt %xcc, __restore_asi
121 add %i2, %g1, %i0
122ENDPROC(NG_ret_i2_plus_g1_minus_48)
123ENTRY(NG_ret_i2_plus_g1_minus_56)
124 sub %g1, 56, %g1
125 ba,pt %xcc, __restore_asi
126 add %i2, %g1, %i0
127ENDPROC(NG_ret_i2_plus_g1_minus_56)
128ENTRY(NG_ret_i2_plus_i4)
129 ba,pt %xcc, __restore_asi
130 add %i2, %i4, %i0
131ENDPROC(NG_ret_i2_plus_i4)
132ENTRY(NG_ret_i2_plus_i4_minus_8)
133 sub %i4, 8, %i4
134 ba,pt %xcc, __restore_asi
135 add %i2, %i4, %i0
136ENDPROC(NG_ret_i2_plus_i4_minus_8)
137ENTRY(NG_ret_i2_plus_8)
138 ba,pt %xcc, __restore_asi
139 add %i2, 8, %i0
140ENDPROC(NG_ret_i2_plus_8)
141ENTRY(NG_ret_i2_plus_4)
142 ba,pt %xcc, __restore_asi
143 add %i2, 4, %i0
144ENDPROC(NG_ret_i2_plus_4)
145ENTRY(NG_ret_i2_plus_1)
146 ba,pt %xcc, __restore_asi
147 add %i2, 1, %i0
148ENDPROC(NG_ret_i2_plus_1)
149ENTRY(NG_ret_i2_plus_g1_plus_1)
150 add %g1, 1, %g1
151 ba,pt %xcc, __restore_asi
152 add %i2, %g1, %i0
153ENDPROC(NG_ret_i2_plus_g1_plus_1)
154ENTRY(NG_ret_i2)
155 ba,pt %xcc, __restore_asi
156 mov %i2, %i0
157ENDPROC(NG_ret_i2)
158ENTRY(NG_ret_i2_and_7_plus_i4)
159 and %i2, 7, %i2
160 ba,pt %xcc, __restore_asi
161 add %i2, %i4, %i0
162ENDPROC(NG_ret_i2_and_7_plus_i4)
163#endif
164
165 .align 64
166
167 .globl FUNC_NAME
168 .type FUNC_NAME,#function
169FUNC_NAME: /* %i0=dst, %i1=src, %i2=len */
170 PREAMBLE
171 save %sp, -SAVE_AMOUNT, %sp
172 srlx %i2, 31, %g2
173 cmp %g2, 0
174 tne %xcc, 5
175 mov %i0, %o0
176 cmp %i2, 0
177 be,pn %XCC, 85f
178 or %o0, %i1, %i3
179 cmp %i2, 16
180 blu,a,pn %XCC, 80f
181 or %i3, %i2, %i3
182
183 /* 2 blocks (128 bytes) is the minimum we can do the block
184 * copy with. We need to ensure that we'll iterate at least
185 * once in the block copy loop. At worst we'll need to align
186 * the destination to a 64-byte boundary which can chew up
187 * to (64 - 1) bytes from the length before we perform the
188 * block copy loop.
189 */
190 cmp %i2, (2 * 64)
191 blu,pt %XCC, 70f
192 andcc %i3, 0x7, %g0
193
194 /* %o0: dst
195 * %i1: src
196 * %i2: len (known to be >= 128)
197 *
198 * The block copy loops will use %i4/%i5,%g2/%g3 as
199 * temporaries while copying the data.
200 */
201
202 LOAD(prefetch, %i1, #one_read)
203 wr %g0, STORE_ASI, %asi
204
205 /* Align destination on 64-byte boundary. */
206 andcc %o0, (64 - 1), %i4
207 be,pt %XCC, 2f
208 sub %i4, 64, %i4
209 sub %g0, %i4, %i4 ! bytes to align dst
210 sub %i2, %i4, %i2
2111: subcc %i4, 1, %i4
212 EX_LD(LOAD(ldub, %i1, %g1), NG_ret_i2_plus_i4_plus_1)
213 EX_ST(STORE(stb, %g1, %o0), NG_ret_i2_plus_i4_plus_1)
214 add %i1, 1, %i1
215 bne,pt %XCC, 1b
216 add %o0, 1, %o0
217
218 /* If the source is on a 16-byte boundary we can do
219 * the direct block copy loop. If it is 8-byte aligned
220 * we can do the 16-byte loads offset by -8 bytes and the
221 * init stores offset by one register.
222 *
223 * If the source is not even 8-byte aligned, we need to do
224 * shifting and masking (basically integer faligndata).
225 *
226 * The careful bit with init stores is that if we store
227 * to any part of the cache line we have to store the whole
228 * cacheline else we can end up with corrupt L2 cache line
229 * contents. Since the loop works on 64-bytes of 64-byte
230 * aligned store data at a time, this is easy to ensure.
231 */
2322:
233 andcc %i1, (16 - 1), %i4
234 andn %i2, (64 - 1), %g1 ! block copy loop iterator
235 be,pt %XCC, 50f
236 sub %i2, %g1, %i2 ! final sub-block copy bytes
237
238 cmp %i4, 8
239 be,pt %XCC, 10f
240 sub %i1, %i4, %i1
241
242 /* Neither 8-byte nor 16-byte aligned, shift and mask. */
243 and %i4, 0x7, GLOBAL_SPARE
244 sll GLOBAL_SPARE, 3, GLOBAL_SPARE
245 mov 64, %i5
246 EX_LD(LOAD_TWIN(%i1, %g2, %g3), NG_ret_i2_plus_g1)
247 sub %i5, GLOBAL_SPARE, %i5
248 mov 16, %o4
249 mov 32, %o5
250 mov 48, %o7
251 mov 64, %i3
252
253 bg,pn %XCC, 9f
254 nop
255
256#define MIX_THREE_WORDS(WORD1, WORD2, WORD3, PRE_SHIFT, POST_SHIFT, TMP) \
257 sllx WORD1, POST_SHIFT, WORD1; \
258 srlx WORD2, PRE_SHIFT, TMP; \
259 sllx WORD2, POST_SHIFT, WORD2; \
260 or WORD1, TMP, WORD1; \
261 srlx WORD3, PRE_SHIFT, TMP; \
262 or WORD2, TMP, WORD2;
263
2648: EX_LD(LOAD_TWIN(%i1 + %o4, %o2, %o3), NG_ret_i2_plus_g1)
265 MIX_THREE_WORDS(%g2, %g3, %o2, %i5, GLOBAL_SPARE, %o1)
266 LOAD(prefetch, %i1 + %i3, #one_read)
267
268 EX_ST(STORE_INIT(%g2, %o0 + 0x00), NG_ret_i2_plus_g1)
269 EX_ST(STORE_INIT(%g3, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
270
271 EX_LD(LOAD_TWIN(%i1 + %o5, %g2, %g3), NG_ret_i2_plus_g1_minus_16)
272 MIX_THREE_WORDS(%o2, %o3, %g2, %i5, GLOBAL_SPARE, %o1)
273
274 EX_ST(STORE_INIT(%o2, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
275 EX_ST(STORE_INIT(%o3, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
276
277 EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
278 MIX_THREE_WORDS(%g2, %g3, %o2, %i5, GLOBAL_SPARE, %o1)
279
280 EX_ST(STORE_INIT(%g2, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
281 EX_ST(STORE_INIT(%g3, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
282
283 EX_LD(LOAD_TWIN(%i1 + %i3, %g2, %g3), NG_ret_i2_plus_g1_minus_48)
284 add %i1, 64, %i1
285 MIX_THREE_WORDS(%o2, %o3, %g2, %i5, GLOBAL_SPARE, %o1)
286
287 EX_ST(STORE_INIT(%o2, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
288 EX_ST(STORE_INIT(%o3, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
289
290 subcc %g1, 64, %g1
291 bne,pt %XCC, 8b
292 add %o0, 64, %o0
293
294 ba,pt %XCC, 60f
295 add %i1, %i4, %i1
296
2979: EX_LD(LOAD_TWIN(%i1 + %o4, %o2, %o3), NG_ret_i2_plus_g1)
298 MIX_THREE_WORDS(%g3, %o2, %o3, %i5, GLOBAL_SPARE, %o1)
299 LOAD(prefetch, %i1 + %i3, #one_read)
300
301 EX_ST(STORE_INIT(%g3, %o0 + 0x00), NG_ret_i2_plus_g1)
302 EX_ST(STORE_INIT(%o2, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
303
304 EX_LD(LOAD_TWIN(%i1 + %o5, %g2, %g3), NG_ret_i2_plus_g1_minus_16)
305 MIX_THREE_WORDS(%o3, %g2, %g3, %i5, GLOBAL_SPARE, %o1)
306
307 EX_ST(STORE_INIT(%o3, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
308 EX_ST(STORE_INIT(%g2, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
309
310 EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
311 MIX_THREE_WORDS(%g3, %o2, %o3, %i5, GLOBAL_SPARE, %o1)
312
313 EX_ST(STORE_INIT(%g3, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
314 EX_ST(STORE_INIT(%o2, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
315
316 EX_LD(LOAD_TWIN(%i1 + %i3, %g2, %g3), NG_ret_i2_plus_g1_minus_48)
317 add %i1, 64, %i1
318 MIX_THREE_WORDS(%o3, %g2, %g3, %i5, GLOBAL_SPARE, %o1)
319
320 EX_ST(STORE_INIT(%o3, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
321 EX_ST(STORE_INIT(%g2, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
322
323 subcc %g1, 64, %g1
324 bne,pt %XCC, 9b
325 add %o0, 64, %o0
326
327 ba,pt %XCC, 60f
328 add %i1, %i4, %i1
329
33010: /* Destination is 64-byte aligned, source was only 8-byte
331 * aligned but it has been subtracted by 8 and we perform
332 * one twin load ahead, then add 8 back into source when
333 * we finish the loop.
334 */
335 EX_LD(LOAD_TWIN(%i1, %o4, %o5), NG_ret_i2_plus_g1)
336 mov 16, %o7
337 mov 32, %g2
338 mov 48, %g3
339 mov 64, %o1
3401: EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1)
341 LOAD(prefetch, %i1 + %o1, #one_read)
342 EX_ST(STORE_INIT(%o5, %o0 + 0x00), NG_ret_i2_plus_g1) ! initializes cache line
343 EX_ST(STORE_INIT(%o2, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
344 EX_LD(LOAD_TWIN(%i1 + %g2, %o4, %o5), NG_ret_i2_plus_g1_minus_16)
345 EX_ST(STORE_INIT(%o3, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
346 EX_ST(STORE_INIT(%o4, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
347 EX_LD(LOAD_TWIN(%i1 + %g3, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
348 EX_ST(STORE_INIT(%o5, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
349 EX_ST(STORE_INIT(%o2, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
350 EX_LD(LOAD_TWIN(%i1 + %o1, %o4, %o5), NG_ret_i2_plus_g1_minus_48)
351 add %i1, 64, %i1
352 EX_ST(STORE_INIT(%o3, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
353 EX_ST(STORE_INIT(%o4, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
354 subcc %g1, 64, %g1
355 bne,pt %XCC, 1b
356 add %o0, 64, %o0
357
358 ba,pt %XCC, 60f
359 add %i1, 0x8, %i1
360
36150: /* Destination is 64-byte aligned, and source is 16-byte
362 * aligned.
363 */
364 mov 16, %o7
365 mov 32, %g2
366 mov 48, %g3
367 mov 64, %o1
3681: EX_LD(LOAD_TWIN(%i1 + %g0, %o4, %o5), NG_ret_i2_plus_g1)
369 EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1)
370 LOAD(prefetch, %i1 + %o1, #one_read)
371 EX_ST(STORE_INIT(%o4, %o0 + 0x00), NG_ret_i2_plus_g1) ! initializes cache line
372 EX_ST(STORE_INIT(%o5, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
373 EX_LD(LOAD_TWIN(%i1 + %g2, %o4, %o5), NG_ret_i2_plus_g1_minus_16)
374 EX_ST(STORE_INIT(%o2, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
375 EX_ST(STORE_INIT(%o3, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
376 EX_LD(LOAD_TWIN(%i1 + %g3, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
377 add %i1, 64, %i1
378 EX_ST(STORE_INIT(%o4, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
379 EX_ST(STORE_INIT(%o5, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
380 EX_ST(STORE_INIT(%o2, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
381 EX_ST(STORE_INIT(%o3, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
382 subcc %g1, 64, %g1
383 bne,pt %XCC, 1b
384 add %o0, 64, %o0
385 /* fall through */
386
38760:
388 membar #Sync
389
390 /* %i2 contains any final bytes still needed to be copied
391 * over. If anything is left, we copy it one byte at a time.
392 */
393 RESTORE_ASI(%i3)
394 brz,pt %i2, 85f
395 sub %o0, %i1, %i3
396 ba,a,pt %XCC, 90f
397 nop
398
399 .align 64
40070: /* 16 < len <= 64 */
401 bne,pn %XCC, 75f
402 sub %o0, %i1, %i3
403
40472:
405 andn %i2, 0xf, %i4
406 and %i2, 0xf, %i2
4071: subcc %i4, 0x10, %i4
408 EX_LD(LOAD(ldx, %i1, %o4), NG_ret_i2_plus_i4)
409 add %i1, 0x08, %i1
410 EX_LD(LOAD(ldx, %i1, %g1), NG_ret_i2_plus_i4)
411 sub %i1, 0x08, %i1
412 EX_ST(STORE(stx, %o4, %i1 + %i3), NG_ret_i2_plus_i4)
413 add %i1, 0x8, %i1
414 EX_ST(STORE(stx, %g1, %i1 + %i3), NG_ret_i2_plus_i4_minus_8)
415 bgu,pt %XCC, 1b
416 add %i1, 0x8, %i1
41773: andcc %i2, 0x8, %g0
418 be,pt %XCC, 1f
419 nop
420 sub %i2, 0x8, %i2
421 EX_LD(LOAD(ldx, %i1, %o4), NG_ret_i2_plus_8)
422 EX_ST(STORE(stx, %o4, %i1 + %i3), NG_ret_i2_plus_8)
423 add %i1, 0x8, %i1
4241: andcc %i2, 0x4, %g0
425 be,pt %XCC, 1f
426 nop
427 sub %i2, 0x4, %i2
428 EX_LD(LOAD(lduw, %i1, %i5), NG_ret_i2_plus_4)
429 EX_ST(STORE(stw, %i5, %i1 + %i3), NG_ret_i2_plus_4)
430 add %i1, 0x4, %i1
4311: cmp %i2, 0
432 be,pt %XCC, 85f
433 nop
434 ba,pt %xcc, 90f
435 nop
436
43775:
438 andcc %o0, 0x7, %g1
439 sub %g1, 0x8, %g1
440 be,pn %icc, 2f
441 sub %g0, %g1, %g1
442 sub %i2, %g1, %i2
443
4441: subcc %g1, 1, %g1
445 EX_LD(LOAD(ldub, %i1, %i5), NG_ret_i2_plus_g1_plus_1)
446 EX_ST(STORE(stb, %i5, %i1 + %i3), NG_ret_i2_plus_g1_plus_1)
447 bgu,pt %icc, 1b
448 add %i1, 1, %i1
449
4502: add %i1, %i3, %o0
451 andcc %i1, 0x7, %g1
452 bne,pt %icc, 8f
453 sll %g1, 3, %g1
454
455 cmp %i2, 16
456 bgeu,pt %icc, 72b
457 nop
458 ba,a,pt %xcc, 73b
459
4608: mov 64, %i3
461 andn %i1, 0x7, %i1
462 EX_LD(LOAD(ldx, %i1, %g2), NG_ret_i2)
463 sub %i3, %g1, %i3
464 andn %i2, 0x7, %i4
465 sllx %g2, %g1, %g2
4661: add %i1, 0x8, %i1
467 EX_LD(LOAD(ldx, %i1, %g3), NG_ret_i2_and_7_plus_i4)
468 subcc %i4, 0x8, %i4
469 srlx %g3, %i3, %i5
470 or %i5, %g2, %i5
471 EX_ST(STORE(stx, %i5, %o0), NG_ret_i2_and_7_plus_i4)
472 add %o0, 0x8, %o0
473 bgu,pt %icc, 1b
474 sllx %g3, %g1, %g2
475
476 srl %g1, 3, %g1
477 andcc %i2, 0x7, %i2
478 be,pn %icc, 85f
479 add %i1, %g1, %i1
480 ba,pt %xcc, 90f
481 sub %o0, %i1, %i3
482
483 .align 64
48480: /* 0 < len <= 16 */
485 andcc %i3, 0x3, %g0
486 bne,pn %XCC, 90f
487 sub %o0, %i1, %i3
488
4891:
490 subcc %i2, 4, %i2
491 EX_LD(LOAD(lduw, %i1, %g1), NG_ret_i2_plus_4)
492 EX_ST(STORE(stw, %g1, %i1 + %i3), NG_ret_i2_plus_4)
493 bgu,pt %XCC, 1b
494 add %i1, 4, %i1
495
49685: ret
497 restore EX_RETVAL(%i0), %g0, %o0
498
499 .align 32
50090:
501 subcc %i2, 1, %i2
502 EX_LD(LOAD(ldub, %i1, %g1), NG_ret_i2_plus_1)
503 EX_ST(STORE(stb, %g1, %i1 + %i3), NG_ret_i2_plus_1)
504 bgu,pt %XCC, 90b
505 add %i1, 1, %i1
506 ret
507 restore EX_RETVAL(%i0), %g0, %o0
508
509 .size FUNC_NAME, .-FUNC_NAME
1/* SPDX-License-Identifier: GPL-2.0 */
2/* NGmemcpy.S: Niagara optimized memcpy.
3 *
4 * Copyright (C) 2006, 2007 David S. Miller (davem@davemloft.net)
5 */
6
7#ifdef __KERNEL__
8#include <linux/linkage.h>
9#include <asm/asi.h>
10#include <asm/thread_info.h>
11#define GLOBAL_SPARE %g7
12#define RESTORE_ASI(TMP) \
13 ldub [%g6 + TI_CURRENT_DS], TMP; \
14 wr TMP, 0x0, %asi;
15#else
16#define GLOBAL_SPARE %g5
17#define RESTORE_ASI(TMP) \
18 wr %g0, ASI_PNF, %asi
19#endif
20
21#ifdef __sparc_v9__
22#define SAVE_AMOUNT 128
23#else
24#define SAVE_AMOUNT 64
25#endif
26
27#ifndef STORE_ASI
28#define STORE_ASI ASI_BLK_INIT_QUAD_LDD_P
29#endif
30
31#ifndef EX_LD
32#define EX_LD(x,y) x
33#endif
34
35#ifndef EX_ST
36#define EX_ST(x,y) x
37#endif
38
39#ifndef LOAD
40#ifndef MEMCPY_DEBUG
41#define LOAD(type,addr,dest) type [addr], dest
42#else
43#define LOAD(type,addr,dest) type##a [addr] 0x80, dest
44#endif
45#endif
46
47#ifndef LOAD_TWIN
48#define LOAD_TWIN(addr_reg,dest0,dest1) \
49 ldda [addr_reg] ASI_BLK_INIT_QUAD_LDD_P, dest0
50#endif
51
52#ifndef STORE
53#define STORE(type,src,addr) type src, [addr]
54#endif
55
56#ifndef STORE_INIT
57#ifndef SIMULATE_NIAGARA_ON_NON_NIAGARA
58#define STORE_INIT(src,addr) stxa src, [addr] %asi
59#else
60#define STORE_INIT(src,addr) stx src, [addr + 0x00]
61#endif
62#endif
63
64#ifndef FUNC_NAME
65#define FUNC_NAME NGmemcpy
66#endif
67
68#ifndef PREAMBLE
69#define PREAMBLE
70#endif
71
72#ifndef XCC
73#define XCC xcc
74#endif
75
76 .register %g2,#scratch
77 .register %g3,#scratch
78
79 .text
80#ifndef EX_RETVAL
81#define EX_RETVAL(x) x
82__restore_asi:
83 ret
84 wr %g0, ASI_AIUS, %asi
85 restore
86ENTRY(NG_ret_i2_plus_i4_plus_1)
87 ba,pt %xcc, __restore_asi
88 add %i2, %i5, %i0
89ENDPROC(NG_ret_i2_plus_i4_plus_1)
90ENTRY(NG_ret_i2_plus_g1)
91 ba,pt %xcc, __restore_asi
92 add %i2, %g1, %i0
93ENDPROC(NG_ret_i2_plus_g1)
94ENTRY(NG_ret_i2_plus_g1_minus_8)
95 sub %g1, 8, %g1
96 ba,pt %xcc, __restore_asi
97 add %i2, %g1, %i0
98ENDPROC(NG_ret_i2_plus_g1_minus_8)
99ENTRY(NG_ret_i2_plus_g1_minus_16)
100 sub %g1, 16, %g1
101 ba,pt %xcc, __restore_asi
102 add %i2, %g1, %i0
103ENDPROC(NG_ret_i2_plus_g1_minus_16)
104ENTRY(NG_ret_i2_plus_g1_minus_24)
105 sub %g1, 24, %g1
106 ba,pt %xcc, __restore_asi
107 add %i2, %g1, %i0
108ENDPROC(NG_ret_i2_plus_g1_minus_24)
109ENTRY(NG_ret_i2_plus_g1_minus_32)
110 sub %g1, 32, %g1
111 ba,pt %xcc, __restore_asi
112 add %i2, %g1, %i0
113ENDPROC(NG_ret_i2_plus_g1_minus_32)
114ENTRY(NG_ret_i2_plus_g1_minus_40)
115 sub %g1, 40, %g1
116 ba,pt %xcc, __restore_asi
117 add %i2, %g1, %i0
118ENDPROC(NG_ret_i2_plus_g1_minus_40)
119ENTRY(NG_ret_i2_plus_g1_minus_48)
120 sub %g1, 48, %g1
121 ba,pt %xcc, __restore_asi
122 add %i2, %g1, %i0
123ENDPROC(NG_ret_i2_plus_g1_minus_48)
124ENTRY(NG_ret_i2_plus_g1_minus_56)
125 sub %g1, 56, %g1
126 ba,pt %xcc, __restore_asi
127 add %i2, %g1, %i0
128ENDPROC(NG_ret_i2_plus_g1_minus_56)
129ENTRY(NG_ret_i2_plus_i4)
130 ba,pt %xcc, __restore_asi
131 add %i2, %i4, %i0
132ENDPROC(NG_ret_i2_plus_i4)
133ENTRY(NG_ret_i2_plus_i4_minus_8)
134 sub %i4, 8, %i4
135 ba,pt %xcc, __restore_asi
136 add %i2, %i4, %i0
137ENDPROC(NG_ret_i2_plus_i4_minus_8)
138ENTRY(NG_ret_i2_plus_8)
139 ba,pt %xcc, __restore_asi
140 add %i2, 8, %i0
141ENDPROC(NG_ret_i2_plus_8)
142ENTRY(NG_ret_i2_plus_4)
143 ba,pt %xcc, __restore_asi
144 add %i2, 4, %i0
145ENDPROC(NG_ret_i2_plus_4)
146ENTRY(NG_ret_i2_plus_1)
147 ba,pt %xcc, __restore_asi
148 add %i2, 1, %i0
149ENDPROC(NG_ret_i2_plus_1)
150ENTRY(NG_ret_i2_plus_g1_plus_1)
151 add %g1, 1, %g1
152 ba,pt %xcc, __restore_asi
153 add %i2, %g1, %i0
154ENDPROC(NG_ret_i2_plus_g1_plus_1)
155ENTRY(NG_ret_i2)
156 ba,pt %xcc, __restore_asi
157 mov %i2, %i0
158ENDPROC(NG_ret_i2)
159ENTRY(NG_ret_i2_and_7_plus_i4)
160 and %i2, 7, %i2
161 ba,pt %xcc, __restore_asi
162 add %i2, %i4, %i0
163ENDPROC(NG_ret_i2_and_7_plus_i4)
164#endif
165
166 .align 64
167
168 .globl FUNC_NAME
169 .type FUNC_NAME,#function
170FUNC_NAME: /* %i0=dst, %i1=src, %i2=len */
171 PREAMBLE
172 save %sp, -SAVE_AMOUNT, %sp
173 srlx %i2, 31, %g2
174 cmp %g2, 0
175 tne %xcc, 5
176 mov %i0, %o0
177 cmp %i2, 0
178 be,pn %XCC, 85f
179 or %o0, %i1, %i3
180 cmp %i2, 16
181 blu,a,pn %XCC, 80f
182 or %i3, %i2, %i3
183
184 /* 2 blocks (128 bytes) is the minimum we can do the block
185 * copy with. We need to ensure that we'll iterate at least
186 * once in the block copy loop. At worst we'll need to align
187 * the destination to a 64-byte boundary which can chew up
188 * to (64 - 1) bytes from the length before we perform the
189 * block copy loop.
190 */
191 cmp %i2, (2 * 64)
192 blu,pt %XCC, 70f
193 andcc %i3, 0x7, %g0
194
195 /* %o0: dst
196 * %i1: src
197 * %i2: len (known to be >= 128)
198 *
199 * The block copy loops will use %i4/%i5,%g2/%g3 as
200 * temporaries while copying the data.
201 */
202
203 LOAD(prefetch, %i1, #one_read)
204 wr %g0, STORE_ASI, %asi
205
206 /* Align destination on 64-byte boundary. */
207 andcc %o0, (64 - 1), %i4
208 be,pt %XCC, 2f
209 sub %i4, 64, %i4
210 sub %g0, %i4, %i4 ! bytes to align dst
211 sub %i2, %i4, %i2
2121: subcc %i4, 1, %i4
213 EX_LD(LOAD(ldub, %i1, %g1), NG_ret_i2_plus_i4_plus_1)
214 EX_ST(STORE(stb, %g1, %o0), NG_ret_i2_plus_i4_plus_1)
215 add %i1, 1, %i1
216 bne,pt %XCC, 1b
217 add %o0, 1, %o0
218
219 /* If the source is on a 16-byte boundary we can do
220 * the direct block copy loop. If it is 8-byte aligned
221 * we can do the 16-byte loads offset by -8 bytes and the
222 * init stores offset by one register.
223 *
224 * If the source is not even 8-byte aligned, we need to do
225 * shifting and masking (basically integer faligndata).
226 *
227 * The careful bit with init stores is that if we store
228 * to any part of the cache line we have to store the whole
229 * cacheline else we can end up with corrupt L2 cache line
230 * contents. Since the loop works on 64-bytes of 64-byte
231 * aligned store data at a time, this is easy to ensure.
232 */
2332:
234 andcc %i1, (16 - 1), %i4
235 andn %i2, (64 - 1), %g1 ! block copy loop iterator
236 be,pt %XCC, 50f
237 sub %i2, %g1, %i2 ! final sub-block copy bytes
238
239 cmp %i4, 8
240 be,pt %XCC, 10f
241 sub %i1, %i4, %i1
242
243 /* Neither 8-byte nor 16-byte aligned, shift and mask. */
244 and %i4, 0x7, GLOBAL_SPARE
245 sll GLOBAL_SPARE, 3, GLOBAL_SPARE
246 mov 64, %i5
247 EX_LD(LOAD_TWIN(%i1, %g2, %g3), NG_ret_i2_plus_g1)
248 sub %i5, GLOBAL_SPARE, %i5
249 mov 16, %o4
250 mov 32, %o5
251 mov 48, %o7
252 mov 64, %i3
253
254 bg,pn %XCC, 9f
255 nop
256
257#define MIX_THREE_WORDS(WORD1, WORD2, WORD3, PRE_SHIFT, POST_SHIFT, TMP) \
258 sllx WORD1, POST_SHIFT, WORD1; \
259 srlx WORD2, PRE_SHIFT, TMP; \
260 sllx WORD2, POST_SHIFT, WORD2; \
261 or WORD1, TMP, WORD1; \
262 srlx WORD3, PRE_SHIFT, TMP; \
263 or WORD2, TMP, WORD2;
264
2658: EX_LD(LOAD_TWIN(%i1 + %o4, %o2, %o3), NG_ret_i2_plus_g1)
266 MIX_THREE_WORDS(%g2, %g3, %o2, %i5, GLOBAL_SPARE, %o1)
267 LOAD(prefetch, %i1 + %i3, #one_read)
268
269 EX_ST(STORE_INIT(%g2, %o0 + 0x00), NG_ret_i2_plus_g1)
270 EX_ST(STORE_INIT(%g3, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
271
272 EX_LD(LOAD_TWIN(%i1 + %o5, %g2, %g3), NG_ret_i2_plus_g1_minus_16)
273 MIX_THREE_WORDS(%o2, %o3, %g2, %i5, GLOBAL_SPARE, %o1)
274
275 EX_ST(STORE_INIT(%o2, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
276 EX_ST(STORE_INIT(%o3, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
277
278 EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
279 MIX_THREE_WORDS(%g2, %g3, %o2, %i5, GLOBAL_SPARE, %o1)
280
281 EX_ST(STORE_INIT(%g2, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
282 EX_ST(STORE_INIT(%g3, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
283
284 EX_LD(LOAD_TWIN(%i1 + %i3, %g2, %g3), NG_ret_i2_plus_g1_minus_48)
285 add %i1, 64, %i1
286 MIX_THREE_WORDS(%o2, %o3, %g2, %i5, GLOBAL_SPARE, %o1)
287
288 EX_ST(STORE_INIT(%o2, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
289 EX_ST(STORE_INIT(%o3, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
290
291 subcc %g1, 64, %g1
292 bne,pt %XCC, 8b
293 add %o0, 64, %o0
294
295 ba,pt %XCC, 60f
296 add %i1, %i4, %i1
297
2989: EX_LD(LOAD_TWIN(%i1 + %o4, %o2, %o3), NG_ret_i2_plus_g1)
299 MIX_THREE_WORDS(%g3, %o2, %o3, %i5, GLOBAL_SPARE, %o1)
300 LOAD(prefetch, %i1 + %i3, #one_read)
301
302 EX_ST(STORE_INIT(%g3, %o0 + 0x00), NG_ret_i2_plus_g1)
303 EX_ST(STORE_INIT(%o2, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
304
305 EX_LD(LOAD_TWIN(%i1 + %o5, %g2, %g3), NG_ret_i2_plus_g1_minus_16)
306 MIX_THREE_WORDS(%o3, %g2, %g3, %i5, GLOBAL_SPARE, %o1)
307
308 EX_ST(STORE_INIT(%o3, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
309 EX_ST(STORE_INIT(%g2, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
310
311 EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
312 MIX_THREE_WORDS(%g3, %o2, %o3, %i5, GLOBAL_SPARE, %o1)
313
314 EX_ST(STORE_INIT(%g3, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
315 EX_ST(STORE_INIT(%o2, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
316
317 EX_LD(LOAD_TWIN(%i1 + %i3, %g2, %g3), NG_ret_i2_plus_g1_minus_48)
318 add %i1, 64, %i1
319 MIX_THREE_WORDS(%o3, %g2, %g3, %i5, GLOBAL_SPARE, %o1)
320
321 EX_ST(STORE_INIT(%o3, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
322 EX_ST(STORE_INIT(%g2, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
323
324 subcc %g1, 64, %g1
325 bne,pt %XCC, 9b
326 add %o0, 64, %o0
327
328 ba,pt %XCC, 60f
329 add %i1, %i4, %i1
330
33110: /* Destination is 64-byte aligned, source was only 8-byte
332 * aligned but it has been subtracted by 8 and we perform
333 * one twin load ahead, then add 8 back into source when
334 * we finish the loop.
335 */
336 EX_LD(LOAD_TWIN(%i1, %o4, %o5), NG_ret_i2_plus_g1)
337 mov 16, %o7
338 mov 32, %g2
339 mov 48, %g3
340 mov 64, %o1
3411: EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1)
342 LOAD(prefetch, %i1 + %o1, #one_read)
343 EX_ST(STORE_INIT(%o5, %o0 + 0x00), NG_ret_i2_plus_g1) ! initializes cache line
344 EX_ST(STORE_INIT(%o2, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
345 EX_LD(LOAD_TWIN(%i1 + %g2, %o4, %o5), NG_ret_i2_plus_g1_minus_16)
346 EX_ST(STORE_INIT(%o3, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
347 EX_ST(STORE_INIT(%o4, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
348 EX_LD(LOAD_TWIN(%i1 + %g3, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
349 EX_ST(STORE_INIT(%o5, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
350 EX_ST(STORE_INIT(%o2, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
351 EX_LD(LOAD_TWIN(%i1 + %o1, %o4, %o5), NG_ret_i2_plus_g1_minus_48)
352 add %i1, 64, %i1
353 EX_ST(STORE_INIT(%o3, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
354 EX_ST(STORE_INIT(%o4, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
355 subcc %g1, 64, %g1
356 bne,pt %XCC, 1b
357 add %o0, 64, %o0
358
359 ba,pt %XCC, 60f
360 add %i1, 0x8, %i1
361
36250: /* Destination is 64-byte aligned, and source is 16-byte
363 * aligned.
364 */
365 mov 16, %o7
366 mov 32, %g2
367 mov 48, %g3
368 mov 64, %o1
3691: EX_LD(LOAD_TWIN(%i1 + %g0, %o4, %o5), NG_ret_i2_plus_g1)
370 EX_LD(LOAD_TWIN(%i1 + %o7, %o2, %o3), NG_ret_i2_plus_g1)
371 LOAD(prefetch, %i1 + %o1, #one_read)
372 EX_ST(STORE_INIT(%o4, %o0 + 0x00), NG_ret_i2_plus_g1) ! initializes cache line
373 EX_ST(STORE_INIT(%o5, %o0 + 0x08), NG_ret_i2_plus_g1_minus_8)
374 EX_LD(LOAD_TWIN(%i1 + %g2, %o4, %o5), NG_ret_i2_plus_g1_minus_16)
375 EX_ST(STORE_INIT(%o2, %o0 + 0x10), NG_ret_i2_plus_g1_minus_16)
376 EX_ST(STORE_INIT(%o3, %o0 + 0x18), NG_ret_i2_plus_g1_minus_24)
377 EX_LD(LOAD_TWIN(%i1 + %g3, %o2, %o3), NG_ret_i2_plus_g1_minus_32)
378 add %i1, 64, %i1
379 EX_ST(STORE_INIT(%o4, %o0 + 0x20), NG_ret_i2_plus_g1_minus_32)
380 EX_ST(STORE_INIT(%o5, %o0 + 0x28), NG_ret_i2_plus_g1_minus_40)
381 EX_ST(STORE_INIT(%o2, %o0 + 0x30), NG_ret_i2_plus_g1_minus_48)
382 EX_ST(STORE_INIT(%o3, %o0 + 0x38), NG_ret_i2_plus_g1_minus_56)
383 subcc %g1, 64, %g1
384 bne,pt %XCC, 1b
385 add %o0, 64, %o0
386 /* fall through */
387
38860:
389 membar #Sync
390
391 /* %i2 contains any final bytes still needed to be copied
392 * over. If anything is left, we copy it one byte at a time.
393 */
394 RESTORE_ASI(%i3)
395 brz,pt %i2, 85f
396 sub %o0, %i1, %i3
397 ba,a,pt %XCC, 90f
398 nop
399
400 .align 64
40170: /* 16 < len <= 64 */
402 bne,pn %XCC, 75f
403 sub %o0, %i1, %i3
404
40572:
406 andn %i2, 0xf, %i4
407 and %i2, 0xf, %i2
4081: subcc %i4, 0x10, %i4
409 EX_LD(LOAD(ldx, %i1, %o4), NG_ret_i2_plus_i4)
410 add %i1, 0x08, %i1
411 EX_LD(LOAD(ldx, %i1, %g1), NG_ret_i2_plus_i4)
412 sub %i1, 0x08, %i1
413 EX_ST(STORE(stx, %o4, %i1 + %i3), NG_ret_i2_plus_i4)
414 add %i1, 0x8, %i1
415 EX_ST(STORE(stx, %g1, %i1 + %i3), NG_ret_i2_plus_i4_minus_8)
416 bgu,pt %XCC, 1b
417 add %i1, 0x8, %i1
41873: andcc %i2, 0x8, %g0
419 be,pt %XCC, 1f
420 nop
421 sub %i2, 0x8, %i2
422 EX_LD(LOAD(ldx, %i1, %o4), NG_ret_i2_plus_8)
423 EX_ST(STORE(stx, %o4, %i1 + %i3), NG_ret_i2_plus_8)
424 add %i1, 0x8, %i1
4251: andcc %i2, 0x4, %g0
426 be,pt %XCC, 1f
427 nop
428 sub %i2, 0x4, %i2
429 EX_LD(LOAD(lduw, %i1, %i5), NG_ret_i2_plus_4)
430 EX_ST(STORE(stw, %i5, %i1 + %i3), NG_ret_i2_plus_4)
431 add %i1, 0x4, %i1
4321: cmp %i2, 0
433 be,pt %XCC, 85f
434 nop
435 ba,pt %xcc, 90f
436 nop
437
43875:
439 andcc %o0, 0x7, %g1
440 sub %g1, 0x8, %g1
441 be,pn %icc, 2f
442 sub %g0, %g1, %g1
443 sub %i2, %g1, %i2
444
4451: subcc %g1, 1, %g1
446 EX_LD(LOAD(ldub, %i1, %i5), NG_ret_i2_plus_g1_plus_1)
447 EX_ST(STORE(stb, %i5, %i1 + %i3), NG_ret_i2_plus_g1_plus_1)
448 bgu,pt %icc, 1b
449 add %i1, 1, %i1
450
4512: add %i1, %i3, %o0
452 andcc %i1, 0x7, %g1
453 bne,pt %icc, 8f
454 sll %g1, 3, %g1
455
456 cmp %i2, 16
457 bgeu,pt %icc, 72b
458 nop
459 ba,a,pt %xcc, 73b
460
4618: mov 64, %i3
462 andn %i1, 0x7, %i1
463 EX_LD(LOAD(ldx, %i1, %g2), NG_ret_i2)
464 sub %i3, %g1, %i3
465 andn %i2, 0x7, %i4
466 sllx %g2, %g1, %g2
4671: add %i1, 0x8, %i1
468 EX_LD(LOAD(ldx, %i1, %g3), NG_ret_i2_and_7_plus_i4)
469 subcc %i4, 0x8, %i4
470 srlx %g3, %i3, %i5
471 or %i5, %g2, %i5
472 EX_ST(STORE(stx, %i5, %o0), NG_ret_i2_and_7_plus_i4)
473 add %o0, 0x8, %o0
474 bgu,pt %icc, 1b
475 sllx %g3, %g1, %g2
476
477 srl %g1, 3, %g1
478 andcc %i2, 0x7, %i2
479 be,pn %icc, 85f
480 add %i1, %g1, %i1
481 ba,pt %xcc, 90f
482 sub %o0, %i1, %i3
483
484 .align 64
48580: /* 0 < len <= 16 */
486 andcc %i3, 0x3, %g0
487 bne,pn %XCC, 90f
488 sub %o0, %i1, %i3
489
4901:
491 subcc %i2, 4, %i2
492 EX_LD(LOAD(lduw, %i1, %g1), NG_ret_i2_plus_4)
493 EX_ST(STORE(stw, %g1, %i1 + %i3), NG_ret_i2_plus_4)
494 bgu,pt %XCC, 1b
495 add %i1, 4, %i1
496
49785: ret
498 restore EX_RETVAL(%i0), %g0, %o0
499
500 .align 32
50190:
502 subcc %i2, 1, %i2
503 EX_LD(LOAD(ldub, %i1, %g1), NG_ret_i2_plus_1)
504 EX_ST(STORE(stb, %g1, %i1 + %i3), NG_ret_i2_plus_1)
505 bgu,pt %XCC, 90b
506 add %i1, 1, %i1
507 ret
508 restore EX_RETVAL(%i0), %g0, %o0
509
510 .size FUNC_NAME, .-FUNC_NAME