1/*
  2 * arch/s390/kernel/relocate_kernel64.S
  3 *
  4 * (C) Copyright IBM Corp. 2005
  5 *
  6 * Author(s): Rolf Adelsberger,
  7 *	      Heiko Carstens <heiko.carstens@de.ibm.com>
  8 *
  9 */
 10
 11#include <linux/linkage.h>
 12
 13/*
 14 * moves the new kernel to its destination...
 15 * %r2 = pointer to first kimage_entry_t
 16 * %r3 = start address - where to jump to after the job is done...
 17 *
 18 * %r5 will be used as temp. storage
 19 * %r6 holds the destination address
 20 * %r7 = PAGE_SIZE
 21 * %r8 holds the source address
 22 * %r9 = PAGE_SIZE
 23 *
 24 * 0xf000 is a page_mask
 25 */
 26
 27	.text
 28ENTRY(relocate_kernel)
 29		basr	%r13,0		# base address
 30	.base:
 31		stnsm	sys_msk-.base(%r13),0xfb	# disable DAT
 32		stctg	%c0,%c15,ctlregs-.base(%r13)
 33		stmg	%r0,%r15,gprregs-.base(%r13)
 34		lghi	%r0,3
 35		sllg	%r0,%r0,31
 36		stg	%r0,0x1d0(%r0)
 37		la	%r0,.back_pgm-.base(%r13)
 38		stg	%r0,0x1d8(%r0)
 39		la	%r1,load_psw-.base(%r13)
 40		mvc	0(8,%r0),0(%r1)
 41		la	%r0,.back-.base(%r13)
 42		st	%r0,4(%r0)
 43		oi	4(%r0),0x80
 44		lghi	%r0,0
 45		diag	%r0,%r0,0x308
 46	.back:
 47		lhi	%r1,1		# mode 1 = esame
 48		sigp	%r1,%r0,0x12	# switch to esame mode
 49		sam64			# switch to 64 bit addressing mode
 50		basr	%r13,0
 51	.back_base:
 52		oi	have_diag308-.back_base(%r13),0x01
 53		lctlg	%c0,%c15,ctlregs-.back_base(%r13)
 54		lmg	%r0,%r15,gprregs-.back_base(%r13)
 55		j	.top
 56	.back_pgm:
 57		lmg	%r0,%r15,gprregs-.base(%r13)
 58	.top:
 59		lghi	%r7,4096	# load PAGE_SIZE in r7
 60		lghi	%r9,4096	# load PAGE_SIZE in r9
 61		lg	%r5,0(%r2)	# read another word for indirection page
 62		aghi	%r2,8		# increment pointer
 63		tml	%r5,0x1		# is it a destination page?
 64		je	.indir_check	# NO, goto "indir_check"
 65		lgr	%r6,%r5		# r6 = r5
 66		nill	%r6,0xf000	# mask it out and...
 67		j	.top		# ...next iteration
 68	.indir_check:
 69		tml	%r5,0x2		# is it a indirection page?
 70		je	.done_test	# NO, goto "done_test"
 71		nill	%r5,0xf000	# YES, mask out,
 72		lgr	%r2,%r5		# move it into the right register,
 73		j	.top		# and read next...
 74	.done_test:
 75		tml	%r5,0x4		# is it the done indicator?
 76		je	.source_test	# NO! Well, then it should be the source indicator...
 77		j	.done		# ok, lets finish it here...
 78	.source_test:
 79		tml	%r5,0x8		# it should be a source indicator...
 80		je	.top		# NO, ignore it...
 81		lgr	%r8,%r5		# r8 = r5
 82		nill	%r8,0xf000	# masking
 83	0:	mvcle	%r6,%r8,0x0	# copy PAGE_SIZE bytes from r8 to r6 - pad with 0
 84		jo	0b
 85		j	.top
 86	.done:
 87		sgr	%r0,%r0		# clear register r0
 88		la	%r4,load_psw-.base(%r13)	# load psw-address into the register
 89		o	%r3,4(%r4)	# or load address into psw
 90		st	%r3,4(%r4)
 91		mvc	0(8,%r0),0(%r4)	# copy psw to absolute address 0
 92		tm	have_diag308-.base(%r13),0x01
 93		jno	.no_diag308
 94		diag	%r0,%r0,0x308
 95	.no_diag308:
 96		sam31			# 31 bit mode
 97		sr	%r1,%r1		# erase register r1
 98		sr	%r2,%r2		# erase register r2
 99		sigp	%r1,%r2,0x12	# set cpuid to zero
100		lpsw	0		# hopefully start new kernel...
101
102		.align	8
103	load_psw:
104		.long	0x00080000,0x80000000
105	sys_msk:
106		.quad	0
107	ctlregs:
108		.rept	16
109		.quad	0
110		.endr
111	gprregs:
112		.rept	16
113		.quad	0
114		.endr
115	have_diag308:
116		.byte	0
117		.align	8
118	relocate_kernel_end:
119	.align 8
120	.globl	relocate_kernel_len
121	relocate_kernel_len:
122		.quad	relocate_kernel_end - relocate_kernel