Loading...
1/* SPDX-License-Identifier: GPL-2.0-only */
2/*
3 * Copyright (C) 2000 Russell King
4 */
5#include <asm/vmlinux.lds.h>
6
7#ifdef CONFIG_CPU_ENDIAN_BE8
8#define ZIMAGE_MAGIC(x) ( (((x) >> 24) & 0x000000ff) | \
9 (((x) >> 8) & 0x0000ff00) | \
10 (((x) << 8) & 0x00ff0000) | \
11 (((x) << 24) & 0xff000000) )
12#else
13#define ZIMAGE_MAGIC(x) (x)
14#endif
15
16OUTPUT_ARCH(arm)
17ENTRY(_start)
18SECTIONS
19{
20 /DISCARD/ : {
21 COMMON_DISCARDS
22 *(.ARM.exidx*)
23 *(.ARM.extab*)
24 *(.note.*)
25 *(.rel.*)
26 *(.printk_index)
27 /*
28 * Discard any r/w data - this produces a link error if we have any,
29 * which is required for PIC decompression. Local data generates
30 * GOTOFF relocations, which prevents it being relocated independently
31 * of the text/got segments.
32 */
33 *(.data)
34 }
35
36 . = TEXT_START;
37 _text = .;
38
39 .text : {
40 _start = .;
41 *(.start)
42 *(.text)
43 *(.text.*)
44 ARM_STUBS_TEXT
45 }
46 .table : ALIGN(4) {
47 _table_start = .;
48 LONG(ZIMAGE_MAGIC(6))
49 LONG(ZIMAGE_MAGIC(0x5a534c4b))
50 LONG(ZIMAGE_MAGIC(__piggy_size_addr - _start))
51 LONG(ZIMAGE_MAGIC(_kernel_bss_size))
52 LONG(ZIMAGE_MAGIC(TEXT_OFFSET))
53 LONG(ZIMAGE_MAGIC(MALLOC_SIZE))
54 LONG(0)
55 _table_end = .;
56 }
57 .rodata : {
58 *(.rodata)
59 *(.rodata.*)
60 *(.data.rel.ro)
61 *(.data.rel.ro.*)
62 }
63 .piggydata : {
64 *(.piggydata)
65 __piggy_size_addr = . - 4;
66 }
67
68 . = ALIGN(4);
69 _etext = .;
70
71 .got.plt : { *(.got.plt) }
72#ifndef CONFIG_EFI_STUB
73 _got_start = .;
74 .got : { *(.got) }
75 _got_end = .;
76#endif
77
78 /* ensure the zImage file size is always a multiple of 64 bits */
79 /* (without a dummy byte, ld just ignores the empty section) */
80 .pad : { BYTE(0); . = ALIGN(8); }
81
82#ifdef CONFIG_EFI_STUB
83 .data : ALIGN(4096) {
84 __pecoff_data_start = .;
85 _got_start = .;
86 *(.got)
87 _got_end = .;
88 /*
89 * The EFI stub always executes from RAM, and runs strictly before the
90 * decompressor, so we can make an exception for its r/w data, and keep it
91 */
92 *(.data.efistub .bss.efistub)
93 __pecoff_data_end = .;
94
95 /*
96 * PE/COFF mandates a file size which is a multiple of 512 bytes if the
97 * section size equals or exceeds 4 KB
98 */
99 . = ALIGN(512);
100 }
101 __pecoff_data_rawsize = . - ADDR(.data);
102#endif
103
104 _edata = .;
105
106 /*
107 * The image_end section appears after any additional loadable sections
108 * that the linker may decide to insert in the binary image. Having
109 * this symbol allows further debug in the near future.
110 */
111 .image_end (NOLOAD) : {
112 /*
113 * EFI requires that the image is aligned to 512 bytes, and appended
114 * DTB requires that we know where the end of the image is. Ensure
115 * that both are satisfied by ensuring that there are no additional
116 * sections emitted into the decompressor image.
117 */
118 _edata_real = .;
119 }
120
121 _magic_sig = ZIMAGE_MAGIC(0x016f2818);
122 _magic_start = ZIMAGE_MAGIC(_start);
123 _magic_end = ZIMAGE_MAGIC(_edata);
124 _magic_table = ZIMAGE_MAGIC(_table_start - _start);
125
126 . = BSS_START;
127 __bss_start = .;
128 .bss : { *(.bss) }
129 _end = .;
130
131 . = ALIGN(8); /* the stack must be 64-bit aligned */
132 .stack : { *(.stack) }
133
134 PROVIDE(__pecoff_data_size = ALIGN(512) - ADDR(.data));
135 PROVIDE(__pecoff_end = ALIGN(512));
136
137 STABS_DEBUG
138 DWARF_DEBUG
139 ARM_DETAILS
140
141 ARM_ASSERTS
142}
143ASSERT(_edata_real == _edata, "error: zImage file size is incorrect");
1/*
2 * Copyright (C) 2000 Russell King
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License version 2 as
6 * published by the Free Software Foundation.
7 */
8
9#ifdef CONFIG_CPU_ENDIAN_BE8
10#define ZIMAGE_MAGIC(x) ( (((x) >> 24) & 0x000000ff) | \
11 (((x) >> 8) & 0x0000ff00) | \
12 (((x) << 8) & 0x00ff0000) | \
13 (((x) << 24) & 0xff000000) )
14#else
15#define ZIMAGE_MAGIC(x) (x)
16#endif
17
18OUTPUT_ARCH(arm)
19ENTRY(_start)
20SECTIONS
21{
22 /DISCARD/ : {
23 *(.ARM.exidx*)
24 *(.ARM.extab*)
25 /*
26 * Discard any r/w data - this produces a link error if we have any,
27 * which is required for PIC decompression. Local data generates
28 * GOTOFF relocations, which prevents it being relocated independently
29 * of the text/got segments.
30 */
31 *(.data)
32 }
33
34 . = TEXT_START;
35 _text = .;
36
37 .text : {
38 _start = .;
39 *(.start)
40 *(.text)
41 *(.text.*)
42 *(.fixup)
43 *(.gnu.warning)
44 *(.glue_7t)
45 *(.glue_7)
46 }
47 .table : ALIGN(4) {
48 _table_start = .;
49 LONG(ZIMAGE_MAGIC(2))
50 LONG(ZIMAGE_MAGIC(0x5a534c4b))
51 LONG(ZIMAGE_MAGIC(__piggy_size_addr - _start))
52 LONG(ZIMAGE_MAGIC(_kernel_bss_size))
53 LONG(0)
54 _table_end = .;
55 }
56 .rodata : {
57 *(.rodata)
58 *(.rodata.*)
59 *(.data.rel.ro)
60 }
61 .piggydata : {
62 *(.piggydata)
63 __piggy_size_addr = . - 4;
64 }
65
66 . = ALIGN(4);
67 _etext = .;
68
69 .got.plt : { *(.got.plt) }
70 _got_start = .;
71 .got : { *(.got) }
72 _got_end = .;
73
74 /* ensure the zImage file size is always a multiple of 64 bits */
75 /* (without a dummy byte, ld just ignores the empty section) */
76 .pad : { BYTE(0); . = ALIGN(8); }
77
78#ifdef CONFIG_EFI_STUB
79 .data : ALIGN(4096) {
80 __pecoff_data_start = .;
81 /*
82 * The EFI stub always executes from RAM, and runs strictly before the
83 * decompressor, so we can make an exception for its r/w data, and keep it
84 */
85 *(.data.efistub)
86 __pecoff_data_end = .;
87
88 /*
89 * PE/COFF mandates a file size which is a multiple of 512 bytes if the
90 * section size equals or exceeds 4 KB
91 */
92 . = ALIGN(512);
93 }
94 __pecoff_data_rawsize = . - ADDR(.data);
95#endif
96
97 _edata = .;
98
99 /*
100 * The image_end section appears after any additional loadable sections
101 * that the linker may decide to insert in the binary image. Having
102 * this symbol allows further debug in the near future.
103 */
104 .image_end (NOLOAD) : {
105 /*
106 * EFI requires that the image is aligned to 512 bytes, and appended
107 * DTB requires that we know where the end of the image is. Ensure
108 * that both are satisfied by ensuring that there are no additional
109 * sections emitted into the decompressor image.
110 */
111 _edata_real = .;
112 }
113
114 _magic_sig = ZIMAGE_MAGIC(0x016f2818);
115 _magic_start = ZIMAGE_MAGIC(_start);
116 _magic_end = ZIMAGE_MAGIC(_edata);
117 _magic_table = ZIMAGE_MAGIC(_table_start - _start);
118
119 . = BSS_START;
120 __bss_start = .;
121 .bss : { *(.bss) }
122 _end = .;
123
124 . = ALIGN(8); /* the stack must be 64-bit aligned */
125 .stack : { *(.stack) }
126
127 PROVIDE(__pecoff_data_size = ALIGN(512) - ADDR(.data));
128 PROVIDE(__pecoff_end = ALIGN(512));
129
130 .stab 0 : { *(.stab) }
131 .stabstr 0 : { *(.stabstr) }
132 .stab.excl 0 : { *(.stab.excl) }
133 .stab.exclstr 0 : { *(.stab.exclstr) }
134 .stab.index 0 : { *(.stab.index) }
135 .stab.indexstr 0 : { *(.stab.indexstr) }
136 .comment 0 : { *(.comment) }
137}
138ASSERT(_edata_real == _edata, "error: zImage file size is incorrect");