Loading...
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3# vim: softtabstop=4
4
5use warnings;
6use strict;
7
8## Copyright (c) 1998 Michael Zucchi, All Rights Reserved ##
9## Copyright (C) 2000, 1 Tim Waugh <twaugh@redhat.com> ##
10## Copyright (C) 2001 Simon Huggins ##
11## Copyright (C) 2005-2012 Randy Dunlap ##
12## Copyright (C) 2012 Dan Luedtke ##
13## ##
14## #define enhancements by Armin Kuster <akuster@mvista.com> ##
15## Copyright (c) 2000 MontaVista Software, Inc. ##
16#
17# Copyright (C) 2022 Tomasz Warniełło (POD)
18
19use Pod::Usage qw/pod2usage/;
20
21=head1 NAME
22
23kernel-doc - Print formatted kernel documentation to stdout
24
25=head1 SYNOPSIS
26
27 kernel-doc [-h] [-v] [-Werror] [-Wall] [-Wreturn] [-Wshort-desc[ription]] [-Wcontents-before-sections]
28 [ -man |
29 -rst [-sphinx-version VERSION] [-enable-lineno] |
30 -none
31 ]
32 [
33 -export |
34 -internal |
35 [-function NAME] ... |
36 [-nosymbol NAME] ...
37 ]
38 [-no-doc-sections]
39 [-export-file FILE] ...
40 FILE ...
41
42Run `kernel-doc -h` for details.
43
44=head1 DESCRIPTION
45
46Read C language source or header FILEs, extract embedded documentation comments,
47and print formatted documentation to standard output.
48
49The documentation comments are identified by the "/**" opening comment mark.
50
51See Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
52
53=cut
54
55# more perldoc at the end of the file
56
57## init lots of data
58
59my $errors = 0;
60my $warnings = 0;
61my $anon_struct_union = 0;
62
63# match expressions used to find embedded type information
64my $type_constant = '\b``([^\`]+)``\b';
65my $type_constant2 = '\%([-_*\w]+)';
66my $type_func = '(\w+)\(\)';
67my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
68my $type_param_ref = '([\!~\*]?)\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
69my $type_fp_param = '\@(\w+)\(\)'; # Special RST handling for func ptr params
70my $type_fp_param2 = '\@(\w+->\S+)\(\)'; # Special RST handling for structs with func ptr params
71my $type_env = '(\$\w+)';
72my $type_enum = '\&(enum\s*([_\w]+))';
73my $type_struct = '\&(struct\s*([_\w]+))';
74my $type_typedef = '\&(typedef\s*([_\w]+))';
75my $type_union = '\&(union\s*([_\w]+))';
76my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
77my $type_fallback = '\&([_\w]+)';
78my $type_member_func = $type_member . '\(\)';
79
80# Output conversion substitutions.
81# One for each output format
82
83# these are pretty rough
84my @highlights_man = (
85 [$type_constant, "\$1"],
86 [$type_constant2, "\$1"],
87 [$type_func, "\\\\fB\$1\\\\fP"],
88 [$type_enum, "\\\\fI\$1\\\\fP"],
89 [$type_struct, "\\\\fI\$1\\\\fP"],
90 [$type_typedef, "\\\\fI\$1\\\\fP"],
91 [$type_union, "\\\\fI\$1\\\\fP"],
92 [$type_param, "\\\\fI\$1\\\\fP"],
93 [$type_param_ref, "\\\\fI\$1\$2\\\\fP"],
94 [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
95 [$type_fallback, "\\\\fI\$1\\\\fP"]
96 );
97my $blankline_man = "";
98
99# rst-mode
100my @highlights_rst = (
101 [$type_constant, "``\$1``"],
102 [$type_constant2, "``\$1``"],
103
104 # Note: need to escape () to avoid func matching later
105 [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
106 [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
107 [$type_fp_param, "**\$1\\\\(\\\\)**"],
108 [$type_fp_param2, "**\$1\\\\(\\\\)**"],
109 [$type_func, "\$1()"],
110 [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
111 [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
112 [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
113 [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
114
115 # in rst this can refer to any type
116 [$type_fallback, "\\:c\\:type\\:`\$1`"],
117 [$type_param_ref, "**\$1\$2**"]
118 );
119my $blankline_rst = "\n";
120
121# read arguments
122if ($#ARGV == -1) {
123 pod2usage(
124 -message => "No arguments!\n",
125 -exitval => 1,
126 -verbose => 99,
127 -sections => 'SYNOPSIS',
128 -output => \*STDERR,
129 );
130}
131
132my $kernelversion;
133my ($sphinx_major, $sphinx_minor, $sphinx_patch);
134
135my $dohighlight = "";
136
137my $verbose = 0;
138my $Werror = 0;
139my $Wreturn = 0;
140my $Wshort_desc = 0;
141my $Wcontents_before_sections = 0;
142my $output_mode = "rst";
143my $output_preformatted = 0;
144my $no_doc_sections = 0;
145my $enable_lineno = 0;
146my @highlights = @highlights_rst;
147my $blankline = $blankline_rst;
148my $modulename = "Kernel API";
149
150use constant {
151 OUTPUT_ALL => 0, # output all symbols and doc sections
152 OUTPUT_INCLUDE => 1, # output only specified symbols
153 OUTPUT_EXPORTED => 2, # output exported symbols
154 OUTPUT_INTERNAL => 3, # output non-exported symbols
155};
156my $output_selection = OUTPUT_ALL;
157my $show_not_found = 0; # No longer used
158
159my @export_file_list;
160
161my @build_time;
162if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
163 (my $seconds = `date -d "${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
164 @build_time = gmtime($seconds);
165} else {
166 @build_time = localtime;
167}
168
169my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
170 'July', 'August', 'September', 'October',
171 'November', 'December')[$build_time[4]] .
172 " " . ($build_time[5]+1900);
173
174# Essentially these are globals.
175# They probably want to be tidied up, made more localised or something.
176# CAVEAT EMPTOR! Some of the others I localised may not want to be, which
177# could cause "use of undefined value" or other bugs.
178my ($function, %function_table, %parametertypes, $declaration_purpose);
179my %nosymbol_table = ();
180my $declaration_start_line;
181my ($type, $declaration_name, $return_type);
182my ($newsection, $newcontents, $prototype, $brcount, %source_map);
183
184if (defined($ENV{'KBUILD_VERBOSE'}) && $ENV{'KBUILD_VERBOSE'} =~ '1') {
185 $verbose = 1;
186}
187
188if (defined($ENV{'KCFLAGS'})) {
189 my $kcflags = "$ENV{'KCFLAGS'}";
190
191 if ($kcflags =~ /(\s|^)-Werror(\s|$)/) {
192 $Werror = 1;
193 }
194}
195
196# reading this variable is for backwards compat just in case
197# someone was calling it with the variable from outside the
198# kernel's build system
199if (defined($ENV{'KDOC_WERROR'})) {
200 $Werror = "$ENV{'KDOC_WERROR'}";
201}
202# other environment variables are converted to command-line
203# arguments in cmd_checkdoc in the build system
204
205# Generated docbook code is inserted in a template at a point where
206# docbook v3.1 requires a non-zero sequence of RefEntry's; see:
207# https://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
208# We keep track of number of generated entries and generate a dummy
209# if needs be to ensure the expanded template can be postprocessed
210# into html.
211my $section_counter = 0;
212
213my $lineprefix="";
214
215# Parser states
216use constant {
217 STATE_NORMAL => 0, # normal code
218 STATE_NAME => 1, # looking for function name
219 STATE_BODY_MAYBE => 2, # body - or maybe more description
220 STATE_BODY => 3, # the body of the comment
221 STATE_BODY_WITH_BLANK_LINE => 4, # the body, which has a blank line
222 STATE_PROTO => 5, # scanning prototype
223 STATE_DOCBLOCK => 6, # documentation block
224 STATE_INLINE => 7, # gathering doc outside main block
225};
226my $state;
227my $in_doc_sect;
228my $leading_space;
229
230# Inline documentation state
231use constant {
232 STATE_INLINE_NA => 0, # not applicable ($state != STATE_INLINE)
233 STATE_INLINE_NAME => 1, # looking for member name (@foo:)
234 STATE_INLINE_TEXT => 2, # looking for member documentation
235 STATE_INLINE_END => 3, # done
236 STATE_INLINE_ERROR => 4, # error - Comment without header was found.
237 # Spit a warning as it's not
238 # proper kernel-doc and ignore the rest.
239};
240my $inline_doc_state;
241
242#declaration types: can be
243# 'function', 'struct', 'union', 'enum', 'typedef'
244my $decl_type;
245
246# Name of the kernel-doc identifier for non-DOC markups
247my $identifier;
248
249my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
250my $doc_end = '\*/';
251my $doc_com = '\s*\*\s*';
252my $doc_com_body = '\s*\* ?';
253my $doc_decl = $doc_com . '(\w+)';
254# @params and a strictly limited set of supported section names
255# Specifically:
256# Match @word:
257# @...:
258# @{section-name}:
259# while trying to not match literal block starts like "example::"
260#
261my $doc_sect = $doc_com .
262 '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:([^:].*)?$';
263my $doc_content = $doc_com_body . '(.*)';
264my $doc_block = $doc_com . 'DOC:\s*(.*)?';
265my $doc_inline_start = '^\s*/\*\*\s*$';
266my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
267my $doc_inline_end = '^\s*\*/\s*$';
268my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
269my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
270my $export_symbol_ns = '^\s*EXPORT_SYMBOL_NS(_GPL)?\s*\(\s*(\w+)\s*,\s*"\S+"\)\s*;';
271my $function_pointer = qr{([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)};
272my $attribute = qr{__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)}i;
273
274my %parameterdescs;
275my %parameterdesc_start_lines;
276my @parameterlist;
277my %sections;
278my @sectionlist;
279my %section_start_lines;
280my $sectcheck;
281my $struct_actual;
282
283my $contents = "";
284my $new_start_line = 0;
285
286# the canonical section names. see also $doc_sect above.
287my $section_default = "Description"; # default section
288my $section_intro = "Introduction";
289my $section = $section_default;
290my $section_context = "Context";
291my $section_return = "Return";
292
293my $undescribed = "-- undescribed --";
294
295reset_state();
296
297while ($ARGV[0] =~ m/^--?(.*)/) {
298 my $cmd = $1;
299 shift @ARGV;
300 if ($cmd eq "man") {
301 $output_mode = "man";
302 @highlights = @highlights_man;
303 $blankline = $blankline_man;
304 } elsif ($cmd eq "rst") {
305 $output_mode = "rst";
306 @highlights = @highlights_rst;
307 $blankline = $blankline_rst;
308 } elsif ($cmd eq "none") {
309 $output_mode = "none";
310 } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
311 $modulename = shift @ARGV;
312 } elsif ($cmd eq "function") { # to only output specific functions
313 $output_selection = OUTPUT_INCLUDE;
314 $function = shift @ARGV;
315 $function_table{$function} = 1;
316 } elsif ($cmd eq "nosymbol") { # Exclude specific symbols
317 my $symbol = shift @ARGV;
318 $nosymbol_table{$symbol} = 1;
319 } elsif ($cmd eq "export") { # only exported symbols
320 $output_selection = OUTPUT_EXPORTED;
321 %function_table = ();
322 } elsif ($cmd eq "internal") { # only non-exported symbols
323 $output_selection = OUTPUT_INTERNAL;
324 %function_table = ();
325 } elsif ($cmd eq "export-file") {
326 my $file = shift @ARGV;
327 push(@export_file_list, $file);
328 } elsif ($cmd eq "v") {
329 $verbose = 1;
330 } elsif ($cmd eq "Werror") {
331 $Werror = 1;
332 } elsif ($cmd eq "Wreturn") {
333 $Wreturn = 1;
334 } elsif ($cmd eq "Wshort-desc" or $cmd eq "Wshort-description") {
335 $Wshort_desc = 1;
336 } elsif ($cmd eq "Wcontents-before-sections") {
337 $Wcontents_before_sections = 1;
338 } elsif ($cmd eq "Wall") {
339 $Wreturn = 1;
340 $Wshort_desc = 1;
341 $Wcontents_before_sections = 1;
342 } elsif (($cmd eq "h") || ($cmd eq "help")) {
343 pod2usage(-exitval => 0, -verbose => 2);
344 } elsif ($cmd eq 'no-doc-sections') {
345 $no_doc_sections = 1;
346 } elsif ($cmd eq 'enable-lineno') {
347 $enable_lineno = 1;
348 } elsif ($cmd eq 'show-not-found') {
349 $show_not_found = 1; # A no-op but don't fail
350 } elsif ($cmd eq "sphinx-version") {
351 my $ver_string = shift @ARGV;
352 if ($ver_string =~ m/^(\d+)(\.\d+)?(\.\d+)?/) {
353 $sphinx_major = $1;
354 if (defined($2)) {
355 $sphinx_minor = substr($2,1);
356 } else {
357 $sphinx_minor = 0;
358 }
359 if (defined($3)) {
360 $sphinx_patch = substr($3,1)
361 } else {
362 $sphinx_patch = 0;
363 }
364 } else {
365 die "Sphinx version should either major.minor or major.minor.patch format\n";
366 }
367 } else {
368 # Unknown argument
369 pod2usage(
370 -message => "Argument unknown!\n",
371 -exitval => 1,
372 -verbose => 99,
373 -sections => 'SYNOPSIS',
374 -output => \*STDERR,
375 );
376 }
377 if ($#ARGV < 0){
378 pod2usage(
379 -message => "FILE argument missing\n",
380 -exitval => 1,
381 -verbose => 99,
382 -sections => 'SYNOPSIS',
383 -output => \*STDERR,
384 );
385 }
386}
387
388# continue execution near EOF;
389
390# The C domain dialect changed on Sphinx 3. So, we need to check the
391# version in order to produce the right tags.
392sub findprog($)
393{
394 foreach(split(/:/, $ENV{PATH})) {
395 return "$_/$_[0]" if(-x "$_/$_[0]");
396 }
397}
398
399sub get_sphinx_version()
400{
401 my $ver;
402
403 my $cmd = "sphinx-build";
404 if (!findprog($cmd)) {
405 my $cmd = "sphinx-build3";
406 if (!findprog($cmd)) {
407 $sphinx_major = 1;
408 $sphinx_minor = 2;
409 $sphinx_patch = 0;
410 printf STDERR "Warning: Sphinx version not found. Using default (Sphinx version %d.%d.%d)\n",
411 $sphinx_major, $sphinx_minor, $sphinx_patch;
412 return;
413 }
414 }
415
416 open IN, "$cmd --version 2>&1 |";
417 while (<IN>) {
418 if (m/^\s*sphinx-build\s+([\d]+)\.([\d\.]+)(\+\/[\da-f]+)?$/) {
419 $sphinx_major = $1;
420 $sphinx_minor = $2;
421 $sphinx_patch = $3;
422 last;
423 }
424 # Sphinx 1.2.x uses a different format
425 if (m/^\s*Sphinx.*\s+([\d]+)\.([\d\.]+)$/) {
426 $sphinx_major = $1;
427 $sphinx_minor = $2;
428 $sphinx_patch = $3;
429 last;
430 }
431 }
432 close IN;
433}
434
435# get kernel version from env
436sub get_kernel_version() {
437 my $version = 'unknown kernel version';
438
439 if (defined($ENV{'KERNELVERSION'})) {
440 $version = $ENV{'KERNELVERSION'};
441 }
442 return $version;
443}
444
445#
446sub print_lineno {
447 my $lineno = shift;
448 if ($enable_lineno && defined($lineno)) {
449 print ".. LINENO " . $lineno . "\n";
450 }
451}
452
453sub emit_warning {
454 my $location = shift;
455 my $msg = shift;
456 print STDERR "$location: warning: $msg";
457 ++$warnings;
458}
459##
460# dumps section contents to arrays/hashes intended for that purpose.
461#
462sub dump_section {
463 my $file = shift;
464 my $name = shift;
465 my $contents = join "\n", @_;
466
467 if ($name =~ m/$type_param/) {
468 $name = $1;
469 $parameterdescs{$name} = $contents;
470 $sectcheck = $sectcheck . $name . " ";
471 $parameterdesc_start_lines{$name} = $new_start_line;
472 $new_start_line = 0;
473 } elsif ($name eq "@\.\.\.") {
474 $name = "...";
475 $parameterdescs{$name} = $contents;
476 $sectcheck = $sectcheck . $name . " ";
477 $parameterdesc_start_lines{$name} = $new_start_line;
478 $new_start_line = 0;
479 } else {
480 if (defined($sections{$name}) && ($sections{$name} ne "")) {
481 # Only warn on user specified duplicate section names.
482 if ($name ne $section_default) {
483 emit_warning("${file}:$.", "duplicate section name '$name'\n");
484 }
485 $sections{$name} .= $contents;
486 } else {
487 $sections{$name} = $contents;
488 push @sectionlist, $name;
489 $section_start_lines{$name} = $new_start_line;
490 $new_start_line = 0;
491 }
492 }
493}
494
495##
496# dump DOC: section after checking that it should go out
497#
498sub dump_doc_section {
499 my $file = shift;
500 my $name = shift;
501 my $contents = join "\n", @_;
502
503 if ($no_doc_sections) {
504 return;
505 }
506
507 return if (defined($nosymbol_table{$name}));
508
509 if (($output_selection == OUTPUT_ALL) ||
510 (($output_selection == OUTPUT_INCLUDE) &&
511 defined($function_table{$name})))
512 {
513 dump_section($file, $name, $contents);
514 output_blockhead({'sectionlist' => \@sectionlist,
515 'sections' => \%sections,
516 'module' => $modulename,
517 'content-only' => ($output_selection != OUTPUT_ALL), });
518 }
519}
520
521##
522# output function
523#
524# parameterdescs, a hash.
525# function => "function name"
526# parameterlist => @list of parameters
527# parameterdescs => %parameter descriptions
528# sectionlist => @list of sections
529# sections => %section descriptions
530#
531
532sub output_highlight {
533 my $contents = join "\n",@_;
534 my $line;
535
536# DEBUG
537# if (!defined $contents) {
538# use Carp;
539# confess "output_highlight got called with no args?\n";
540# }
541
542# print STDERR "contents b4:$contents\n";
543 eval $dohighlight;
544 die $@ if $@;
545# print STDERR "contents af:$contents\n";
546
547 foreach $line (split "\n", $contents) {
548 if (! $output_preformatted) {
549 $line =~ s/^\s*//;
550 }
551 if ($line eq ""){
552 if (! $output_preformatted) {
553 print $lineprefix, $blankline;
554 }
555 } else {
556 if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
557 print "\\&$line";
558 } else {
559 print $lineprefix, $line;
560 }
561 }
562 print "\n";
563 }
564}
565
566##
567# output function in man
568sub output_function_man(%) {
569 my %args = %{$_[0]};
570 my ($parameter, $section);
571 my $count;
572 my $func_macro = $args{'func_macro'};
573 my $paramcount = $#{$args{'parameterlist'}}; # -1 is empty
574
575 print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
576
577 print ".SH NAME\n";
578 print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
579
580 print ".SH SYNOPSIS\n";
581 if ($args{'functiontype'} ne "") {
582 print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
583 } else {
584 print ".B \"" . $args{'function'} . "\n";
585 }
586 $count = 0;
587 my $parenth = "(";
588 my $post = ",";
589 foreach my $parameter (@{$args{'parameterlist'}}) {
590 if ($count == $#{$args{'parameterlist'}}) {
591 $post = ");";
592 }
593 $type = $args{'parametertypes'}{$parameter};
594 if ($type =~ m/$function_pointer/) {
595 # pointer-to-function
596 print ".BI \"" . $parenth . $1 . "\" " . " \") (" . $2 . ")" . $post . "\"\n";
597 } else {
598 $type =~ s/([^\*])$/$1 /;
599 print ".BI \"" . $parenth . $type . "\" " . " \"" . $post . "\"\n";
600 }
601 $count++;
602 $parenth = "";
603 }
604
605 $paramcount = $#{$args{'parameterlist'}}; # -1 is empty
606 if ($paramcount >= 0) {
607 print ".SH ARGUMENTS\n";
608 }
609 foreach $parameter (@{$args{'parameterlist'}}) {
610 my $parameter_name = $parameter;
611 $parameter_name =~ s/\[.*//;
612
613 print ".IP \"" . $parameter . "\" 12\n";
614 output_highlight($args{'parameterdescs'}{$parameter_name});
615 }
616 foreach $section (@{$args{'sectionlist'}}) {
617 print ".SH \"", uc $section, "\"\n";
618 output_highlight($args{'sections'}{$section});
619 }
620}
621
622##
623# output enum in man
624sub output_enum_man(%) {
625 my %args = %{$_[0]};
626 my ($parameter, $section);
627 my $count;
628
629 print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
630
631 print ".SH NAME\n";
632 print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
633
634 print ".SH SYNOPSIS\n";
635 print "enum " . $args{'enum'} . " {\n";
636 $count = 0;
637 foreach my $parameter (@{$args{'parameterlist'}}) {
638 print ".br\n.BI \" $parameter\"\n";
639 if ($count == $#{$args{'parameterlist'}}) {
640 print "\n};\n";
641 last;
642 } else {
643 print ", \n.br\n";
644 }
645 $count++;
646 }
647
648 print ".SH Constants\n";
649 foreach $parameter (@{$args{'parameterlist'}}) {
650 my $parameter_name = $parameter;
651 $parameter_name =~ s/\[.*//;
652
653 print ".IP \"" . $parameter . "\" 12\n";
654 output_highlight($args{'parameterdescs'}{$parameter_name});
655 }
656 foreach $section (@{$args{'sectionlist'}}) {
657 print ".SH \"$section\"\n";
658 output_highlight($args{'sections'}{$section});
659 }
660}
661
662##
663# output struct in man
664sub output_struct_man(%) {
665 my %args = %{$_[0]};
666 my ($parameter, $section);
667
668 print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
669
670 print ".SH NAME\n";
671 print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
672
673 my $declaration = $args{'definition'};
674 $declaration =~ s/\t/ /g;
675 $declaration =~ s/\n/"\n.br\n.BI \"/g;
676 print ".SH SYNOPSIS\n";
677 print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
678 print ".BI \"$declaration\n};\n.br\n\n";
679
680 print ".SH Members\n";
681 foreach $parameter (@{$args{'parameterlist'}}) {
682 ($parameter =~ /^#/) && next;
683
684 my $parameter_name = $parameter;
685 $parameter_name =~ s/\[.*//;
686
687 ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
688 print ".IP \"" . $parameter . "\" 12\n";
689 output_highlight($args{'parameterdescs'}{$parameter_name});
690 }
691 foreach $section (@{$args{'sectionlist'}}) {
692 print ".SH \"$section\"\n";
693 output_highlight($args{'sections'}{$section});
694 }
695}
696
697##
698# output typedef in man
699sub output_typedef_man(%) {
700 my %args = %{$_[0]};
701 my ($parameter, $section);
702
703 print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
704
705 print ".SH NAME\n";
706 print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
707
708 foreach $section (@{$args{'sectionlist'}}) {
709 print ".SH \"$section\"\n";
710 output_highlight($args{'sections'}{$section});
711 }
712}
713
714sub output_blockhead_man(%) {
715 my %args = %{$_[0]};
716 my ($parameter, $section);
717 my $count;
718
719 print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
720
721 foreach $section (@{$args{'sectionlist'}}) {
722 print ".SH \"$section\"\n";
723 output_highlight($args{'sections'}{$section});
724 }
725}
726
727##
728# output in restructured text
729#
730
731#
732# This could use some work; it's used to output the DOC: sections, and
733# starts by putting out the name of the doc section itself, but that tends
734# to duplicate a header already in the template file.
735#
736sub output_blockhead_rst(%) {
737 my %args = %{$_[0]};
738 my ($parameter, $section);
739
740 foreach $section (@{$args{'sectionlist'}}) {
741 next if (defined($nosymbol_table{$section}));
742
743 if ($output_selection != OUTPUT_INCLUDE) {
744 print ".. _$section:\n\n";
745 print "**$section**\n\n";
746 }
747 print_lineno($section_start_lines{$section});
748 output_highlight_rst($args{'sections'}{$section});
749 print "\n";
750 }
751}
752
753#
754# Apply the RST highlights to a sub-block of text.
755#
756sub highlight_block($) {
757 # The dohighlight kludge requires the text be called $contents
758 my $contents = shift;
759 eval $dohighlight;
760 die $@ if $@;
761 return $contents;
762}
763
764#
765# Regexes used only here.
766#
767my $sphinx_literal = '^[^.].*::$';
768my $sphinx_cblock = '^\.\.\ +code-block::';
769
770sub output_highlight_rst {
771 my $input = join "\n",@_;
772 my $output = "";
773 my $line;
774 my $in_literal = 0;
775 my $litprefix;
776 my $block = "";
777
778 foreach $line (split "\n",$input) {
779 #
780 # If we're in a literal block, see if we should drop out
781 # of it. Otherwise pass the line straight through unmunged.
782 #
783 if ($in_literal) {
784 if (! ($line =~ /^\s*$/)) {
785 #
786 # If this is the first non-blank line in a literal
787 # block we need to figure out what the proper indent is.
788 #
789 if ($litprefix eq "") {
790 $line =~ /^(\s*)/;
791 $litprefix = '^' . $1;
792 $output .= $line . "\n";
793 } elsif (! ($line =~ /$litprefix/)) {
794 $in_literal = 0;
795 } else {
796 $output .= $line . "\n";
797 }
798 } else {
799 $output .= $line . "\n";
800 }
801 }
802 #
803 # Not in a literal block (or just dropped out)
804 #
805 if (! $in_literal) {
806 $block .= $line . "\n";
807 if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
808 $in_literal = 1;
809 $litprefix = "";
810 $output .= highlight_block($block);
811 $block = ""
812 }
813 }
814 }
815
816 if ($block) {
817 $output .= highlight_block($block);
818 }
819 foreach $line (split "\n", $output) {
820 print $lineprefix . $line . "\n";
821 }
822}
823
824sub output_function_rst(%) {
825 my %args = %{$_[0]};
826 my ($parameter, $section);
827 my $oldprefix = $lineprefix;
828
829 my $signature = "";
830 my $func_macro = $args{'func_macro'};
831 my $paramcount = $#{$args{'parameterlist'}}; # -1 is empty
832
833 if ($func_macro) {
834 $signature = $args{'function'};
835 } else {
836 if ($args{'functiontype'}) {
837 $signature = $args{'functiontype'} . " ";
838 }
839 $signature .= $args{'function'} . " (";
840 }
841
842 my $count = 0;
843 foreach my $parameter (@{$args{'parameterlist'}}) {
844 if ($count ne 0) {
845 $signature .= ", ";
846 }
847 $count++;
848 $type = $args{'parametertypes'}{$parameter};
849
850 if ($type =~ m/$function_pointer/) {
851 # pointer-to-function
852 $signature .= $1 . $parameter . ") (" . $2 . ")";
853 } else {
854 $signature .= $type;
855 }
856 }
857
858 if (!$func_macro) {
859 $signature .= ")";
860 }
861
862 if ($sphinx_major < 3) {
863 if ($args{'typedef'}) {
864 print ".. c:type:: ". $args{'function'} . "\n\n";
865 print_lineno($declaration_start_line);
866 print " **Typedef**: ";
867 $lineprefix = "";
868 output_highlight_rst($args{'purpose'});
869 print "\n\n**Syntax**\n\n";
870 print " ``$signature``\n\n";
871 } else {
872 print ".. c:function:: $signature\n\n";
873 }
874 } else {
875 if ($args{'typedef'} || $args{'functiontype'} eq "") {
876 print ".. c:macro:: ". $args{'function'} . "\n\n";
877
878 if ($args{'typedef'}) {
879 print_lineno($declaration_start_line);
880 print " **Typedef**: ";
881 $lineprefix = "";
882 output_highlight_rst($args{'purpose'});
883 print "\n\n**Syntax**\n\n";
884 print " ``$signature``\n\n";
885 } else {
886 print "``$signature``\n\n";
887 }
888 } else {
889 print ".. c:function:: $signature\n\n";
890 }
891 }
892
893 if (!$args{'typedef'}) {
894 print_lineno($declaration_start_line);
895 $lineprefix = " ";
896 output_highlight_rst($args{'purpose'});
897 print "\n";
898 }
899
900 #
901 # Put our descriptive text into a container (thus an HTML <div>) to help
902 # set the function prototypes apart.
903 #
904 $lineprefix = " ";
905 if ($paramcount >= 0) {
906 print ".. container:: kernelindent\n\n";
907 print $lineprefix . "**Parameters**\n\n";
908 }
909 foreach $parameter (@{$args{'parameterlist'}}) {
910 my $parameter_name = $parameter;
911 $parameter_name =~ s/\[.*//;
912 $type = $args{'parametertypes'}{$parameter};
913
914 if ($type ne "") {
915 print $lineprefix . "``$type``\n";
916 } else {
917 print $lineprefix . "``$parameter``\n";
918 }
919
920 print_lineno($parameterdesc_start_lines{$parameter_name});
921
922 $lineprefix = " ";
923 if (defined($args{'parameterdescs'}{$parameter_name}) &&
924 $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
925 output_highlight_rst($args{'parameterdescs'}{$parameter_name});
926 } else {
927 print $lineprefix . "*undescribed*\n";
928 }
929 $lineprefix = " ";
930 print "\n";
931 }
932
933 output_section_rst(@_);
934 $lineprefix = $oldprefix;
935}
936
937sub output_section_rst(%) {
938 my %args = %{$_[0]};
939 my $section;
940 my $oldprefix = $lineprefix;
941
942 foreach $section (@{$args{'sectionlist'}}) {
943 print $lineprefix . "**$section**\n\n";
944 print_lineno($section_start_lines{$section});
945 output_highlight_rst($args{'sections'}{$section});
946 print "\n";
947 }
948 print "\n";
949}
950
951sub output_enum_rst(%) {
952 my %args = %{$_[0]};
953 my ($parameter);
954 my $oldprefix = $lineprefix;
955 my $count;
956 my $outer;
957
958 if ($sphinx_major < 3) {
959 my $name = "enum " . $args{'enum'};
960 print "\n\n.. c:type:: " . $name . "\n\n";
961 } else {
962 my $name = $args{'enum'};
963 print "\n\n.. c:enum:: " . $name . "\n\n";
964 }
965 print_lineno($declaration_start_line);
966 $lineprefix = " ";
967 output_highlight_rst($args{'purpose'});
968 print "\n";
969
970 print ".. container:: kernelindent\n\n";
971 $outer = $lineprefix . " ";
972 $lineprefix = $outer . " ";
973 print $outer . "**Constants**\n\n";
974 foreach $parameter (@{$args{'parameterlist'}}) {
975 print $outer . "``$parameter``\n";
976
977 if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
978 output_highlight_rst($args{'parameterdescs'}{$parameter});
979 } else {
980 print $lineprefix . "*undescribed*\n";
981 }
982 print "\n";
983 }
984 print "\n";
985 $lineprefix = $oldprefix;
986 output_section_rst(@_);
987}
988
989sub output_typedef_rst(%) {
990 my %args = %{$_[0]};
991 my ($parameter);
992 my $oldprefix = $lineprefix;
993 my $name;
994
995 if ($sphinx_major < 3) {
996 $name = "typedef " . $args{'typedef'};
997 } else {
998 $name = $args{'typedef'};
999 }
1000 print "\n\n.. c:type:: " . $name . "\n\n";
1001 print_lineno($declaration_start_line);
1002 $lineprefix = " ";
1003 output_highlight_rst($args{'purpose'});
1004 print "\n";
1005
1006 $lineprefix = $oldprefix;
1007 output_section_rst(@_);
1008}
1009
1010sub output_struct_rst(%) {
1011 my %args = %{$_[0]};
1012 my ($parameter);
1013 my $oldprefix = $lineprefix;
1014
1015 if ($sphinx_major < 3) {
1016 my $name = $args{'type'} . " " . $args{'struct'};
1017 print "\n\n.. c:type:: " . $name . "\n\n";
1018 } else {
1019 my $name = $args{'struct'};
1020 if ($args{'type'} eq 'union') {
1021 print "\n\n.. c:union:: " . $name . "\n\n";
1022 } else {
1023 print "\n\n.. c:struct:: " . $name . "\n\n";
1024 }
1025 }
1026 print_lineno($declaration_start_line);
1027 $lineprefix = " ";
1028 output_highlight_rst($args{'purpose'});
1029 print "\n";
1030
1031 print ".. container:: kernelindent\n\n";
1032 print $lineprefix . "**Definition**::\n\n";
1033 my $declaration = $args{'definition'};
1034 $lineprefix = $lineprefix . " ";
1035 $declaration =~ s/\t/$lineprefix/g;
1036 print $lineprefix . $args{'type'} . " " . $args{'struct'} . " {\n$declaration" . $lineprefix . "};\n\n";
1037
1038 $lineprefix = " ";
1039 print $lineprefix . "**Members**\n\n";
1040 foreach $parameter (@{$args{'parameterlist'}}) {
1041 ($parameter =~ /^#/) && next;
1042
1043 my $parameter_name = $parameter;
1044 $parameter_name =~ s/\[.*//;
1045
1046 ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
1047 $type = $args{'parametertypes'}{$parameter};
1048 print_lineno($parameterdesc_start_lines{$parameter_name});
1049 print $lineprefix . "``" . $parameter . "``\n";
1050 $lineprefix = " ";
1051 output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1052 $lineprefix = " ";
1053 print "\n";
1054 }
1055 print "\n";
1056
1057 $lineprefix = $oldprefix;
1058 output_section_rst(@_);
1059}
1060
1061## none mode output functions
1062
1063sub output_function_none(%) {
1064}
1065
1066sub output_enum_none(%) {
1067}
1068
1069sub output_typedef_none(%) {
1070}
1071
1072sub output_struct_none(%) {
1073}
1074
1075sub output_blockhead_none(%) {
1076}
1077
1078##
1079# generic output function for all types (function, struct/union, typedef, enum);
1080# calls the generated, variable output_ function name based on
1081# functype and output_mode
1082sub output_declaration {
1083 no strict 'refs';
1084 my $name = shift;
1085 my $functype = shift;
1086 my $func = "output_${functype}_$output_mode";
1087
1088 return if (defined($nosymbol_table{$name}));
1089
1090 if (($output_selection == OUTPUT_ALL) ||
1091 (($output_selection == OUTPUT_INCLUDE ||
1092 $output_selection == OUTPUT_EXPORTED) &&
1093 defined($function_table{$name})) ||
1094 ($output_selection == OUTPUT_INTERNAL &&
1095 !($functype eq "function" && defined($function_table{$name}))))
1096 {
1097 &$func(@_);
1098 $section_counter++;
1099 }
1100}
1101
1102##
1103# generic output function - calls the right one based on current output mode.
1104sub output_blockhead {
1105 no strict 'refs';
1106 my $func = "output_blockhead_" . $output_mode;
1107 &$func(@_);
1108 $section_counter++;
1109}
1110
1111##
1112# takes a declaration (struct, union, enum, typedef) and
1113# invokes the right handler. NOT called for functions.
1114sub dump_declaration($$) {
1115 no strict 'refs';
1116 my ($prototype, $file) = @_;
1117 my $func = "dump_" . $decl_type;
1118 &$func(@_);
1119}
1120
1121sub dump_union($$) {
1122 dump_struct(@_);
1123}
1124
1125sub dump_struct($$) {
1126 my $x = shift;
1127 my $file = shift;
1128 my $decl_type;
1129 my $members;
1130 my $type = qr{struct|union};
1131 # For capturing struct/union definition body, i.e. "{members*}qualifiers*"
1132 my $qualifiers = qr{$attribute|__packed|__aligned|____cacheline_aligned_in_smp|____cacheline_aligned};
1133 my $definition_body = qr{\{(.*)\}\s*$qualifiers*};
1134 my $struct_members = qr{($type)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;};
1135
1136 if ($x =~ /($type)\s+(\w+)\s*$definition_body/) {
1137 $decl_type = $1;
1138 $declaration_name = $2;
1139 $members = $3;
1140 } elsif ($x =~ /typedef\s+($type)\s*$definition_body\s*(\w+)\s*;/) {
1141 $decl_type = $1;
1142 $declaration_name = $3;
1143 $members = $2;
1144 }
1145
1146 if ($members) {
1147 if ($identifier ne $declaration_name) {
1148 emit_warning("${file}:$.", "expecting prototype for $decl_type $identifier. Prototype was for $decl_type $declaration_name instead\n");
1149 return;
1150 }
1151
1152 # ignore members marked private:
1153 $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1154 $members =~ s/\/\*\s*private:.*//gosi;
1155 # strip comments:
1156 $members =~ s/\/\*.*?\*\///gos;
1157 # strip attributes
1158 $members =~ s/\s*$attribute/ /gi;
1159 $members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1160 $members =~ s/\s*__counted_by\s*\([^;]*\)/ /gos;
1161 $members =~ s/\s*__counted_by_(le|be)\s*\([^;]*\)/ /gos;
1162 $members =~ s/\s*__packed\s*/ /gos;
1163 $members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1164 $members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1165 $members =~ s/\s*____cacheline_aligned/ /gos;
1166 # unwrap struct_group():
1167 # - first eat non-declaration parameters and rewrite for final match
1168 # - then remove macro, outer parens, and trailing semicolon
1169 $members =~ s/\bstruct_group\s*\(([^,]*,)/STRUCT_GROUP(/gos;
1170 $members =~ s/\bstruct_group_attr\s*\(([^,]*,){2}/STRUCT_GROUP(/gos;
1171 $members =~ s/\bstruct_group_tagged\s*\(([^,]*),([^,]*),/struct $1 $2; STRUCT_GROUP(/gos;
1172 $members =~ s/\b__struct_group\s*\(([^,]*,){3}/STRUCT_GROUP(/gos;
1173 $members =~ s/\bSTRUCT_GROUP(\(((?:(?>[^)(]+)|(?1))*)\))[^;]*;/$2/gos;
1174
1175 my $args = qr{([^,)]+)};
1176 # replace DECLARE_BITMAP
1177 $members =~ s/__ETHTOOL_DECLARE_LINK_MODE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, __ETHTOOL_LINK_MODE_MASK_NBITS)/gos;
1178 $members =~ s/DECLARE_PHY_INTERFACE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, PHY_INTERFACE_MODE_MAX)/gos;
1179 $members =~ s/DECLARE_BITMAP\s*\($args,\s*$args\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1180 # replace DECLARE_HASHTABLE
1181 $members =~ s/DECLARE_HASHTABLE\s*\($args,\s*$args\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1182 # replace DECLARE_KFIFO
1183 $members =~ s/DECLARE_KFIFO\s*\($args,\s*$args,\s*$args\)/$2 \*$1/gos;
1184 # replace DECLARE_KFIFO_PTR
1185 $members =~ s/DECLARE_KFIFO_PTR\s*\($args,\s*$args\)/$2 \*$1/gos;
1186 # replace DECLARE_FLEX_ARRAY
1187 $members =~ s/(?:__)?DECLARE_FLEX_ARRAY\s*\($args,\s*$args\)/$1 $2\[\]/gos;
1188 #replace DEFINE_DMA_UNMAP_ADDR
1189 $members =~ s/DEFINE_DMA_UNMAP_ADDR\s*\($args\)/dma_addr_t $1/gos;
1190 #replace DEFINE_DMA_UNMAP_LEN
1191 $members =~ s/DEFINE_DMA_UNMAP_LEN\s*\($args\)/__u32 $1/gos;
1192 my $declaration = $members;
1193
1194 # Split nested struct/union elements as newer ones
1195 while ($members =~ m/$struct_members/) {
1196 my $newmember;
1197 my $maintype = $1;
1198 my $ids = $4;
1199 my $content = $3;
1200 foreach my $id(split /,/, $ids) {
1201 $newmember .= "$maintype $id; ";
1202
1203 $id =~ s/[:\[].*//;
1204 $id =~ s/^\s*\**(\S+)\s*/$1/;
1205 foreach my $arg (split /;/, $content) {
1206 next if ($arg =~ m/^\s*$/);
1207 if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1208 # pointer-to-function
1209 my $type = $1;
1210 my $name = $2;
1211 my $extra = $3;
1212 next if (!$name);
1213 if ($id =~ m/^\s*$/) {
1214 # anonymous struct/union
1215 $newmember .= "$type$name$extra; ";
1216 } else {
1217 $newmember .= "$type$id.$name$extra; ";
1218 }
1219 } else {
1220 my $type;
1221 my $names;
1222 $arg =~ s/^\s+//;
1223 $arg =~ s/\s+$//;
1224 # Handle bitmaps
1225 $arg =~ s/:\s*\d+\s*//g;
1226 # Handle arrays
1227 $arg =~ s/\[.*\]//g;
1228 # The type may have multiple words,
1229 # and multiple IDs can be defined, like:
1230 # const struct foo, *bar, foobar
1231 # So, we remove spaces when parsing the
1232 # names, in order to match just names
1233 # and commas for the names
1234 $arg =~ s/\s*,\s*/,/g;
1235 if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1236 $type = $1;
1237 $names = $2;
1238 } else {
1239 $newmember .= "$arg; ";
1240 next;
1241 }
1242 foreach my $name (split /,/, $names) {
1243 $name =~ s/^\s*\**(\S+)\s*/$1/;
1244 next if (($name =~ m/^\s*$/));
1245 if ($id =~ m/^\s*$/) {
1246 # anonymous struct/union
1247 $newmember .= "$type $name; ";
1248 } else {
1249 $newmember .= "$type $id.$name; ";
1250 }
1251 }
1252 }
1253 }
1254 }
1255 $members =~ s/$struct_members/$newmember/;
1256 }
1257
1258 # Ignore other nested elements, like enums
1259 $members =~ s/(\{[^\{\}]*\})//g;
1260
1261 create_parameterlist($members, ';', $file, $declaration_name);
1262 check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1263
1264 # Adjust declaration for better display
1265 $declaration =~ s/([\{;])/$1\n/g;
1266 $declaration =~ s/\}\s+;/};/g;
1267 # Better handle inlined enums
1268 do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1269
1270 my @def_args = split /\n/, $declaration;
1271 my $level = 1;
1272 $declaration = "";
1273 foreach my $clause (@def_args) {
1274 $clause =~ s/^\s+//;
1275 $clause =~ s/\s+$//;
1276 $clause =~ s/\s+/ /;
1277 next if (!$clause);
1278 $level-- if ($clause =~ m/(\})/ && $level > 1);
1279 if (!($clause =~ m/^\s*#/)) {
1280 $declaration .= "\t" x $level;
1281 }
1282 $declaration .= "\t" . $clause . "\n";
1283 $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1284 }
1285 output_declaration($declaration_name,
1286 'struct',
1287 {'struct' => $declaration_name,
1288 'module' => $modulename,
1289 'definition' => $declaration,
1290 'parameterlist' => \@parameterlist,
1291 'parameterdescs' => \%parameterdescs,
1292 'parametertypes' => \%parametertypes,
1293 'sectionlist' => \@sectionlist,
1294 'sections' => \%sections,
1295 'purpose' => $declaration_purpose,
1296 'type' => $decl_type
1297 });
1298 } else {
1299 print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1300 ++$errors;
1301 }
1302}
1303
1304
1305sub show_warnings($$) {
1306 my $functype = shift;
1307 my $name = shift;
1308
1309 return 0 if (defined($nosymbol_table{$name}));
1310
1311 return 1 if ($output_selection == OUTPUT_ALL);
1312
1313 if ($output_selection == OUTPUT_EXPORTED) {
1314 if (defined($function_table{$name})) {
1315 return 1;
1316 } else {
1317 return 0;
1318 }
1319 }
1320 if ($output_selection == OUTPUT_INTERNAL) {
1321 if (!($functype eq "function" && defined($function_table{$name}))) {
1322 return 1;
1323 } else {
1324 return 0;
1325 }
1326 }
1327 if ($output_selection == OUTPUT_INCLUDE) {
1328 if (defined($function_table{$name})) {
1329 return 1;
1330 } else {
1331 return 0;
1332 }
1333 }
1334 die("Please add the new output type at show_warnings()");
1335}
1336
1337sub dump_enum($$) {
1338 my $x = shift;
1339 my $file = shift;
1340 my $members;
1341
1342 # ignore members marked private:
1343 $x =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1344 $x =~ s/\/\*\s*private:.*}/}/gosi;
1345
1346 $x =~ s@/\*.*?\*/@@gos; # strip comments.
1347 # strip #define macros inside enums
1348 $x =~ s@#\s*((define|ifdef|if)\s+|endif)[^;]*;@@gos;
1349
1350 if ($x =~ /typedef\s+enum\s*\{(.*)\}\s*(\w*)\s*;/) {
1351 $declaration_name = $2;
1352 $members = $1;
1353 } elsif ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1354 $declaration_name = $1;
1355 $members = $2;
1356 }
1357
1358 if ($members) {
1359 if ($identifier ne $declaration_name) {
1360 if ($identifier eq "") {
1361 emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n");
1362 } else {
1363 emit_warning("${file}:$.", "expecting prototype for enum $identifier. Prototype was for enum $declaration_name instead\n");
1364 }
1365 return;
1366 }
1367 $declaration_name = "(anonymous)" if ($declaration_name eq "");
1368
1369 my %_members;
1370
1371 $members =~ s/\s+$//;
1372 $members =~ s/\([^;]*?[\)]//g;
1373
1374 foreach my $arg (split ',', $members) {
1375 $arg =~ s/^\s*(\w+).*/$1/;
1376 push @parameterlist, $arg;
1377 if (!$parameterdescs{$arg}) {
1378 $parameterdescs{$arg} = $undescribed;
1379 if (show_warnings("enum", $declaration_name)) {
1380 emit_warning("${file}:$.", "Enum value '$arg' not described in enum '$declaration_name'\n");
1381 }
1382 }
1383 $_members{$arg} = 1;
1384 }
1385
1386 while (my ($k, $v) = each %parameterdescs) {
1387 if (!exists($_members{$k})) {
1388 if (show_warnings("enum", $declaration_name)) {
1389 emit_warning("${file}:$.", "Excess enum value '$k' description in '$declaration_name'\n");
1390 }
1391 }
1392 }
1393
1394 output_declaration($declaration_name,
1395 'enum',
1396 {'enum' => $declaration_name,
1397 'module' => $modulename,
1398 'parameterlist' => \@parameterlist,
1399 'parameterdescs' => \%parameterdescs,
1400 'sectionlist' => \@sectionlist,
1401 'sections' => \%sections,
1402 'purpose' => $declaration_purpose
1403 });
1404 } else {
1405 print STDERR "${file}:$.: error: Cannot parse enum!\n";
1406 ++$errors;
1407 }
1408}
1409
1410my $typedef_type = qr { ((?:\s+[\w\*]+\b){1,8})\s* }x;
1411my $typedef_ident = qr { \*?\s*(\w\S+)\s* }x;
1412my $typedef_args = qr { \s*\((.*)\); }x;
1413
1414my $typedef1 = qr { typedef$typedef_type\($typedef_ident\)$typedef_args }x;
1415my $typedef2 = qr { typedef$typedef_type$typedef_ident$typedef_args }x;
1416
1417sub dump_typedef($$) {
1418 my $x = shift;
1419 my $file = shift;
1420
1421 $x =~ s@/\*.*?\*/@@gos; # strip comments.
1422
1423 # Parse function typedef prototypes
1424 if ($x =~ $typedef1 || $x =~ $typedef2) {
1425 $return_type = $1;
1426 $declaration_name = $2;
1427 my $args = $3;
1428 $return_type =~ s/^\s+//;
1429
1430 if ($identifier ne $declaration_name) {
1431 emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1432 return;
1433 }
1434
1435 create_parameterlist($args, ',', $file, $declaration_name);
1436
1437 output_declaration($declaration_name,
1438 'function',
1439 {'function' => $declaration_name,
1440 'typedef' => 1,
1441 'module' => $modulename,
1442 'functiontype' => $return_type,
1443 'parameterlist' => \@parameterlist,
1444 'parameterdescs' => \%parameterdescs,
1445 'parametertypes' => \%parametertypes,
1446 'sectionlist' => \@sectionlist,
1447 'sections' => \%sections,
1448 'purpose' => $declaration_purpose
1449 });
1450 return;
1451 }
1452
1453 while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1454 $x =~ s/\(*.\)\s*;$/;/;
1455 $x =~ s/\[*.\]\s*;$/;/;
1456 }
1457
1458 if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1459 $declaration_name = $1;
1460
1461 if ($identifier ne $declaration_name) {
1462 emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1463 return;
1464 }
1465
1466 output_declaration($declaration_name,
1467 'typedef',
1468 {'typedef' => $declaration_name,
1469 'module' => $modulename,
1470 'sectionlist' => \@sectionlist,
1471 'sections' => \%sections,
1472 'purpose' => $declaration_purpose
1473 });
1474 } else {
1475 print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1476 ++$errors;
1477 }
1478}
1479
1480sub save_struct_actual($) {
1481 my $actual = shift;
1482
1483 # strip all spaces from the actual param so that it looks like one string item
1484 $actual =~ s/\s*//g;
1485 $struct_actual = $struct_actual . $actual . " ";
1486}
1487
1488sub create_parameterlist($$$$) {
1489 my $args = shift;
1490 my $splitter = shift;
1491 my $file = shift;
1492 my $declaration_name = shift;
1493 my $type;
1494 my $param;
1495
1496 # temporarily replace commas inside function pointer definition
1497 my $arg_expr = qr{\([^\),]+};
1498 while ($args =~ /$arg_expr,/) {
1499 $args =~ s/($arg_expr),/$1#/g;
1500 }
1501
1502 foreach my $arg (split($splitter, $args)) {
1503 # strip comments
1504 $arg =~ s/\/\*.*\*\///;
1505 # ignore argument attributes
1506 $arg =~ s/\sPOS0?\s/ /;
1507 # strip leading/trailing spaces
1508 $arg =~ s/^\s*//;
1509 $arg =~ s/\s*$//;
1510 $arg =~ s/\s+/ /;
1511
1512 if ($arg =~ /^#/) {
1513 # Treat preprocessor directive as a typeless variable just to fill
1514 # corresponding data structures "correctly". Catch it later in
1515 # output_* subs.
1516 push_parameter($arg, "", "", $file);
1517 } elsif ($arg =~ m/\(.+\)\s*\(/) {
1518 # pointer-to-function
1519 $arg =~ tr/#/,/;
1520 $arg =~ m/[^\(]+\(\*?\s*([\w\[\]\.]*)\s*\)/;
1521 $param = $1;
1522 $type = $arg;
1523 $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1524 save_struct_actual($param);
1525 push_parameter($param, $type, $arg, $file, $declaration_name);
1526 } elsif ($arg =~ m/\(.+\)\s*\[/) {
1527 # array-of-pointers
1528 $arg =~ tr/#/,/;
1529 $arg =~ m/[^\(]+\(\s*\*\s*([\w\[\]\.]*?)\s*(\s*\[\s*[\w]+\s*\]\s*)*\)/;
1530 $param = $1;
1531 $type = $arg;
1532 $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1533 save_struct_actual($param);
1534 push_parameter($param, $type, $arg, $file, $declaration_name);
1535 } elsif ($arg) {
1536 $arg =~ s/\s*:\s*/:/g;
1537 $arg =~ s/\s*\[/\[/g;
1538
1539 my @args = split('\s*,\s*', $arg);
1540 if ($args[0] =~ m/\*/) {
1541 $args[0] =~ s/(\*+)\s*/ $1/;
1542 }
1543
1544 my @first_arg;
1545 if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1546 shift @args;
1547 push(@first_arg, split('\s+', $1));
1548 push(@first_arg, $2);
1549 } else {
1550 @first_arg = split('\s+', shift @args);
1551 }
1552
1553 unshift(@args, pop @first_arg);
1554 $type = join " ", @first_arg;
1555
1556 foreach $param (@args) {
1557 if ($param =~ m/^(\*+)\s*(.*)/) {
1558 save_struct_actual($2);
1559
1560 push_parameter($2, "$type $1", $arg, $file, $declaration_name);
1561 } elsif ($param =~ m/(.*?):(\w+)/) {
1562 if ($type ne "") { # skip unnamed bit-fields
1563 save_struct_actual($1);
1564 push_parameter($1, "$type:$2", $arg, $file, $declaration_name)
1565 }
1566 } else {
1567 save_struct_actual($param);
1568 push_parameter($param, $type, $arg, $file, $declaration_name);
1569 }
1570 }
1571 }
1572 }
1573}
1574
1575sub push_parameter($$$$$) {
1576 my $param = shift;
1577 my $type = shift;
1578 my $org_arg = shift;
1579 my $file = shift;
1580 my $declaration_name = shift;
1581
1582 if (($anon_struct_union == 1) && ($type eq "") &&
1583 ($param eq "}")) {
1584 return; # ignore the ending }; from anon. struct/union
1585 }
1586
1587 $anon_struct_union = 0;
1588 $param =~ s/[\[\)].*//;
1589
1590 if ($type eq "" && $param =~ /\.\.\.$/)
1591 {
1592 if (!$param =~ /\w\.\.\.$/) {
1593 # handles unnamed variable parameters
1594 $param = "...";
1595 } elsif ($param =~ /\w\.\.\.$/) {
1596 # for named variable parameters of the form `x...`, remove the dots
1597 $param =~ s/\.\.\.$//;
1598 }
1599 if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1600 $parameterdescs{$param} = "variable arguments";
1601 }
1602 }
1603 elsif ($type eq "" && ($param eq "" or $param eq "void"))
1604 {
1605 $param="void";
1606 $parameterdescs{void} = "no arguments";
1607 }
1608 elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1609 # handle unnamed (anonymous) union or struct:
1610 {
1611 $type = $param;
1612 $param = "{unnamed_" . $param . "}";
1613 $parameterdescs{$param} = "anonymous\n";
1614 $anon_struct_union = 1;
1615 }
1616 elsif ($param =~ "__cacheline_group" )
1617 # handle cache group enforcing variables: they do not need be described in header files
1618 {
1619 return; # ignore __cacheline_group_begin and __cacheline_group_end
1620 }
1621
1622 # warn if parameter has no description
1623 # (but ignore ones starting with # as these are not parameters
1624 # but inline preprocessor statements);
1625 # Note: It will also ignore void params and unnamed structs/unions
1626 if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1627 $parameterdescs{$param} = $undescribed;
1628
1629 if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1630 emit_warning("${file}:$.", "Function parameter or struct member '$param' not described in '$declaration_name'\n");
1631 }
1632 }
1633
1634 # strip spaces from $param so that it is one continuous string
1635 # on @parameterlist;
1636 # this fixes a problem where check_sections() cannot find
1637 # a parameter like "addr[6 + 2]" because it actually appears
1638 # as "addr[6", "+", "2]" on the parameter list;
1639 # but it's better to maintain the param string unchanged for output,
1640 # so just weaken the string compare in check_sections() to ignore
1641 # "[blah" in a parameter string;
1642 ###$param =~ s/\s*//g;
1643 push @parameterlist, $param;
1644 $org_arg =~ s/\s\s+/ /g;
1645 $parametertypes{$param} = $org_arg;
1646}
1647
1648sub check_sections($$$$$) {
1649 my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1650 my @sects = split ' ', $sectcheck;
1651 my @prms = split ' ', $prmscheck;
1652 my $err;
1653 my ($px, $sx);
1654 my $prm_clean; # strip trailing "[array size]" and/or beginning "*"
1655
1656 foreach $sx (0 .. $#sects) {
1657 $err = 1;
1658 foreach $px (0 .. $#prms) {
1659 $prm_clean = $prms[$px];
1660 $prm_clean =~ s/\[.*\]//;
1661 $prm_clean =~ s/$attribute//i;
1662 # ignore array size in a parameter string;
1663 # however, the original param string may contain
1664 # spaces, e.g.: addr[6 + 2]
1665 # and this appears in @prms as "addr[6" since the
1666 # parameter list is split at spaces;
1667 # hence just ignore "[..." for the sections check;
1668 $prm_clean =~ s/\[.*//;
1669
1670 ##$prm_clean =~ s/^\**//;
1671 if ($prm_clean eq $sects[$sx]) {
1672 $err = 0;
1673 last;
1674 }
1675 }
1676 if ($err) {
1677 if ($decl_type eq "function") {
1678 emit_warning("${file}:$.",
1679 "Excess function parameter " .
1680 "'$sects[$sx]' " .
1681 "description in '$decl_name'\n");
1682 } elsif (($decl_type eq "struct") or
1683 ($decl_type eq "union")) {
1684 emit_warning("${file}:$.",
1685 "Excess $decl_type member " .
1686 "'$sects[$sx]' " .
1687 "description in '$decl_name'\n");
1688 }
1689 }
1690 }
1691}
1692
1693##
1694# Checks the section describing the return value of a function.
1695sub check_return_section {
1696 my $file = shift;
1697 my $declaration_name = shift;
1698 my $return_type = shift;
1699
1700 # Ignore an empty return type (It's a macro)
1701 # Ignore functions with a "void" return type. (But don't ignore "void *")
1702 if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1703 return;
1704 }
1705
1706 if (!defined($sections{$section_return}) ||
1707 $sections{$section_return} eq "")
1708 {
1709 emit_warning("${file}:$.",
1710 "No description found for return value of " .
1711 "'$declaration_name'\n");
1712 }
1713}
1714
1715##
1716# takes a function prototype and the name of the current file being
1717# processed and spits out all the details stored in the global
1718# arrays/hashes.
1719sub dump_function($$) {
1720 my $prototype = shift;
1721 my $file = shift;
1722 my $func_macro = 0;
1723
1724 print_lineno($new_start_line);
1725
1726 $prototype =~ s/^static +//;
1727 $prototype =~ s/^extern +//;
1728 $prototype =~ s/^asmlinkage +//;
1729 $prototype =~ s/^inline +//;
1730 $prototype =~ s/^__inline__ +//;
1731 $prototype =~ s/^__inline +//;
1732 $prototype =~ s/^__always_inline +//;
1733 $prototype =~ s/^noinline +//;
1734 $prototype =~ s/^__FORTIFY_INLINE +//;
1735 $prototype =~ s/__init +//;
1736 $prototype =~ s/__init_or_module +//;
1737 $prototype =~ s/__deprecated +//;
1738 $prototype =~ s/__flatten +//;
1739 $prototype =~ s/__meminit +//;
1740 $prototype =~ s/__must_check +//;
1741 $prototype =~ s/__weak +//;
1742 $prototype =~ s/__sched +//;
1743 $prototype =~ s/_noprof//;
1744 $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1745 $prototype =~ s/__(?:re)?alloc_size\s*\(\s*\d+\s*(?:,\s*\d+\s*)?\) +//;
1746 $prototype =~ s/__diagnose_as\s*\(\s*\S+\s*(?:,\s*\d+\s*)*\) +//;
1747 $prototype =~ s/DECL_BUCKET_PARAMS\s*\(\s*(\S+)\s*,\s*(\S+)\s*\)/$1, $2/;
1748 my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1749 $prototype =~ s/__attribute_const__ +//;
1750 $prototype =~ s/__attribute__\s*\(\(
1751 (?:
1752 [\w\s]++ # attribute name
1753 (?:\([^)]*+\))? # attribute arguments
1754 \s*+,? # optional comma at the end
1755 )+
1756 \)\)\s+//x;
1757
1758 # Yes, this truly is vile. We are looking for:
1759 # 1. Return type (may be nothing if we're looking at a macro)
1760 # 2. Function name
1761 # 3. Function parameters.
1762 #
1763 # All the while we have to watch out for function pointer parameters
1764 # (which IIRC is what the two sections are for), C types (these
1765 # regexps don't even start to express all the possibilities), and
1766 # so on.
1767 #
1768 # If you mess with these regexps, it's a good idea to check that
1769 # the following functions' documentation still comes out right:
1770 # - parport_register_device (function pointer parameters)
1771 # - atomic_set (macro)
1772 # - pci_match_device, __copy_to_user (long return type)
1773 my $name = qr{[a-zA-Z0-9_~:]+};
1774 my $prototype_end1 = qr{[^\(]*};
1775 my $prototype_end2 = qr{[^\{]*};
1776 my $prototype_end = qr{\(($prototype_end1|$prototype_end2)\)};
1777 my $type1 = qr{[\w\s]+};
1778 my $type2 = qr{$type1\*+};
1779
1780 if ($define && $prototype =~ m/^()($name)\s+/) {
1781 # This is an object-like macro, it has no return type and no parameter
1782 # list.
1783 # Function-like macros are not allowed to have spaces between
1784 # declaration_name and opening parenthesis (notice the \s+).
1785 $return_type = $1;
1786 $declaration_name = $2;
1787 $func_macro = 1;
1788 } elsif ($prototype =~ m/^()($name)\s*$prototype_end/ ||
1789 $prototype =~ m/^($type1)\s+($name)\s*$prototype_end/ ||
1790 $prototype =~ m/^($type2+)\s*($name)\s*$prototype_end/) {
1791 $return_type = $1;
1792 $declaration_name = $2;
1793 my $args = $3;
1794
1795 create_parameterlist($args, ',', $file, $declaration_name);
1796 } else {
1797 emit_warning("${file}:$.", "cannot understand function prototype: '$prototype'\n");
1798 return;
1799 }
1800
1801 if ($identifier ne $declaration_name) {
1802 emit_warning("${file}:$.", "expecting prototype for $identifier(). Prototype was for $declaration_name() instead\n");
1803 return;
1804 }
1805
1806 my $prms = join " ", @parameterlist;
1807 check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1808
1809 # This check emits a lot of warnings at the moment, because many
1810 # functions don't have a 'Return' doc section. So until the number
1811 # of warnings goes sufficiently down, the check is only performed in
1812 # -Wreturn mode.
1813 # TODO: always perform the check.
1814 if ($Wreturn && !$func_macro) {
1815 check_return_section($file, $declaration_name, $return_type);
1816 }
1817
1818 # The function parser can be called with a typedef parameter.
1819 # Handle it.
1820 if ($return_type =~ /typedef/) {
1821 output_declaration($declaration_name,
1822 'function',
1823 {'function' => $declaration_name,
1824 'typedef' => 1,
1825 'module' => $modulename,
1826 'functiontype' => $return_type,
1827 'parameterlist' => \@parameterlist,
1828 'parameterdescs' => \%parameterdescs,
1829 'parametertypes' => \%parametertypes,
1830 'sectionlist' => \@sectionlist,
1831 'sections' => \%sections,
1832 'purpose' => $declaration_purpose,
1833 'func_macro' => $func_macro
1834 });
1835 } else {
1836 output_declaration($declaration_name,
1837 'function',
1838 {'function' => $declaration_name,
1839 'module' => $modulename,
1840 'functiontype' => $return_type,
1841 'parameterlist' => \@parameterlist,
1842 'parameterdescs' => \%parameterdescs,
1843 'parametertypes' => \%parametertypes,
1844 'sectionlist' => \@sectionlist,
1845 'sections' => \%sections,
1846 'purpose' => $declaration_purpose,
1847 'func_macro' => $func_macro
1848 });
1849 }
1850}
1851
1852sub reset_state {
1853 $function = "";
1854 %parameterdescs = ();
1855 %parametertypes = ();
1856 @parameterlist = ();
1857 %sections = ();
1858 @sectionlist = ();
1859 $sectcheck = "";
1860 $struct_actual = "";
1861 $prototype = "";
1862
1863 $state = STATE_NORMAL;
1864 $inline_doc_state = STATE_INLINE_NA;
1865}
1866
1867sub tracepoint_munge($) {
1868 my $file = shift;
1869 my $tracepointname = 0;
1870 my $tracepointargs = 0;
1871
1872 if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1873 $tracepointname = $1;
1874 }
1875 if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1876 $tracepointname = $1;
1877 }
1878 if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1879 $tracepointname = $2;
1880 }
1881 $tracepointname =~ s/^\s+//; #strip leading whitespace
1882 if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1883 $tracepointargs = $1;
1884 }
1885 if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1886 emit_warning("${file}:$.", "Unrecognized tracepoint format: \n".
1887 "$prototype\n");
1888 } else {
1889 $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1890 $identifier = "trace_$identifier";
1891 }
1892}
1893
1894sub syscall_munge() {
1895 my $void = 0;
1896
1897 $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1898## if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1899 if ($prototype =~ m/SYSCALL_DEFINE0/) {
1900 $void = 1;
1901## $prototype = "long sys_$1(void)";
1902 }
1903
1904 $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1905 if ($prototype =~ m/long (sys_.*?),/) {
1906 $prototype =~ s/,/\(/;
1907 } elsif ($void) {
1908 $prototype =~ s/\)/\(void\)/;
1909 }
1910
1911 # now delete all of the odd-number commas in $prototype
1912 # so that arg types & arg names don't have a comma between them
1913 my $count = 0;
1914 my $len = length($prototype);
1915 if ($void) {
1916 $len = 0; # skip the for-loop
1917 }
1918 for (my $ix = 0; $ix < $len; $ix++) {
1919 if (substr($prototype, $ix, 1) eq ',') {
1920 $count++;
1921 if ($count % 2 == 1) {
1922 substr($prototype, $ix, 1) = ' ';
1923 }
1924 }
1925 }
1926}
1927
1928sub process_proto_function($$) {
1929 my $x = shift;
1930 my $file = shift;
1931
1932 $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1933
1934 if ($x =~ /^#/ && $x !~ /^#\s*define/) {
1935 # do nothing
1936 } elsif ($x =~ /([^\{]*)/) {
1937 $prototype .= $1;
1938 }
1939
1940 if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1941 $prototype =~ s@/\*.*?\*/@@gos; # strip comments.
1942 $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1943 $prototype =~ s@^\s+@@gos; # strip leading spaces
1944
1945 # Handle prototypes for function pointers like:
1946 # int (*pcs_config)(struct foo)
1947 $prototype =~ s@^(\S+\s+)\(\s*\*(\S+)\)@$1$2@gos;
1948
1949 if ($prototype =~ /SYSCALL_DEFINE/) {
1950 syscall_munge();
1951 }
1952 if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1953 $prototype =~ /DEFINE_SINGLE_EVENT/)
1954 {
1955 tracepoint_munge($file);
1956 }
1957 dump_function($prototype, $file);
1958 reset_state();
1959 }
1960}
1961
1962sub process_proto_type($$) {
1963 my $x = shift;
1964 my $file = shift;
1965
1966 $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1967 $x =~ s@^\s+@@gos; # strip leading spaces
1968 $x =~ s@\s+$@@gos; # strip trailing spaces
1969 $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1970
1971 if ($x =~ /^#/) {
1972 # To distinguish preprocessor directive from regular declaration later.
1973 $x .= ";";
1974 }
1975
1976 while (1) {
1977 if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1978 if( length $prototype ) {
1979 $prototype .= " "
1980 }
1981 $prototype .= $1 . $2;
1982 ($2 eq '{') && $brcount++;
1983 ($2 eq '}') && $brcount--;
1984 if (($2 eq ';') && ($brcount == 0)) {
1985 dump_declaration($prototype, $file);
1986 reset_state();
1987 last;
1988 }
1989 $x = $3;
1990 } else {
1991 $prototype .= $x;
1992 last;
1993 }
1994 }
1995}
1996
1997
1998sub map_filename($) {
1999 my $file;
2000 my ($orig_file) = @_;
2001
2002 if (defined($ENV{'SRCTREE'})) {
2003 $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
2004 } else {
2005 $file = $orig_file;
2006 }
2007
2008 if (defined($source_map{$file})) {
2009 $file = $source_map{$file};
2010 }
2011
2012 return $file;
2013}
2014
2015sub process_export_file($) {
2016 my ($orig_file) = @_;
2017 my $file = map_filename($orig_file);
2018
2019 if (!open(IN,"<$file")) {
2020 print STDERR "Error: Cannot open file $file\n";
2021 ++$errors;
2022 return;
2023 }
2024
2025 while (<IN>) {
2026 if (/$export_symbol/) {
2027 next if (defined($nosymbol_table{$2}));
2028 $function_table{$2} = 1;
2029 }
2030 if (/$export_symbol_ns/) {
2031 next if (defined($nosymbol_table{$2}));
2032 $function_table{$2} = 1;
2033 }
2034 }
2035
2036 close(IN);
2037}
2038
2039#
2040# Parsers for the various processing states.
2041#
2042# STATE_NORMAL: looking for the /** to begin everything.
2043#
2044sub process_normal() {
2045 if (/$doc_start/o) {
2046 $state = STATE_NAME; # next line is always the function name
2047 $in_doc_sect = 0;
2048 $declaration_start_line = $. + 1;
2049 }
2050}
2051
2052#
2053# STATE_NAME: Looking for the "name - description" line
2054#
2055sub process_name($$) {
2056 my $file = shift;
2057 my $descr;
2058
2059 if (/$doc_block/o) {
2060 $state = STATE_DOCBLOCK;
2061 $contents = "";
2062 $new_start_line = $.;
2063
2064 if ( $1 eq "" ) {
2065 $section = $section_intro;
2066 } else {
2067 $section = $1;
2068 }
2069 } elsif (/$doc_decl/o) {
2070 $identifier = $1;
2071 my $is_kernel_comment = 0;
2072 my $decl_start = qr{$doc_com};
2073 # test for pointer declaration type, foo * bar() - desc
2074 my $fn_type = qr{\w+\s*\*\s*};
2075 my $parenthesis = qr{\(\w*\)};
2076 my $decl_end = qr{[-:].*};
2077 if (/^$decl_start([\w\s]+?)$parenthesis?\s*$decl_end?$/) {
2078 $identifier = $1;
2079 }
2080 if ($identifier =~ m/^(struct|union|enum|typedef)\b\s*(\S*)/) {
2081 $decl_type = $1;
2082 $identifier = $2;
2083 $is_kernel_comment = 1;
2084 }
2085 # Look for foo() or static void foo() - description; or misspelt
2086 # identifier
2087 elsif (/^$decl_start$fn_type?(\w+)\s*$parenthesis?\s*$decl_end?$/ ||
2088 /^$decl_start$fn_type?(\w+.*)$parenthesis?\s*$decl_end$/) {
2089 $identifier = $1;
2090 $decl_type = 'function';
2091 $identifier =~ s/^define\s+//;
2092 $is_kernel_comment = 1;
2093 }
2094 $identifier =~ s/\s+$//;
2095
2096 $state = STATE_BODY;
2097 # if there's no @param blocks need to set up default section
2098 # here
2099 $contents = "";
2100 $section = $section_default;
2101 $new_start_line = $. + 1;
2102 if (/[-:](.*)/) {
2103 # strip leading/trailing/multiple spaces
2104 $descr= $1;
2105 $descr =~ s/^\s*//;
2106 $descr =~ s/\s*$//;
2107 $descr =~ s/\s+/ /g;
2108 $declaration_purpose = $descr;
2109 $state = STATE_BODY_MAYBE;
2110 } else {
2111 $declaration_purpose = "";
2112 }
2113
2114 if (!$is_kernel_comment) {
2115 emit_warning("${file}:$.", "This comment starts with '/**', but isn't a kernel-doc comment. Refer Documentation/doc-guide/kernel-doc.rst\n$_");
2116 $state = STATE_NORMAL;
2117 }
2118
2119 if (($declaration_purpose eq "") && $Wshort_desc) {
2120 emit_warning("${file}:$.", "missing initial short description on line:\n$_");
2121 }
2122
2123 if ($identifier eq "" && $decl_type ne "enum") {
2124 emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n$_");
2125 $state = STATE_NORMAL;
2126 }
2127
2128 if ($verbose) {
2129 print STDERR "${file}:$.: info: Scanning doc for $decl_type $identifier\n";
2130 }
2131 } else {
2132 emit_warning("${file}:$.", "Cannot understand $_ on line $. - I thought it was a doc line\n");
2133 $state = STATE_NORMAL;
2134 }
2135}
2136
2137
2138#
2139# STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
2140#
2141sub process_body($$) {
2142 my $file = shift;
2143
2144 if ($state == STATE_BODY_WITH_BLANK_LINE && /^\s*\*\s?\S/) {
2145 dump_section($file, $section, $contents);
2146 $section = $section_default;
2147 $new_start_line = $.;
2148 $contents = "";
2149 }
2150
2151 if (/$doc_sect/i) { # case insensitive for supported section names
2152 $in_doc_sect = 1;
2153 $newsection = $1;
2154 $newcontents = $2;
2155
2156 # map the supported section names to the canonical names
2157 if ($newsection =~ m/^description$/i) {
2158 $newsection = $section_default;
2159 } elsif ($newsection =~ m/^context$/i) {
2160 $newsection = $section_context;
2161 } elsif ($newsection =~ m/^returns?$/i) {
2162 $newsection = $section_return;
2163 } elsif ($newsection =~ m/^\@return$/) {
2164 # special: @return is a section, not a param description
2165 $newsection = $section_return;
2166 }
2167
2168 if (($contents ne "") && ($contents ne "\n")) {
2169 if (!$in_doc_sect && $Wcontents_before_sections) {
2170 emit_warning("${file}:$.", "contents before sections\n");
2171 }
2172 dump_section($file, $section, $contents);
2173 $section = $section_default;
2174 }
2175
2176 $in_doc_sect = 1;
2177 $state = STATE_BODY;
2178 $contents = $newcontents;
2179 $new_start_line = $.;
2180 while (substr($contents, 0, 1) eq " ") {
2181 $contents = substr($contents, 1);
2182 }
2183 if ($contents ne "") {
2184 $contents .= "\n";
2185 }
2186 $section = $newsection;
2187 $leading_space = undef;
2188 } elsif (/$doc_end/) {
2189 if (($contents ne "") && ($contents ne "\n")) {
2190 dump_section($file, $section, $contents);
2191 $section = $section_default;
2192 $contents = "";
2193 }
2194 # look for doc_com + <text> + doc_end:
2195 if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2196 emit_warning("${file}:$.", "suspicious ending line: $_");
2197 }
2198
2199 $prototype = "";
2200 $state = STATE_PROTO;
2201 $brcount = 0;
2202 $new_start_line = $. + 1;
2203 } elsif (/$doc_content/) {
2204 if ($1 eq "") {
2205 if ($section eq $section_context) {
2206 dump_section($file, $section, $contents);
2207 $section = $section_default;
2208 $contents = "";
2209 $new_start_line = $.;
2210 $state = STATE_BODY;
2211 } else {
2212 if ($section ne $section_default) {
2213 $state = STATE_BODY_WITH_BLANK_LINE;
2214 } else {
2215 $state = STATE_BODY;
2216 }
2217 $contents .= "\n";
2218 }
2219 } elsif ($state == STATE_BODY_MAYBE) {
2220 # Continued declaration purpose
2221 chomp($declaration_purpose);
2222 $declaration_purpose .= " " . $1;
2223 $declaration_purpose =~ s/\s+/ /g;
2224 } else {
2225 my $cont = $1;
2226 if ($section =~ m/^@/ || $section eq $section_context) {
2227 if (!defined $leading_space) {
2228 if ($cont =~ m/^(\s+)/) {
2229 $leading_space = $1;
2230 } else {
2231 $leading_space = "";
2232 }
2233 }
2234 $cont =~ s/^$leading_space//;
2235 }
2236 $contents .= $cont . "\n";
2237 }
2238 } else {
2239 # i dont know - bad line? ignore.
2240 emit_warning("${file}:$.", "bad line: $_");
2241 }
2242}
2243
2244
2245#
2246# STATE_PROTO: reading a function/whatever prototype.
2247#
2248sub process_proto($$) {
2249 my $file = shift;
2250
2251 if (/$doc_inline_oneline/) {
2252 $section = $1;
2253 $contents = $2;
2254 if ($contents ne "") {
2255 $contents .= "\n";
2256 dump_section($file, $section, $contents);
2257 $section = $section_default;
2258 $contents = "";
2259 }
2260 } elsif (/$doc_inline_start/) {
2261 $state = STATE_INLINE;
2262 $inline_doc_state = STATE_INLINE_NAME;
2263 } elsif ($decl_type eq 'function') {
2264 process_proto_function($_, $file);
2265 } else {
2266 process_proto_type($_, $file);
2267 }
2268}
2269
2270#
2271# STATE_DOCBLOCK: within a DOC: block.
2272#
2273sub process_docblock($$) {
2274 my $file = shift;
2275
2276 if (/$doc_end/) {
2277 dump_doc_section($file, $section, $contents);
2278 $section = $section_default;
2279 $contents = "";
2280 $function = "";
2281 %parameterdescs = ();
2282 %parametertypes = ();
2283 @parameterlist = ();
2284 %sections = ();
2285 @sectionlist = ();
2286 $prototype = "";
2287 $state = STATE_NORMAL;
2288 } elsif (/$doc_content/) {
2289 if ( $1 eq "" ) {
2290 $contents .= $blankline;
2291 } else {
2292 $contents .= $1 . "\n";
2293 }
2294 }
2295}
2296
2297#
2298# STATE_INLINE: docbook comments within a prototype.
2299#
2300sub process_inline($$) {
2301 my $file = shift;
2302
2303 # First line (state 1) needs to be a @parameter
2304 if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2305 $section = $1;
2306 $contents = $2;
2307 $new_start_line = $.;
2308 if ($contents ne "") {
2309 while (substr($contents, 0, 1) eq " ") {
2310 $contents = substr($contents, 1);
2311 }
2312 $contents .= "\n";
2313 }
2314 $inline_doc_state = STATE_INLINE_TEXT;
2315 # Documentation block end */
2316 } elsif (/$doc_inline_end/) {
2317 if (($contents ne "") && ($contents ne "\n")) {
2318 dump_section($file, $section, $contents);
2319 $section = $section_default;
2320 $contents = "";
2321 }
2322 $state = STATE_PROTO;
2323 $inline_doc_state = STATE_INLINE_NA;
2324 # Regular text
2325 } elsif (/$doc_content/) {
2326 if ($inline_doc_state == STATE_INLINE_TEXT) {
2327 $contents .= $1 . "\n";
2328 # nuke leading blank lines
2329 if ($contents =~ /^\s*$/) {
2330 $contents = "";
2331 }
2332 } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2333 $inline_doc_state = STATE_INLINE_ERROR;
2334 emit_warning("${file}:$.", "Incorrect use of kernel-doc format: $_");
2335 }
2336 }
2337}
2338
2339
2340sub process_file($) {
2341 my $file;
2342 my ($orig_file) = @_;
2343
2344 $file = map_filename($orig_file);
2345
2346 if (!open(IN_FILE,"<$file")) {
2347 print STDERR "Error: Cannot open file $file\n";
2348 ++$errors;
2349 return;
2350 }
2351
2352 $. = 1;
2353
2354 $section_counter = 0;
2355 while (<IN_FILE>) {
2356 while (!/^ \*/ && s/\\\s*$//) {
2357 $_ .= <IN_FILE>;
2358 }
2359 # Replace tabs by spaces
2360 while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2361 # Hand this line to the appropriate state handler
2362 if ($state == STATE_NORMAL) {
2363 process_normal();
2364 } elsif ($state == STATE_NAME) {
2365 process_name($file, $_);
2366 } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE ||
2367 $state == STATE_BODY_WITH_BLANK_LINE) {
2368 process_body($file, $_);
2369 } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2370 process_inline($file, $_);
2371 } elsif ($state == STATE_PROTO) {
2372 process_proto($file, $_);
2373 } elsif ($state == STATE_DOCBLOCK) {
2374 process_docblock($file, $_);
2375 }
2376 }
2377
2378 # Make sure we got something interesting.
2379 if (!$section_counter && $output_mode ne "none") {
2380 if ($output_selection == OUTPUT_INCLUDE) {
2381 emit_warning("${file}:1", "'$_' not found\n")
2382 for keys %function_table;
2383 } else {
2384 emit_warning("${file}:1", "no structured comments found\n");
2385 }
2386 }
2387 close IN_FILE;
2388}
2389
2390
2391if ($output_mode eq "rst") {
2392 get_sphinx_version() if (!$sphinx_major);
2393}
2394
2395$kernelversion = get_kernel_version();
2396
2397# generate a sequence of code that will splice in highlighting information
2398# using the s// operator.
2399for (my $k = 0; $k < @highlights; $k++) {
2400 my $pattern = $highlights[$k][0];
2401 my $result = $highlights[$k][1];
2402# print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2403 $dohighlight .= "\$contents =~ s:$pattern:$result:gs;\n";
2404}
2405
2406# Read the file that maps relative names to absolute names for
2407# separate source and object directories and for shadow trees.
2408if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2409 my ($relname, $absname);
2410 while(<SOURCE_MAP>) {
2411 chop();
2412 ($relname, $absname) = (split())[0..1];
2413 $relname =~ s:^/+::;
2414 $source_map{$relname} = $absname;
2415 }
2416 close(SOURCE_MAP);
2417}
2418
2419if ($output_selection == OUTPUT_EXPORTED ||
2420 $output_selection == OUTPUT_INTERNAL) {
2421
2422 push(@export_file_list, @ARGV);
2423
2424 foreach (@export_file_list) {
2425 chomp;
2426 process_export_file($_);
2427 }
2428}
2429
2430foreach (@ARGV) {
2431 chomp;
2432 process_file($_);
2433}
2434if ($verbose && $errors) {
2435 print STDERR "$errors errors\n";
2436}
2437if ($verbose && $warnings) {
2438 print STDERR "$warnings warnings\n";
2439}
2440
2441if ($Werror && $warnings) {
2442 print STDERR "$warnings warnings as Errors\n";
2443 exit($warnings);
2444} else {
2445 exit($output_mode eq "none" ? 0 : $errors)
2446}
2447
2448__END__
2449
2450=head1 OPTIONS
2451
2452=head2 Output format selection (mutually exclusive):
2453
2454=over 8
2455
2456=item -man
2457
2458Output troff manual page format.
2459
2460=item -rst
2461
2462Output reStructuredText format. This is the default.
2463
2464=item -none
2465
2466Do not output documentation, only warnings.
2467
2468=back
2469
2470=head2 Output format modifiers
2471
2472=head3 reStructuredText only
2473
2474=over 8
2475
2476=item -sphinx-version VERSION
2477
2478Use the ReST C domain dialect compatible with a specific Sphinx Version.
2479
2480If not specified, kernel-doc will auto-detect using the sphinx-build version
2481found on PATH.
2482
2483=back
2484
2485=head2 Output selection (mutually exclusive):
2486
2487=over 8
2488
2489=item -export
2490
2491Only output documentation for the symbols that have been exported using
2492EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2493
2494=item -internal
2495
2496Only output documentation for the symbols that have NOT been exported using
2497EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2498
2499=item -function NAME
2500
2501Only output documentation for the given function or DOC: section title.
2502All other functions and DOC: sections are ignored.
2503
2504May be specified multiple times.
2505
2506=item -nosymbol NAME
2507
2508Exclude the specified symbol from the output documentation.
2509
2510May be specified multiple times.
2511
2512=back
2513
2514=head2 Output selection modifiers:
2515
2516=over 8
2517
2518=item -no-doc-sections
2519
2520Do not output DOC: sections.
2521
2522=item -export-file FILE
2523
2524Specify an additional FILE in which to look for EXPORT_SYMBOL information.
2525
2526To be used with -export or -internal.
2527
2528May be specified multiple times.
2529
2530=back
2531
2532=head3 reStructuredText only
2533
2534=over 8
2535
2536=item -enable-lineno
2537
2538Enable output of .. LINENO lines.
2539
2540=back
2541
2542=head2 Other parameters:
2543
2544=over 8
2545
2546=item -h, -help
2547
2548Print this help.
2549
2550=item -v
2551
2552Verbose output, more warnings and other information.
2553
2554=item -Werror
2555
2556Treat warnings as errors.
2557
2558=back
2559
2560=cut
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3
4use warnings;
5use strict;
6
7## Copyright (c) 1998 Michael Zucchi, All Rights Reserved ##
8## Copyright (C) 2000, 1 Tim Waugh <twaugh@redhat.com> ##
9## Copyright (C) 2001 Simon Huggins ##
10## Copyright (C) 2005-2012 Randy Dunlap ##
11## Copyright (C) 2012 Dan Luedtke ##
12## ##
13## #define enhancements by Armin Kuster <akuster@mvista.com> ##
14## Copyright (c) 2000 MontaVista Software, Inc. ##
15## ##
16## This software falls under the GNU General Public License. ##
17## Please read the COPYING file for more information ##
18
19# 18/01/2001 - Cleanups
20# Functions prototyped as foo(void) same as foo()
21# Stop eval'ing where we don't need to.
22# -- huggie@earth.li
23
24# 27/06/2001 - Allowed whitespace after initial "/**" and
25# allowed comments before function declarations.
26# -- Christian Kreibich <ck@whoop.org>
27
28# Still to do:
29# - add perldoc documentation
30# - Look more closely at some of the scarier bits :)
31
32# 26/05/2001 - Support for separate source and object trees.
33# Return error code.
34# Keith Owens <kaos@ocs.com.au>
35
36# 23/09/2001 - Added support for typedefs, structs, enums and unions
37# Support for Context section; can be terminated using empty line
38# Small fixes (like spaces vs. \s in regex)
39# -- Tim Jansen <tim@tjansen.de>
40
41# 25/07/2012 - Added support for HTML5
42# -- Dan Luedtke <mail@danrl.de>
43
44sub usage {
45 my $message = <<"EOF";
46Usage: $0 [OPTION ...] FILE ...
47
48Read C language source or header FILEs, extract embedded documentation comments,
49and print formatted documentation to standard output.
50
51The documentation comments are identified by "/**" opening comment mark. See
52Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
53
54Output format selection (mutually exclusive):
55 -man Output troff manual page format. This is the default.
56 -rst Output reStructuredText format.
57 -none Do not output documentation, only warnings.
58
59Output selection (mutually exclusive):
60 -export Only output documentation for symbols that have been
61 exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
62 in any input FILE or -export-file FILE.
63 -internal Only output documentation for symbols that have NOT been
64 exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
65 in any input FILE or -export-file FILE.
66 -function NAME Only output documentation for the given function(s)
67 or DOC: section title(s). All other functions and DOC:
68 sections are ignored. May be specified multiple times.
69 -nofunction NAME Do NOT output documentation for the given function(s);
70 only output documentation for the other functions and
71 DOC: sections. May be specified multiple times.
72
73Output selection modifiers:
74 -no-doc-sections Do not output DOC: sections.
75 -enable-lineno Enable output of #define LINENO lines. Only works with
76 reStructuredText format.
77 -export-file FILE Specify an additional FILE in which to look for
78 EXPORT_SYMBOL() and EXPORT_SYMBOL_GPL(). To be used with
79 -export or -internal. May be specified multiple times.
80
81Other parameters:
82 -v Verbose output, more warnings and other information.
83 -h Print this help.
84
85EOF
86 print $message;
87 exit 1;
88}
89
90#
91# format of comments.
92# In the following table, (...)? signifies optional structure.
93# (...)* signifies 0 or more structure elements
94# /**
95# * function_name(:)? (- short description)?
96# (* @parameterx: (description of parameter x)?)*
97# (* a blank line)?
98# * (Description:)? (Description of function)?
99# * (section header: (section description)? )*
100# (*)?*/
101#
102# So .. the trivial example would be:
103#
104# /**
105# * my_function
106# */
107#
108# If the Description: header tag is omitted, then there must be a blank line
109# after the last parameter specification.
110# e.g.
111# /**
112# * my_function - does my stuff
113# * @my_arg: its mine damnit
114# *
115# * Does my stuff explained.
116# */
117#
118# or, could also use:
119# /**
120# * my_function - does my stuff
121# * @my_arg: its mine damnit
122# * Description: Does my stuff explained.
123# */
124# etc.
125#
126# Besides functions you can also write documentation for structs, unions,
127# enums and typedefs. Instead of the function name you must write the name
128# of the declaration; the struct/union/enum/typedef must always precede
129# the name. Nesting of declarations is not supported.
130# Use the argument mechanism to document members or constants.
131# e.g.
132# /**
133# * struct my_struct - short description
134# * @a: first member
135# * @b: second member
136# *
137# * Longer description
138# */
139# struct my_struct {
140# int a;
141# int b;
142# /* private: */
143# int c;
144# };
145#
146# All descriptions can be multiline, except the short function description.
147#
148# For really longs structs, you can also describe arguments inside the
149# body of the struct.
150# eg.
151# /**
152# * struct my_struct - short description
153# * @a: first member
154# * @b: second member
155# *
156# * Longer description
157# */
158# struct my_struct {
159# int a;
160# int b;
161# /**
162# * @c: This is longer description of C
163# *
164# * You can use paragraphs to describe arguments
165# * using this method.
166# */
167# int c;
168# };
169#
170# This should be use only for struct/enum members.
171#
172# You can also add additional sections. When documenting kernel functions you
173# should document the "Context:" of the function, e.g. whether the functions
174# can be called form interrupts. Unlike other sections you can end it with an
175# empty line.
176# A non-void function should have a "Return:" section describing the return
177# value(s).
178# Example-sections should contain the string EXAMPLE so that they are marked
179# appropriately in DocBook.
180#
181# Example:
182# /**
183# * user_function - function that can only be called in user context
184# * @a: some argument
185# * Context: !in_interrupt()
186# *
187# * Some description
188# * Example:
189# * user_function(22);
190# */
191# ...
192#
193#
194# All descriptive text is further processed, scanning for the following special
195# patterns, which are highlighted appropriately.
196#
197# 'funcname()' - function
198# '$ENVVAR' - environmental variable
199# '&struct_name' - name of a structure (up to two words including 'struct')
200# '&struct_name.member' - name of a structure member
201# '@parameter' - name of a parameter
202# '%CONST' - name of a constant.
203# '``LITERAL``' - literal string without any spaces on it.
204
205## init lots of data
206
207my $errors = 0;
208my $warnings = 0;
209my $anon_struct_union = 0;
210
211# match expressions used to find embedded type information
212my $type_constant = '\b``([^\`]+)``\b';
213my $type_constant2 = '\%([-_\w]+)';
214my $type_func = '(\w+)\(\)';
215my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
216my $type_fp_param = '\@(\w+)\(\)'; # Special RST handling for func ptr params
217my $type_env = '(\$\w+)';
218my $type_enum = '\&(enum\s*([_\w]+))';
219my $type_struct = '\&(struct\s*([_\w]+))';
220my $type_typedef = '\&(typedef\s*([_\w]+))';
221my $type_union = '\&(union\s*([_\w]+))';
222my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
223my $type_fallback = '\&([_\w]+)';
224my $type_member_func = $type_member . '\(\)';
225
226# Output conversion substitutions.
227# One for each output format
228
229# these are pretty rough
230my @highlights_man = (
231 [$type_constant, "\$1"],
232 [$type_constant2, "\$1"],
233 [$type_func, "\\\\fB\$1\\\\fP"],
234 [$type_enum, "\\\\fI\$1\\\\fP"],
235 [$type_struct, "\\\\fI\$1\\\\fP"],
236 [$type_typedef, "\\\\fI\$1\\\\fP"],
237 [$type_union, "\\\\fI\$1\\\\fP"],
238 [$type_param, "\\\\fI\$1\\\\fP"],
239 [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
240 [$type_fallback, "\\\\fI\$1\\\\fP"]
241 );
242my $blankline_man = "";
243
244# rst-mode
245my @highlights_rst = (
246 [$type_constant, "``\$1``"],
247 [$type_constant2, "``\$1``"],
248 # Note: need to escape () to avoid func matching later
249 [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
250 [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
251 [$type_fp_param, "**\$1\\\\(\\\\)**"],
252 [$type_func, "\$1()"],
253 [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
254 [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
255 [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
256 [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
257 # in rst this can refer to any type
258 [$type_fallback, "\\:c\\:type\\:`\$1`"],
259 [$type_param, "**\$1**"]
260 );
261my $blankline_rst = "\n";
262
263# read arguments
264if ($#ARGV == -1) {
265 usage();
266}
267
268my $kernelversion;
269my $dohighlight = "";
270
271my $verbose = 0;
272my $output_mode = "rst";
273my $output_preformatted = 0;
274my $no_doc_sections = 0;
275my $enable_lineno = 0;
276my @highlights = @highlights_rst;
277my $blankline = $blankline_rst;
278my $modulename = "Kernel API";
279
280use constant {
281 OUTPUT_ALL => 0, # output all symbols and doc sections
282 OUTPUT_INCLUDE => 1, # output only specified symbols
283 OUTPUT_EXCLUDE => 2, # output everything except specified symbols
284 OUTPUT_EXPORTED => 3, # output exported symbols
285 OUTPUT_INTERNAL => 4, # output non-exported symbols
286};
287my $output_selection = OUTPUT_ALL;
288my $show_not_found = 0; # No longer used
289
290my @export_file_list;
291
292my @build_time;
293if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
294 (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
295 @build_time = gmtime($seconds);
296} else {
297 @build_time = localtime;
298}
299
300my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
301 'July', 'August', 'September', 'October',
302 'November', 'December')[$build_time[4]] .
303 " " . ($build_time[5]+1900);
304
305# Essentially these are globals.
306# They probably want to be tidied up, made more localised or something.
307# CAVEAT EMPTOR! Some of the others I localised may not want to be, which
308# could cause "use of undefined value" or other bugs.
309my ($function, %function_table, %parametertypes, $declaration_purpose);
310my $declaration_start_line;
311my ($type, $declaration_name, $return_type);
312my ($newsection, $newcontents, $prototype, $brcount, %source_map);
313
314if (defined($ENV{'KBUILD_VERBOSE'})) {
315 $verbose = "$ENV{'KBUILD_VERBOSE'}";
316}
317
318# Generated docbook code is inserted in a template at a point where
319# docbook v3.1 requires a non-zero sequence of RefEntry's; see:
320# http://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
321# We keep track of number of generated entries and generate a dummy
322# if needs be to ensure the expanded template can be postprocessed
323# into html.
324my $section_counter = 0;
325
326my $lineprefix="";
327
328# Parser states
329use constant {
330 STATE_NORMAL => 0, # normal code
331 STATE_NAME => 1, # looking for function name
332 STATE_BODY_MAYBE => 2, # body - or maybe more description
333 STATE_BODY => 3, # the body of the comment
334 STATE_PROTO => 4, # scanning prototype
335 STATE_DOCBLOCK => 5, # documentation block
336 STATE_INLINE => 6, # gathering documentation outside main block
337};
338my $state;
339my $in_doc_sect;
340my $leading_space;
341
342# Inline documentation state
343use constant {
344 STATE_INLINE_NA => 0, # not applicable ($state != STATE_INLINE)
345 STATE_INLINE_NAME => 1, # looking for member name (@foo:)
346 STATE_INLINE_TEXT => 2, # looking for member documentation
347 STATE_INLINE_END => 3, # done
348 STATE_INLINE_ERROR => 4, # error - Comment without header was found.
349 # Spit a warning as it's not
350 # proper kernel-doc and ignore the rest.
351};
352my $inline_doc_state;
353
354#declaration types: can be
355# 'function', 'struct', 'union', 'enum', 'typedef'
356my $decl_type;
357
358my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
359my $doc_end = '\*/';
360my $doc_com = '\s*\*\s*';
361my $doc_com_body = '\s*\* ?';
362my $doc_decl = $doc_com . '(\w+)';
363# @params and a strictly limited set of supported section names
364my $doc_sect = $doc_com .
365 '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:(.*)';
366my $doc_content = $doc_com_body . '(.*)';
367my $doc_block = $doc_com . 'DOC:\s*(.*)?';
368my $doc_inline_start = '^\s*/\*\*\s*$';
369my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
370my $doc_inline_end = '^\s*\*/\s*$';
371my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
372my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
373
374my %parameterdescs;
375my %parameterdesc_start_lines;
376my @parameterlist;
377my %sections;
378my @sectionlist;
379my %section_start_lines;
380my $sectcheck;
381my $struct_actual;
382
383my $contents = "";
384my $new_start_line = 0;
385
386# the canonical section names. see also $doc_sect above.
387my $section_default = "Description"; # default section
388my $section_intro = "Introduction";
389my $section = $section_default;
390my $section_context = "Context";
391my $section_return = "Return";
392
393my $undescribed = "-- undescribed --";
394
395reset_state();
396
397while ($ARGV[0] =~ m/^--?(.*)/) {
398 my $cmd = $1;
399 shift @ARGV;
400 if ($cmd eq "man") {
401 $output_mode = "man";
402 @highlights = @highlights_man;
403 $blankline = $blankline_man;
404 } elsif ($cmd eq "rst") {
405 $output_mode = "rst";
406 @highlights = @highlights_rst;
407 $blankline = $blankline_rst;
408 } elsif ($cmd eq "none") {
409 $output_mode = "none";
410 } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
411 $modulename = shift @ARGV;
412 } elsif ($cmd eq "function") { # to only output specific functions
413 $output_selection = OUTPUT_INCLUDE;
414 $function = shift @ARGV;
415 $function_table{$function} = 1;
416 } elsif ($cmd eq "nofunction") { # output all except specific functions
417 $output_selection = OUTPUT_EXCLUDE;
418 $function = shift @ARGV;
419 $function_table{$function} = 1;
420 } elsif ($cmd eq "export") { # only exported symbols
421 $output_selection = OUTPUT_EXPORTED;
422 %function_table = ();
423 } elsif ($cmd eq "internal") { # only non-exported symbols
424 $output_selection = OUTPUT_INTERNAL;
425 %function_table = ();
426 } elsif ($cmd eq "export-file") {
427 my $file = shift @ARGV;
428 push(@export_file_list, $file);
429 } elsif ($cmd eq "v") {
430 $verbose = 1;
431 } elsif (($cmd eq "h") || ($cmd eq "help")) {
432 usage();
433 } elsif ($cmd eq 'no-doc-sections') {
434 $no_doc_sections = 1;
435 } elsif ($cmd eq 'enable-lineno') {
436 $enable_lineno = 1;
437 } elsif ($cmd eq 'show-not-found') {
438 $show_not_found = 1; # A no-op but don't fail
439 } else {
440 # Unknown argument
441 usage();
442 }
443}
444
445# continue execution near EOF;
446
447# get kernel version from env
448sub get_kernel_version() {
449 my $version = 'unknown kernel version';
450
451 if (defined($ENV{'KERNELVERSION'})) {
452 $version = $ENV{'KERNELVERSION'};
453 }
454 return $version;
455}
456
457#
458sub print_lineno {
459 my $lineno = shift;
460 if ($enable_lineno && defined($lineno)) {
461 print "#define LINENO " . $lineno . "\n";
462 }
463}
464##
465# dumps section contents to arrays/hashes intended for that purpose.
466#
467sub dump_section {
468 my $file = shift;
469 my $name = shift;
470 my $contents = join "\n", @_;
471
472 if ($name =~ m/$type_param/) {
473 $name = $1;
474 $parameterdescs{$name} = $contents;
475 $sectcheck = $sectcheck . $name . " ";
476 $parameterdesc_start_lines{$name} = $new_start_line;
477 $new_start_line = 0;
478 } elsif ($name eq "@\.\.\.") {
479 $name = "...";
480 $parameterdescs{$name} = $contents;
481 $sectcheck = $sectcheck . $name . " ";
482 $parameterdesc_start_lines{$name} = $new_start_line;
483 $new_start_line = 0;
484 } else {
485 if (defined($sections{$name}) && ($sections{$name} ne "")) {
486 # Only warn on user specified duplicate section names.
487 if ($name ne $section_default) {
488 print STDERR "${file}:$.: warning: duplicate section name '$name'\n";
489 ++$warnings;
490 }
491 $sections{$name} .= $contents;
492 } else {
493 $sections{$name} = $contents;
494 push @sectionlist, $name;
495 $section_start_lines{$name} = $new_start_line;
496 $new_start_line = 0;
497 }
498 }
499}
500
501##
502# dump DOC: section after checking that it should go out
503#
504sub dump_doc_section {
505 my $file = shift;
506 my $name = shift;
507 my $contents = join "\n", @_;
508
509 if ($no_doc_sections) {
510 return;
511 }
512
513 if (($output_selection == OUTPUT_ALL) ||
514 ($output_selection == OUTPUT_INCLUDE &&
515 defined($function_table{$name})) ||
516 ($output_selection == OUTPUT_EXCLUDE &&
517 !defined($function_table{$name})))
518 {
519 dump_section($file, $name, $contents);
520 output_blockhead({'sectionlist' => \@sectionlist,
521 'sections' => \%sections,
522 'module' => $modulename,
523 'content-only' => ($output_selection != OUTPUT_ALL), });
524 }
525}
526
527##
528# output function
529#
530# parameterdescs, a hash.
531# function => "function name"
532# parameterlist => @list of parameters
533# parameterdescs => %parameter descriptions
534# sectionlist => @list of sections
535# sections => %section descriptions
536#
537
538sub output_highlight {
539 my $contents = join "\n",@_;
540 my $line;
541
542# DEBUG
543# if (!defined $contents) {
544# use Carp;
545# confess "output_highlight got called with no args?\n";
546# }
547
548# print STDERR "contents b4:$contents\n";
549 eval $dohighlight;
550 die $@ if $@;
551# print STDERR "contents af:$contents\n";
552
553 foreach $line (split "\n", $contents) {
554 if (! $output_preformatted) {
555 $line =~ s/^\s*//;
556 }
557 if ($line eq ""){
558 if (! $output_preformatted) {
559 print $lineprefix, $blankline;
560 }
561 } else {
562 if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
563 print "\\&$line";
564 } else {
565 print $lineprefix, $line;
566 }
567 }
568 print "\n";
569 }
570}
571
572##
573# output function in man
574sub output_function_man(%) {
575 my %args = %{$_[0]};
576 my ($parameter, $section);
577 my $count;
578
579 print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
580
581 print ".SH NAME\n";
582 print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
583
584 print ".SH SYNOPSIS\n";
585 if ($args{'functiontype'} ne "") {
586 print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
587 } else {
588 print ".B \"" . $args{'function'} . "\n";
589 }
590 $count = 0;
591 my $parenth = "(";
592 my $post = ",";
593 foreach my $parameter (@{$args{'parameterlist'}}) {
594 if ($count == $#{$args{'parameterlist'}}) {
595 $post = ");";
596 }
597 $type = $args{'parametertypes'}{$parameter};
598 if ($type =~ m/([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)/) {
599 # pointer-to-function
600 print ".BI \"" . $parenth . $1 . "\" " . $parameter . " \") (" . $2 . ")" . $post . "\"\n";
601 } else {
602 $type =~ s/([^\*])$/$1 /;
603 print ".BI \"" . $parenth . $type . "\" " . $parameter . " \"" . $post . "\"\n";
604 }
605 $count++;
606 $parenth = "";
607 }
608
609 print ".SH ARGUMENTS\n";
610 foreach $parameter (@{$args{'parameterlist'}}) {
611 my $parameter_name = $parameter;
612 $parameter_name =~ s/\[.*//;
613
614 print ".IP \"" . $parameter . "\" 12\n";
615 output_highlight($args{'parameterdescs'}{$parameter_name});
616 }
617 foreach $section (@{$args{'sectionlist'}}) {
618 print ".SH \"", uc $section, "\"\n";
619 output_highlight($args{'sections'}{$section});
620 }
621}
622
623##
624# output enum in man
625sub output_enum_man(%) {
626 my %args = %{$_[0]};
627 my ($parameter, $section);
628 my $count;
629
630 print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
631
632 print ".SH NAME\n";
633 print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
634
635 print ".SH SYNOPSIS\n";
636 print "enum " . $args{'enum'} . " {\n";
637 $count = 0;
638 foreach my $parameter (@{$args{'parameterlist'}}) {
639 print ".br\n.BI \" $parameter\"\n";
640 if ($count == $#{$args{'parameterlist'}}) {
641 print "\n};\n";
642 last;
643 }
644 else {
645 print ", \n.br\n";
646 }
647 $count++;
648 }
649
650 print ".SH Constants\n";
651 foreach $parameter (@{$args{'parameterlist'}}) {
652 my $parameter_name = $parameter;
653 $parameter_name =~ s/\[.*//;
654
655 print ".IP \"" . $parameter . "\" 12\n";
656 output_highlight($args{'parameterdescs'}{$parameter_name});
657 }
658 foreach $section (@{$args{'sectionlist'}}) {
659 print ".SH \"$section\"\n";
660 output_highlight($args{'sections'}{$section});
661 }
662}
663
664##
665# output struct in man
666sub output_struct_man(%) {
667 my %args = %{$_[0]};
668 my ($parameter, $section);
669
670 print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
671
672 print ".SH NAME\n";
673 print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
674
675 my $declaration = $args{'definition'};
676 $declaration =~ s/\t/ /g;
677 $declaration =~ s/\n/"\n.br\n.BI \"/g;
678 print ".SH SYNOPSIS\n";
679 print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
680 print ".BI \"$declaration\n};\n.br\n\n";
681
682 print ".SH Members\n";
683 foreach $parameter (@{$args{'parameterlist'}}) {
684 ($parameter =~ /^#/) && next;
685
686 my $parameter_name = $parameter;
687 $parameter_name =~ s/\[.*//;
688
689 ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
690 print ".IP \"" . $parameter . "\" 12\n";
691 output_highlight($args{'parameterdescs'}{$parameter_name});
692 }
693 foreach $section (@{$args{'sectionlist'}}) {
694 print ".SH \"$section\"\n";
695 output_highlight($args{'sections'}{$section});
696 }
697}
698
699##
700# output typedef in man
701sub output_typedef_man(%) {
702 my %args = %{$_[0]};
703 my ($parameter, $section);
704
705 print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
706
707 print ".SH NAME\n";
708 print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
709
710 foreach $section (@{$args{'sectionlist'}}) {
711 print ".SH \"$section\"\n";
712 output_highlight($args{'sections'}{$section});
713 }
714}
715
716sub output_blockhead_man(%) {
717 my %args = %{$_[0]};
718 my ($parameter, $section);
719 my $count;
720
721 print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
722
723 foreach $section (@{$args{'sectionlist'}}) {
724 print ".SH \"$section\"\n";
725 output_highlight($args{'sections'}{$section});
726 }
727}
728
729##
730# output in restructured text
731#
732
733#
734# This could use some work; it's used to output the DOC: sections, and
735# starts by putting out the name of the doc section itself, but that tends
736# to duplicate a header already in the template file.
737#
738sub output_blockhead_rst(%) {
739 my %args = %{$_[0]};
740 my ($parameter, $section);
741
742 foreach $section (@{$args{'sectionlist'}}) {
743 if ($output_selection != OUTPUT_INCLUDE) {
744 print "**$section**\n\n";
745 }
746 print_lineno($section_start_lines{$section});
747 output_highlight_rst($args{'sections'}{$section});
748 print "\n";
749 }
750}
751
752#
753# Apply the RST highlights to a sub-block of text.
754#
755sub highlight_block($) {
756 # The dohighlight kludge requires the text be called $contents
757 my $contents = shift;
758 eval $dohighlight;
759 die $@ if $@;
760 return $contents;
761}
762
763#
764# Regexes used only here.
765#
766my $sphinx_literal = '^[^.].*::$';
767my $sphinx_cblock = '^\.\.\ +code-block::';
768
769sub output_highlight_rst {
770 my $input = join "\n",@_;
771 my $output = "";
772 my $line;
773 my $in_literal = 0;
774 my $litprefix;
775 my $block = "";
776
777 foreach $line (split "\n",$input) {
778 #
779 # If we're in a literal block, see if we should drop out
780 # of it. Otherwise pass the line straight through unmunged.
781 #
782 if ($in_literal) {
783 if (! ($line =~ /^\s*$/)) {
784 #
785 # If this is the first non-blank line in a literal
786 # block we need to figure out what the proper indent is.
787 #
788 if ($litprefix eq "") {
789 $line =~ /^(\s*)/;
790 $litprefix = '^' . $1;
791 $output .= $line . "\n";
792 } elsif (! ($line =~ /$litprefix/)) {
793 $in_literal = 0;
794 } else {
795 $output .= $line . "\n";
796 }
797 } else {
798 $output .= $line . "\n";
799 }
800 }
801 #
802 # Not in a literal block (or just dropped out)
803 #
804 if (! $in_literal) {
805 $block .= $line . "\n";
806 if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
807 $in_literal = 1;
808 $litprefix = "";
809 $output .= highlight_block($block);
810 $block = ""
811 }
812 }
813 }
814
815 if ($block) {
816 $output .= highlight_block($block);
817 }
818 foreach $line (split "\n", $output) {
819 print $lineprefix . $line . "\n";
820 }
821}
822
823sub output_function_rst(%) {
824 my %args = %{$_[0]};
825 my ($parameter, $section);
826 my $oldprefix = $lineprefix;
827 my $start = "";
828
829 if ($args{'typedef'}) {
830 print ".. c:type:: ". $args{'function'} . "\n\n";
831 print_lineno($declaration_start_line);
832 print " **Typedef**: ";
833 $lineprefix = "";
834 output_highlight_rst($args{'purpose'});
835 $start = "\n\n**Syntax**\n\n ``";
836 } else {
837 print ".. c:function:: ";
838 }
839 if ($args{'functiontype'} ne "") {
840 $start .= $args{'functiontype'} . " " . $args{'function'} . " (";
841 } else {
842 $start .= $args{'function'} . " (";
843 }
844 print $start;
845
846 my $count = 0;
847 foreach my $parameter (@{$args{'parameterlist'}}) {
848 if ($count ne 0) {
849 print ", ";
850 }
851 $count++;
852 $type = $args{'parametertypes'}{$parameter};
853
854 if ($type =~ m/([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)/) {
855 # pointer-to-function
856 print $1 . $parameter . ") (" . $2;
857 } else {
858 print $type . " " . $parameter;
859 }
860 }
861 if ($args{'typedef'}) {
862 print ");``\n\n";
863 } else {
864 print ")\n\n";
865 print_lineno($declaration_start_line);
866 $lineprefix = " ";
867 output_highlight_rst($args{'purpose'});
868 print "\n";
869 }
870
871 print "**Parameters**\n\n";
872 $lineprefix = " ";
873 foreach $parameter (@{$args{'parameterlist'}}) {
874 my $parameter_name = $parameter;
875 $parameter_name =~ s/\[.*//;
876 $type = $args{'parametertypes'}{$parameter};
877
878 if ($type ne "") {
879 print "``$type $parameter``\n";
880 } else {
881 print "``$parameter``\n";
882 }
883
884 print_lineno($parameterdesc_start_lines{$parameter_name});
885
886 if (defined($args{'parameterdescs'}{$parameter_name}) &&
887 $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
888 output_highlight_rst($args{'parameterdescs'}{$parameter_name});
889 } else {
890 print " *undescribed*\n";
891 }
892 print "\n";
893 }
894
895 $lineprefix = $oldprefix;
896 output_section_rst(@_);
897}
898
899sub output_section_rst(%) {
900 my %args = %{$_[0]};
901 my $section;
902 my $oldprefix = $lineprefix;
903 $lineprefix = "";
904
905 foreach $section (@{$args{'sectionlist'}}) {
906 print "**$section**\n\n";
907 print_lineno($section_start_lines{$section});
908 output_highlight_rst($args{'sections'}{$section});
909 print "\n";
910 }
911 print "\n";
912 $lineprefix = $oldprefix;
913}
914
915sub output_enum_rst(%) {
916 my %args = %{$_[0]};
917 my ($parameter);
918 my $oldprefix = $lineprefix;
919 my $count;
920 my $name = "enum " . $args{'enum'};
921
922 print "\n\n.. c:type:: " . $name . "\n\n";
923 print_lineno($declaration_start_line);
924 $lineprefix = " ";
925 output_highlight_rst($args{'purpose'});
926 print "\n";
927
928 print "**Constants**\n\n";
929 $lineprefix = " ";
930 foreach $parameter (@{$args{'parameterlist'}}) {
931 print "``$parameter``\n";
932 if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
933 output_highlight_rst($args{'parameterdescs'}{$parameter});
934 } else {
935 print " *undescribed*\n";
936 }
937 print "\n";
938 }
939
940 $lineprefix = $oldprefix;
941 output_section_rst(@_);
942}
943
944sub output_typedef_rst(%) {
945 my %args = %{$_[0]};
946 my ($parameter);
947 my $oldprefix = $lineprefix;
948 my $name = "typedef " . $args{'typedef'};
949
950 print "\n\n.. c:type:: " . $name . "\n\n";
951 print_lineno($declaration_start_line);
952 $lineprefix = " ";
953 output_highlight_rst($args{'purpose'});
954 print "\n";
955
956 $lineprefix = $oldprefix;
957 output_section_rst(@_);
958}
959
960sub output_struct_rst(%) {
961 my %args = %{$_[0]};
962 my ($parameter);
963 my $oldprefix = $lineprefix;
964 my $name = $args{'type'} . " " . $args{'struct'};
965
966 print "\n\n.. c:type:: " . $name . "\n\n";
967 print_lineno($declaration_start_line);
968 $lineprefix = " ";
969 output_highlight_rst($args{'purpose'});
970 print "\n";
971
972 print "**Definition**\n\n";
973 print "::\n\n";
974 my $declaration = $args{'definition'};
975 $declaration =~ s/\t/ /g;
976 print " " . $args{'type'} . " " . $args{'struct'} . " {\n$declaration };\n\n";
977
978 print "**Members**\n\n";
979 $lineprefix = " ";
980 foreach $parameter (@{$args{'parameterlist'}}) {
981 ($parameter =~ /^#/) && next;
982
983 my $parameter_name = $parameter;
984 $parameter_name =~ s/\[.*//;
985
986 ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
987 $type = $args{'parametertypes'}{$parameter};
988 print_lineno($parameterdesc_start_lines{$parameter_name});
989 print "``" . $parameter . "``\n";
990 output_highlight_rst($args{'parameterdescs'}{$parameter_name});
991 print "\n";
992 }
993 print "\n";
994
995 $lineprefix = $oldprefix;
996 output_section_rst(@_);
997}
998
999## none mode output functions
1000
1001sub output_function_none(%) {
1002}
1003
1004sub output_enum_none(%) {
1005}
1006
1007sub output_typedef_none(%) {
1008}
1009
1010sub output_struct_none(%) {
1011}
1012
1013sub output_blockhead_none(%) {
1014}
1015
1016##
1017# generic output function for all types (function, struct/union, typedef, enum);
1018# calls the generated, variable output_ function name based on
1019# functype and output_mode
1020sub output_declaration {
1021 no strict 'refs';
1022 my $name = shift;
1023 my $functype = shift;
1024 my $func = "output_${functype}_$output_mode";
1025 if (($output_selection == OUTPUT_ALL) ||
1026 (($output_selection == OUTPUT_INCLUDE ||
1027 $output_selection == OUTPUT_EXPORTED) &&
1028 defined($function_table{$name})) ||
1029 (($output_selection == OUTPUT_EXCLUDE ||
1030 $output_selection == OUTPUT_INTERNAL) &&
1031 !($functype eq "function" && defined($function_table{$name}))))
1032 {
1033 &$func(@_);
1034 $section_counter++;
1035 }
1036}
1037
1038##
1039# generic output function - calls the right one based on current output mode.
1040sub output_blockhead {
1041 no strict 'refs';
1042 my $func = "output_blockhead_" . $output_mode;
1043 &$func(@_);
1044 $section_counter++;
1045}
1046
1047##
1048# takes a declaration (struct, union, enum, typedef) and
1049# invokes the right handler. NOT called for functions.
1050sub dump_declaration($$) {
1051 no strict 'refs';
1052 my ($prototype, $file) = @_;
1053 my $func = "dump_" . $decl_type;
1054 &$func(@_);
1055}
1056
1057sub dump_union($$) {
1058 dump_struct(@_);
1059}
1060
1061sub dump_struct($$) {
1062 my $x = shift;
1063 my $file = shift;
1064
1065 if ($x =~ /(struct|union)\s+(\w+)\s*\{(.*)\}(\s*(__packed|__aligned|__attribute__\s*\(\([a-z0-9,_\s\(\)]*\)\)))*/) {
1066 my $decl_type = $1;
1067 $declaration_name = $2;
1068 my $members = $3;
1069
1070 # ignore members marked private:
1071 $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1072 $members =~ s/\/\*\s*private:.*//gosi;
1073 # strip comments:
1074 $members =~ s/\/\*.*?\*\///gos;
1075 # strip attributes
1076 $members =~ s/\s*__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)//gi;
1077 $members =~ s/\s*__aligned\s*\([^;]*\)//gos;
1078 $members =~ s/\s*__packed\s*//gos;
1079 $members =~ s/\s*CRYPTO_MINALIGN_ATTR//gos;
1080 # replace DECLARE_BITMAP
1081 $members =~ s/DECLARE_BITMAP\s*\(([^,)]+),\s*([^,)]+)\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1082 # replace DECLARE_HASHTABLE
1083 $members =~ s/DECLARE_HASHTABLE\s*\(([^,)]+),\s*([^,)]+)\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1084 # replace DECLARE_KFIFO
1085 $members =~ s/DECLARE_KFIFO\s*\(([^,)]+),\s*([^,)]+),\s*([^,)]+)\)/$2 \*$1/gos;
1086 # replace DECLARE_KFIFO_PTR
1087 $members =~ s/DECLARE_KFIFO_PTR\s*\(([^,)]+),\s*([^,)]+)\)/$2 \*$1/gos;
1088
1089 my $declaration = $members;
1090
1091 # Split nested struct/union elements as newer ones
1092 while ($members =~ m/(struct|union)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;/) {
1093 my $newmember;
1094 my $maintype = $1;
1095 my $ids = $4;
1096 my $content = $3;
1097 foreach my $id(split /,/, $ids) {
1098 $newmember .= "$maintype $id; ";
1099
1100 $id =~ s/[:\[].*//;
1101 $id =~ s/^\s*\**(\S+)\s*/$1/;
1102 foreach my $arg (split /;/, $content) {
1103 next if ($arg =~ m/^\s*$/);
1104 if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1105 # pointer-to-function
1106 my $type = $1;
1107 my $name = $2;
1108 my $extra = $3;
1109 next if (!$name);
1110 if ($id =~ m/^\s*$/) {
1111 # anonymous struct/union
1112 $newmember .= "$type$name$extra; ";
1113 } else {
1114 $newmember .= "$type$id.$name$extra; ";
1115 }
1116 } else {
1117 my $type;
1118 my $names;
1119 $arg =~ s/^\s+//;
1120 $arg =~ s/\s+$//;
1121 # Handle bitmaps
1122 $arg =~ s/:\s*\d+\s*//g;
1123 # Handle arrays
1124 $arg =~ s/\[.*\]//g;
1125 # The type may have multiple words,
1126 # and multiple IDs can be defined, like:
1127 # const struct foo, *bar, foobar
1128 # So, we remove spaces when parsing the
1129 # names, in order to match just names
1130 # and commas for the names
1131 $arg =~ s/\s*,\s*/,/g;
1132 if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1133 $type = $1;
1134 $names = $2;
1135 } else {
1136 $newmember .= "$arg; ";
1137 next;
1138 }
1139 foreach my $name (split /,/, $names) {
1140 $name =~ s/^\s*\**(\S+)\s*/$1/;
1141 next if (($name =~ m/^\s*$/));
1142 if ($id =~ m/^\s*$/) {
1143 # anonymous struct/union
1144 $newmember .= "$type $name; ";
1145 } else {
1146 $newmember .= "$type $id.$name; ";
1147 }
1148 }
1149 }
1150 }
1151 }
1152 $members =~ s/(struct|union)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;/$newmember/;
1153 }
1154
1155 # Ignore other nested elements, like enums
1156 $members =~ s/(\{[^\{\}]*\})//g;
1157
1158 create_parameterlist($members, ';', $file, $declaration_name);
1159 check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1160
1161 # Adjust declaration for better display
1162 $declaration =~ s/([\{;])/$1\n/g;
1163 $declaration =~ s/\}\s+;/};/g;
1164 # Better handle inlined enums
1165 do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1166
1167 my @def_args = split /\n/, $declaration;
1168 my $level = 1;
1169 $declaration = "";
1170 foreach my $clause (@def_args) {
1171 $clause =~ s/^\s+//;
1172 $clause =~ s/\s+$//;
1173 $clause =~ s/\s+/ /;
1174 next if (!$clause);
1175 $level-- if ($clause =~ m/(\})/ && $level > 1);
1176 if (!($clause =~ m/^\s*#/)) {
1177 $declaration .= "\t" x $level;
1178 }
1179 $declaration .= "\t" . $clause . "\n";
1180 $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1181 }
1182 output_declaration($declaration_name,
1183 'struct',
1184 {'struct' => $declaration_name,
1185 'module' => $modulename,
1186 'definition' => $declaration,
1187 'parameterlist' => \@parameterlist,
1188 'parameterdescs' => \%parameterdescs,
1189 'parametertypes' => \%parametertypes,
1190 'sectionlist' => \@sectionlist,
1191 'sections' => \%sections,
1192 'purpose' => $declaration_purpose,
1193 'type' => $decl_type
1194 });
1195 }
1196 else {
1197 print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1198 ++$errors;
1199 }
1200}
1201
1202
1203sub show_warnings($$) {
1204 my $functype = shift;
1205 my $name = shift;
1206
1207 return 1 if ($output_selection == OUTPUT_ALL);
1208
1209 if ($output_selection == OUTPUT_EXPORTED) {
1210 if (defined($function_table{$name})) {
1211 return 1;
1212 } else {
1213 return 0;
1214 }
1215 }
1216 if ($output_selection == OUTPUT_INTERNAL) {
1217 if (!($functype eq "function" && defined($function_table{$name}))) {
1218 return 1;
1219 } else {
1220 return 0;
1221 }
1222 }
1223 if ($output_selection == OUTPUT_INCLUDE) {
1224 if (defined($function_table{$name})) {
1225 return 1;
1226 } else {
1227 return 0;
1228 }
1229 }
1230 if ($output_selection == OUTPUT_EXCLUDE) {
1231 if (!defined($function_table{$name})) {
1232 return 1;
1233 } else {
1234 return 0;
1235 }
1236 }
1237 die("Please add the new output type at show_warnings()");
1238}
1239
1240sub dump_enum($$) {
1241 my $x = shift;
1242 my $file = shift;
1243
1244 $x =~ s@/\*.*?\*/@@gos; # strip comments.
1245 # strip #define macros inside enums
1246 $x =~ s@#\s*((define|ifdef)\s+|endif)[^;]*;@@gos;
1247
1248 if ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1249 $declaration_name = $1;
1250 my $members = $2;
1251 my %_members;
1252
1253 $members =~ s/\s+$//;
1254
1255 foreach my $arg (split ',', $members) {
1256 $arg =~ s/^\s*(\w+).*/$1/;
1257 push @parameterlist, $arg;
1258 if (!$parameterdescs{$arg}) {
1259 $parameterdescs{$arg} = $undescribed;
1260 if (show_warnings("enum", $declaration_name)) {
1261 print STDERR "${file}:$.: warning: Enum value '$arg' not described in enum '$declaration_name'\n";
1262 }
1263 }
1264 $_members{$arg} = 1;
1265 }
1266
1267 while (my ($k, $v) = each %parameterdescs) {
1268 if (!exists($_members{$k})) {
1269 if (show_warnings("enum", $declaration_name)) {
1270 print STDERR "${file}:$.: warning: Excess enum value '$k' description in '$declaration_name'\n";
1271 }
1272 }
1273 }
1274
1275 output_declaration($declaration_name,
1276 'enum',
1277 {'enum' => $declaration_name,
1278 'module' => $modulename,
1279 'parameterlist' => \@parameterlist,
1280 'parameterdescs' => \%parameterdescs,
1281 'sectionlist' => \@sectionlist,
1282 'sections' => \%sections,
1283 'purpose' => $declaration_purpose
1284 });
1285 }
1286 else {
1287 print STDERR "${file}:$.: error: Cannot parse enum!\n";
1288 ++$errors;
1289 }
1290}
1291
1292sub dump_typedef($$) {
1293 my $x = shift;
1294 my $file = shift;
1295
1296 $x =~ s@/\*.*?\*/@@gos; # strip comments.
1297
1298 # Parse function prototypes
1299 if ($x =~ /typedef\s+(\w+)\s*\(\*\s*(\w\S+)\s*\)\s*\((.*)\);/ ||
1300 $x =~ /typedef\s+(\w+)\s*(\w\S+)\s*\s*\((.*)\);/) {
1301
1302 # Function typedefs
1303 $return_type = $1;
1304 $declaration_name = $2;
1305 my $args = $3;
1306
1307 create_parameterlist($args, ',', $file, $declaration_name);
1308
1309 output_declaration($declaration_name,
1310 'function',
1311 {'function' => $declaration_name,
1312 'typedef' => 1,
1313 'module' => $modulename,
1314 'functiontype' => $return_type,
1315 'parameterlist' => \@parameterlist,
1316 'parameterdescs' => \%parameterdescs,
1317 'parametertypes' => \%parametertypes,
1318 'sectionlist' => \@sectionlist,
1319 'sections' => \%sections,
1320 'purpose' => $declaration_purpose
1321 });
1322 return;
1323 }
1324
1325 while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1326 $x =~ s/\(*.\)\s*;$/;/;
1327 $x =~ s/\[*.\]\s*;$/;/;
1328 }
1329
1330 if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1331 $declaration_name = $1;
1332
1333 output_declaration($declaration_name,
1334 'typedef',
1335 {'typedef' => $declaration_name,
1336 'module' => $modulename,
1337 'sectionlist' => \@sectionlist,
1338 'sections' => \%sections,
1339 'purpose' => $declaration_purpose
1340 });
1341 }
1342 else {
1343 print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1344 ++$errors;
1345 }
1346}
1347
1348sub save_struct_actual($) {
1349 my $actual = shift;
1350
1351 # strip all spaces from the actual param so that it looks like one string item
1352 $actual =~ s/\s*//g;
1353 $struct_actual = $struct_actual . $actual . " ";
1354}
1355
1356sub create_parameterlist($$$$) {
1357 my $args = shift;
1358 my $splitter = shift;
1359 my $file = shift;
1360 my $declaration_name = shift;
1361 my $type;
1362 my $param;
1363
1364 # temporarily replace commas inside function pointer definition
1365 while ($args =~ /(\([^\),]+),/) {
1366 $args =~ s/(\([^\),]+),/$1#/g;
1367 }
1368
1369 foreach my $arg (split($splitter, $args)) {
1370 # strip comments
1371 $arg =~ s/\/\*.*\*\///;
1372 # strip leading/trailing spaces
1373 $arg =~ s/^\s*//;
1374 $arg =~ s/\s*$//;
1375 $arg =~ s/\s+/ /;
1376
1377 if ($arg =~ /^#/) {
1378 # Treat preprocessor directive as a typeless variable just to fill
1379 # corresponding data structures "correctly". Catch it later in
1380 # output_* subs.
1381 push_parameter($arg, "", $file);
1382 } elsif ($arg =~ m/\(.+\)\s*\(/) {
1383 # pointer-to-function
1384 $arg =~ tr/#/,/;
1385 $arg =~ m/[^\(]+\(\*?\s*([\w\.]*)\s*\)/;
1386 $param = $1;
1387 $type = $arg;
1388 $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1389 save_struct_actual($param);
1390 push_parameter($param, $type, $file, $declaration_name);
1391 } elsif ($arg) {
1392 $arg =~ s/\s*:\s*/:/g;
1393 $arg =~ s/\s*\[/\[/g;
1394
1395 my @args = split('\s*,\s*', $arg);
1396 if ($args[0] =~ m/\*/) {
1397 $args[0] =~ s/(\*+)\s*/ $1/;
1398 }
1399
1400 my @first_arg;
1401 if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1402 shift @args;
1403 push(@first_arg, split('\s+', $1));
1404 push(@first_arg, $2);
1405 } else {
1406 @first_arg = split('\s+', shift @args);
1407 }
1408
1409 unshift(@args, pop @first_arg);
1410 $type = join " ", @first_arg;
1411
1412 foreach $param (@args) {
1413 if ($param =~ m/^(\*+)\s*(.*)/) {
1414 save_struct_actual($2);
1415 push_parameter($2, "$type $1", $file, $declaration_name);
1416 }
1417 elsif ($param =~ m/(.*?):(\d+)/) {
1418 if ($type ne "") { # skip unnamed bit-fields
1419 save_struct_actual($1);
1420 push_parameter($1, "$type:$2", $file, $declaration_name)
1421 }
1422 }
1423 else {
1424 save_struct_actual($param);
1425 push_parameter($param, $type, $file, $declaration_name);
1426 }
1427 }
1428 }
1429 }
1430}
1431
1432sub push_parameter($$$$) {
1433 my $param = shift;
1434 my $type = shift;
1435 my $file = shift;
1436 my $declaration_name = shift;
1437
1438 if (($anon_struct_union == 1) && ($type eq "") &&
1439 ($param eq "}")) {
1440 return; # ignore the ending }; from anon. struct/union
1441 }
1442
1443 $anon_struct_union = 0;
1444 $param =~ s/[\[\)].*//;
1445
1446 if ($type eq "" && $param =~ /\.\.\.$/)
1447 {
1448 if (!$param =~ /\w\.\.\.$/) {
1449 # handles unnamed variable parameters
1450 $param = "...";
1451 }
1452 if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1453 $parameterdescs{$param} = "variable arguments";
1454 }
1455 }
1456 elsif ($type eq "" && ($param eq "" or $param eq "void"))
1457 {
1458 $param="void";
1459 $parameterdescs{void} = "no arguments";
1460 }
1461 elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1462 # handle unnamed (anonymous) union or struct:
1463 {
1464 $type = $param;
1465 $param = "{unnamed_" . $param . "}";
1466 $parameterdescs{$param} = "anonymous\n";
1467 $anon_struct_union = 1;
1468 }
1469
1470 # warn if parameter has no description
1471 # (but ignore ones starting with # as these are not parameters
1472 # but inline preprocessor statements);
1473 # Note: It will also ignore void params and unnamed structs/unions
1474 if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1475 $parameterdescs{$param} = $undescribed;
1476
1477 if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1478 print STDERR
1479 "${file}:$.: warning: Function parameter or member '$param' not described in '$declaration_name'\n";
1480 ++$warnings;
1481 }
1482 }
1483
1484 # strip spaces from $param so that it is one continuous string
1485 # on @parameterlist;
1486 # this fixes a problem where check_sections() cannot find
1487 # a parameter like "addr[6 + 2]" because it actually appears
1488 # as "addr[6", "+", "2]" on the parameter list;
1489 # but it's better to maintain the param string unchanged for output,
1490 # so just weaken the string compare in check_sections() to ignore
1491 # "[blah" in a parameter string;
1492 ###$param =~ s/\s*//g;
1493 push @parameterlist, $param;
1494 $type =~ s/\s\s+/ /g;
1495 $parametertypes{$param} = $type;
1496}
1497
1498sub check_sections($$$$$) {
1499 my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1500 my @sects = split ' ', $sectcheck;
1501 my @prms = split ' ', $prmscheck;
1502 my $err;
1503 my ($px, $sx);
1504 my $prm_clean; # strip trailing "[array size]" and/or beginning "*"
1505
1506 foreach $sx (0 .. $#sects) {
1507 $err = 1;
1508 foreach $px (0 .. $#prms) {
1509 $prm_clean = $prms[$px];
1510 $prm_clean =~ s/\[.*\]//;
1511 $prm_clean =~ s/__attribute__\s*\(\([a-z,_\*\s\(\)]*\)\)//i;
1512 # ignore array size in a parameter string;
1513 # however, the original param string may contain
1514 # spaces, e.g.: addr[6 + 2]
1515 # and this appears in @prms as "addr[6" since the
1516 # parameter list is split at spaces;
1517 # hence just ignore "[..." for the sections check;
1518 $prm_clean =~ s/\[.*//;
1519
1520 ##$prm_clean =~ s/^\**//;
1521 if ($prm_clean eq $sects[$sx]) {
1522 $err = 0;
1523 last;
1524 }
1525 }
1526 if ($err) {
1527 if ($decl_type eq "function") {
1528 print STDERR "${file}:$.: warning: " .
1529 "Excess function parameter " .
1530 "'$sects[$sx]' " .
1531 "description in '$decl_name'\n";
1532 ++$warnings;
1533 }
1534 }
1535 }
1536}
1537
1538##
1539# Checks the section describing the return value of a function.
1540sub check_return_section {
1541 my $file = shift;
1542 my $declaration_name = shift;
1543 my $return_type = shift;
1544
1545 # Ignore an empty return type (It's a macro)
1546 # Ignore functions with a "void" return type. (But don't ignore "void *")
1547 if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1548 return;
1549 }
1550
1551 if (!defined($sections{$section_return}) ||
1552 $sections{$section_return} eq "") {
1553 print STDERR "${file}:$.: warning: " .
1554 "No description found for return value of " .
1555 "'$declaration_name'\n";
1556 ++$warnings;
1557 }
1558}
1559
1560##
1561# takes a function prototype and the name of the current file being
1562# processed and spits out all the details stored in the global
1563# arrays/hashes.
1564sub dump_function($$) {
1565 my $prototype = shift;
1566 my $file = shift;
1567 my $noret = 0;
1568
1569 $prototype =~ s/^static +//;
1570 $prototype =~ s/^extern +//;
1571 $prototype =~ s/^asmlinkage +//;
1572 $prototype =~ s/^inline +//;
1573 $prototype =~ s/^__inline__ +//;
1574 $prototype =~ s/^__inline +//;
1575 $prototype =~ s/^__always_inline +//;
1576 $prototype =~ s/^noinline +//;
1577 $prototype =~ s/__init +//;
1578 $prototype =~ s/__init_or_module +//;
1579 $prototype =~ s/__meminit +//;
1580 $prototype =~ s/__must_check +//;
1581 $prototype =~ s/__weak +//;
1582 $prototype =~ s/__sched +//;
1583 $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1584 my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1585 $prototype =~ s/__attribute__\s*\(\(
1586 (?:
1587 [\w\s]++ # attribute name
1588 (?:\([^)]*+\))? # attribute arguments
1589 \s*+,? # optional comma at the end
1590 )+
1591 \)\)\s+//x;
1592
1593 # Yes, this truly is vile. We are looking for:
1594 # 1. Return type (may be nothing if we're looking at a macro)
1595 # 2. Function name
1596 # 3. Function parameters.
1597 #
1598 # All the while we have to watch out for function pointer parameters
1599 # (which IIRC is what the two sections are for), C types (these
1600 # regexps don't even start to express all the possibilities), and
1601 # so on.
1602 #
1603 # If you mess with these regexps, it's a good idea to check that
1604 # the following functions' documentation still comes out right:
1605 # - parport_register_device (function pointer parameters)
1606 # - atomic_set (macro)
1607 # - pci_match_device, __copy_to_user (long return type)
1608
1609 if ($define && $prototype =~ m/^()([a-zA-Z0-9_~:]+)\s+/) {
1610 # This is an object-like macro, it has no return type and no parameter
1611 # list.
1612 # Function-like macros are not allowed to have spaces between
1613 # declaration_name and opening parenthesis (notice the \s+).
1614 $return_type = $1;
1615 $declaration_name = $2;
1616 $noret = 1;
1617 } elsif ($prototype =~ m/^()([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1618 $prototype =~ m/^(\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1619 $prototype =~ m/^(\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1620 $prototype =~ m/^(\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1621 $prototype =~ m/^(\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1622 $prototype =~ m/^(\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1623 $prototype =~ m/^(\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1624 $prototype =~ m/^()([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1625 $prototype =~ m/^(\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1626 $prototype =~ m/^(\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1627 $prototype =~ m/^(\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1628 $prototype =~ m/^(\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1629 $prototype =~ m/^(\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1630 $prototype =~ m/^(\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1631 $prototype =~ m/^(\w+\s+\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1632 $prototype =~ m/^(\w+\s+\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1633 $prototype =~ m/^(\w+\s+\w+\s*\*+\s*\w+\s*\*+\s*)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/) {
1634 $return_type = $1;
1635 $declaration_name = $2;
1636 my $args = $3;
1637
1638 create_parameterlist($args, ',', $file, $declaration_name);
1639 } else {
1640 print STDERR "${file}:$.: warning: cannot understand function prototype: '$prototype'\n";
1641 return;
1642 }
1643
1644 my $prms = join " ", @parameterlist;
1645 check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1646
1647 # This check emits a lot of warnings at the moment, because many
1648 # functions don't have a 'Return' doc section. So until the number
1649 # of warnings goes sufficiently down, the check is only performed in
1650 # verbose mode.
1651 # TODO: always perform the check.
1652 if ($verbose && !$noret) {
1653 check_return_section($file, $declaration_name, $return_type);
1654 }
1655
1656 output_declaration($declaration_name,
1657 'function',
1658 {'function' => $declaration_name,
1659 'module' => $modulename,
1660 'functiontype' => $return_type,
1661 'parameterlist' => \@parameterlist,
1662 'parameterdescs' => \%parameterdescs,
1663 'parametertypes' => \%parametertypes,
1664 'sectionlist' => \@sectionlist,
1665 'sections' => \%sections,
1666 'purpose' => $declaration_purpose
1667 });
1668}
1669
1670sub reset_state {
1671 $function = "";
1672 %parameterdescs = ();
1673 %parametertypes = ();
1674 @parameterlist = ();
1675 %sections = ();
1676 @sectionlist = ();
1677 $sectcheck = "";
1678 $struct_actual = "";
1679 $prototype = "";
1680
1681 $state = STATE_NORMAL;
1682 $inline_doc_state = STATE_INLINE_NA;
1683}
1684
1685sub tracepoint_munge($) {
1686 my $file = shift;
1687 my $tracepointname = 0;
1688 my $tracepointargs = 0;
1689
1690 if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1691 $tracepointname = $1;
1692 }
1693 if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1694 $tracepointname = $1;
1695 }
1696 if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1697 $tracepointname = $2;
1698 }
1699 $tracepointname =~ s/^\s+//; #strip leading whitespace
1700 if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1701 $tracepointargs = $1;
1702 }
1703 if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1704 print STDERR "${file}:$.: warning: Unrecognized tracepoint format: \n".
1705 "$prototype\n";
1706 } else {
1707 $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1708 }
1709}
1710
1711sub syscall_munge() {
1712 my $void = 0;
1713
1714 $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1715## if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1716 if ($prototype =~ m/SYSCALL_DEFINE0/) {
1717 $void = 1;
1718## $prototype = "long sys_$1(void)";
1719 }
1720
1721 $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1722 if ($prototype =~ m/long (sys_.*?),/) {
1723 $prototype =~ s/,/\(/;
1724 } elsif ($void) {
1725 $prototype =~ s/\)/\(void\)/;
1726 }
1727
1728 # now delete all of the odd-number commas in $prototype
1729 # so that arg types & arg names don't have a comma between them
1730 my $count = 0;
1731 my $len = length($prototype);
1732 if ($void) {
1733 $len = 0; # skip the for-loop
1734 }
1735 for (my $ix = 0; $ix < $len; $ix++) {
1736 if (substr($prototype, $ix, 1) eq ',') {
1737 $count++;
1738 if ($count % 2 == 1) {
1739 substr($prototype, $ix, 1) = ' ';
1740 }
1741 }
1742 }
1743}
1744
1745sub process_proto_function($$) {
1746 my $x = shift;
1747 my $file = shift;
1748
1749 $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1750
1751 if ($x =~ m#\s*/\*\s+MACDOC\s*#io || ($x =~ /^#/ && $x !~ /^#\s*define/)) {
1752 # do nothing
1753 }
1754 elsif ($x =~ /([^\{]*)/) {
1755 $prototype .= $1;
1756 }
1757
1758 if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1759 $prototype =~ s@/\*.*?\*/@@gos; # strip comments.
1760 $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1761 $prototype =~ s@^\s+@@gos; # strip leading spaces
1762 if ($prototype =~ /SYSCALL_DEFINE/) {
1763 syscall_munge();
1764 }
1765 if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1766 $prototype =~ /DEFINE_SINGLE_EVENT/)
1767 {
1768 tracepoint_munge($file);
1769 }
1770 dump_function($prototype, $file);
1771 reset_state();
1772 }
1773}
1774
1775sub process_proto_type($$) {
1776 my $x = shift;
1777 my $file = shift;
1778
1779 $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1780 $x =~ s@^\s+@@gos; # strip leading spaces
1781 $x =~ s@\s+$@@gos; # strip trailing spaces
1782 $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1783
1784 if ($x =~ /^#/) {
1785 # To distinguish preprocessor directive from regular declaration later.
1786 $x .= ";";
1787 }
1788
1789 while (1) {
1790 if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1791 if( length $prototype ) {
1792 $prototype .= " "
1793 }
1794 $prototype .= $1 . $2;
1795 ($2 eq '{') && $brcount++;
1796 ($2 eq '}') && $brcount--;
1797 if (($2 eq ';') && ($brcount == 0)) {
1798 dump_declaration($prototype, $file);
1799 reset_state();
1800 last;
1801 }
1802 $x = $3;
1803 } else {
1804 $prototype .= $x;
1805 last;
1806 }
1807 }
1808}
1809
1810
1811sub map_filename($) {
1812 my $file;
1813 my ($orig_file) = @_;
1814
1815 if (defined($ENV{'SRCTREE'})) {
1816 $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
1817 } else {
1818 $file = $orig_file;
1819 }
1820
1821 if (defined($source_map{$file})) {
1822 $file = $source_map{$file};
1823 }
1824
1825 return $file;
1826}
1827
1828sub process_export_file($) {
1829 my ($orig_file) = @_;
1830 my $file = map_filename($orig_file);
1831
1832 if (!open(IN,"<$file")) {
1833 print STDERR "Error: Cannot open file $file\n";
1834 ++$errors;
1835 return;
1836 }
1837
1838 while (<IN>) {
1839 if (/$export_symbol/) {
1840 $function_table{$2} = 1;
1841 }
1842 }
1843
1844 close(IN);
1845}
1846
1847#
1848# Parsers for the various processing states.
1849#
1850# STATE_NORMAL: looking for the /** to begin everything.
1851#
1852sub process_normal() {
1853 if (/$doc_start/o) {
1854 $state = STATE_NAME; # next line is always the function name
1855 $in_doc_sect = 0;
1856 $declaration_start_line = $. + 1;
1857 }
1858}
1859
1860#
1861# STATE_NAME: Looking for the "name - description" line
1862#
1863sub process_name($$) {
1864 my $file = shift;
1865 my $identifier;
1866 my $descr;
1867
1868 if (/$doc_block/o) {
1869 $state = STATE_DOCBLOCK;
1870 $contents = "";
1871 $new_start_line = $. + 1;
1872
1873 if ( $1 eq "" ) {
1874 $section = $section_intro;
1875 } else {
1876 $section = $1;
1877 }
1878 }
1879 elsif (/$doc_decl/o) {
1880 $identifier = $1;
1881 if (/\s*([\w\s]+?)(\(\))?\s*-/) {
1882 $identifier = $1;
1883 }
1884
1885 $state = STATE_BODY;
1886 # if there's no @param blocks need to set up default section
1887 # here
1888 $contents = "";
1889 $section = $section_default;
1890 $new_start_line = $. + 1;
1891 if (/-(.*)/) {
1892 # strip leading/trailing/multiple spaces
1893 $descr= $1;
1894 $descr =~ s/^\s*//;
1895 $descr =~ s/\s*$//;
1896 $descr =~ s/\s+/ /g;
1897 $declaration_purpose = $descr;
1898 $state = STATE_BODY_MAYBE;
1899 } else {
1900 $declaration_purpose = "";
1901 }
1902
1903 if (($declaration_purpose eq "") && $verbose) {
1904 print STDERR "${file}:$.: warning: missing initial short description on line:\n";
1905 print STDERR $_;
1906 ++$warnings;
1907 }
1908
1909 if ($identifier =~ m/^struct\b/) {
1910 $decl_type = 'struct';
1911 } elsif ($identifier =~ m/^union\b/) {
1912 $decl_type = 'union';
1913 } elsif ($identifier =~ m/^enum\b/) {
1914 $decl_type = 'enum';
1915 } elsif ($identifier =~ m/^typedef\b/) {
1916 $decl_type = 'typedef';
1917 } else {
1918 $decl_type = 'function';
1919 }
1920
1921 if ($verbose) {
1922 print STDERR "${file}:$.: info: Scanning doc for $identifier\n";
1923 }
1924 } else {
1925 print STDERR "${file}:$.: warning: Cannot understand $_ on line $.",
1926 " - I thought it was a doc line\n";
1927 ++$warnings;
1928 $state = STATE_NORMAL;
1929 }
1930}
1931
1932
1933#
1934# STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
1935#
1936sub process_body($$) {
1937 my $file = shift;
1938
1939 if (/$doc_sect/i) { # case insensitive for supported section names
1940 $newsection = $1;
1941 $newcontents = $2;
1942
1943 # map the supported section names to the canonical names
1944 if ($newsection =~ m/^description$/i) {
1945 $newsection = $section_default;
1946 } elsif ($newsection =~ m/^context$/i) {
1947 $newsection = $section_context;
1948 } elsif ($newsection =~ m/^returns?$/i) {
1949 $newsection = $section_return;
1950 } elsif ($newsection =~ m/^\@return$/) {
1951 # special: @return is a section, not a param description
1952 $newsection = $section_return;
1953 }
1954
1955 if (($contents ne "") && ($contents ne "\n")) {
1956 if (!$in_doc_sect && $verbose) {
1957 print STDERR "${file}:$.: warning: contents before sections\n";
1958 ++$warnings;
1959 }
1960 dump_section($file, $section, $contents);
1961 $section = $section_default;
1962 }
1963
1964 $in_doc_sect = 1;
1965 $state = STATE_BODY;
1966 $contents = $newcontents;
1967 $new_start_line = $.;
1968 while (substr($contents, 0, 1) eq " ") {
1969 $contents = substr($contents, 1);
1970 }
1971 if ($contents ne "") {
1972 $contents .= "\n";
1973 }
1974 $section = $newsection;
1975 $leading_space = undef;
1976 } elsif (/$doc_end/) {
1977 if (($contents ne "") && ($contents ne "\n")) {
1978 dump_section($file, $section, $contents);
1979 $section = $section_default;
1980 $contents = "";
1981 }
1982 # look for doc_com + <text> + doc_end:
1983 if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
1984 print STDERR "${file}:$.: warning: suspicious ending line: $_";
1985 ++$warnings;
1986 }
1987
1988 $prototype = "";
1989 $state = STATE_PROTO;
1990 $brcount = 0;
1991 } elsif (/$doc_content/) {
1992 # miguel-style comment kludge, look for blank lines after
1993 # @parameter line to signify start of description
1994 if ($1 eq "") {
1995 if ($section =~ m/^@/ || $section eq $section_context) {
1996 dump_section($file, $section, $contents);
1997 $section = $section_default;
1998 $contents = "";
1999 $new_start_line = $.;
2000 } else {
2001 $contents .= "\n";
2002 }
2003 $state = STATE_BODY;
2004 } elsif ($state == STATE_BODY_MAYBE) {
2005 # Continued declaration purpose
2006 chomp($declaration_purpose);
2007 $declaration_purpose .= " " . $1;
2008 $declaration_purpose =~ s/\s+/ /g;
2009 } else {
2010 my $cont = $1;
2011 if ($section =~ m/^@/ || $section eq $section_context) {
2012 if (!defined $leading_space) {
2013 if ($cont =~ m/^(\s+)/) {
2014 $leading_space = $1;
2015 } else {
2016 $leading_space = "";
2017 }
2018 }
2019 $cont =~ s/^$leading_space//;
2020 }
2021 $contents .= $cont . "\n";
2022 }
2023 } else {
2024 # i dont know - bad line? ignore.
2025 print STDERR "${file}:$.: warning: bad line: $_";
2026 ++$warnings;
2027 }
2028}
2029
2030
2031#
2032# STATE_PROTO: reading a function/whatever prototype.
2033#
2034sub process_proto($$) {
2035 my $file = shift;
2036
2037 if (/$doc_inline_oneline/) {
2038 $section = $1;
2039 $contents = $2;
2040 if ($contents ne "") {
2041 $contents .= "\n";
2042 dump_section($file, $section, $contents);
2043 $section = $section_default;
2044 $contents = "";
2045 }
2046 } elsif (/$doc_inline_start/) {
2047 $state = STATE_INLINE;
2048 $inline_doc_state = STATE_INLINE_NAME;
2049 } elsif ($decl_type eq 'function') {
2050 process_proto_function($_, $file);
2051 } else {
2052 process_proto_type($_, $file);
2053 }
2054}
2055
2056#
2057# STATE_DOCBLOCK: within a DOC: block.
2058#
2059sub process_docblock($$) {
2060 my $file = shift;
2061
2062 if (/$doc_end/) {
2063 dump_doc_section($file, $section, $contents);
2064 $section = $section_default;
2065 $contents = "";
2066 $function = "";
2067 %parameterdescs = ();
2068 %parametertypes = ();
2069 @parameterlist = ();
2070 %sections = ();
2071 @sectionlist = ();
2072 $prototype = "";
2073 $state = STATE_NORMAL;
2074 } elsif (/$doc_content/) {
2075 if ( $1 eq "" ) {
2076 $contents .= $blankline;
2077 } else {
2078 $contents .= $1 . "\n";
2079 }
2080 }
2081}
2082
2083#
2084# STATE_INLINE: docbook comments within a prototype.
2085#
2086sub process_inline($$) {
2087 my $file = shift;
2088
2089 # First line (state 1) needs to be a @parameter
2090 if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2091 $section = $1;
2092 $contents = $2;
2093 $new_start_line = $.;
2094 if ($contents ne "") {
2095 while (substr($contents, 0, 1) eq " ") {
2096 $contents = substr($contents, 1);
2097 }
2098 $contents .= "\n";
2099 }
2100 $inline_doc_state = STATE_INLINE_TEXT;
2101 # Documentation block end */
2102 } elsif (/$doc_inline_end/) {
2103 if (($contents ne "") && ($contents ne "\n")) {
2104 dump_section($file, $section, $contents);
2105 $section = $section_default;
2106 $contents = "";
2107 }
2108 $state = STATE_PROTO;
2109 $inline_doc_state = STATE_INLINE_NA;
2110 # Regular text
2111 } elsif (/$doc_content/) {
2112 if ($inline_doc_state == STATE_INLINE_TEXT) {
2113 $contents .= $1 . "\n";
2114 # nuke leading blank lines
2115 if ($contents =~ /^\s*$/) {
2116 $contents = "";
2117 }
2118 } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2119 $inline_doc_state = STATE_INLINE_ERROR;
2120 print STDERR "${file}:$.: warning: ";
2121 print STDERR "Incorrect use of kernel-doc format: $_";
2122 ++$warnings;
2123 }
2124 }
2125}
2126
2127
2128sub process_file($) {
2129 my $file;
2130 my $initial_section_counter = $section_counter;
2131 my ($orig_file) = @_;
2132
2133 $file = map_filename($orig_file);
2134
2135 if (!open(IN,"<$file")) {
2136 print STDERR "Error: Cannot open file $file\n";
2137 ++$errors;
2138 return;
2139 }
2140
2141 $. = 1;
2142
2143 $section_counter = 0;
2144 while (<IN>) {
2145 while (s/\\\s*$//) {
2146 $_ .= <IN>;
2147 }
2148 # Replace tabs by spaces
2149 while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2150 # Hand this line to the appropriate state handler
2151 if ($state == STATE_NORMAL) {
2152 process_normal();
2153 } elsif ($state == STATE_NAME) {
2154 process_name($file, $_);
2155 } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE) {
2156 process_body($file, $_);
2157 } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2158 process_inline($file, $_);
2159 } elsif ($state == STATE_PROTO) {
2160 process_proto($file, $_);
2161 } elsif ($state == STATE_DOCBLOCK) {
2162 process_docblock($file, $_);
2163 }
2164 }
2165
2166 # Make sure we got something interesting.
2167 if ($initial_section_counter == $section_counter && $
2168 output_mode ne "none") {
2169 if ($output_selection == OUTPUT_INCLUDE) {
2170 print STDERR "${file}:1: warning: '$_' not found\n"
2171 for keys %function_table;
2172 }
2173 else {
2174 print STDERR "${file}:1: warning: no structured comments found\n";
2175 }
2176 }
2177}
2178
2179
2180$kernelversion = get_kernel_version();
2181
2182# generate a sequence of code that will splice in highlighting information
2183# using the s// operator.
2184for (my $k = 0; $k < @highlights; $k++) {
2185 my $pattern = $highlights[$k][0];
2186 my $result = $highlights[$k][1];
2187# print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2188 $dohighlight .= "\$contents =~ s:$pattern:$result:gs;\n";
2189}
2190
2191# Read the file that maps relative names to absolute names for
2192# separate source and object directories and for shadow trees.
2193if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2194 my ($relname, $absname);
2195 while(<SOURCE_MAP>) {
2196 chop();
2197 ($relname, $absname) = (split())[0..1];
2198 $relname =~ s:^/+::;
2199 $source_map{$relname} = $absname;
2200 }
2201 close(SOURCE_MAP);
2202}
2203
2204if ($output_selection == OUTPUT_EXPORTED ||
2205 $output_selection == OUTPUT_INTERNAL) {
2206
2207 push(@export_file_list, @ARGV);
2208
2209 foreach (@export_file_list) {
2210 chomp;
2211 process_export_file($_);
2212 }
2213}
2214
2215foreach (@ARGV) {
2216 chomp;
2217 process_file($_);
2218}
2219if ($verbose && $errors) {
2220 print STDERR "$errors errors\n";
2221}
2222if ($verbose && $warnings) {
2223 print STDERR "$warnings warnings\n";
2224}
2225
2226exit($output_mode eq "none" ? 0 : $errors);