1/*
 2 * This file is subject to the terms and conditions of the GNU General Public
 3 * License.  See the file "COPYING" in the main directory of this archive
 4 * for more details.
 5 *
 6 * Copyright (C) 1996, 1998, 1999, 2004 by Ralf Baechle
 7 * Copyright (C) 1999 Silicon Graphics, Inc.
 8 * Copyright (C) 2011 MIPS Technologies, Inc.
 9 */
10#include <asm/asm.h>
11#include <asm/asm-offsets.h>
12#include <asm/regdef.h>
13
14#define EX(insn,reg,addr,handler)			\
159:	insn	reg, addr;				\
16	.section __ex_table,"a";			\
17	PTR	9b, handler;				\
18	.previous
19
20/*
21 * Return the size of a string (including the ending 0)
22 *
23 * Return 0 for error
24 */
25	.macro __BUILD_STRLEN_ASM func
26LEAF(__strlen_\func\()_asm)
27	LONG_L		v0, TI_ADDR_LIMIT($28)	# pointer ok?
28	and		v0, a0
29	bnez		v0, .Lfault\@
30
31FEXPORT(__strlen_\func\()_nocheck_asm)
32	move		v0, a0
33.ifeqs "\func", "kernel"
341:	EX(lbu, v1, (v0), .Lfault\@)
35.else
361:	EX(lbue, v1, (v0), .Lfault\@)
37.endif
38	PTR_ADDIU	v0, 1
39	bnez		v1, 1b
40	PTR_SUBU	v0, a0
41	jr		ra
42	END(__strlen_\func\()_asm)
43
44.Lfault\@:	move		v0, zero
45	jr		ra
46	.endm
47
48#ifndef CONFIG_EVA
49	/* Set aliases */
50	.global __strlen_user_asm
51	.global __strlen_user_nocheck_asm
52	.set __strlen_user_asm, __strlen_kernel_asm
53	.set __strlen_user_nocheck_asm, __strlen_kernel_nocheck_asm
54#endif
55
56__BUILD_STRLEN_ASM kernel
57
58#ifdef CONFIG_EVA
59
60	.set push
61	.set eva
62__BUILD_STRLEN_ASM user
63	.set pop
64#endif