Loading...
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requirements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#include <asm-generic/codetag.lds.h>
54
55#ifndef LOAD_OFFSET
56#define LOAD_OFFSET 0
57#endif
58
59/*
60 * Only some architectures want to have the .notes segment visible in
61 * a separate PT_NOTE ELF Program Header. When this happens, it needs
62 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
63 * Program Headers. In this case, though, the PT_LOAD needs to be made
64 * the default again so that all the following sections don't also end
65 * up in the PT_NOTE Program Header.
66 */
67#ifdef EMITS_PT_NOTE
68#define NOTES_HEADERS :text :note
69#define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
70#else
71#define NOTES_HEADERS
72#define NOTES_HEADERS_RESTORE
73#endif
74
75/*
76 * Some architectures have non-executable read-only exception tables.
77 * They can be added to the RO_DATA segment by specifying their desired
78 * alignment.
79 */
80#ifdef RO_EXCEPTION_TABLE_ALIGN
81#define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
82#else
83#define RO_EXCEPTION_TABLE
84#endif
85
86/* Align . function alignment. */
87#define ALIGN_FUNCTION() . = ALIGN(CONFIG_FUNCTION_ALIGNMENT)
88
89/*
90 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
91 * generates .data.identifier sections, which need to be pulled in with
92 * .data. We don't want to pull in .data..other sections, which Linux
93 * has defined. Same for text and bss.
94 *
95 * With LTO_CLANG, the linker also splits sections by default, so we need
96 * these macros to combine the sections during the final link.
97 *
98 * With AUTOFDO_CLANG and PROPELLER_CLANG, by default, the linker splits
99 * text sections and regroups functions into subsections.
100 *
101 * RODATA_MAIN is not used because existing code already defines .rodata.x
102 * sections to be brought in with rodata.
103 */
104#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG) || \
105defined(CONFIG_AUTOFDO_CLANG) || defined(CONFIG_PROPELLER_CLANG)
106#define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
107#else
108#define TEXT_MAIN .text
109#endif
110#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG)
111#define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..L* .data..compoundliteral* .data.$__unnamed_* .data.$L*
112#define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
113#define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]* .rodata..L*
114#define BSS_MAIN .bss .bss.[0-9a-zA-Z_]* .bss..L* .bss..compoundliteral*
115#define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
116#else
117#define DATA_MAIN .data
118#define SDATA_MAIN .sdata
119#define RODATA_MAIN .rodata
120#define BSS_MAIN .bss
121#define SBSS_MAIN .sbss
122#endif
123
124/*
125 * GCC 4.5 and later have a 32 bytes section alignment for structures.
126 * Except GCC 4.9, that feels the need to align on 64 bytes.
127 */
128#define STRUCT_ALIGNMENT 32
129#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
130
131/*
132 * The order of the sched class addresses are important, as they are
133 * used to determine the order of the priority of each sched class in
134 * relation to each other.
135 */
136#define SCHED_DATA \
137 STRUCT_ALIGN(); \
138 __sched_class_highest = .; \
139 *(__stop_sched_class) \
140 *(__dl_sched_class) \
141 *(__rt_sched_class) \
142 *(__fair_sched_class) \
143 *(__ext_sched_class) \
144 *(__idle_sched_class) \
145 __sched_class_lowest = .;
146
147/* The actual configuration determine if the init/exit sections
148 * are handled as text/data or they can be discarded (which
149 * often happens at runtime)
150 */
151
152#ifndef CONFIG_HAVE_DYNAMIC_FTRACE_NO_PATCHABLE
153#define KEEP_PATCHABLE KEEP(*(__patchable_function_entries))
154#define PATCHABLE_DISCARDS
155#else
156#define KEEP_PATCHABLE
157#define PATCHABLE_DISCARDS *(__patchable_function_entries)
158#endif
159
160#ifndef CONFIG_ARCH_SUPPORTS_CFI_CLANG
161/*
162 * Simply points to ftrace_stub, but with the proper protocol.
163 * Defined by the linker script in linux/vmlinux.lds.h
164 */
165#define FTRACE_STUB_HACK ftrace_stub_graph = ftrace_stub;
166#else
167#define FTRACE_STUB_HACK
168#endif
169
170#ifdef CONFIG_FTRACE_MCOUNT_RECORD
171/*
172 * The ftrace call sites are logged to a section whose name depends on the
173 * compiler option used. A given kernel image will only use one, AKA
174 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
175 * dependencies for FTRACE_CALLSITE_SECTION's definition.
176 *
177 * ftrace_ops_list_func will be defined as arch_ftrace_ops_list_func
178 * as some archs will have a different prototype for that function
179 * but ftrace_ops_list_func() will have a single prototype.
180 */
181#define MCOUNT_REC() . = ALIGN(8); \
182 __start_mcount_loc = .; \
183 KEEP(*(__mcount_loc)) \
184 KEEP_PATCHABLE \
185 __stop_mcount_loc = .; \
186 FTRACE_STUB_HACK \
187 ftrace_ops_list_func = arch_ftrace_ops_list_func;
188#else
189# ifdef CONFIG_FUNCTION_TRACER
190# define MCOUNT_REC() FTRACE_STUB_HACK \
191 ftrace_ops_list_func = arch_ftrace_ops_list_func;
192# else
193# define MCOUNT_REC()
194# endif
195#endif
196
197#define BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_) \
198 _BEGIN_##_label_ = .; \
199 KEEP(*(_sec_)) \
200 _END_##_label_ = .;
201
202#define BOUNDED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_) \
203 _label_##_BEGIN_ = .; \
204 KEEP(*(_sec_)) \
205 _label_##_END_ = .;
206
207#define BOUNDED_SECTION_BY(_sec_, _label_) \
208 BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, __start, __stop)
209
210#define BOUNDED_SECTION(_sec) BOUNDED_SECTION_BY(_sec, _sec)
211
212#define HEADERED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_, _HDR_) \
213 _HDR_##_label_ = .; \
214 KEEP(*(.gnu.linkonce.##_sec_)) \
215 BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_)
216
217#define HEADERED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_, _HDR_) \
218 _label_##_HDR_ = .; \
219 KEEP(*(.gnu.linkonce.##_sec_)) \
220 BOUNDED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_)
221
222#define HEADERED_SECTION_BY(_sec_, _label_) \
223 HEADERED_SECTION_PRE_LABEL(_sec_, _label_, __start, __stop)
224
225#define HEADERED_SECTION(_sec) HEADERED_SECTION_BY(_sec, _sec)
226
227#ifdef CONFIG_TRACE_BRANCH_PROFILING
228#define LIKELY_PROFILE() \
229 BOUNDED_SECTION_BY(_ftrace_annotated_branch, _annotated_branch_profile)
230#else
231#define LIKELY_PROFILE()
232#endif
233
234#ifdef CONFIG_PROFILE_ALL_BRANCHES
235#define BRANCH_PROFILE() \
236 BOUNDED_SECTION_BY(_ftrace_branch, _branch_profile)
237#else
238#define BRANCH_PROFILE()
239#endif
240
241#ifdef CONFIG_KPROBES
242#define KPROBE_BLACKLIST() \
243 . = ALIGN(8); \
244 BOUNDED_SECTION(_kprobe_blacklist)
245#else
246#define KPROBE_BLACKLIST()
247#endif
248
249#ifdef CONFIG_FUNCTION_ERROR_INJECTION
250#define ERROR_INJECT_WHITELIST() \
251 STRUCT_ALIGN(); \
252 BOUNDED_SECTION(_error_injection_whitelist)
253#else
254#define ERROR_INJECT_WHITELIST()
255#endif
256
257#ifdef CONFIG_EVENT_TRACING
258#define FTRACE_EVENTS() \
259 . = ALIGN(8); \
260 BOUNDED_SECTION(_ftrace_events) \
261 BOUNDED_SECTION_BY(_ftrace_eval_map, _ftrace_eval_maps)
262#else
263#define FTRACE_EVENTS()
264#endif
265
266#ifdef CONFIG_TRACING
267#define TRACE_PRINTKS() BOUNDED_SECTION_BY(__trace_printk_fmt, ___trace_bprintk_fmt)
268#define TRACEPOINT_STR() BOUNDED_SECTION_BY(__tracepoint_str, ___tracepoint_str)
269#else
270#define TRACE_PRINTKS()
271#define TRACEPOINT_STR()
272#endif
273
274#ifdef CONFIG_FTRACE_SYSCALLS
275#define TRACE_SYSCALLS() \
276 . = ALIGN(8); \
277 BOUNDED_SECTION_BY(__syscalls_metadata, _syscalls_metadata)
278#else
279#define TRACE_SYSCALLS()
280#endif
281
282#ifdef CONFIG_BPF_EVENTS
283#define BPF_RAW_TP() STRUCT_ALIGN(); \
284 BOUNDED_SECTION_BY(__bpf_raw_tp_map, __bpf_raw_tp)
285#else
286#define BPF_RAW_TP()
287#endif
288
289#ifdef CONFIG_SERIAL_EARLYCON
290#define EARLYCON_TABLE() \
291 . = ALIGN(8); \
292 BOUNDED_SECTION_POST_LABEL(__earlycon_table, __earlycon_table, , _end)
293#else
294#define EARLYCON_TABLE()
295#endif
296
297#ifdef CONFIG_SECURITY
298#define LSM_TABLE() \
299 . = ALIGN(8); \
300 BOUNDED_SECTION_PRE_LABEL(.lsm_info.init, _lsm_info, __start, __end)
301
302#define EARLY_LSM_TABLE() \
303 . = ALIGN(8); \
304 BOUNDED_SECTION_PRE_LABEL(.early_lsm_info.init, _early_lsm_info, __start, __end)
305#else
306#define LSM_TABLE()
307#define EARLY_LSM_TABLE()
308#endif
309
310#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
311#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
312#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
313#define _OF_TABLE_0(name)
314#define _OF_TABLE_1(name) \
315 . = ALIGN(8); \
316 __##name##_of_table = .; \
317 KEEP(*(__##name##_of_table)) \
318 KEEP(*(__##name##_of_table_end))
319
320#define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
321#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
322#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
323#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
324#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
325#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
326
327#ifdef CONFIG_ACPI
328#define ACPI_PROBE_TABLE(name) \
329 . = ALIGN(8); \
330 BOUNDED_SECTION_POST_LABEL(__##name##_acpi_probe_table, \
331 __##name##_acpi_probe_table,, _end)
332#else
333#define ACPI_PROBE_TABLE(name)
334#endif
335
336#ifdef CONFIG_THERMAL
337#define THERMAL_TABLE(name) \
338 . = ALIGN(8); \
339 BOUNDED_SECTION_POST_LABEL(__##name##_thermal_table, \
340 __##name##_thermal_table,, _end)
341#else
342#define THERMAL_TABLE(name)
343#endif
344
345#define KERNEL_DTB() \
346 STRUCT_ALIGN(); \
347 __dtb_start = .; \
348 KEEP(*(.dtb.init.rodata)) \
349 __dtb_end = .;
350
351/*
352 * .data section
353 */
354#define DATA_DATA \
355 *(.xiptext) \
356 *(DATA_MAIN) \
357 *(.data..decrypted) \
358 *(.ref.data) \
359 *(.data..shared_aligned) /* percpu related */ \
360 *(.data..unlikely) \
361 __start_once = .; \
362 *(.data..once) \
363 __end_once = .; \
364 STRUCT_ALIGN(); \
365 *(__tracepoints) \
366 /* implement dynamic printk debug */ \
367 . = ALIGN(8); \
368 BOUNDED_SECTION_BY(__dyndbg_classes, ___dyndbg_classes) \
369 BOUNDED_SECTION_BY(__dyndbg, ___dyndbg) \
370 CODETAG_SECTIONS() \
371 LIKELY_PROFILE() \
372 BRANCH_PROFILE() \
373 TRACE_PRINTKS() \
374 BPF_RAW_TP() \
375 TRACEPOINT_STR() \
376 KUNIT_TABLE()
377
378/*
379 * Data section helpers
380 */
381#define NOSAVE_DATA \
382 . = ALIGN(PAGE_SIZE); \
383 __nosave_begin = .; \
384 *(.data..nosave) \
385 . = ALIGN(PAGE_SIZE); \
386 __nosave_end = .;
387
388#define PAGE_ALIGNED_DATA(page_align) \
389 . = ALIGN(page_align); \
390 *(.data..page_aligned) \
391 . = ALIGN(page_align);
392
393#define READ_MOSTLY_DATA(align) \
394 . = ALIGN(align); \
395 *(.data..read_mostly) \
396 . = ALIGN(align);
397
398#define CACHELINE_ALIGNED_DATA(align) \
399 . = ALIGN(align); \
400 *(.data..cacheline_aligned)
401
402#define INIT_TASK_DATA(align) \
403 . = ALIGN(align); \
404 __start_init_stack = .; \
405 init_thread_union = .; \
406 init_stack = .; \
407 KEEP(*(.data..init_task)) \
408 KEEP(*(.data..init_thread_info)) \
409 . = __start_init_stack + THREAD_SIZE; \
410 __end_init_stack = .;
411
412#define JUMP_TABLE_DATA \
413 . = ALIGN(8); \
414 BOUNDED_SECTION_BY(__jump_table, ___jump_table)
415
416#ifdef CONFIG_HAVE_STATIC_CALL_INLINE
417#define STATIC_CALL_DATA \
418 . = ALIGN(8); \
419 BOUNDED_SECTION_BY(.static_call_sites, _static_call_sites) \
420 BOUNDED_SECTION_BY(.static_call_tramp_key, _static_call_tramp_key)
421#else
422#define STATIC_CALL_DATA
423#endif
424
425/*
426 * Allow architectures to handle ro_after_init data on their
427 * own by defining an empty RO_AFTER_INIT_DATA.
428 */
429#ifndef RO_AFTER_INIT_DATA
430#define RO_AFTER_INIT_DATA \
431 . = ALIGN(8); \
432 __start_ro_after_init = .; \
433 *(.data..ro_after_init) \
434 JUMP_TABLE_DATA \
435 STATIC_CALL_DATA \
436 __end_ro_after_init = .;
437#endif
438
439/*
440 * .kcfi_traps contains a list KCFI trap locations.
441 */
442#ifndef KCFI_TRAPS
443#ifdef CONFIG_ARCH_USES_CFI_TRAPS
444#define KCFI_TRAPS \
445 __kcfi_traps : AT(ADDR(__kcfi_traps) - LOAD_OFFSET) { \
446 BOUNDED_SECTION_BY(.kcfi_traps, ___kcfi_traps) \
447 }
448#else
449#define KCFI_TRAPS
450#endif
451#endif
452
453/*
454 * Read only Data
455 */
456#define RO_DATA(align) \
457 . = ALIGN((align)); \
458 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
459 __start_rodata = .; \
460 *(.rodata) *(.rodata.*) *(.data.rel.ro*) \
461 SCHED_DATA \
462 RO_AFTER_INIT_DATA /* Read only after init */ \
463 . = ALIGN(8); \
464 BOUNDED_SECTION_BY(__tracepoints_ptrs, ___tracepoints_ptrs) \
465 *(__tracepoints_strings)/* Tracepoints: strings */ \
466 } \
467 \
468 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
469 *(.rodata1) \
470 } \
471 \
472 /* PCI quirks */ \
473 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
474 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_early, _pci_fixups_early, __start, __end) \
475 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_header, _pci_fixups_header, __start, __end) \
476 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_final, _pci_fixups_final, __start, __end) \
477 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_enable, _pci_fixups_enable, __start, __end) \
478 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_resume, _pci_fixups_resume, __start, __end) \
479 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_suspend, _pci_fixups_suspend, __start, __end) \
480 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_resume_early, _pci_fixups_resume_early, __start, __end) \
481 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_suspend_late, _pci_fixups_suspend_late, __start, __end) \
482 } \
483 \
484 FW_LOADER_BUILT_IN_DATA \
485 TRACEDATA \
486 \
487 PRINTK_INDEX \
488 \
489 /* Kernel symbol table: Normal symbols */ \
490 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
491 __start___ksymtab = .; \
492 KEEP(*(SORT(___ksymtab+*))) \
493 __stop___ksymtab = .; \
494 } \
495 \
496 /* Kernel symbol table: GPL-only symbols */ \
497 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
498 __start___ksymtab_gpl = .; \
499 KEEP(*(SORT(___ksymtab_gpl+*))) \
500 __stop___ksymtab_gpl = .; \
501 } \
502 \
503 /* Kernel symbol table: Normal symbols */ \
504 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
505 __start___kcrctab = .; \
506 KEEP(*(SORT(___kcrctab+*))) \
507 __stop___kcrctab = .; \
508 } \
509 \
510 /* Kernel symbol table: GPL-only symbols */ \
511 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
512 __start___kcrctab_gpl = .; \
513 KEEP(*(SORT(___kcrctab_gpl+*))) \
514 __stop___kcrctab_gpl = .; \
515 } \
516 \
517 /* Kernel symbol table: strings */ \
518 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
519 *(__ksymtab_strings) \
520 } \
521 \
522 /* __*init sections */ \
523 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
524 *(.ref.rodata) \
525 } \
526 \
527 /* Built-in module parameters. */ \
528 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
529 BOUNDED_SECTION_BY(__param, ___param) \
530 } \
531 \
532 /* Built-in module versions. */ \
533 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
534 BOUNDED_SECTION_BY(__modver, ___modver) \
535 } \
536 \
537 KCFI_TRAPS \
538 \
539 RO_EXCEPTION_TABLE \
540 NOTES \
541 BTF \
542 \
543 . = ALIGN((align)); \
544 __end_rodata = .;
545
546
547/*
548 * Non-instrumentable text section
549 */
550#define NOINSTR_TEXT \
551 ALIGN_FUNCTION(); \
552 __noinstr_text_start = .; \
553 *(.noinstr.text) \
554 __cpuidle_text_start = .; \
555 *(.cpuidle.text) \
556 __cpuidle_text_end = .; \
557 __noinstr_text_end = .;
558
559#define TEXT_SPLIT \
560 __split_text_start = .; \
561 *(.text.split .text.split.[0-9a-zA-Z_]*) \
562 __split_text_end = .;
563
564#define TEXT_UNLIKELY \
565 __unlikely_text_start = .; \
566 *(.text.unlikely .text.unlikely.*) \
567 __unlikely_text_end = .;
568
569#define TEXT_HOT \
570 __hot_text_start = .; \
571 *(.text.hot .text.hot.*) \
572 __hot_text_end = .;
573
574/*
575 * .text section. Map to function alignment to avoid address changes
576 * during second ld run in second ld pass when generating System.map
577 *
578 * TEXT_MAIN here will match symbols with a fixed pattern (for example,
579 * .text.hot or .text.unlikely) if dead code elimination or
580 * function-section is enabled. Match these symbols first before
581 * TEXT_MAIN to ensure they are grouped together.
582 *
583 * Also placing .text.hot section at the beginning of a page, this
584 * would help the TLB performance.
585 */
586#define TEXT_TEXT \
587 ALIGN_FUNCTION(); \
588 *(.text.asan.* .text.tsan.*) \
589 *(.text.unknown .text.unknown.*) \
590 TEXT_SPLIT \
591 TEXT_UNLIKELY \
592 . = ALIGN(PAGE_SIZE); \
593 TEXT_HOT \
594 *(TEXT_MAIN .text.fixup) \
595 NOINSTR_TEXT \
596 *(.ref.text)
597
598/* sched.text is aling to function alignment to secure we have same
599 * address even at second ld pass when generating System.map */
600#define SCHED_TEXT \
601 ALIGN_FUNCTION(); \
602 __sched_text_start = .; \
603 *(.sched.text) \
604 __sched_text_end = .;
605
606/* spinlock.text is aling to function alignment to secure we have same
607 * address even at second ld pass when generating System.map */
608#define LOCK_TEXT \
609 ALIGN_FUNCTION(); \
610 __lock_text_start = .; \
611 *(.spinlock.text) \
612 __lock_text_end = .;
613
614#define KPROBES_TEXT \
615 ALIGN_FUNCTION(); \
616 __kprobes_text_start = .; \
617 *(.kprobes.text) \
618 __kprobes_text_end = .;
619
620#define ENTRY_TEXT \
621 ALIGN_FUNCTION(); \
622 __entry_text_start = .; \
623 *(.entry.text) \
624 __entry_text_end = .;
625
626#define IRQENTRY_TEXT \
627 ALIGN_FUNCTION(); \
628 __irqentry_text_start = .; \
629 *(.irqentry.text) \
630 __irqentry_text_end = .;
631
632#define SOFTIRQENTRY_TEXT \
633 ALIGN_FUNCTION(); \
634 __softirqentry_text_start = .; \
635 *(.softirqentry.text) \
636 __softirqentry_text_end = .;
637
638#define STATIC_CALL_TEXT \
639 ALIGN_FUNCTION(); \
640 __static_call_text_start = .; \
641 *(.static_call.text) \
642 __static_call_text_end = .;
643
644/* Section used for early init (in .S files) */
645#define HEAD_TEXT KEEP(*(.head.text))
646
647#define HEAD_TEXT_SECTION \
648 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
649 HEAD_TEXT \
650 }
651
652/*
653 * Exception table
654 */
655#define EXCEPTION_TABLE(align) \
656 . = ALIGN(align); \
657 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
658 BOUNDED_SECTION_BY(__ex_table, ___ex_table) \
659 }
660
661/*
662 * .BTF
663 */
664#ifdef CONFIG_DEBUG_INFO_BTF
665#define BTF \
666 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
667 BOUNDED_SECTION_BY(.BTF, _BTF) \
668 } \
669 . = ALIGN(4); \
670 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
671 *(.BTF_ids) \
672 }
673#else
674#define BTF
675#endif
676
677/*
678 * Init task
679 */
680#define INIT_TASK_DATA_SECTION(align) \
681 . = ALIGN(align); \
682 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
683 INIT_TASK_DATA(align) \
684 }
685
686#ifdef CONFIG_CONSTRUCTORS
687#define KERNEL_CTORS() . = ALIGN(8); \
688 __ctors_start = .; \
689 KEEP(*(SORT(.ctors.*))) \
690 KEEP(*(.ctors)) \
691 KEEP(*(SORT(.init_array.*))) \
692 KEEP(*(.init_array)) \
693 __ctors_end = .;
694#else
695#define KERNEL_CTORS()
696#endif
697
698/* init and exit section handling */
699#define INIT_DATA \
700 KEEP(*(SORT(___kentry+*))) \
701 *(.init.data .init.data.*) \
702 KERNEL_CTORS() \
703 MCOUNT_REC() \
704 *(.init.rodata .init.rodata.*) \
705 FTRACE_EVENTS() \
706 TRACE_SYSCALLS() \
707 KPROBE_BLACKLIST() \
708 ERROR_INJECT_WHITELIST() \
709 CLK_OF_TABLES() \
710 RESERVEDMEM_OF_TABLES() \
711 TIMER_OF_TABLES() \
712 CPU_METHOD_OF_TABLES() \
713 CPUIDLE_METHOD_OF_TABLES() \
714 KERNEL_DTB() \
715 IRQCHIP_OF_MATCH_TABLE() \
716 ACPI_PROBE_TABLE(irqchip) \
717 ACPI_PROBE_TABLE(timer) \
718 THERMAL_TABLE(governor) \
719 EARLYCON_TABLE() \
720 LSM_TABLE() \
721 EARLY_LSM_TABLE() \
722 KUNIT_INIT_TABLE()
723
724#define INIT_TEXT \
725 *(.init.text .init.text.*) \
726 *(.text.startup)
727
728#define EXIT_DATA \
729 *(.exit.data .exit.data.*) \
730 *(.fini_array .fini_array.*) \
731 *(.dtors .dtors.*) \
732
733#define EXIT_TEXT \
734 *(.exit.text) \
735 *(.text.exit) \
736
737#define EXIT_CALL \
738 *(.exitcall.exit)
739
740/*
741 * bss (Block Started by Symbol) - uninitialized data
742 * zeroed during startup
743 */
744#define SBSS(sbss_align) \
745 . = ALIGN(sbss_align); \
746 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
747 *(.dynsbss) \
748 *(SBSS_MAIN) \
749 *(.scommon) \
750 }
751
752/*
753 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
754 * sections to the front of bss.
755 */
756#ifndef BSS_FIRST_SECTIONS
757#define BSS_FIRST_SECTIONS
758#endif
759
760#define BSS(bss_align) \
761 . = ALIGN(bss_align); \
762 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
763 BSS_FIRST_SECTIONS \
764 . = ALIGN(PAGE_SIZE); \
765 *(.bss..page_aligned) \
766 . = ALIGN(PAGE_SIZE); \
767 *(.dynbss) \
768 *(BSS_MAIN) \
769 *(COMMON) \
770 }
771
772/*
773 * DWARF debug sections.
774 * Symbols in the DWARF debugging sections are relative to
775 * the beginning of the section so we begin them at 0.
776 */
777#define DWARF_DEBUG \
778 /* DWARF 1 */ \
779 .debug 0 : { *(.debug) } \
780 .line 0 : { *(.line) } \
781 /* GNU DWARF 1 extensions */ \
782 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
783 .debug_sfnames 0 : { *(.debug_sfnames) } \
784 /* DWARF 1.1 and DWARF 2 */ \
785 .debug_aranges 0 : { *(.debug_aranges) } \
786 .debug_pubnames 0 : { *(.debug_pubnames) } \
787 /* DWARF 2 */ \
788 .debug_info 0 : { *(.debug_info \
789 .gnu.linkonce.wi.*) } \
790 .debug_abbrev 0 : { *(.debug_abbrev) } \
791 .debug_line 0 : { *(.debug_line) } \
792 .debug_frame 0 : { *(.debug_frame) } \
793 .debug_str 0 : { *(.debug_str) } \
794 .debug_loc 0 : { *(.debug_loc) } \
795 .debug_macinfo 0 : { *(.debug_macinfo) } \
796 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
797 /* DWARF 3 */ \
798 .debug_ranges 0 : { *(.debug_ranges) } \
799 /* SGI/MIPS DWARF 2 extensions */ \
800 .debug_weaknames 0 : { *(.debug_weaknames) } \
801 .debug_funcnames 0 : { *(.debug_funcnames) } \
802 .debug_typenames 0 : { *(.debug_typenames) } \
803 .debug_varnames 0 : { *(.debug_varnames) } \
804 /* GNU DWARF 2 extensions */ \
805 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
806 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
807 /* DWARF 4 */ \
808 .debug_types 0 : { *(.debug_types) } \
809 /* DWARF 5 */ \
810 .debug_addr 0 : { *(.debug_addr) } \
811 .debug_line_str 0 : { *(.debug_line_str) } \
812 .debug_loclists 0 : { *(.debug_loclists) } \
813 .debug_macro 0 : { *(.debug_macro) } \
814 .debug_names 0 : { *(.debug_names) } \
815 .debug_rnglists 0 : { *(.debug_rnglists) } \
816 .debug_str_offsets 0 : { *(.debug_str_offsets) }
817
818/* Stabs debugging sections. */
819#define STABS_DEBUG \
820 .stab 0 : { *(.stab) } \
821 .stabstr 0 : { *(.stabstr) } \
822 .stab.excl 0 : { *(.stab.excl) } \
823 .stab.exclstr 0 : { *(.stab.exclstr) } \
824 .stab.index 0 : { *(.stab.index) } \
825 .stab.indexstr 0 : { *(.stab.indexstr) }
826
827/* Required sections not related to debugging. */
828#define ELF_DETAILS \
829 .comment 0 : { *(.comment) } \
830 .symtab 0 : { *(.symtab) } \
831 .strtab 0 : { *(.strtab) } \
832 .shstrtab 0 : { *(.shstrtab) }
833
834#ifdef CONFIG_GENERIC_BUG
835#define BUG_TABLE \
836 . = ALIGN(8); \
837 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
838 BOUNDED_SECTION_BY(__bug_table, ___bug_table) \
839 }
840#else
841#define BUG_TABLE
842#endif
843
844#ifdef CONFIG_UNWINDER_ORC
845#define ORC_UNWIND_TABLE \
846 .orc_header : AT(ADDR(.orc_header) - LOAD_OFFSET) { \
847 BOUNDED_SECTION_BY(.orc_header, _orc_header) \
848 } \
849 . = ALIGN(4); \
850 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
851 BOUNDED_SECTION_BY(.orc_unwind_ip, _orc_unwind_ip) \
852 } \
853 . = ALIGN(2); \
854 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
855 BOUNDED_SECTION_BY(.orc_unwind, _orc_unwind) \
856 } \
857 text_size = _etext - _stext; \
858 . = ALIGN(4); \
859 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
860 orc_lookup = .; \
861 . += (((text_size + LOOKUP_BLOCK_SIZE - 1) / \
862 LOOKUP_BLOCK_SIZE) + 1) * 4; \
863 orc_lookup_end = .; \
864 }
865#else
866#define ORC_UNWIND_TABLE
867#endif
868
869/* Built-in firmware blobs */
870#ifdef CONFIG_FW_LOADER
871#define FW_LOADER_BUILT_IN_DATA \
872 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
873 BOUNDED_SECTION_PRE_LABEL(.builtin_fw, _builtin_fw, __start, __end) \
874 }
875#else
876#define FW_LOADER_BUILT_IN_DATA
877#endif
878
879#ifdef CONFIG_PM_TRACE
880#define TRACEDATA \
881 . = ALIGN(4); \
882 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
883 BOUNDED_SECTION_POST_LABEL(.tracedata, __tracedata, _start, _end) \
884 }
885#else
886#define TRACEDATA
887#endif
888
889#ifdef CONFIG_PRINTK_INDEX
890#define PRINTK_INDEX \
891 .printk_index : AT(ADDR(.printk_index) - LOAD_OFFSET) { \
892 BOUNDED_SECTION_BY(.printk_index, _printk_index) \
893 }
894#else
895#define PRINTK_INDEX
896#endif
897
898/*
899 * Discard .note.GNU-stack, which is emitted as PROGBITS by the compiler.
900 * Otherwise, the type of .notes section would become PROGBITS instead of NOTES.
901 *
902 * Also, discard .note.gnu.property, otherwise it forces the notes section to
903 * be 8-byte aligned which causes alignment mismatches with the kernel's custom
904 * 4-byte aligned notes.
905 */
906#define NOTES \
907 /DISCARD/ : { \
908 *(.note.GNU-stack) \
909 *(.note.gnu.property) \
910 } \
911 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
912 BOUNDED_SECTION_BY(.note.*, _notes) \
913 } NOTES_HEADERS \
914 NOTES_HEADERS_RESTORE
915
916#define INIT_SETUP(initsetup_align) \
917 . = ALIGN(initsetup_align); \
918 BOUNDED_SECTION_POST_LABEL(.init.setup, __setup, _start, _end)
919
920#define INIT_CALLS_LEVEL(level) \
921 __initcall##level##_start = .; \
922 KEEP(*(.initcall##level##.init)) \
923 KEEP(*(.initcall##level##s.init)) \
924
925#define INIT_CALLS \
926 __initcall_start = .; \
927 KEEP(*(.initcallearly.init)) \
928 INIT_CALLS_LEVEL(0) \
929 INIT_CALLS_LEVEL(1) \
930 INIT_CALLS_LEVEL(2) \
931 INIT_CALLS_LEVEL(3) \
932 INIT_CALLS_LEVEL(4) \
933 INIT_CALLS_LEVEL(5) \
934 INIT_CALLS_LEVEL(rootfs) \
935 INIT_CALLS_LEVEL(6) \
936 INIT_CALLS_LEVEL(7) \
937 __initcall_end = .;
938
939#define CON_INITCALL \
940 BOUNDED_SECTION_POST_LABEL(.con_initcall.init, __con_initcall, _start, _end)
941
942#define NAMED_SECTION(name) \
943 . = ALIGN(8); \
944 name : AT(ADDR(name) - LOAD_OFFSET) \
945 { BOUNDED_SECTION_PRE_LABEL(name, name, __start_, __stop_) }
946
947#define RUNTIME_CONST(t,x) NAMED_SECTION(runtime_##t##_##x)
948
949#define RUNTIME_CONST_VARIABLES \
950 RUNTIME_CONST(shift, d_hash_shift) \
951 RUNTIME_CONST(ptr, dentry_hashtable)
952
953/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
954#define KUNIT_TABLE() \
955 . = ALIGN(8); \
956 BOUNDED_SECTION_POST_LABEL(.kunit_test_suites, __kunit_suites, _start, _end)
957
958/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
959#define KUNIT_INIT_TABLE() \
960 . = ALIGN(8); \
961 BOUNDED_SECTION_POST_LABEL(.kunit_init_test_suites, \
962 __kunit_init_suites, _start, _end)
963
964#ifdef CONFIG_BLK_DEV_INITRD
965#define INIT_RAM_FS \
966 . = ALIGN(4); \
967 __initramfs_start = .; \
968 KEEP(*(.init.ramfs)) \
969 . = ALIGN(8); \
970 KEEP(*(.init.ramfs.info))
971#else
972#define INIT_RAM_FS
973#endif
974
975/*
976 * Memory encryption operates on a page basis. Since we need to clear
977 * the memory encryption mask for this section, it needs to be aligned
978 * on a page boundary and be a page-size multiple in length.
979 *
980 * Note: We use a separate section so that only this section gets
981 * decrypted to avoid exposing more than we wish.
982 */
983#ifdef CONFIG_AMD_MEM_ENCRYPT
984#define PERCPU_DECRYPTED_SECTION \
985 . = ALIGN(PAGE_SIZE); \
986 *(.data..percpu..decrypted) \
987 . = ALIGN(PAGE_SIZE);
988#else
989#define PERCPU_DECRYPTED_SECTION
990#endif
991
992
993/*
994 * Default discarded sections.
995 *
996 * Some archs want to discard exit text/data at runtime rather than
997 * link time due to cross-section references such as alt instructions,
998 * bug table, eh_frame, etc. DISCARDS must be the last of output
999 * section definitions so that such archs put those in earlier section
1000 * definitions.
1001 */
1002#ifdef RUNTIME_DISCARD_EXIT
1003#define EXIT_DISCARDS
1004#else
1005#define EXIT_DISCARDS \
1006 EXIT_TEXT \
1007 EXIT_DATA
1008#endif
1009
1010/*
1011 * Clang's -fprofile-arcs, -fsanitize=kernel-address, and
1012 * -fsanitize=thread produce unwanted sections (.eh_frame
1013 * and .init_array.*), but CONFIG_CONSTRUCTORS wants to
1014 * keep any .init_array.* sections.
1015 * https://llvm.org/pr46478
1016 */
1017#ifdef CONFIG_UNWIND_TABLES
1018#define DISCARD_EH_FRAME
1019#else
1020#define DISCARD_EH_FRAME *(.eh_frame)
1021#endif
1022#if defined(CONFIG_GCOV_KERNEL) || defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN)
1023# ifdef CONFIG_CONSTRUCTORS
1024# define SANITIZER_DISCARDS \
1025 DISCARD_EH_FRAME
1026# else
1027# define SANITIZER_DISCARDS \
1028 *(.init_array) *(.init_array.*) \
1029 DISCARD_EH_FRAME
1030# endif
1031#else
1032# define SANITIZER_DISCARDS
1033#endif
1034
1035#define COMMON_DISCARDS \
1036 SANITIZER_DISCARDS \
1037 PATCHABLE_DISCARDS \
1038 *(.discard) \
1039 *(.discard.*) \
1040 *(.export_symbol) \
1041 *(.modinfo) \
1042 /* ld.bfd warns about .gnu.version* even when not emitted */ \
1043 *(.gnu.version*) \
1044
1045#define DISCARDS \
1046 /DISCARD/ : { \
1047 EXIT_DISCARDS \
1048 EXIT_CALL \
1049 COMMON_DISCARDS \
1050 }
1051
1052/**
1053 * PERCPU_INPUT - the percpu input sections
1054 * @cacheline: cacheline size
1055 *
1056 * The core percpu section names and core symbols which do not rely
1057 * directly upon load addresses.
1058 *
1059 * @cacheline is used to align subsections to avoid false cacheline
1060 * sharing between subsections for different purposes.
1061 */
1062#define PERCPU_INPUT(cacheline) \
1063 __per_cpu_start = .; \
1064 *(.data..percpu..first) \
1065 . = ALIGN(PAGE_SIZE); \
1066 *(.data..percpu..page_aligned) \
1067 . = ALIGN(cacheline); \
1068 *(.data..percpu..read_mostly) \
1069 . = ALIGN(cacheline); \
1070 *(.data..percpu) \
1071 *(.data..percpu..shared_aligned) \
1072 PERCPU_DECRYPTED_SECTION \
1073 __per_cpu_end = .;
1074
1075/**
1076 * PERCPU_VADDR - define output section for percpu area
1077 * @cacheline: cacheline size
1078 * @vaddr: explicit base address (optional)
1079 * @phdr: destination PHDR (optional)
1080 *
1081 * Macro which expands to output section for percpu area.
1082 *
1083 * @cacheline is used to align subsections to avoid false cacheline
1084 * sharing between subsections for different purposes.
1085 *
1086 * If @vaddr is not blank, it specifies explicit base address and all
1087 * percpu symbols will be offset from the given address. If blank,
1088 * @vaddr always equals @laddr + LOAD_OFFSET.
1089 *
1090 * @phdr defines the output PHDR to use if not blank. Be warned that
1091 * output PHDR is sticky. If @phdr is specified, the next output
1092 * section in the linker script will go there too. @phdr should have
1093 * a leading colon.
1094 *
1095 * Note that this macros defines __per_cpu_load as an absolute symbol.
1096 * If there is no need to put the percpu section at a predetermined
1097 * address, use PERCPU_SECTION.
1098 */
1099#define PERCPU_VADDR(cacheline, vaddr, phdr) \
1100 __per_cpu_load = .; \
1101 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1102 PERCPU_INPUT(cacheline) \
1103 } phdr \
1104 . = __per_cpu_load + SIZEOF(.data..percpu);
1105
1106/**
1107 * PERCPU_SECTION - define output section for percpu area, simple version
1108 * @cacheline: cacheline size
1109 *
1110 * Align to PAGE_SIZE and outputs output section for percpu area. This
1111 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1112 * __per_cpu_start will be identical.
1113 *
1114 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1115 * except that __per_cpu_load is defined as a relative symbol against
1116 * .data..percpu which is required for relocatable x86_32 configuration.
1117 */
1118#define PERCPU_SECTION(cacheline) \
1119 . = ALIGN(PAGE_SIZE); \
1120 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1121 __per_cpu_load = .; \
1122 PERCPU_INPUT(cacheline) \
1123 }
1124
1125
1126/*
1127 * Definition of the high level *_SECTION macros
1128 * They will fit only a subset of the architectures
1129 */
1130
1131
1132/*
1133 * Writeable data.
1134 * All sections are combined in a single .data section.
1135 * The sections following CONSTRUCTORS are arranged so their
1136 * typical alignment matches.
1137 * A cacheline is typical/always less than a PAGE_SIZE so
1138 * the sections that has this restriction (or similar)
1139 * is located before the ones requiring PAGE_SIZE alignment.
1140 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1141 * matches the requirement of PAGE_ALIGNED_DATA.
1142 *
1143 * use 0 as page_align if page_aligned data is not used */
1144#define RW_DATA(cacheline, pagealigned, inittask) \
1145 . = ALIGN(PAGE_SIZE); \
1146 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1147 INIT_TASK_DATA(inittask) \
1148 NOSAVE_DATA \
1149 PAGE_ALIGNED_DATA(pagealigned) \
1150 CACHELINE_ALIGNED_DATA(cacheline) \
1151 READ_MOSTLY_DATA(cacheline) \
1152 DATA_DATA \
1153 CONSTRUCTORS \
1154 } \
1155 BUG_TABLE \
1156
1157#define INIT_TEXT_SECTION(inittext_align) \
1158 . = ALIGN(inittext_align); \
1159 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1160 _sinittext = .; \
1161 INIT_TEXT \
1162 _einittext = .; \
1163 }
1164
1165#define INIT_DATA_SECTION(initsetup_align) \
1166 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1167 INIT_DATA \
1168 INIT_SETUP(initsetup_align) \
1169 INIT_CALLS \
1170 CON_INITCALL \
1171 INIT_RAM_FS \
1172 }
1173
1174#define BSS_SECTION(sbss_align, bss_align, stop_align) \
1175 . = ALIGN(sbss_align); \
1176 __bss_start = .; \
1177 SBSS(sbss_align) \
1178 BSS(bss_align) \
1179 . = ALIGN(stop_align); \
1180 __bss_stop = .;
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#ifndef LOAD_OFFSET
54#define LOAD_OFFSET 0
55#endif
56
57/*
58 * Only some architectures want to have the .notes segment visible in
59 * a separate PT_NOTE ELF Program Header. When this happens, it needs
60 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
61 * Program Headers. In this case, though, the PT_LOAD needs to be made
62 * the default again so that all the following sections don't also end
63 * up in the PT_NOTE Program Header.
64 */
65#ifdef EMITS_PT_NOTE
66#define NOTES_HEADERS :text :note
67#define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
68#else
69#define NOTES_HEADERS
70#define NOTES_HEADERS_RESTORE
71#endif
72
73/*
74 * Some architectures have non-executable read-only exception tables.
75 * They can be added to the RO_DATA segment by specifying their desired
76 * alignment.
77 */
78#ifdef RO_EXCEPTION_TABLE_ALIGN
79#define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
80#else
81#define RO_EXCEPTION_TABLE
82#endif
83
84/* Align . to a 8 byte boundary equals to maximum function alignment. */
85#define ALIGN_FUNCTION() . = ALIGN(8)
86
87/*
88 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
89 * generates .data.identifier sections, which need to be pulled in with
90 * .data. We don't want to pull in .data..other sections, which Linux
91 * has defined. Same for text and bss.
92 *
93 * With LTO_CLANG, the linker also splits sections by default, so we need
94 * these macros to combine the sections during the final link.
95 *
96 * RODATA_MAIN is not used because existing code already defines .rodata.x
97 * sections to be brought in with rodata.
98 */
99#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG)
100#define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
101#define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..L* .data..compoundliteral* .data.$__unnamed_* .data.$L*
102#define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
103#define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]* .rodata..L*
104#define BSS_MAIN .bss .bss.[0-9a-zA-Z_]* .bss..compoundliteral*
105#define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
106#else
107#define TEXT_MAIN .text
108#define DATA_MAIN .data
109#define SDATA_MAIN .sdata
110#define RODATA_MAIN .rodata
111#define BSS_MAIN .bss
112#define SBSS_MAIN .sbss
113#endif
114
115/*
116 * GCC 4.5 and later have a 32 bytes section alignment for structures.
117 * Except GCC 4.9, that feels the need to align on 64 bytes.
118 */
119#if __GNUC__ == 4 && __GNUC_MINOR__ == 9
120#define STRUCT_ALIGNMENT 64
121#else
122#define STRUCT_ALIGNMENT 32
123#endif
124#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
125
126/*
127 * The order of the sched class addresses are important, as they are
128 * used to determine the order of the priority of each sched class in
129 * relation to each other.
130 */
131#define SCHED_DATA \
132 STRUCT_ALIGN(); \
133 __begin_sched_classes = .; \
134 *(__idle_sched_class) \
135 *(__fair_sched_class) \
136 *(__rt_sched_class) \
137 *(__dl_sched_class) \
138 *(__stop_sched_class) \
139 __end_sched_classes = .;
140
141/* The actual configuration determine if the init/exit sections
142 * are handled as text/data or they can be discarded (which
143 * often happens at runtime)
144 */
145#ifdef CONFIG_HOTPLUG_CPU
146#define CPU_KEEP(sec) *(.cpu##sec)
147#define CPU_DISCARD(sec)
148#else
149#define CPU_KEEP(sec)
150#define CPU_DISCARD(sec) *(.cpu##sec)
151#endif
152
153#if defined(CONFIG_MEMORY_HOTPLUG)
154#define MEM_KEEP(sec) *(.mem##sec)
155#define MEM_DISCARD(sec)
156#else
157#define MEM_KEEP(sec)
158#define MEM_DISCARD(sec) *(.mem##sec)
159#endif
160
161#ifdef CONFIG_FTRACE_MCOUNT_RECORD
162/*
163 * The ftrace call sites are logged to a section whose name depends on the
164 * compiler option used. A given kernel image will only use one, AKA
165 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
166 * dependencies for FTRACE_CALLSITE_SECTION's definition.
167 *
168 * Need to also make ftrace_stub_graph point to ftrace_stub
169 * so that the same stub location may have different protocols
170 * and not mess up with C verifiers.
171 */
172#define MCOUNT_REC() . = ALIGN(8); \
173 __start_mcount_loc = .; \
174 KEEP(*(__mcount_loc)) \
175 KEEP(*(__patchable_function_entries)) \
176 __stop_mcount_loc = .; \
177 ftrace_stub_graph = ftrace_stub;
178#else
179# ifdef CONFIG_FUNCTION_TRACER
180# define MCOUNT_REC() ftrace_stub_graph = ftrace_stub;
181# else
182# define MCOUNT_REC()
183# endif
184#endif
185
186#ifdef CONFIG_TRACE_BRANCH_PROFILING
187#define LIKELY_PROFILE() __start_annotated_branch_profile = .; \
188 KEEP(*(_ftrace_annotated_branch)) \
189 __stop_annotated_branch_profile = .;
190#else
191#define LIKELY_PROFILE()
192#endif
193
194#ifdef CONFIG_PROFILE_ALL_BRANCHES
195#define BRANCH_PROFILE() __start_branch_profile = .; \
196 KEEP(*(_ftrace_branch)) \
197 __stop_branch_profile = .;
198#else
199#define BRANCH_PROFILE()
200#endif
201
202#ifdef CONFIG_KPROBES
203#define KPROBE_BLACKLIST() . = ALIGN(8); \
204 __start_kprobe_blacklist = .; \
205 KEEP(*(_kprobe_blacklist)) \
206 __stop_kprobe_blacklist = .;
207#else
208#define KPROBE_BLACKLIST()
209#endif
210
211#ifdef CONFIG_FUNCTION_ERROR_INJECTION
212#define ERROR_INJECT_WHITELIST() STRUCT_ALIGN(); \
213 __start_error_injection_whitelist = .; \
214 KEEP(*(_error_injection_whitelist)) \
215 __stop_error_injection_whitelist = .;
216#else
217#define ERROR_INJECT_WHITELIST()
218#endif
219
220#ifdef CONFIG_EVENT_TRACING
221#define FTRACE_EVENTS() . = ALIGN(8); \
222 __start_ftrace_events = .; \
223 KEEP(*(_ftrace_events)) \
224 __stop_ftrace_events = .; \
225 __start_ftrace_eval_maps = .; \
226 KEEP(*(_ftrace_eval_map)) \
227 __stop_ftrace_eval_maps = .;
228#else
229#define FTRACE_EVENTS()
230#endif
231
232#ifdef CONFIG_TRACING
233#define TRACE_PRINTKS() __start___trace_bprintk_fmt = .; \
234 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
235 __stop___trace_bprintk_fmt = .;
236#define TRACEPOINT_STR() __start___tracepoint_str = .; \
237 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
238 __stop___tracepoint_str = .;
239#else
240#define TRACE_PRINTKS()
241#define TRACEPOINT_STR()
242#endif
243
244#ifdef CONFIG_FTRACE_SYSCALLS
245#define TRACE_SYSCALLS() . = ALIGN(8); \
246 __start_syscalls_metadata = .; \
247 KEEP(*(__syscalls_metadata)) \
248 __stop_syscalls_metadata = .;
249#else
250#define TRACE_SYSCALLS()
251#endif
252
253#ifdef CONFIG_BPF_EVENTS
254#define BPF_RAW_TP() STRUCT_ALIGN(); \
255 __start__bpf_raw_tp = .; \
256 KEEP(*(__bpf_raw_tp_map)) \
257 __stop__bpf_raw_tp = .;
258#else
259#define BPF_RAW_TP()
260#endif
261
262#ifdef CONFIG_SERIAL_EARLYCON
263#define EARLYCON_TABLE() . = ALIGN(8); \
264 __earlycon_table = .; \
265 KEEP(*(__earlycon_table)) \
266 __earlycon_table_end = .;
267#else
268#define EARLYCON_TABLE()
269#endif
270
271#ifdef CONFIG_SECURITY
272#define LSM_TABLE() . = ALIGN(8); \
273 __start_lsm_info = .; \
274 KEEP(*(.lsm_info.init)) \
275 __end_lsm_info = .;
276#define EARLY_LSM_TABLE() . = ALIGN(8); \
277 __start_early_lsm_info = .; \
278 KEEP(*(.early_lsm_info.init)) \
279 __end_early_lsm_info = .;
280#else
281#define LSM_TABLE()
282#define EARLY_LSM_TABLE()
283#endif
284
285#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
286#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
287#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
288#define _OF_TABLE_0(name)
289#define _OF_TABLE_1(name) \
290 . = ALIGN(8); \
291 __##name##_of_table = .; \
292 KEEP(*(__##name##_of_table)) \
293 KEEP(*(__##name##_of_table_end))
294
295#define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
296#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
297#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
298#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
299#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
300#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
301
302#ifdef CONFIG_ACPI
303#define ACPI_PROBE_TABLE(name) \
304 . = ALIGN(8); \
305 __##name##_acpi_probe_table = .; \
306 KEEP(*(__##name##_acpi_probe_table)) \
307 __##name##_acpi_probe_table_end = .;
308#else
309#define ACPI_PROBE_TABLE(name)
310#endif
311
312#ifdef CONFIG_THERMAL
313#define THERMAL_TABLE(name) \
314 . = ALIGN(8); \
315 __##name##_thermal_table = .; \
316 KEEP(*(__##name##_thermal_table)) \
317 __##name##_thermal_table_end = .;
318#else
319#define THERMAL_TABLE(name)
320#endif
321
322#ifdef CONFIG_DTPM
323#define DTPM_TABLE() \
324 . = ALIGN(8); \
325 __dtpm_table = .; \
326 KEEP(*(__dtpm_table)) \
327 __dtpm_table_end = .;
328#else
329#define DTPM_TABLE()
330#endif
331
332#define KERNEL_DTB() \
333 STRUCT_ALIGN(); \
334 __dtb_start = .; \
335 KEEP(*(.dtb.init.rodata)) \
336 __dtb_end = .;
337
338/*
339 * .data section
340 */
341#define DATA_DATA \
342 *(.xiptext) \
343 *(DATA_MAIN) \
344 *(.ref.data) \
345 *(.data..shared_aligned) /* percpu related */ \
346 MEM_KEEP(init.data*) \
347 MEM_KEEP(exit.data*) \
348 *(.data.unlikely) \
349 __start_once = .; \
350 *(.data.once) \
351 __end_once = .; \
352 STRUCT_ALIGN(); \
353 *(__tracepoints) \
354 /* implement dynamic printk debug */ \
355 . = ALIGN(8); \
356 __start___dyndbg = .; \
357 KEEP(*(__dyndbg)) \
358 __stop___dyndbg = .; \
359 LIKELY_PROFILE() \
360 BRANCH_PROFILE() \
361 TRACE_PRINTKS() \
362 BPF_RAW_TP() \
363 TRACEPOINT_STR()
364
365/*
366 * Data section helpers
367 */
368#define NOSAVE_DATA \
369 . = ALIGN(PAGE_SIZE); \
370 __nosave_begin = .; \
371 *(.data..nosave) \
372 . = ALIGN(PAGE_SIZE); \
373 __nosave_end = .;
374
375#define PAGE_ALIGNED_DATA(page_align) \
376 . = ALIGN(page_align); \
377 *(.data..page_aligned) \
378 . = ALIGN(page_align);
379
380#define READ_MOSTLY_DATA(align) \
381 . = ALIGN(align); \
382 *(.data..read_mostly) \
383 . = ALIGN(align);
384
385#define CACHELINE_ALIGNED_DATA(align) \
386 . = ALIGN(align); \
387 *(.data..cacheline_aligned)
388
389#define INIT_TASK_DATA(align) \
390 . = ALIGN(align); \
391 __start_init_task = .; \
392 init_thread_union = .; \
393 init_stack = .; \
394 KEEP(*(.data..init_task)) \
395 KEEP(*(.data..init_thread_info)) \
396 . = __start_init_task + THREAD_SIZE; \
397 __end_init_task = .;
398
399#define JUMP_TABLE_DATA \
400 . = ALIGN(8); \
401 __start___jump_table = .; \
402 KEEP(*(__jump_table)) \
403 __stop___jump_table = .;
404
405#define STATIC_CALL_DATA \
406 . = ALIGN(8); \
407 __start_static_call_sites = .; \
408 KEEP(*(.static_call_sites)) \
409 __stop_static_call_sites = .; \
410 __start_static_call_tramp_key = .; \
411 KEEP(*(.static_call_tramp_key)) \
412 __stop_static_call_tramp_key = .;
413
414/*
415 * Allow architectures to handle ro_after_init data on their
416 * own by defining an empty RO_AFTER_INIT_DATA.
417 */
418#ifndef RO_AFTER_INIT_DATA
419#define RO_AFTER_INIT_DATA \
420 . = ALIGN(8); \
421 __start_ro_after_init = .; \
422 *(.data..ro_after_init) \
423 JUMP_TABLE_DATA \
424 STATIC_CALL_DATA \
425 __end_ro_after_init = .;
426#endif
427
428/*
429 * Read only Data
430 */
431#define RO_DATA(align) \
432 . = ALIGN((align)); \
433 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
434 __start_rodata = .; \
435 *(.rodata) *(.rodata.*) \
436 SCHED_DATA \
437 RO_AFTER_INIT_DATA /* Read only after init */ \
438 . = ALIGN(8); \
439 __start___tracepoints_ptrs = .; \
440 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
441 __stop___tracepoints_ptrs = .; \
442 *(__tracepoints_strings)/* Tracepoints: strings */ \
443 } \
444 \
445 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
446 *(.rodata1) \
447 } \
448 \
449 /* PCI quirks */ \
450 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
451 __start_pci_fixups_early = .; \
452 KEEP(*(.pci_fixup_early)) \
453 __end_pci_fixups_early = .; \
454 __start_pci_fixups_header = .; \
455 KEEP(*(.pci_fixup_header)) \
456 __end_pci_fixups_header = .; \
457 __start_pci_fixups_final = .; \
458 KEEP(*(.pci_fixup_final)) \
459 __end_pci_fixups_final = .; \
460 __start_pci_fixups_enable = .; \
461 KEEP(*(.pci_fixup_enable)) \
462 __end_pci_fixups_enable = .; \
463 __start_pci_fixups_resume = .; \
464 KEEP(*(.pci_fixup_resume)) \
465 __end_pci_fixups_resume = .; \
466 __start_pci_fixups_resume_early = .; \
467 KEEP(*(.pci_fixup_resume_early)) \
468 __end_pci_fixups_resume_early = .; \
469 __start_pci_fixups_suspend = .; \
470 KEEP(*(.pci_fixup_suspend)) \
471 __end_pci_fixups_suspend = .; \
472 __start_pci_fixups_suspend_late = .; \
473 KEEP(*(.pci_fixup_suspend_late)) \
474 __end_pci_fixups_suspend_late = .; \
475 } \
476 \
477 /* Built-in firmware blobs */ \
478 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
479 __start_builtin_fw = .; \
480 KEEP(*(.builtin_fw)) \
481 __end_builtin_fw = .; \
482 } \
483 \
484 TRACEDATA \
485 \
486 /* Kernel symbol table: Normal symbols */ \
487 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
488 __start___ksymtab = .; \
489 KEEP(*(SORT(___ksymtab+*))) \
490 __stop___ksymtab = .; \
491 } \
492 \
493 /* Kernel symbol table: GPL-only symbols */ \
494 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
495 __start___ksymtab_gpl = .; \
496 KEEP(*(SORT(___ksymtab_gpl+*))) \
497 __stop___ksymtab_gpl = .; \
498 } \
499 \
500 /* Kernel symbol table: Normal symbols */ \
501 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
502 __start___kcrctab = .; \
503 KEEP(*(SORT(___kcrctab+*))) \
504 __stop___kcrctab = .; \
505 } \
506 \
507 /* Kernel symbol table: GPL-only symbols */ \
508 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
509 __start___kcrctab_gpl = .; \
510 KEEP(*(SORT(___kcrctab_gpl+*))) \
511 __stop___kcrctab_gpl = .; \
512 } \
513 \
514 /* Kernel symbol table: strings */ \
515 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
516 *(__ksymtab_strings) \
517 } \
518 \
519 /* __*init sections */ \
520 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
521 *(.ref.rodata) \
522 MEM_KEEP(init.rodata) \
523 MEM_KEEP(exit.rodata) \
524 } \
525 \
526 /* Built-in module parameters. */ \
527 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
528 __start___param = .; \
529 KEEP(*(__param)) \
530 __stop___param = .; \
531 } \
532 \
533 /* Built-in module versions. */ \
534 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
535 __start___modver = .; \
536 KEEP(*(__modver)) \
537 __stop___modver = .; \
538 } \
539 \
540 RO_EXCEPTION_TABLE \
541 NOTES \
542 BTF \
543 \
544 . = ALIGN((align)); \
545 __end_rodata = .;
546
547
548/*
549 * .text..L.cfi.jumptable.* contain Control-Flow Integrity (CFI)
550 * jump table entries.
551 */
552#ifdef CONFIG_CFI_CLANG
553#define TEXT_CFI_JT \
554 . = ALIGN(PMD_SIZE); \
555 __cfi_jt_start = .; \
556 *(.text..L.cfi.jumptable .text..L.cfi.jumptable.*) \
557 . = ALIGN(PMD_SIZE); \
558 __cfi_jt_end = .;
559#else
560#define TEXT_CFI_JT
561#endif
562
563/*
564 * Non-instrumentable text section
565 */
566#define NOINSTR_TEXT \
567 ALIGN_FUNCTION(); \
568 __noinstr_text_start = .; \
569 *(.noinstr.text) \
570 __noinstr_text_end = .;
571
572/*
573 * .text section. Map to function alignment to avoid address changes
574 * during second ld run in second ld pass when generating System.map
575 *
576 * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
577 * code elimination is enabled, so these sections should be converted
578 * to use ".." first.
579 */
580#define TEXT_TEXT \
581 ALIGN_FUNCTION(); \
582 *(.text.hot .text.hot.*) \
583 *(TEXT_MAIN .text.fixup) \
584 *(.text.unlikely .text.unlikely.*) \
585 *(.text.unknown .text.unknown.*) \
586 NOINSTR_TEXT \
587 *(.text..refcount) \
588 *(.ref.text) \
589 *(.text.asan.* .text.tsan.*) \
590 TEXT_CFI_JT \
591 MEM_KEEP(init.text*) \
592 MEM_KEEP(exit.text*) \
593
594
595/* sched.text is aling to function alignment to secure we have same
596 * address even at second ld pass when generating System.map */
597#define SCHED_TEXT \
598 ALIGN_FUNCTION(); \
599 __sched_text_start = .; \
600 *(.sched.text) \
601 __sched_text_end = .;
602
603/* spinlock.text is aling to function alignment to secure we have same
604 * address even at second ld pass when generating System.map */
605#define LOCK_TEXT \
606 ALIGN_FUNCTION(); \
607 __lock_text_start = .; \
608 *(.spinlock.text) \
609 __lock_text_end = .;
610
611#define CPUIDLE_TEXT \
612 ALIGN_FUNCTION(); \
613 __cpuidle_text_start = .; \
614 *(.cpuidle.text) \
615 __cpuidle_text_end = .;
616
617#define KPROBES_TEXT \
618 ALIGN_FUNCTION(); \
619 __kprobes_text_start = .; \
620 *(.kprobes.text) \
621 __kprobes_text_end = .;
622
623#define ENTRY_TEXT \
624 ALIGN_FUNCTION(); \
625 __entry_text_start = .; \
626 *(.entry.text) \
627 __entry_text_end = .;
628
629#define IRQENTRY_TEXT \
630 ALIGN_FUNCTION(); \
631 __irqentry_text_start = .; \
632 *(.irqentry.text) \
633 __irqentry_text_end = .;
634
635#define SOFTIRQENTRY_TEXT \
636 ALIGN_FUNCTION(); \
637 __softirqentry_text_start = .; \
638 *(.softirqentry.text) \
639 __softirqentry_text_end = .;
640
641#define STATIC_CALL_TEXT \
642 ALIGN_FUNCTION(); \
643 __static_call_text_start = .; \
644 *(.static_call.text) \
645 __static_call_text_end = .;
646
647/* Section used for early init (in .S files) */
648#define HEAD_TEXT KEEP(*(.head.text))
649
650#define HEAD_TEXT_SECTION \
651 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
652 HEAD_TEXT \
653 }
654
655/*
656 * Exception table
657 */
658#define EXCEPTION_TABLE(align) \
659 . = ALIGN(align); \
660 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
661 __start___ex_table = .; \
662 KEEP(*(__ex_table)) \
663 __stop___ex_table = .; \
664 }
665
666/*
667 * .BTF
668 */
669#ifdef CONFIG_DEBUG_INFO_BTF
670#define BTF \
671 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
672 __start_BTF = .; \
673 KEEP(*(.BTF)) \
674 __stop_BTF = .; \
675 } \
676 . = ALIGN(4); \
677 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
678 *(.BTF_ids) \
679 }
680#else
681#define BTF
682#endif
683
684/*
685 * Init task
686 */
687#define INIT_TASK_DATA_SECTION(align) \
688 . = ALIGN(align); \
689 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
690 INIT_TASK_DATA(align) \
691 }
692
693#ifdef CONFIG_CONSTRUCTORS
694#define KERNEL_CTORS() . = ALIGN(8); \
695 __ctors_start = .; \
696 KEEP(*(SORT(.ctors.*))) \
697 KEEP(*(.ctors)) \
698 KEEP(*(SORT(.init_array.*))) \
699 KEEP(*(.init_array)) \
700 __ctors_end = .;
701#else
702#define KERNEL_CTORS()
703#endif
704
705/* init and exit section handling */
706#define INIT_DATA \
707 KEEP(*(SORT(___kentry+*))) \
708 *(.init.data init.data.*) \
709 MEM_DISCARD(init.data*) \
710 KERNEL_CTORS() \
711 MCOUNT_REC() \
712 *(.init.rodata .init.rodata.*) \
713 FTRACE_EVENTS() \
714 TRACE_SYSCALLS() \
715 KPROBE_BLACKLIST() \
716 ERROR_INJECT_WHITELIST() \
717 MEM_DISCARD(init.rodata) \
718 CLK_OF_TABLES() \
719 RESERVEDMEM_OF_TABLES() \
720 TIMER_OF_TABLES() \
721 CPU_METHOD_OF_TABLES() \
722 CPUIDLE_METHOD_OF_TABLES() \
723 KERNEL_DTB() \
724 IRQCHIP_OF_MATCH_TABLE() \
725 ACPI_PROBE_TABLE(irqchip) \
726 ACPI_PROBE_TABLE(timer) \
727 THERMAL_TABLE(governor) \
728 DTPM_TABLE() \
729 EARLYCON_TABLE() \
730 LSM_TABLE() \
731 EARLY_LSM_TABLE() \
732 KUNIT_TABLE()
733
734#define INIT_TEXT \
735 *(.init.text .init.text.*) \
736 *(.text.startup) \
737 MEM_DISCARD(init.text*)
738
739#define EXIT_DATA \
740 *(.exit.data .exit.data.*) \
741 *(.fini_array .fini_array.*) \
742 *(.dtors .dtors.*) \
743 MEM_DISCARD(exit.data*) \
744 MEM_DISCARD(exit.rodata*)
745
746#define EXIT_TEXT \
747 *(.exit.text) \
748 *(.text.exit) \
749 MEM_DISCARD(exit.text)
750
751#define EXIT_CALL \
752 *(.exitcall.exit)
753
754/*
755 * bss (Block Started by Symbol) - uninitialized data
756 * zeroed during startup
757 */
758#define SBSS(sbss_align) \
759 . = ALIGN(sbss_align); \
760 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
761 *(.dynsbss) \
762 *(SBSS_MAIN) \
763 *(.scommon) \
764 }
765
766/*
767 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
768 * sections to the front of bss.
769 */
770#ifndef BSS_FIRST_SECTIONS
771#define BSS_FIRST_SECTIONS
772#endif
773
774#define BSS(bss_align) \
775 . = ALIGN(bss_align); \
776 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
777 BSS_FIRST_SECTIONS \
778 . = ALIGN(PAGE_SIZE); \
779 *(.bss..page_aligned) \
780 . = ALIGN(PAGE_SIZE); \
781 *(.dynbss) \
782 *(BSS_MAIN) \
783 *(COMMON) \
784 }
785
786/*
787 * DWARF debug sections.
788 * Symbols in the DWARF debugging sections are relative to
789 * the beginning of the section so we begin them at 0.
790 */
791#define DWARF_DEBUG \
792 /* DWARF 1 */ \
793 .debug 0 : { *(.debug) } \
794 .line 0 : { *(.line) } \
795 /* GNU DWARF 1 extensions */ \
796 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
797 .debug_sfnames 0 : { *(.debug_sfnames) } \
798 /* DWARF 1.1 and DWARF 2 */ \
799 .debug_aranges 0 : { *(.debug_aranges) } \
800 .debug_pubnames 0 : { *(.debug_pubnames) } \
801 /* DWARF 2 */ \
802 .debug_info 0 : { *(.debug_info \
803 .gnu.linkonce.wi.*) } \
804 .debug_abbrev 0 : { *(.debug_abbrev) } \
805 .debug_line 0 : { *(.debug_line) } \
806 .debug_frame 0 : { *(.debug_frame) } \
807 .debug_str 0 : { *(.debug_str) } \
808 .debug_loc 0 : { *(.debug_loc) } \
809 .debug_macinfo 0 : { *(.debug_macinfo) } \
810 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
811 /* DWARF 3 */ \
812 .debug_ranges 0 : { *(.debug_ranges) } \
813 /* SGI/MIPS DWARF 2 extensions */ \
814 .debug_weaknames 0 : { *(.debug_weaknames) } \
815 .debug_funcnames 0 : { *(.debug_funcnames) } \
816 .debug_typenames 0 : { *(.debug_typenames) } \
817 .debug_varnames 0 : { *(.debug_varnames) } \
818 /* GNU DWARF 2 extensions */ \
819 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
820 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
821 /* DWARF 4 */ \
822 .debug_types 0 : { *(.debug_types) } \
823 /* DWARF 5 */ \
824 .debug_addr 0 : { *(.debug_addr) } \
825 .debug_line_str 0 : { *(.debug_line_str) } \
826 .debug_loclists 0 : { *(.debug_loclists) } \
827 .debug_macro 0 : { *(.debug_macro) } \
828 .debug_names 0 : { *(.debug_names) } \
829 .debug_rnglists 0 : { *(.debug_rnglists) } \
830 .debug_str_offsets 0 : { *(.debug_str_offsets) }
831
832/* Stabs debugging sections. */
833#define STABS_DEBUG \
834 .stab 0 : { *(.stab) } \
835 .stabstr 0 : { *(.stabstr) } \
836 .stab.excl 0 : { *(.stab.excl) } \
837 .stab.exclstr 0 : { *(.stab.exclstr) } \
838 .stab.index 0 : { *(.stab.index) } \
839 .stab.indexstr 0 : { *(.stab.indexstr) }
840
841/* Required sections not related to debugging. */
842#define ELF_DETAILS \
843 .comment 0 : { *(.comment) } \
844 .symtab 0 : { *(.symtab) } \
845 .strtab 0 : { *(.strtab) } \
846 .shstrtab 0 : { *(.shstrtab) }
847
848#ifdef CONFIG_GENERIC_BUG
849#define BUG_TABLE \
850 . = ALIGN(8); \
851 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
852 __start___bug_table = .; \
853 KEEP(*(__bug_table)) \
854 __stop___bug_table = .; \
855 }
856#else
857#define BUG_TABLE
858#endif
859
860#ifdef CONFIG_UNWINDER_ORC
861#define ORC_UNWIND_TABLE \
862 . = ALIGN(4); \
863 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
864 __start_orc_unwind_ip = .; \
865 KEEP(*(.orc_unwind_ip)) \
866 __stop_orc_unwind_ip = .; \
867 } \
868 . = ALIGN(2); \
869 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
870 __start_orc_unwind = .; \
871 KEEP(*(.orc_unwind)) \
872 __stop_orc_unwind = .; \
873 } \
874 . = ALIGN(4); \
875 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
876 orc_lookup = .; \
877 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) / \
878 LOOKUP_BLOCK_SIZE) + 1) * 4; \
879 orc_lookup_end = .; \
880 }
881#else
882#define ORC_UNWIND_TABLE
883#endif
884
885#ifdef CONFIG_PM_TRACE
886#define TRACEDATA \
887 . = ALIGN(4); \
888 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
889 __tracedata_start = .; \
890 KEEP(*(.tracedata)) \
891 __tracedata_end = .; \
892 }
893#else
894#define TRACEDATA
895#endif
896
897#define NOTES \
898 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
899 __start_notes = .; \
900 KEEP(*(.note.*)) \
901 __stop_notes = .; \
902 } NOTES_HEADERS \
903 NOTES_HEADERS_RESTORE
904
905#define INIT_SETUP(initsetup_align) \
906 . = ALIGN(initsetup_align); \
907 __setup_start = .; \
908 KEEP(*(.init.setup)) \
909 __setup_end = .;
910
911#define INIT_CALLS_LEVEL(level) \
912 __initcall##level##_start = .; \
913 KEEP(*(.initcall##level##.init)) \
914 KEEP(*(.initcall##level##s.init)) \
915
916#define INIT_CALLS \
917 __initcall_start = .; \
918 KEEP(*(.initcallearly.init)) \
919 INIT_CALLS_LEVEL(0) \
920 INIT_CALLS_LEVEL(1) \
921 INIT_CALLS_LEVEL(2) \
922 INIT_CALLS_LEVEL(3) \
923 INIT_CALLS_LEVEL(4) \
924 INIT_CALLS_LEVEL(5) \
925 INIT_CALLS_LEVEL(rootfs) \
926 INIT_CALLS_LEVEL(6) \
927 INIT_CALLS_LEVEL(7) \
928 __initcall_end = .;
929
930#define CON_INITCALL \
931 __con_initcall_start = .; \
932 KEEP(*(.con_initcall.init)) \
933 __con_initcall_end = .;
934
935/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
936#define KUNIT_TABLE() \
937 . = ALIGN(8); \
938 __kunit_suites_start = .; \
939 KEEP(*(.kunit_test_suites)) \
940 __kunit_suites_end = .;
941
942#ifdef CONFIG_BLK_DEV_INITRD
943#define INIT_RAM_FS \
944 . = ALIGN(4); \
945 __initramfs_start = .; \
946 KEEP(*(.init.ramfs)) \
947 . = ALIGN(8); \
948 KEEP(*(.init.ramfs.info))
949#else
950#define INIT_RAM_FS
951#endif
952
953/*
954 * Memory encryption operates on a page basis. Since we need to clear
955 * the memory encryption mask for this section, it needs to be aligned
956 * on a page boundary and be a page-size multiple in length.
957 *
958 * Note: We use a separate section so that only this section gets
959 * decrypted to avoid exposing more than we wish.
960 */
961#ifdef CONFIG_AMD_MEM_ENCRYPT
962#define PERCPU_DECRYPTED_SECTION \
963 . = ALIGN(PAGE_SIZE); \
964 *(.data..decrypted) \
965 *(.data..percpu..decrypted) \
966 . = ALIGN(PAGE_SIZE);
967#else
968#define PERCPU_DECRYPTED_SECTION
969#endif
970
971
972/*
973 * Default discarded sections.
974 *
975 * Some archs want to discard exit text/data at runtime rather than
976 * link time due to cross-section references such as alt instructions,
977 * bug table, eh_frame, etc. DISCARDS must be the last of output
978 * section definitions so that such archs put those in earlier section
979 * definitions.
980 */
981#ifdef RUNTIME_DISCARD_EXIT
982#define EXIT_DISCARDS
983#else
984#define EXIT_DISCARDS \
985 EXIT_TEXT \
986 EXIT_DATA
987#endif
988
989/*
990 * Clang's -fprofile-arcs, -fsanitize=kernel-address, and
991 * -fsanitize=thread produce unwanted sections (.eh_frame
992 * and .init_array.*), but CONFIG_CONSTRUCTORS wants to
993 * keep any .init_array.* sections.
994 * https://bugs.llvm.org/show_bug.cgi?id=46478
995 */
996#if defined(CONFIG_GCOV_KERNEL) || defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN) || \
997 defined(CONFIG_CFI_CLANG)
998# ifdef CONFIG_CONSTRUCTORS
999# define SANITIZER_DISCARDS \
1000 *(.eh_frame)
1001# else
1002# define SANITIZER_DISCARDS \
1003 *(.init_array) *(.init_array.*) \
1004 *(.eh_frame)
1005# endif
1006#else
1007# define SANITIZER_DISCARDS
1008#endif
1009
1010#define COMMON_DISCARDS \
1011 SANITIZER_DISCARDS \
1012 *(.discard) \
1013 *(.discard.*) \
1014 *(.modinfo) \
1015 /* ld.bfd warns about .gnu.version* even when not emitted */ \
1016 *(.gnu.version*) \
1017
1018#define DISCARDS \
1019 /DISCARD/ : { \
1020 EXIT_DISCARDS \
1021 EXIT_CALL \
1022 COMMON_DISCARDS \
1023 }
1024
1025/**
1026 * PERCPU_INPUT - the percpu input sections
1027 * @cacheline: cacheline size
1028 *
1029 * The core percpu section names and core symbols which do not rely
1030 * directly upon load addresses.
1031 *
1032 * @cacheline is used to align subsections to avoid false cacheline
1033 * sharing between subsections for different purposes.
1034 */
1035#define PERCPU_INPUT(cacheline) \
1036 __per_cpu_start = .; \
1037 *(.data..percpu..first) \
1038 . = ALIGN(PAGE_SIZE); \
1039 *(.data..percpu..page_aligned) \
1040 . = ALIGN(cacheline); \
1041 *(.data..percpu..read_mostly) \
1042 . = ALIGN(cacheline); \
1043 *(.data..percpu) \
1044 *(.data..percpu..shared_aligned) \
1045 PERCPU_DECRYPTED_SECTION \
1046 __per_cpu_end = .;
1047
1048/**
1049 * PERCPU_VADDR - define output section for percpu area
1050 * @cacheline: cacheline size
1051 * @vaddr: explicit base address (optional)
1052 * @phdr: destination PHDR (optional)
1053 *
1054 * Macro which expands to output section for percpu area.
1055 *
1056 * @cacheline is used to align subsections to avoid false cacheline
1057 * sharing between subsections for different purposes.
1058 *
1059 * If @vaddr is not blank, it specifies explicit base address and all
1060 * percpu symbols will be offset from the given address. If blank,
1061 * @vaddr always equals @laddr + LOAD_OFFSET.
1062 *
1063 * @phdr defines the output PHDR to use if not blank. Be warned that
1064 * output PHDR is sticky. If @phdr is specified, the next output
1065 * section in the linker script will go there too. @phdr should have
1066 * a leading colon.
1067 *
1068 * Note that this macros defines __per_cpu_load as an absolute symbol.
1069 * If there is no need to put the percpu section at a predetermined
1070 * address, use PERCPU_SECTION.
1071 */
1072#define PERCPU_VADDR(cacheline, vaddr, phdr) \
1073 __per_cpu_load = .; \
1074 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1075 PERCPU_INPUT(cacheline) \
1076 } phdr \
1077 . = __per_cpu_load + SIZEOF(.data..percpu);
1078
1079/**
1080 * PERCPU_SECTION - define output section for percpu area, simple version
1081 * @cacheline: cacheline size
1082 *
1083 * Align to PAGE_SIZE and outputs output section for percpu area. This
1084 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1085 * __per_cpu_start will be identical.
1086 *
1087 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1088 * except that __per_cpu_load is defined as a relative symbol against
1089 * .data..percpu which is required for relocatable x86_32 configuration.
1090 */
1091#define PERCPU_SECTION(cacheline) \
1092 . = ALIGN(PAGE_SIZE); \
1093 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1094 __per_cpu_load = .; \
1095 PERCPU_INPUT(cacheline) \
1096 }
1097
1098
1099/*
1100 * Definition of the high level *_SECTION macros
1101 * They will fit only a subset of the architectures
1102 */
1103
1104
1105/*
1106 * Writeable data.
1107 * All sections are combined in a single .data section.
1108 * The sections following CONSTRUCTORS are arranged so their
1109 * typical alignment matches.
1110 * A cacheline is typical/always less than a PAGE_SIZE so
1111 * the sections that has this restriction (or similar)
1112 * is located before the ones requiring PAGE_SIZE alignment.
1113 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1114 * matches the requirement of PAGE_ALIGNED_DATA.
1115 *
1116 * use 0 as page_align if page_aligned data is not used */
1117#define RW_DATA(cacheline, pagealigned, inittask) \
1118 . = ALIGN(PAGE_SIZE); \
1119 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1120 INIT_TASK_DATA(inittask) \
1121 NOSAVE_DATA \
1122 PAGE_ALIGNED_DATA(pagealigned) \
1123 CACHELINE_ALIGNED_DATA(cacheline) \
1124 READ_MOSTLY_DATA(cacheline) \
1125 DATA_DATA \
1126 CONSTRUCTORS \
1127 } \
1128 BUG_TABLE \
1129
1130#define INIT_TEXT_SECTION(inittext_align) \
1131 . = ALIGN(inittext_align); \
1132 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1133 _sinittext = .; \
1134 INIT_TEXT \
1135 _einittext = .; \
1136 }
1137
1138#define INIT_DATA_SECTION(initsetup_align) \
1139 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1140 INIT_DATA \
1141 INIT_SETUP(initsetup_align) \
1142 INIT_CALLS \
1143 CON_INITCALL \
1144 INIT_RAM_FS \
1145 }
1146
1147#define BSS_SECTION(sbss_align, bss_align, stop_align) \
1148 . = ALIGN(sbss_align); \
1149 __bss_start = .; \
1150 SBSS(sbss_align) \
1151 BSS(bss_align) \
1152 . = ALIGN(stop_align); \
1153 __bss_stop = .;