Loading...
1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * header.S
4 *
5 * Copyright (C) 1991, 1992 Linus Torvalds
6 *
7 * Based on bootsect.S and setup.S
8 * modified by more people than can be counted
9 *
10 * Rewritten as a common file by H. Peter Anvin (Apr 2007)
11 *
12 * BIG FAT NOTE: We're in real mode using 64k segments. Therefore segment
13 * addresses must be multiplied by 16 to obtain their respective linear
14 * addresses. To avoid confusion, linear addresses are written using leading
15 * hex while segment addresses are written as segment:offset.
16 *
17 */
18#include <linux/pe.h>
19#include <asm/segment.h>
20#include <asm/boot.h>
21#include <asm/page_types.h>
22#include <asm/setup.h>
23#include <asm/bootparam.h>
24#include "boot.h"
25#include "voffset.h"
26#include "zoffset.h"
27
28BOOTSEG = 0x07C0 /* original address of boot-sector */
29SYSSEG = 0x1000 /* historical load address >> 4 */
30
31#ifndef SVGA_MODE
32#define SVGA_MODE ASK_VGA
33#endif
34
35#ifndef ROOT_RDONLY
36#define ROOT_RDONLY 1
37#endif
38
39 .code16
40 .section ".bstext", "ax"
41
42 .global bootsect_start
43bootsect_start:
44#ifdef CONFIG_EFI_STUB
45 # "MZ", MS-DOS header
46 .word MZ_MAGIC
47#endif
48
49 # Normalize the start address
50 ljmp $BOOTSEG, $start2
51
52start2:
53 movw %cs, %ax
54 movw %ax, %ds
55 movw %ax, %es
56 movw %ax, %ss
57 xorw %sp, %sp
58 sti
59 cld
60
61 movw $bugger_off_msg, %si
62
63msg_loop:
64 lodsb
65 andb %al, %al
66 jz bs_die
67 movb $0xe, %ah
68 movw $7, %bx
69 int $0x10
70 jmp msg_loop
71
72bs_die:
73 # Allow the user to press a key, then reboot
74 xorw %ax, %ax
75 int $0x16
76 int $0x19
77
78 # int 0x19 should never return. In case it does anyway,
79 # invoke the BIOS reset code...
80 ljmp $0xf000,$0xfff0
81
82#ifdef CONFIG_EFI_STUB
83 .org 0x38
84 #
85 # Offset to the PE header.
86 #
87 .long LINUX_PE_MAGIC
88 .long pe_header
89#endif /* CONFIG_EFI_STUB */
90
91 .section ".bsdata", "a"
92bugger_off_msg:
93 .ascii "Use a boot loader.\r\n"
94 .ascii "\n"
95 .ascii "Remove disk and press any key to reboot...\r\n"
96 .byte 0
97
98#ifdef CONFIG_EFI_STUB
99pe_header:
100 .long PE_MAGIC
101
102coff_header:
103#ifdef CONFIG_X86_32
104 .set image_file_add_flags, IMAGE_FILE_32BIT_MACHINE
105 .set pe_opt_magic, PE_OPT_MAGIC_PE32
106 .word IMAGE_FILE_MACHINE_I386
107#else
108 .set image_file_add_flags, 0
109 .set pe_opt_magic, PE_OPT_MAGIC_PE32PLUS
110 .word IMAGE_FILE_MACHINE_AMD64
111#endif
112 .word section_count # nr_sections
113 .long 0 # TimeDateStamp
114 .long 0 # PointerToSymbolTable
115 .long 1 # NumberOfSymbols
116 .word section_table - optional_header # SizeOfOptionalHeader
117 .word IMAGE_FILE_EXECUTABLE_IMAGE | \
118 image_file_add_flags | \
119 IMAGE_FILE_DEBUG_STRIPPED | \
120 IMAGE_FILE_LINE_NUMS_STRIPPED # Characteristics
121
122optional_header:
123 .word pe_opt_magic
124 .byte 0x02 # MajorLinkerVersion
125 .byte 0x14 # MinorLinkerVersion
126
127 # Filled in by build.c
128 .long 0 # SizeOfCode
129
130 .long 0 # SizeOfInitializedData
131 .long 0 # SizeOfUninitializedData
132
133 # Filled in by build.c
134 .long 0x0000 # AddressOfEntryPoint
135
136 .long 0x0200 # BaseOfCode
137#ifdef CONFIG_X86_32
138 .long 0 # data
139#endif
140
141extra_header_fields:
142 # PE specification requires ImageBase to be 64k aligned
143 .set image_base, (LOAD_PHYSICAL_ADDR + 0xffff) & ~0xffff
144#ifdef CONFIG_X86_32
145 .long image_base # ImageBase
146#else
147 .quad image_base # ImageBase
148#endif
149 .long 0x20 # SectionAlignment
150 .long 0x20 # FileAlignment
151 .word 0 # MajorOperatingSystemVersion
152 .word 0 # MinorOperatingSystemVersion
153 .word LINUX_EFISTUB_MAJOR_VERSION # MajorImageVersion
154 .word LINUX_EFISTUB_MINOR_VERSION # MinorImageVersion
155 .word 0 # MajorSubsystemVersion
156 .word 0 # MinorSubsystemVersion
157 .long 0 # Win32VersionValue
158
159 #
160 # The size of the bzImage is written in tools/build.c
161 #
162 .long 0 # SizeOfImage
163
164 .long 0x200 # SizeOfHeaders
165 .long 0 # CheckSum
166 .word IMAGE_SUBSYSTEM_EFI_APPLICATION # Subsystem (EFI application)
167#ifdef CONFIG_EFI_DXE_MEM_ATTRIBUTES
168 .word IMAGE_DLL_CHARACTERISTICS_NX_COMPAT # DllCharacteristics
169#else
170 .word 0 # DllCharacteristics
171#endif
172#ifdef CONFIG_X86_32
173 .long 0 # SizeOfStackReserve
174 .long 0 # SizeOfStackCommit
175 .long 0 # SizeOfHeapReserve
176 .long 0 # SizeOfHeapCommit
177#else
178 .quad 0 # SizeOfStackReserve
179 .quad 0 # SizeOfStackCommit
180 .quad 0 # SizeOfHeapReserve
181 .quad 0 # SizeOfHeapCommit
182#endif
183 .long 0 # LoaderFlags
184 .long (section_table - .) / 8 # NumberOfRvaAndSizes
185
186 .quad 0 # ExportTable
187 .quad 0 # ImportTable
188 .quad 0 # ResourceTable
189 .quad 0 # ExceptionTable
190 .quad 0 # CertificationTable
191 .quad 0 # BaseRelocationTable
192
193 # Section table
194section_table:
195 #
196 # The offset & size fields are filled in by build.c.
197 #
198 .ascii ".setup"
199 .byte 0
200 .byte 0
201 .long 0
202 .long 0x0 # startup_{32,64}
203 .long 0 # Size of initialized data
204 # on disk
205 .long 0x0 # startup_{32,64}
206 .long 0 # PointerToRelocations
207 .long 0 # PointerToLineNumbers
208 .word 0 # NumberOfRelocations
209 .word 0 # NumberOfLineNumbers
210 .long IMAGE_SCN_CNT_CODE | \
211 IMAGE_SCN_MEM_READ | \
212 IMAGE_SCN_MEM_EXECUTE | \
213 IMAGE_SCN_ALIGN_16BYTES # Characteristics
214
215 #
216 # The EFI application loader requires a relocation section
217 # because EFI applications must be relocatable. The .reloc
218 # offset & size fields are filled in by build.c.
219 #
220 .ascii ".reloc"
221 .byte 0
222 .byte 0
223 .long 0
224 .long 0
225 .long 0 # SizeOfRawData
226 .long 0 # PointerToRawData
227 .long 0 # PointerToRelocations
228 .long 0 # PointerToLineNumbers
229 .word 0 # NumberOfRelocations
230 .word 0 # NumberOfLineNumbers
231 .long IMAGE_SCN_CNT_INITIALIZED_DATA | \
232 IMAGE_SCN_MEM_READ | \
233 IMAGE_SCN_MEM_DISCARDABLE | \
234 IMAGE_SCN_ALIGN_1BYTES # Characteristics
235
236#ifdef CONFIG_EFI_MIXED
237 #
238 # The offset & size fields are filled in by build.c.
239 #
240 .asciz ".compat"
241 .long 0
242 .long 0x0
243 .long 0 # Size of initialized data
244 # on disk
245 .long 0x0
246 .long 0 # PointerToRelocations
247 .long 0 # PointerToLineNumbers
248 .word 0 # NumberOfRelocations
249 .word 0 # NumberOfLineNumbers
250 .long IMAGE_SCN_CNT_INITIALIZED_DATA | \
251 IMAGE_SCN_MEM_READ | \
252 IMAGE_SCN_MEM_DISCARDABLE | \
253 IMAGE_SCN_ALIGN_1BYTES # Characteristics
254#endif
255
256 #
257 # The offset & size fields are filled in by build.c.
258 #
259 .ascii ".text"
260 .byte 0
261 .byte 0
262 .byte 0
263 .long 0
264 .long 0x0 # startup_{32,64}
265 .long 0 # Size of initialized data
266 # on disk
267 .long 0x0 # startup_{32,64}
268 .long 0 # PointerToRelocations
269 .long 0 # PointerToLineNumbers
270 .word 0 # NumberOfRelocations
271 .word 0 # NumberOfLineNumbers
272 .long IMAGE_SCN_CNT_CODE | \
273 IMAGE_SCN_MEM_READ | \
274 IMAGE_SCN_MEM_EXECUTE | \
275 IMAGE_SCN_ALIGN_16BYTES # Characteristics
276
277 .set section_count, (. - section_table) / 40
278#endif /* CONFIG_EFI_STUB */
279
280 # Kernel attributes; used by setup. This is part 1 of the
281 # header, from the old boot sector.
282
283 .section ".header", "a"
284 .globl sentinel
285sentinel: .byte 0xff, 0xff /* Used to detect broken loaders */
286
287 .globl hdr
288hdr:
289setup_sects: .byte 0 /* Filled in by build.c */
290root_flags: .word ROOT_RDONLY
291syssize: .long 0 /* Filled in by build.c */
292ram_size: .word 0 /* Obsolete */
293vid_mode: .word SVGA_MODE
294root_dev: .word 0 /* Filled in by build.c */
295boot_flag: .word 0xAA55
296
297 # offset 512, entry point
298
299 .globl _start
300_start:
301 # Explicitly enter this as bytes, or the assembler
302 # tries to generate a 3-byte jump here, which causes
303 # everything else to push off to the wrong offset.
304 .byte 0xeb # short (2-byte) jump
305 .byte start_of_setup-1f
3061:
307
308 # Part 2 of the header, from the old setup.S
309
310 .ascii "HdrS" # header signature
311 .word 0x020f # header version number (>= 0x0105)
312 # or else old loadlin-1.5 will fail)
313 .globl realmode_swtch
314realmode_swtch: .word 0, 0 # default_switch, SETUPSEG
315start_sys_seg: .word SYSSEG # obsolete and meaningless, but just
316 # in case something decided to "use" it
317 .word kernel_version-512 # pointing to kernel version string
318 # above section of header is compatible
319 # with loadlin-1.5 (header v1.5). Don't
320 # change it.
321
322type_of_loader: .byte 0 # 0 means ancient bootloader, newer
323 # bootloaders know to change this.
324 # See Documentation/x86/boot.rst for
325 # assigned ids
326
327# flags, unused bits must be zero (RFU) bit within loadflags
328loadflags:
329 .byte LOADED_HIGH # The kernel is to be loaded high
330
331setup_move_size: .word 0x8000 # size to move, when setup is not
332 # loaded at 0x90000. We will move setup
333 # to 0x90000 then just before jumping
334 # into the kernel. However, only the
335 # loader knows how much data behind
336 # us also needs to be loaded.
337
338code32_start: # here loaders can put a different
339 # start address for 32-bit code.
340 .long 0x100000 # 0x100000 = default for big kernel
341
342ramdisk_image: .long 0 # address of loaded ramdisk image
343 # Here the loader puts the 32-bit
344 # address where it loaded the image.
345 # This only will be read by the kernel.
346
347ramdisk_size: .long 0 # its size in bytes
348
349bootsect_kludge:
350 .long 0 # obsolete
351
352heap_end_ptr: .word _end+STACK_SIZE-512
353 # (Header version 0x0201 or later)
354 # space from here (exclusive) down to
355 # end of setup code can be used by setup
356 # for local heap purposes.
357
358ext_loader_ver:
359 .byte 0 # Extended boot loader version
360ext_loader_type:
361 .byte 0 # Extended boot loader type
362
363cmd_line_ptr: .long 0 # (Header version 0x0202 or later)
364 # If nonzero, a 32-bit pointer
365 # to the kernel command line.
366 # The command line should be
367 # located between the start of
368 # setup and the end of low
369 # memory (0xa0000), or it may
370 # get overwritten before it
371 # gets read. If this field is
372 # used, there is no longer
373 # anything magical about the
374 # 0x90000 segment; the setup
375 # can be located anywhere in
376 # low memory 0x10000 or higher.
377
378initrd_addr_max: .long 0x7fffffff
379 # (Header version 0x0203 or later)
380 # The highest safe address for
381 # the contents of an initrd
382 # The current kernel allows up to 4 GB,
383 # but leave it at 2 GB to avoid
384 # possible bootloader bugs.
385
386kernel_alignment: .long CONFIG_PHYSICAL_ALIGN #physical addr alignment
387 #required for protected mode
388 #kernel
389#ifdef CONFIG_RELOCATABLE
390relocatable_kernel: .byte 1
391#else
392relocatable_kernel: .byte 0
393#endif
394min_alignment: .byte MIN_KERNEL_ALIGN_LG2 # minimum alignment
395
396xloadflags:
397#ifdef CONFIG_X86_64
398# define XLF0 XLF_KERNEL_64 /* 64-bit kernel */
399#else
400# define XLF0 0
401#endif
402
403#if defined(CONFIG_RELOCATABLE) && defined(CONFIG_X86_64)
404 /* kernel/boot_param/ramdisk could be loaded above 4g */
405# define XLF1 XLF_CAN_BE_LOADED_ABOVE_4G
406#else
407# define XLF1 0
408#endif
409
410#ifdef CONFIG_EFI_HANDOVER_PROTOCOL
411# ifdef CONFIG_EFI_MIXED
412# define XLF23 (XLF_EFI_HANDOVER_32|XLF_EFI_HANDOVER_64)
413# else
414# ifdef CONFIG_X86_64
415# define XLF23 XLF_EFI_HANDOVER_64 /* 64-bit EFI handover ok */
416# else
417# define XLF23 XLF_EFI_HANDOVER_32 /* 32-bit EFI handover ok */
418# endif
419# endif
420#else
421# define XLF23 0
422#endif
423
424#if defined(CONFIG_X86_64) && defined(CONFIG_EFI) && defined(CONFIG_KEXEC_CORE)
425# define XLF4 XLF_EFI_KEXEC
426#else
427# define XLF4 0
428#endif
429
430#ifdef CONFIG_X86_64
431#ifdef CONFIG_X86_5LEVEL
432#define XLF56 (XLF_5LEVEL|XLF_5LEVEL_ENABLED)
433#else
434#define XLF56 XLF_5LEVEL
435#endif
436#else
437#define XLF56 0
438#endif
439
440 .word XLF0 | XLF1 | XLF23 | XLF4 | XLF56
441
442cmdline_size: .long COMMAND_LINE_SIZE-1 #length of the command line,
443 #added with boot protocol
444 #version 2.06
445
446hardware_subarch: .long 0 # subarchitecture, added with 2.07
447 # default to 0 for normal x86 PC
448
449hardware_subarch_data: .quad 0
450
451payload_offset: .long ZO_input_data
452payload_length: .long ZO_z_input_len
453
454setup_data: .quad 0 # 64-bit physical pointer to
455 # single linked list of
456 # struct setup_data
457
458pref_address: .quad LOAD_PHYSICAL_ADDR # preferred load addr
459
460#
461# Getting to provably safe in-place decompression is hard. Worst case
462# behaviours need to be analyzed. Here let's take the decompression of
463# a gzip-compressed kernel as example, to illustrate it:
464#
465# The file layout of gzip compressed kernel is:
466#
467# magic[2]
468# method[1]
469# flags[1]
470# timestamp[4]
471# extraflags[1]
472# os[1]
473# compressed data blocks[N]
474# crc[4] orig_len[4]
475#
476# ... resulting in +18 bytes overhead of uncompressed data.
477#
478# (For more information, please refer to RFC 1951 and RFC 1952.)
479#
480# Files divided into blocks
481# 1 bit (last block flag)
482# 2 bits (block type)
483#
484# 1 block occurs every 32K -1 bytes or when there 50% compression
485# has been achieved. The smallest block type encoding is always used.
486#
487# stored:
488# 32 bits length in bytes.
489#
490# fixed:
491# magic fixed tree.
492# symbols.
493#
494# dynamic:
495# dynamic tree encoding.
496# symbols.
497#
498#
499# The buffer for decompression in place is the length of the uncompressed
500# data, plus a small amount extra to keep the algorithm safe. The
501# compressed data is placed at the end of the buffer. The output pointer
502# is placed at the start of the buffer and the input pointer is placed
503# where the compressed data starts. Problems will occur when the output
504# pointer overruns the input pointer.
505#
506# The output pointer can only overrun the input pointer if the input
507# pointer is moving faster than the output pointer. A condition only
508# triggered by data whose compressed form is larger than the uncompressed
509# form.
510#
511# The worst case at the block level is a growth of the compressed data
512# of 5 bytes per 32767 bytes.
513#
514# The worst case internal to a compressed block is very hard to figure.
515# The worst case can at least be bounded by having one bit that represents
516# 32764 bytes and then all of the rest of the bytes representing the very
517# very last byte.
518#
519# All of which is enough to compute an amount of extra data that is required
520# to be safe. To avoid problems at the block level allocating 5 extra bytes
521# per 32767 bytes of data is sufficient. To avoid problems internal to a
522# block adding an extra 32767 bytes (the worst case uncompressed block size)
523# is sufficient, to ensure that in the worst case the decompressed data for
524# block will stop the byte before the compressed data for a block begins.
525# To avoid problems with the compressed data's meta information an extra 18
526# bytes are needed. Leading to the formula:
527#
528# extra_bytes = (uncompressed_size >> 12) + 32768 + 18
529#
530# Adding 8 bytes per 32K is a bit excessive but much easier to calculate.
531# Adding 32768 instead of 32767 just makes for round numbers.
532#
533# Above analysis is for decompressing gzip compressed kernel only. Up to
534# now 6 different decompressor are supported all together. And among them
535# xz stores data in chunks and has maximum chunk of 64K. Hence safety
536# margin should be updated to cover all decompressors so that we don't
537# need to deal with each of them separately. Please check
538# the description in lib/decompressor_xxx.c for specific information.
539#
540# extra_bytes = (uncompressed_size >> 12) + 65536 + 128
541#
542# LZ4 is even worse: data that cannot be further compressed grows by 0.4%,
543# or one byte per 256 bytes. OTOH, we can safely get rid of the +128 as
544# the size-dependent part now grows so fast.
545#
546# extra_bytes = (uncompressed_size >> 8) + 65536
547#
548# ZSTD compressed data grows by at most 3 bytes per 128K, and only has a 22
549# byte fixed overhead but has a maximum block size of 128K, so it needs a
550# larger margin.
551#
552# extra_bytes = (uncompressed_size >> 8) + 131072
553
554#define ZO_z_extra_bytes ((ZO_z_output_len >> 8) + 131072)
555#if ZO_z_output_len > ZO_z_input_len
556# define ZO_z_extract_offset (ZO_z_output_len + ZO_z_extra_bytes - \
557 ZO_z_input_len)
558#else
559# define ZO_z_extract_offset ZO_z_extra_bytes
560#endif
561
562/*
563 * The extract_offset has to be bigger than ZO head section. Otherwise when
564 * the head code is running to move ZO to the end of the buffer, it will
565 * overwrite the head code itself.
566 */
567#if (ZO__ehead - ZO_startup_32) > ZO_z_extract_offset
568# define ZO_z_min_extract_offset ((ZO__ehead - ZO_startup_32 + 4095) & ~4095)
569#else
570# define ZO_z_min_extract_offset ((ZO_z_extract_offset + 4095) & ~4095)
571#endif
572
573#define ZO_INIT_SIZE (ZO__end - ZO_startup_32 + ZO_z_min_extract_offset)
574
575#define VO_INIT_SIZE (VO__end - VO__text)
576#if ZO_INIT_SIZE > VO_INIT_SIZE
577# define INIT_SIZE ZO_INIT_SIZE
578#else
579# define INIT_SIZE VO_INIT_SIZE
580#endif
581
582init_size: .long INIT_SIZE # kernel initialization size
583handover_offset: .long 0 # Filled in by build.c
584kernel_info_offset: .long 0 # Filled in by build.c
585
586# End of setup header #####################################################
587
588 .section ".entrytext", "ax"
589start_of_setup:
590# Force %es = %ds
591 movw %ds, %ax
592 movw %ax, %es
593 cld
594
595# Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
596# which happened to work by accident for the old code. Recalculate the stack
597# pointer if %ss is invalid. Otherwise leave it alone, LOADLIN sets up the
598# stack behind its own code, so we can't blindly put it directly past the heap.
599
600 movw %ss, %dx
601 cmpw %ax, %dx # %ds == %ss?
602 movw %sp, %dx
603 je 2f # -> assume %sp is reasonably set
604
605 # Invalid %ss, make up a new stack
606 movw $_end, %dx
607 testb $CAN_USE_HEAP, loadflags
608 jz 1f
609 movw heap_end_ptr, %dx
6101: addw $STACK_SIZE, %dx
611 jnc 2f
612 xorw %dx, %dx # Prevent wraparound
613
6142: # Now %dx should point to the end of our stack space
615 andw $~3, %dx # dword align (might as well...)
616 jnz 3f
617 movw $0xfffc, %dx # Make sure we're not zero
6183: movw %ax, %ss
619 movzwl %dx, %esp # Clear upper half of %esp
620 sti # Now we should have a working stack
621
622# We will have entered with %cs = %ds+0x20, normalize %cs so
623# it is on par with the other segments.
624 pushw %ds
625 pushw $6f
626 lretw
6276:
628
629# Check signature at end of setup
630 cmpl $0x5a5aaa55, setup_sig
631 jne setup_bad
632
633# Zero the bss
634 movw $__bss_start, %di
635 movw $_end+3, %cx
636 xorl %eax, %eax
637 subw %di, %cx
638 shrw $2, %cx
639 rep; stosl
640
641# Jump to C code (should not return)
642 calll main
643
644# Setup corrupt somehow...
645setup_bad:
646 movl $setup_corrupt, %eax
647 calll puts
648 # Fall through...
649
650 .globl die
651 .type die, @function
652die:
653 hlt
654 jmp die
655
656 .size die, .-die
657
658 .section ".initdata", "a"
659setup_corrupt:
660 .byte 7
661 .string "No setup signature found...\n"
1/*
2 * header.S
3 *
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 *
6 * Based on bootsect.S and setup.S
7 * modified by more people than can be counted
8 *
9 * Rewritten as a common file by H. Peter Anvin (Apr 2007)
10 *
11 * BIG FAT NOTE: We're in real mode using 64k segments. Therefore segment
12 * addresses must be multiplied by 16 to obtain their respective linear
13 * addresses. To avoid confusion, linear addresses are written using leading
14 * hex while segment addresses are written as segment:offset.
15 *
16 */
17
18#include <asm/segment.h>
19#include <generated/utsrelease.h>
20#include <asm/boot.h>
21#include <asm/e820.h>
22#include <asm/page_types.h>
23#include <asm/setup.h>
24#include "boot.h"
25#include "voffset.h"
26#include "zoffset.h"
27
28BOOTSEG = 0x07C0 /* original address of boot-sector */
29SYSSEG = 0x1000 /* historical load address >> 4 */
30
31#ifndef SVGA_MODE
32#define SVGA_MODE ASK_VGA
33#endif
34
35#ifndef RAMDISK
36#define RAMDISK 0
37#endif
38
39#ifndef ROOT_RDONLY
40#define ROOT_RDONLY 1
41#endif
42
43 .code16
44 .section ".bstext", "ax"
45
46 .global bootsect_start
47bootsect_start:
48#ifdef CONFIG_EFI_STUB
49 # "MZ", MS-DOS header
50 .byte 0x4d
51 .byte 0x5a
52#endif
53
54 # Normalize the start address
55 ljmp $BOOTSEG, $start2
56
57start2:
58 movw %cs, %ax
59 movw %ax, %ds
60 movw %ax, %es
61 movw %ax, %ss
62 xorw %sp, %sp
63 sti
64 cld
65
66 movw $bugger_off_msg, %si
67
68msg_loop:
69 lodsb
70 andb %al, %al
71 jz bs_die
72 movb $0xe, %ah
73 movw $7, %bx
74 int $0x10
75 jmp msg_loop
76
77bs_die:
78 # Allow the user to press a key, then reboot
79 xorw %ax, %ax
80 int $0x16
81 int $0x19
82
83 # int 0x19 should never return. In case it does anyway,
84 # invoke the BIOS reset code...
85 ljmp $0xf000,$0xfff0
86
87#ifdef CONFIG_EFI_STUB
88 .org 0x3c
89 #
90 # Offset to the PE header.
91 #
92 .long pe_header
93#endif /* CONFIG_EFI_STUB */
94
95 .section ".bsdata", "a"
96bugger_off_msg:
97 .ascii "Direct floppy boot is not supported. "
98 .ascii "Use a boot loader program instead.\r\n"
99 .ascii "\n"
100 .ascii "Remove disk and press any key to reboot ...\r\n"
101 .byte 0
102
103#ifdef CONFIG_EFI_STUB
104pe_header:
105 .ascii "PE"
106 .word 0
107
108coff_header:
109#ifdef CONFIG_X86_32
110 .word 0x14c # i386
111#else
112 .word 0x8664 # x86-64
113#endif
114 .word 3 # nr_sections
115 .long 0 # TimeDateStamp
116 .long 0 # PointerToSymbolTable
117 .long 1 # NumberOfSymbols
118 .word section_table - optional_header # SizeOfOptionalHeader
119#ifdef CONFIG_X86_32
120 .word 0x306 # Characteristics.
121 # IMAGE_FILE_32BIT_MACHINE |
122 # IMAGE_FILE_DEBUG_STRIPPED |
123 # IMAGE_FILE_EXECUTABLE_IMAGE |
124 # IMAGE_FILE_LINE_NUMS_STRIPPED
125#else
126 .word 0x206 # Characteristics
127 # IMAGE_FILE_DEBUG_STRIPPED |
128 # IMAGE_FILE_EXECUTABLE_IMAGE |
129 # IMAGE_FILE_LINE_NUMS_STRIPPED
130#endif
131
132optional_header:
133#ifdef CONFIG_X86_32
134 .word 0x10b # PE32 format
135#else
136 .word 0x20b # PE32+ format
137#endif
138 .byte 0x02 # MajorLinkerVersion
139 .byte 0x14 # MinorLinkerVersion
140
141 # Filled in by build.c
142 .long 0 # SizeOfCode
143
144 .long 0 # SizeOfInitializedData
145 .long 0 # SizeOfUninitializedData
146
147 # Filled in by build.c
148 .long 0x0000 # AddressOfEntryPoint
149
150 .long 0x0200 # BaseOfCode
151#ifdef CONFIG_X86_32
152 .long 0 # data
153#endif
154
155extra_header_fields:
156#ifdef CONFIG_X86_32
157 .long 0 # ImageBase
158#else
159 .quad 0 # ImageBase
160#endif
161 .long 0x20 # SectionAlignment
162 .long 0x20 # FileAlignment
163 .word 0 # MajorOperatingSystemVersion
164 .word 0 # MinorOperatingSystemVersion
165 .word 0 # MajorImageVersion
166 .word 0 # MinorImageVersion
167 .word 0 # MajorSubsystemVersion
168 .word 0 # MinorSubsystemVersion
169 .long 0 # Win32VersionValue
170
171 #
172 # The size of the bzImage is written in tools/build.c
173 #
174 .long 0 # SizeOfImage
175
176 .long 0x200 # SizeOfHeaders
177 .long 0 # CheckSum
178 .word 0xa # Subsystem (EFI application)
179 .word 0 # DllCharacteristics
180#ifdef CONFIG_X86_32
181 .long 0 # SizeOfStackReserve
182 .long 0 # SizeOfStackCommit
183 .long 0 # SizeOfHeapReserve
184 .long 0 # SizeOfHeapCommit
185#else
186 .quad 0 # SizeOfStackReserve
187 .quad 0 # SizeOfStackCommit
188 .quad 0 # SizeOfHeapReserve
189 .quad 0 # SizeOfHeapCommit
190#endif
191 .long 0 # LoaderFlags
192 .long 0x6 # NumberOfRvaAndSizes
193
194 .quad 0 # ExportTable
195 .quad 0 # ImportTable
196 .quad 0 # ResourceTable
197 .quad 0 # ExceptionTable
198 .quad 0 # CertificationTable
199 .quad 0 # BaseRelocationTable
200
201 # Section table
202section_table:
203 #
204 # The offset & size fields are filled in by build.c.
205 #
206 .ascii ".setup"
207 .byte 0
208 .byte 0
209 .long 0
210 .long 0x0 # startup_{32,64}
211 .long 0 # Size of initialized data
212 # on disk
213 .long 0x0 # startup_{32,64}
214 .long 0 # PointerToRelocations
215 .long 0 # PointerToLineNumbers
216 .word 0 # NumberOfRelocations
217 .word 0 # NumberOfLineNumbers
218 .long 0x60500020 # Characteristics (section flags)
219
220 #
221 # The EFI application loader requires a relocation section
222 # because EFI applications must be relocatable. The .reloc
223 # offset & size fields are filled in by build.c.
224 #
225 .ascii ".reloc"
226 .byte 0
227 .byte 0
228 .long 0
229 .long 0
230 .long 0 # SizeOfRawData
231 .long 0 # PointerToRawData
232 .long 0 # PointerToRelocations
233 .long 0 # PointerToLineNumbers
234 .word 0 # NumberOfRelocations
235 .word 0 # NumberOfLineNumbers
236 .long 0x42100040 # Characteristics (section flags)
237
238 #
239 # The offset & size fields are filled in by build.c.
240 #
241 .ascii ".text"
242 .byte 0
243 .byte 0
244 .byte 0
245 .long 0
246 .long 0x0 # startup_{32,64}
247 .long 0 # Size of initialized data
248 # on disk
249 .long 0x0 # startup_{32,64}
250 .long 0 # PointerToRelocations
251 .long 0 # PointerToLineNumbers
252 .word 0 # NumberOfRelocations
253 .word 0 # NumberOfLineNumbers
254 .long 0x60500020 # Characteristics (section flags)
255
256#endif /* CONFIG_EFI_STUB */
257
258 # Kernel attributes; used by setup. This is part 1 of the
259 # header, from the old boot sector.
260
261 .section ".header", "a"
262 .globl hdr
263hdr:
264setup_sects: .byte 0 /* Filled in by build.c */
265root_flags: .word ROOT_RDONLY
266syssize: .long 0 /* Filled in by build.c */
267ram_size: .word 0 /* Obsolete */
268vid_mode: .word SVGA_MODE
269root_dev: .word 0 /* Filled in by build.c */
270boot_flag: .word 0xAA55
271
272 # offset 512, entry point
273
274 .globl _start
275_start:
276 # Explicitly enter this as bytes, or the assembler
277 # tries to generate a 3-byte jump here, which causes
278 # everything else to push off to the wrong offset.
279 .byte 0xeb # short (2-byte) jump
280 .byte start_of_setup-1f
2811:
282
283 # Part 2 of the header, from the old setup.S
284
285 .ascii "HdrS" # header signature
286 .word 0x020a # header version number (>= 0x0105)
287 # or else old loadlin-1.5 will fail)
288 .globl realmode_swtch
289realmode_swtch: .word 0, 0 # default_switch, SETUPSEG
290start_sys_seg: .word SYSSEG # obsolete and meaningless, but just
291 # in case something decided to "use" it
292 .word kernel_version-512 # pointing to kernel version string
293 # above section of header is compatible
294 # with loadlin-1.5 (header v1.5). Don't
295 # change it.
296
297type_of_loader: .byte 0 # 0 means ancient bootloader, newer
298 # bootloaders know to change this.
299 # See Documentation/x86/boot.txt for
300 # assigned ids
301
302# flags, unused bits must be zero (RFU) bit within loadflags
303loadflags:
304LOADED_HIGH = 1 # If set, the kernel is loaded high
305CAN_USE_HEAP = 0x80 # If set, the loader also has set
306 # heap_end_ptr to tell how much
307 # space behind setup.S can be used for
308 # heap purposes.
309 # Only the loader knows what is free
310 .byte LOADED_HIGH
311
312setup_move_size: .word 0x8000 # size to move, when setup is not
313 # loaded at 0x90000. We will move setup
314 # to 0x90000 then just before jumping
315 # into the kernel. However, only the
316 # loader knows how much data behind
317 # us also needs to be loaded.
318
319code32_start: # here loaders can put a different
320 # start address for 32-bit code.
321 .long 0x100000 # 0x100000 = default for big kernel
322
323ramdisk_image: .long 0 # address of loaded ramdisk image
324 # Here the loader puts the 32-bit
325 # address where it loaded the image.
326 # This only will be read by the kernel.
327
328ramdisk_size: .long 0 # its size in bytes
329
330bootsect_kludge:
331 .long 0 # obsolete
332
333heap_end_ptr: .word _end+STACK_SIZE-512
334 # (Header version 0x0201 or later)
335 # space from here (exclusive) down to
336 # end of setup code can be used by setup
337 # for local heap purposes.
338
339ext_loader_ver:
340 .byte 0 # Extended boot loader version
341ext_loader_type:
342 .byte 0 # Extended boot loader type
343
344cmd_line_ptr: .long 0 # (Header version 0x0202 or later)
345 # If nonzero, a 32-bit pointer
346 # to the kernel command line.
347 # The command line should be
348 # located between the start of
349 # setup and the end of low
350 # memory (0xa0000), or it may
351 # get overwritten before it
352 # gets read. If this field is
353 # used, there is no longer
354 # anything magical about the
355 # 0x90000 segment; the setup
356 # can be located anywhere in
357 # low memory 0x10000 or higher.
358
359ramdisk_max: .long 0x7fffffff
360 # (Header version 0x0203 or later)
361 # The highest safe address for
362 # the contents of an initrd
363 # The current kernel allows up to 4 GB,
364 # but leave it at 2 GB to avoid
365 # possible bootloader bugs.
366
367kernel_alignment: .long CONFIG_PHYSICAL_ALIGN #physical addr alignment
368 #required for protected mode
369 #kernel
370#ifdef CONFIG_RELOCATABLE
371relocatable_kernel: .byte 1
372#else
373relocatable_kernel: .byte 0
374#endif
375min_alignment: .byte MIN_KERNEL_ALIGN_LG2 # minimum alignment
376pad3: .word 0
377
378cmdline_size: .long COMMAND_LINE_SIZE-1 #length of the command line,
379 #added with boot protocol
380 #version 2.06
381
382hardware_subarch: .long 0 # subarchitecture, added with 2.07
383 # default to 0 for normal x86 PC
384
385hardware_subarch_data: .quad 0
386
387payload_offset: .long ZO_input_data
388payload_length: .long ZO_z_input_len
389
390setup_data: .quad 0 # 64-bit physical pointer to
391 # single linked list of
392 # struct setup_data
393
394pref_address: .quad LOAD_PHYSICAL_ADDR # preferred load addr
395
396#define ZO_INIT_SIZE (ZO__end - ZO_startup_32 + ZO_z_extract_offset)
397#define VO_INIT_SIZE (VO__end - VO__text)
398#if ZO_INIT_SIZE > VO_INIT_SIZE
399#define INIT_SIZE ZO_INIT_SIZE
400#else
401#define INIT_SIZE VO_INIT_SIZE
402#endif
403init_size: .long INIT_SIZE # kernel initialization size
404
405# End of setup header #####################################################
406
407 .section ".entrytext", "ax"
408start_of_setup:
409#ifdef SAFE_RESET_DISK_CONTROLLER
410# Reset the disk controller.
411 movw $0x0000, %ax # Reset disk controller
412 movb $0x80, %dl # All disks
413 int $0x13
414#endif
415
416# Force %es = %ds
417 movw %ds, %ax
418 movw %ax, %es
419 cld
420
421# Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
422# which happened to work by accident for the old code. Recalculate the stack
423# pointer if %ss is invalid. Otherwise leave it alone, LOADLIN sets up the
424# stack behind its own code, so we can't blindly put it directly past the heap.
425
426 movw %ss, %dx
427 cmpw %ax, %dx # %ds == %ss?
428 movw %sp, %dx
429 je 2f # -> assume %sp is reasonably set
430
431 # Invalid %ss, make up a new stack
432 movw $_end, %dx
433 testb $CAN_USE_HEAP, loadflags
434 jz 1f
435 movw heap_end_ptr, %dx
4361: addw $STACK_SIZE, %dx
437 jnc 2f
438 xorw %dx, %dx # Prevent wraparound
439
4402: # Now %dx should point to the end of our stack space
441 andw $~3, %dx # dword align (might as well...)
442 jnz 3f
443 movw $0xfffc, %dx # Make sure we're not zero
4443: movw %ax, %ss
445 movzwl %dx, %esp # Clear upper half of %esp
446 sti # Now we should have a working stack
447
448# We will have entered with %cs = %ds+0x20, normalize %cs so
449# it is on par with the other segments.
450 pushw %ds
451 pushw $6f
452 lretw
4536:
454
455# Check signature at end of setup
456 cmpl $0x5a5aaa55, setup_sig
457 jne setup_bad
458
459# Zero the bss
460 movw $__bss_start, %di
461 movw $_end+3, %cx
462 xorl %eax, %eax
463 subw %di, %cx
464 shrw $2, %cx
465 rep; stosl
466
467# Jump to C code (should not return)
468 calll main
469
470# Setup corrupt somehow...
471setup_bad:
472 movl $setup_corrupt, %eax
473 calll puts
474 # Fall through...
475
476 .globl die
477 .type die, @function
478die:
479 hlt
480 jmp die
481
482 .size die, .-die
483
484 .section ".initdata", "a"
485setup_corrupt:
486 .byte 7
487 .string "No setup signature found...\n"
488
489 .data
490dummy: .long 0