Loading...
1%pure-parser
2%parse-param {void *_parse_state}
3%parse-param {void *scanner}
4%lex-param {void* scanner}
5%locations
6
7%{
8
9#define YYDEBUG 1
10
11#include <fnmatch.h>
12#include <stdio.h>
13#include <linux/compiler.h>
14#include <linux/types.h>
15#include "pmu.h"
16#include "evsel.h"
17#include "parse-events.h"
18#include "parse-events-bison.h"
19
20void parse_events_error(YYLTYPE *loc, void *parse_state, void *scanner, char const *msg);
21
22#define ABORT_ON(val) \
23do { \
24 if (val) \
25 YYABORT; \
26} while (0)
27
28#define ALLOC_LIST(list) \
29do { \
30 list = malloc(sizeof(*list)); \
31 ABORT_ON(!list); \
32 INIT_LIST_HEAD(list); \
33} while (0)
34
35static void inc_group_count(struct list_head *list,
36 struct parse_events_state *parse_state)
37{
38 /* Count groups only have more than 1 members */
39 if (!list_is_last(list->next, list))
40 parse_state->nr_groups++;
41}
42
43%}
44
45%token PE_START_EVENTS PE_START_TERMS
46%token PE_VALUE PE_VALUE_SYM_HW PE_VALUE_SYM_SW PE_RAW PE_TERM
47%token PE_VALUE_SYM_TOOL
48%token PE_EVENT_NAME
49%token PE_NAME
50%token PE_BPF_OBJECT PE_BPF_SOURCE
51%token PE_MODIFIER_EVENT PE_MODIFIER_BP
52%token PE_NAME_CACHE_TYPE PE_NAME_CACHE_OP_RESULT
53%token PE_PREFIX_MEM PE_PREFIX_RAW PE_PREFIX_GROUP
54%token PE_ERROR
55%token PE_PMU_EVENT_PRE PE_PMU_EVENT_SUF PE_KERNEL_PMU_EVENT
56%token PE_ARRAY_ALL PE_ARRAY_RANGE
57%token PE_DRV_CFG_TERM
58%type <num> PE_VALUE
59%type <num> PE_VALUE_SYM_HW
60%type <num> PE_VALUE_SYM_SW
61%type <num> PE_VALUE_SYM_TOOL
62%type <num> PE_RAW
63%type <num> PE_TERM
64%type <str> PE_NAME
65%type <str> PE_BPF_OBJECT
66%type <str> PE_BPF_SOURCE
67%type <str> PE_NAME_CACHE_TYPE
68%type <str> PE_NAME_CACHE_OP_RESULT
69%type <str> PE_MODIFIER_EVENT
70%type <str> PE_MODIFIER_BP
71%type <str> PE_EVENT_NAME
72%type <str> PE_PMU_EVENT_PRE PE_PMU_EVENT_SUF PE_KERNEL_PMU_EVENT
73%type <str> PE_DRV_CFG_TERM
74%type <num> value_sym
75%type <head> event_config
76%type <head> opt_event_config
77%type <head> opt_pmu_config
78%type <term> event_term
79%type <head> event_pmu
80%type <head> event_legacy_symbol
81%type <head> event_legacy_cache
82%type <head> event_legacy_mem
83%type <head> event_legacy_tracepoint
84%type <tracepoint_name> tracepoint_name
85%type <head> event_legacy_numeric
86%type <head> event_legacy_raw
87%type <head> event_bpf_file
88%type <head> event_def
89%type <head> event_mod
90%type <head> event_name
91%type <head> event
92%type <head> events
93%type <head> group_def
94%type <head> group
95%type <head> groups
96%type <array> array
97%type <array> array_term
98%type <array> array_terms
99
100%union
101{
102 char *str;
103 u64 num;
104 struct list_head *head;
105 struct parse_events_term *term;
106 struct tracepoint_name {
107 char *sys;
108 char *event;
109 } tracepoint_name;
110 struct parse_events_array array;
111}
112%%
113
114start:
115PE_START_EVENTS start_events
116|
117PE_START_TERMS start_terms
118
119start_events: groups
120{
121 struct parse_events_state *parse_state = _parse_state;
122
123 parse_events_update_lists($1, &parse_state->list);
124}
125
126groups:
127groups ',' group
128{
129 struct list_head *list = $1;
130 struct list_head *group = $3;
131
132 parse_events_update_lists(group, list);
133 $$ = list;
134}
135|
136groups ',' event
137{
138 struct list_head *list = $1;
139 struct list_head *event = $3;
140
141 parse_events_update_lists(event, list);
142 $$ = list;
143}
144|
145group
146|
147event
148
149group:
150group_def ':' PE_MODIFIER_EVENT
151{
152 struct list_head *list = $1;
153
154 ABORT_ON(parse_events__modifier_group(list, $3));
155 $$ = list;
156}
157|
158group_def
159
160group_def:
161PE_NAME '{' events '}'
162{
163 struct list_head *list = $3;
164
165 inc_group_count(list, _parse_state);
166 parse_events__set_leader($1, list, _parse_state);
167 $$ = list;
168}
169|
170'{' events '}'
171{
172 struct list_head *list = $2;
173
174 inc_group_count(list, _parse_state);
175 parse_events__set_leader(NULL, list, _parse_state);
176 $$ = list;
177}
178
179events:
180events ',' event
181{
182 struct list_head *event = $3;
183 struct list_head *list = $1;
184
185 parse_events_update_lists(event, list);
186 $$ = list;
187}
188|
189event
190
191event: event_mod
192
193event_mod:
194event_name PE_MODIFIER_EVENT
195{
196 struct list_head *list = $1;
197
198 /*
199 * Apply modifier on all events added by single event definition
200 * (there could be more events added for multiple tracepoint
201 * definitions via '*?'.
202 */
203 ABORT_ON(parse_events__modifier_event(list, $2, false));
204 $$ = list;
205}
206|
207event_name
208
209event_name:
210PE_EVENT_NAME event_def
211{
212 ABORT_ON(parse_events_name($2, $1));
213 free($1);
214 $$ = $2;
215}
216|
217event_def
218
219event_def: event_pmu |
220 event_legacy_symbol |
221 event_legacy_cache sep_dc |
222 event_legacy_mem |
223 event_legacy_tracepoint sep_dc |
224 event_legacy_numeric sep_dc |
225 event_legacy_raw sep_dc |
226 event_bpf_file
227
228event_pmu:
229PE_NAME opt_pmu_config
230{
231 struct parse_events_state *parse_state = _parse_state;
232 struct parse_events_error *error = parse_state->error;
233 struct list_head *list, *orig_terms, *terms;
234
235 if (parse_events_copy_term_list($2, &orig_terms))
236 YYABORT;
237
238 if (error)
239 error->idx = @1.first_column;
240
241 ALLOC_LIST(list);
242 if (parse_events_add_pmu(_parse_state, list, $1, $2, false, false)) {
243 struct perf_pmu *pmu = NULL;
244 int ok = 0;
245 char *pattern;
246
247 if (asprintf(&pattern, "%s*", $1) < 0)
248 YYABORT;
249
250 while ((pmu = perf_pmu__scan(pmu)) != NULL) {
251 char *name = pmu->name;
252
253 if (!strncmp(name, "uncore_", 7) &&
254 strncmp($1, "uncore_", 7))
255 name += 7;
256 if (!fnmatch(pattern, name, 0)) {
257 if (parse_events_copy_term_list(orig_terms, &terms)) {
258 free(pattern);
259 YYABORT;
260 }
261 if (!parse_events_add_pmu(_parse_state, list, pmu->name, terms, true, false))
262 ok++;
263 parse_events_terms__delete(terms);
264 }
265 }
266
267 free(pattern);
268
269 if (!ok)
270 YYABORT;
271 }
272 parse_events_terms__delete($2);
273 parse_events_terms__delete(orig_terms);
274 $$ = list;
275}
276|
277PE_KERNEL_PMU_EVENT sep_dc
278{
279 struct list_head *list;
280
281 if (parse_events_multi_pmu_add(_parse_state, $1, &list) < 0)
282 YYABORT;
283 $$ = list;
284}
285|
286PE_PMU_EVENT_PRE '-' PE_PMU_EVENT_SUF sep_dc
287{
288 struct list_head *list;
289 char pmu_name[128];
290
291 snprintf(&pmu_name, 128, "%s-%s", $1, $3);
292 if (parse_events_multi_pmu_add(_parse_state, pmu_name, &list) < 0)
293 YYABORT;
294 $$ = list;
295}
296
297value_sym:
298PE_VALUE_SYM_HW
299|
300PE_VALUE_SYM_SW
301
302event_legacy_symbol:
303value_sym '/' event_config '/'
304{
305 struct list_head *list;
306 int type = $1 >> 16;
307 int config = $1 & 255;
308
309 ALLOC_LIST(list);
310 ABORT_ON(parse_events_add_numeric(_parse_state, list, type, config, $3));
311 parse_events_terms__delete($3);
312 $$ = list;
313}
314|
315value_sym sep_slash_slash_dc
316{
317 struct list_head *list;
318 int type = $1 >> 16;
319 int config = $1 & 255;
320
321 ALLOC_LIST(list);
322 ABORT_ON(parse_events_add_numeric(_parse_state, list, type, config, NULL));
323 $$ = list;
324}
325|
326PE_VALUE_SYM_TOOL sep_slash_slash_dc
327{
328 struct list_head *list;
329
330 ALLOC_LIST(list);
331 ABORT_ON(parse_events_add_tool(_parse_state, list, $1));
332 $$ = list;
333}
334
335event_legacy_cache:
336PE_NAME_CACHE_TYPE '-' PE_NAME_CACHE_OP_RESULT '-' PE_NAME_CACHE_OP_RESULT opt_event_config
337{
338 struct parse_events_state *parse_state = _parse_state;
339 struct parse_events_error *error = parse_state->error;
340 struct list_head *list;
341
342 ALLOC_LIST(list);
343 ABORT_ON(parse_events_add_cache(list, &parse_state->idx, $1, $3, $5, error, $6));
344 parse_events_terms__delete($6);
345 $$ = list;
346}
347|
348PE_NAME_CACHE_TYPE '-' PE_NAME_CACHE_OP_RESULT opt_event_config
349{
350 struct parse_events_state *parse_state = _parse_state;
351 struct parse_events_error *error = parse_state->error;
352 struct list_head *list;
353
354 ALLOC_LIST(list);
355 ABORT_ON(parse_events_add_cache(list, &parse_state->idx, $1, $3, NULL, error, $4));
356 parse_events_terms__delete($4);
357 $$ = list;
358}
359|
360PE_NAME_CACHE_TYPE opt_event_config
361{
362 struct parse_events_state *parse_state = _parse_state;
363 struct parse_events_error *error = parse_state->error;
364 struct list_head *list;
365
366 ALLOC_LIST(list);
367 ABORT_ON(parse_events_add_cache(list, &parse_state->idx, $1, NULL, NULL, error, $2));
368 parse_events_terms__delete($2);
369 $$ = list;
370}
371
372event_legacy_mem:
373PE_PREFIX_MEM PE_VALUE '/' PE_VALUE ':' PE_MODIFIER_BP sep_dc
374{
375 struct parse_events_state *parse_state = _parse_state;
376 struct list_head *list;
377
378 ALLOC_LIST(list);
379 ABORT_ON(parse_events_add_breakpoint(list, &parse_state->idx,
380 (void *) $2, $6, $4));
381 $$ = list;
382}
383|
384PE_PREFIX_MEM PE_VALUE '/' PE_VALUE sep_dc
385{
386 struct parse_events_state *parse_state = _parse_state;
387 struct list_head *list;
388
389 ALLOC_LIST(list);
390 ABORT_ON(parse_events_add_breakpoint(list, &parse_state->idx,
391 (void *) $2, NULL, $4));
392 $$ = list;
393}
394|
395PE_PREFIX_MEM PE_VALUE ':' PE_MODIFIER_BP sep_dc
396{
397 struct parse_events_state *parse_state = _parse_state;
398 struct list_head *list;
399
400 ALLOC_LIST(list);
401 ABORT_ON(parse_events_add_breakpoint(list, &parse_state->idx,
402 (void *) $2, $4, 0));
403 $$ = list;
404}
405|
406PE_PREFIX_MEM PE_VALUE sep_dc
407{
408 struct parse_events_state *parse_state = _parse_state;
409 struct list_head *list;
410
411 ALLOC_LIST(list);
412 ABORT_ON(parse_events_add_breakpoint(list, &parse_state->idx,
413 (void *) $2, NULL, 0));
414 $$ = list;
415}
416
417event_legacy_tracepoint:
418tracepoint_name opt_event_config
419{
420 struct parse_events_state *parse_state = _parse_state;
421 struct parse_events_error *error = parse_state->error;
422 struct list_head *list;
423
424 ALLOC_LIST(list);
425 if (error)
426 error->idx = @1.first_column;
427
428 if (parse_events_add_tracepoint(list, &parse_state->idx, $1.sys, $1.event,
429 error, $2))
430 return -1;
431
432 $$ = list;
433}
434
435tracepoint_name:
436PE_NAME '-' PE_NAME ':' PE_NAME
437{
438 char sys_name[128];
439 struct tracepoint_name tracepoint;
440
441 snprintf(&sys_name, 128, "%s-%s", $1, $3);
442 tracepoint.sys = &sys_name;
443 tracepoint.event = $5;
444
445 $$ = tracepoint;
446}
447|
448PE_NAME ':' PE_NAME
449{
450 struct tracepoint_name tracepoint = {$1, $3};
451
452 $$ = tracepoint;
453}
454
455event_legacy_numeric:
456PE_VALUE ':' PE_VALUE opt_event_config
457{
458 struct list_head *list;
459
460 ALLOC_LIST(list);
461 ABORT_ON(parse_events_add_numeric(_parse_state, list, (u32)$1, $3, $4));
462 parse_events_terms__delete($4);
463 $$ = list;
464}
465
466event_legacy_raw:
467PE_RAW opt_event_config
468{
469 struct list_head *list;
470
471 ALLOC_LIST(list);
472 ABORT_ON(parse_events_add_numeric(_parse_state, list, PERF_TYPE_RAW, $1, $2));
473 parse_events_terms__delete($2);
474 $$ = list;
475}
476
477event_bpf_file:
478PE_BPF_OBJECT opt_event_config
479{
480 struct parse_events_state *parse_state = _parse_state;
481 struct list_head *list;
482
483 ALLOC_LIST(list);
484 ABORT_ON(parse_events_load_bpf(parse_state, list, $1, false, $2));
485 parse_events_terms__delete($2);
486 $$ = list;
487}
488|
489PE_BPF_SOURCE opt_event_config
490{
491 struct list_head *list;
492
493 ALLOC_LIST(list);
494 ABORT_ON(parse_events_load_bpf(_parse_state, list, $1, true, $2));
495 parse_events_terms__delete($2);
496 $$ = list;
497}
498
499opt_event_config:
500'/' event_config '/'
501{
502 $$ = $2;
503}
504|
505'/' '/'
506{
507 $$ = NULL;
508}
509|
510{
511 $$ = NULL;
512}
513
514opt_pmu_config:
515'/' event_config '/'
516{
517 $$ = $2;
518}
519|
520'/' '/'
521{
522 $$ = NULL;
523}
524
525start_terms: event_config
526{
527 struct parse_events_state *parse_state = _parse_state;
528 parse_state->terms = $1;
529}
530
531event_config:
532event_config ',' event_term
533{
534 struct list_head *head = $1;
535 struct parse_events_term *term = $3;
536
537 ABORT_ON(!head);
538 list_add_tail(&term->list, head);
539 $$ = $1;
540}
541|
542event_term
543{
544 struct list_head *head = malloc(sizeof(*head));
545 struct parse_events_term *term = $1;
546
547 ABORT_ON(!head);
548 INIT_LIST_HEAD(head);
549 list_add_tail(&term->list, head);
550 $$ = head;
551}
552
553event_term:
554PE_NAME '=' PE_NAME
555{
556 struct parse_events_term *term;
557
558 ABORT_ON(parse_events_term__str(&term, PARSE_EVENTS__TERM_TYPE_USER,
559 $1, $3, &@1, &@3));
560 $$ = term;
561}
562|
563PE_NAME '=' PE_VALUE
564{
565 struct parse_events_term *term;
566
567 ABORT_ON(parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
568 $1, $3, false, &@1, &@3));
569 $$ = term;
570}
571|
572PE_NAME '=' PE_VALUE_SYM_HW
573{
574 struct parse_events_term *term;
575 int config = $3 & 255;
576
577 ABORT_ON(parse_events_term__sym_hw(&term, $1, config));
578 $$ = term;
579}
580|
581PE_NAME
582{
583 struct parse_events_term *term;
584
585 ABORT_ON(parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
586 $1, 1, true, &@1, NULL));
587 $$ = term;
588}
589|
590PE_VALUE_SYM_HW
591{
592 struct parse_events_term *term;
593 int config = $1 & 255;
594
595 ABORT_ON(parse_events_term__sym_hw(&term, NULL, config));
596 $$ = term;
597}
598|
599PE_TERM '=' PE_NAME
600{
601 struct parse_events_term *term;
602
603 ABORT_ON(parse_events_term__str(&term, (int)$1, NULL, $3, &@1, &@3));
604 $$ = term;
605}
606|
607PE_TERM '=' PE_VALUE
608{
609 struct parse_events_term *term;
610
611 ABORT_ON(parse_events_term__num(&term, (int)$1, NULL, $3, false, &@1, &@3));
612 $$ = term;
613}
614|
615PE_TERM
616{
617 struct parse_events_term *term;
618
619 ABORT_ON(parse_events_term__num(&term, (int)$1, NULL, 1, true, &@1, NULL));
620 $$ = term;
621}
622|
623PE_NAME array '=' PE_NAME
624{
625 struct parse_events_term *term;
626
627 ABORT_ON(parse_events_term__str(&term, PARSE_EVENTS__TERM_TYPE_USER,
628 $1, $4, &@1, &@4));
629
630 term->array = $2;
631 $$ = term;
632}
633|
634PE_NAME array '=' PE_VALUE
635{
636 struct parse_events_term *term;
637
638 ABORT_ON(parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
639 $1, $4, false, &@1, &@4));
640 term->array = $2;
641 $$ = term;
642}
643|
644PE_DRV_CFG_TERM
645{
646 struct parse_events_term *term;
647
648 ABORT_ON(parse_events_term__str(&term, PARSE_EVENTS__TERM_TYPE_DRV_CFG,
649 $1, $1, &@1, NULL));
650 $$ = term;
651}
652
653array:
654'[' array_terms ']'
655{
656 $$ = $2;
657}
658|
659PE_ARRAY_ALL
660{
661 $$.nr_ranges = 0;
662 $$.ranges = NULL;
663}
664
665array_terms:
666array_terms ',' array_term
667{
668 struct parse_events_array new_array;
669
670 new_array.nr_ranges = $1.nr_ranges + $3.nr_ranges;
671 new_array.ranges = malloc(sizeof(new_array.ranges[0]) *
672 new_array.nr_ranges);
673 ABORT_ON(!new_array.ranges);
674 memcpy(&new_array.ranges[0], $1.ranges,
675 $1.nr_ranges * sizeof(new_array.ranges[0]));
676 memcpy(&new_array.ranges[$1.nr_ranges], $3.ranges,
677 $3.nr_ranges * sizeof(new_array.ranges[0]));
678 free($1.ranges);
679 free($3.ranges);
680 $$ = new_array;
681}
682|
683array_term
684
685array_term:
686PE_VALUE
687{
688 struct parse_events_array array;
689
690 array.nr_ranges = 1;
691 array.ranges = malloc(sizeof(array.ranges[0]));
692 ABORT_ON(!array.ranges);
693 array.ranges[0].start = $1;
694 array.ranges[0].length = 1;
695 $$ = array;
696}
697|
698PE_VALUE PE_ARRAY_RANGE PE_VALUE
699{
700 struct parse_events_array array;
701
702 ABORT_ON($3 < $1);
703 array.nr_ranges = 1;
704 array.ranges = malloc(sizeof(array.ranges[0]));
705 ABORT_ON(!array.ranges);
706 array.ranges[0].start = $1;
707 array.ranges[0].length = $3 - $1 + 1;
708 $$ = array;
709}
710
711sep_dc: ':' |
712
713sep_slash_slash_dc: '/' '/' | ':' |
714
715%%
716
717void parse_events_error(YYLTYPE *loc, void *parse_state,
718 void *scanner __maybe_unused,
719 char const *msg __maybe_unused)
720{
721 parse_events_evlist_error(parse_state, loc->last_column, "parser error");
722}
1%define api.pure full
2%parse-param {void *_parse_state}
3%parse-param {void *scanner}
4%lex-param {void* scanner}
5%locations
6
7%{
8
9#define YYDEBUG 1
10
11#include <fnmatch.h>
12#include <stdio.h>
13#include <linux/compiler.h>
14#include <linux/types.h>
15#include <linux/zalloc.h>
16#include "pmu.h"
17#include "evsel.h"
18#include "parse-events.h"
19#include "parse-events-bison.h"
20
21void parse_events_error(YYLTYPE *loc, void *parse_state, void *scanner, char const *msg);
22
23#define ABORT_ON(val) \
24do { \
25 if (val) \
26 YYABORT; \
27} while (0)
28
29static struct list_head* alloc_list(void)
30{
31 struct list_head *list;
32
33 list = malloc(sizeof(*list));
34 if (!list)
35 return NULL;
36
37 INIT_LIST_HEAD(list);
38 return list;
39}
40
41static void free_list_evsel(struct list_head* list_evsel)
42{
43 struct evsel *evsel, *tmp;
44
45 list_for_each_entry_safe(evsel, tmp, list_evsel, core.node) {
46 list_del_init(&evsel->core.node);
47 evsel__delete(evsel);
48 }
49 free(list_evsel);
50}
51
52static void inc_group_count(struct list_head *list,
53 struct parse_events_state *parse_state)
54{
55 /* Count groups only have more than 1 members */
56 if (!list_is_last(list->next, list))
57 parse_state->nr_groups++;
58}
59
60%}
61
62%token PE_START_EVENTS PE_START_TERMS
63%token PE_VALUE PE_VALUE_SYM_HW PE_VALUE_SYM_SW PE_RAW PE_TERM
64%token PE_VALUE_SYM_TOOL
65%token PE_EVENT_NAME
66%token PE_NAME
67%token PE_BPF_OBJECT PE_BPF_SOURCE
68%token PE_MODIFIER_EVENT PE_MODIFIER_BP
69%token PE_NAME_CACHE_TYPE PE_NAME_CACHE_OP_RESULT
70%token PE_PREFIX_MEM PE_PREFIX_RAW PE_PREFIX_GROUP
71%token PE_ERROR
72%token PE_PMU_EVENT_PRE PE_PMU_EVENT_SUF PE_PMU_EVENT_SUF2 PE_KERNEL_PMU_EVENT PE_PMU_EVENT_FAKE
73%token PE_ARRAY_ALL PE_ARRAY_RANGE
74%token PE_DRV_CFG_TERM
75%type <num> PE_VALUE
76%type <num> PE_VALUE_SYM_HW
77%type <num> PE_VALUE_SYM_SW
78%type <num> PE_VALUE_SYM_TOOL
79%type <num> PE_RAW
80%type <num> PE_TERM
81%type <num> value_sym
82%type <str> PE_NAME
83%type <str> PE_BPF_OBJECT
84%type <str> PE_BPF_SOURCE
85%type <str> PE_NAME_CACHE_TYPE
86%type <str> PE_NAME_CACHE_OP_RESULT
87%type <str> PE_MODIFIER_EVENT
88%type <str> PE_MODIFIER_BP
89%type <str> PE_EVENT_NAME
90%type <str> PE_PMU_EVENT_PRE PE_PMU_EVENT_SUF PE_PMU_EVENT_SUF2 PE_KERNEL_PMU_EVENT PE_PMU_EVENT_FAKE
91%type <str> PE_DRV_CFG_TERM
92%type <str> event_pmu_name
93%destructor { free ($$); } <str>
94%type <term> event_term
95%destructor { parse_events_term__delete ($$); } <term>
96%type <list_terms> event_config
97%type <list_terms> opt_event_config
98%type <list_terms> opt_pmu_config
99%destructor { parse_events_terms__delete ($$); } <list_terms>
100%type <list_evsel> event_pmu
101%type <list_evsel> event_legacy_symbol
102%type <list_evsel> event_legacy_cache
103%type <list_evsel> event_legacy_mem
104%type <list_evsel> event_legacy_tracepoint
105%type <list_evsel> event_legacy_numeric
106%type <list_evsel> event_legacy_raw
107%type <list_evsel> event_bpf_file
108%type <list_evsel> event_def
109%type <list_evsel> event_mod
110%type <list_evsel> event_name
111%type <list_evsel> event
112%type <list_evsel> events
113%type <list_evsel> group_def
114%type <list_evsel> group
115%type <list_evsel> groups
116%destructor { free_list_evsel ($$); } <list_evsel>
117%type <tracepoint_name> tracepoint_name
118%destructor { free ($$.sys); free ($$.event); } <tracepoint_name>
119%type <array> array
120%type <array> array_term
121%type <array> array_terms
122%destructor { free ($$.ranges); } <array>
123
124%union
125{
126 char *str;
127 u64 num;
128 struct list_head *list_evsel;
129 struct list_head *list_terms;
130 struct parse_events_term *term;
131 struct tracepoint_name {
132 char *sys;
133 char *event;
134 } tracepoint_name;
135 struct parse_events_array array;
136}
137%%
138
139start:
140PE_START_EVENTS start_events
141|
142PE_START_TERMS start_terms
143
144start_events: groups
145{
146 struct parse_events_state *parse_state = _parse_state;
147
148 /* frees $1 */
149 parse_events_update_lists($1, &parse_state->list);
150}
151
152groups:
153groups ',' group
154{
155 struct list_head *list = $1;
156 struct list_head *group = $3;
157
158 /* frees $3 */
159 parse_events_update_lists(group, list);
160 $$ = list;
161}
162|
163groups ',' event
164{
165 struct list_head *list = $1;
166 struct list_head *event = $3;
167
168 /* frees $3 */
169 parse_events_update_lists(event, list);
170 $$ = list;
171}
172|
173group
174|
175event
176
177group:
178group_def ':' PE_MODIFIER_EVENT
179{
180 struct list_head *list = $1;
181 int err;
182
183 err = parse_events__modifier_group(list, $3);
184 free($3);
185 if (err) {
186 struct parse_events_state *parse_state = _parse_state;
187 struct parse_events_error *error = parse_state->error;
188
189 parse_events_error__handle(error, @3.first_column,
190 strdup("Bad modifier"), NULL);
191 free_list_evsel(list);
192 YYABORT;
193 }
194 $$ = list;
195}
196|
197group_def
198
199group_def:
200PE_NAME '{' events '}'
201{
202 struct list_head *list = $3;
203
204 inc_group_count(list, _parse_state);
205 parse_events__set_leader($1, list, _parse_state);
206 free($1);
207 $$ = list;
208}
209|
210'{' events '}'
211{
212 struct list_head *list = $2;
213
214 inc_group_count(list, _parse_state);
215 parse_events__set_leader(NULL, list, _parse_state);
216 $$ = list;
217}
218
219events:
220events ',' event
221{
222 struct list_head *event = $3;
223 struct list_head *list = $1;
224
225 /* frees $3 */
226 parse_events_update_lists(event, list);
227 $$ = list;
228}
229|
230event
231
232event: event_mod
233
234event_mod:
235event_name PE_MODIFIER_EVENT
236{
237 struct list_head *list = $1;
238 int err;
239
240 /*
241 * Apply modifier on all events added by single event definition
242 * (there could be more events added for multiple tracepoint
243 * definitions via '*?'.
244 */
245 err = parse_events__modifier_event(list, $2, false);
246 free($2);
247 if (err) {
248 struct parse_events_state *parse_state = _parse_state;
249 struct parse_events_error *error = parse_state->error;
250
251 parse_events_error__handle(error, @2.first_column,
252 strdup("Bad modifier"), NULL);
253 free_list_evsel(list);
254 YYABORT;
255 }
256 $$ = list;
257}
258|
259event_name
260
261event_name:
262PE_EVENT_NAME event_def
263{
264 int err;
265
266 err = parse_events_name($2, $1);
267 free($1);
268 if (err) {
269 free_list_evsel($2);
270 YYABORT;
271 }
272 $$ = $2;
273}
274|
275event_def
276
277event_def: event_pmu |
278 event_legacy_symbol |
279 event_legacy_cache sep_dc |
280 event_legacy_mem |
281 event_legacy_tracepoint sep_dc |
282 event_legacy_numeric sep_dc |
283 event_legacy_raw sep_dc |
284 event_bpf_file
285
286event_pmu_name:
287PE_NAME | PE_PMU_EVENT_PRE
288
289event_pmu:
290event_pmu_name opt_pmu_config
291{
292 struct parse_events_state *parse_state = _parse_state;
293 struct parse_events_error *error = parse_state->error;
294 struct list_head *list = NULL, *orig_terms = NULL, *terms= NULL;
295 char *pattern = NULL;
296
297#define CLEANUP_YYABORT \
298 do { \
299 parse_events_terms__delete($2); \
300 parse_events_terms__delete(orig_terms); \
301 free(list); \
302 free($1); \
303 free(pattern); \
304 YYABORT; \
305 } while(0)
306
307 if (parse_events_copy_term_list($2, &orig_terms))
308 CLEANUP_YYABORT;
309
310 if (error)
311 error->idx = @1.first_column;
312
313 list = alloc_list();
314 if (!list)
315 CLEANUP_YYABORT;
316 if (parse_events_add_pmu(_parse_state, list, $1, $2, false, false)) {
317 struct perf_pmu *pmu = NULL;
318 int ok = 0;
319
320 if (asprintf(&pattern, "%s*", $1) < 0)
321 CLEANUP_YYABORT;
322
323 while ((pmu = perf_pmu__scan(pmu)) != NULL) {
324 char *name = pmu->name;
325
326 if (!strncmp(name, "uncore_", 7) &&
327 strncmp($1, "uncore_", 7))
328 name += 7;
329 if (!perf_pmu__match(pattern, name, $1) ||
330 !perf_pmu__match(pattern, pmu->alias_name, $1)) {
331 if (parse_events_copy_term_list(orig_terms, &terms))
332 CLEANUP_YYABORT;
333 if (!parse_events_add_pmu(_parse_state, list, pmu->name, terms, true, false))
334 ok++;
335 parse_events_terms__delete(terms);
336 }
337 }
338
339 if (!ok)
340 CLEANUP_YYABORT;
341 }
342 parse_events_terms__delete($2);
343 parse_events_terms__delete(orig_terms);
344 free(pattern);
345 free($1);
346 $$ = list;
347#undef CLEANUP_YYABORT
348}
349|
350PE_KERNEL_PMU_EVENT sep_dc
351{
352 struct list_head *list;
353 int err;
354
355 err = parse_events_multi_pmu_add(_parse_state, $1, NULL, &list);
356 free($1);
357 if (err < 0)
358 YYABORT;
359 $$ = list;
360}
361|
362PE_KERNEL_PMU_EVENT opt_pmu_config
363{
364 struct list_head *list;
365 int err;
366
367 /* frees $2 */
368 err = parse_events_multi_pmu_add(_parse_state, $1, $2, &list);
369 free($1);
370 if (err < 0)
371 YYABORT;
372 $$ = list;
373}
374|
375PE_PMU_EVENT_PRE '-' PE_PMU_EVENT_SUF '-' PE_PMU_EVENT_SUF2 sep_dc
376{
377 struct list_head *list;
378 char pmu_name[128];
379 snprintf(pmu_name, sizeof(pmu_name), "%s-%s-%s", $1, $3, $5);
380 free($1);
381 free($3);
382 free($5);
383 if (parse_events_multi_pmu_add(_parse_state, pmu_name, NULL, &list) < 0)
384 YYABORT;
385 $$ = list;
386}
387|
388PE_PMU_EVENT_PRE '-' PE_PMU_EVENT_SUF sep_dc
389{
390 struct list_head *list;
391 char pmu_name[128];
392
393 snprintf(pmu_name, sizeof(pmu_name), "%s-%s", $1, $3);
394 free($1);
395 free($3);
396 if (parse_events_multi_pmu_add(_parse_state, pmu_name, NULL, &list) < 0)
397 YYABORT;
398 $$ = list;
399}
400|
401PE_PMU_EVENT_FAKE sep_dc
402{
403 struct list_head *list;
404 int err;
405
406 list = alloc_list();
407 if (!list)
408 YYABORT;
409
410 err = parse_events_add_pmu(_parse_state, list, $1, NULL, false, false);
411 free($1);
412 if (err < 0) {
413 free(list);
414 YYABORT;
415 }
416 $$ = list;
417}
418|
419PE_PMU_EVENT_FAKE opt_pmu_config
420{
421 struct list_head *list;
422 int err;
423
424 list = alloc_list();
425 if (!list)
426 YYABORT;
427
428 err = parse_events_add_pmu(_parse_state, list, $1, $2, false, false);
429 free($1);
430 parse_events_terms__delete($2);
431 if (err < 0) {
432 free(list);
433 YYABORT;
434 }
435 $$ = list;
436}
437
438value_sym:
439PE_VALUE_SYM_HW
440|
441PE_VALUE_SYM_SW
442
443event_legacy_symbol:
444value_sym '/' event_config '/'
445{
446 struct list_head *list;
447 int type = $1 >> 16;
448 int config = $1 & 255;
449 int err;
450
451 list = alloc_list();
452 ABORT_ON(!list);
453 err = parse_events_add_numeric(_parse_state, list, type, config, $3);
454 parse_events_terms__delete($3);
455 if (err) {
456 free_list_evsel(list);
457 YYABORT;
458 }
459 $$ = list;
460}
461|
462value_sym sep_slash_slash_dc
463{
464 struct list_head *list;
465 int type = $1 >> 16;
466 int config = $1 & 255;
467
468 list = alloc_list();
469 ABORT_ON(!list);
470 ABORT_ON(parse_events_add_numeric(_parse_state, list, type, config, NULL));
471 $$ = list;
472}
473|
474PE_VALUE_SYM_TOOL sep_slash_slash_dc
475{
476 struct list_head *list;
477
478 list = alloc_list();
479 ABORT_ON(!list);
480 ABORT_ON(parse_events_add_tool(_parse_state, list, $1));
481 $$ = list;
482}
483
484event_legacy_cache:
485PE_NAME_CACHE_TYPE '-' PE_NAME_CACHE_OP_RESULT '-' PE_NAME_CACHE_OP_RESULT opt_event_config
486{
487 struct parse_events_state *parse_state = _parse_state;
488 struct parse_events_error *error = parse_state->error;
489 struct list_head *list;
490 int err;
491
492 list = alloc_list();
493 ABORT_ON(!list);
494 err = parse_events_add_cache(list, &parse_state->idx, $1, $3, $5, error, $6,
495 parse_state);
496 parse_events_terms__delete($6);
497 free($1);
498 free($3);
499 free($5);
500 if (err) {
501 free_list_evsel(list);
502 YYABORT;
503 }
504 $$ = list;
505}
506|
507PE_NAME_CACHE_TYPE '-' PE_NAME_CACHE_OP_RESULT opt_event_config
508{
509 struct parse_events_state *parse_state = _parse_state;
510 struct parse_events_error *error = parse_state->error;
511 struct list_head *list;
512 int err;
513
514 list = alloc_list();
515 ABORT_ON(!list);
516 err = parse_events_add_cache(list, &parse_state->idx, $1, $3, NULL, error, $4,
517 parse_state);
518 parse_events_terms__delete($4);
519 free($1);
520 free($3);
521 if (err) {
522 free_list_evsel(list);
523 YYABORT;
524 }
525 $$ = list;
526}
527|
528PE_NAME_CACHE_TYPE opt_event_config
529{
530 struct parse_events_state *parse_state = _parse_state;
531 struct parse_events_error *error = parse_state->error;
532 struct list_head *list;
533 int err;
534
535 list = alloc_list();
536 ABORT_ON(!list);
537 err = parse_events_add_cache(list, &parse_state->idx, $1, NULL, NULL, error, $2,
538 parse_state);
539 parse_events_terms__delete($2);
540 free($1);
541 if (err) {
542 free_list_evsel(list);
543 YYABORT;
544 }
545 $$ = list;
546}
547
548event_legacy_mem:
549PE_PREFIX_MEM PE_VALUE '/' PE_VALUE ':' PE_MODIFIER_BP sep_dc
550{
551 struct parse_events_state *parse_state = _parse_state;
552 struct list_head *list;
553 int err;
554
555 list = alloc_list();
556 ABORT_ON(!list);
557 err = parse_events_add_breakpoint(list, &parse_state->idx,
558 $2, $6, $4);
559 free($6);
560 if (err) {
561 free(list);
562 YYABORT;
563 }
564 $$ = list;
565}
566|
567PE_PREFIX_MEM PE_VALUE '/' PE_VALUE sep_dc
568{
569 struct parse_events_state *parse_state = _parse_state;
570 struct list_head *list;
571
572 list = alloc_list();
573 ABORT_ON(!list);
574 if (parse_events_add_breakpoint(list, &parse_state->idx,
575 $2, NULL, $4)) {
576 free(list);
577 YYABORT;
578 }
579 $$ = list;
580}
581|
582PE_PREFIX_MEM PE_VALUE ':' PE_MODIFIER_BP sep_dc
583{
584 struct parse_events_state *parse_state = _parse_state;
585 struct list_head *list;
586 int err;
587
588 list = alloc_list();
589 ABORT_ON(!list);
590 err = parse_events_add_breakpoint(list, &parse_state->idx,
591 $2, $4, 0);
592 free($4);
593 if (err) {
594 free(list);
595 YYABORT;
596 }
597 $$ = list;
598}
599|
600PE_PREFIX_MEM PE_VALUE sep_dc
601{
602 struct parse_events_state *parse_state = _parse_state;
603 struct list_head *list;
604
605 list = alloc_list();
606 ABORT_ON(!list);
607 if (parse_events_add_breakpoint(list, &parse_state->idx,
608 $2, NULL, 0)) {
609 free(list);
610 YYABORT;
611 }
612 $$ = list;
613}
614
615event_legacy_tracepoint:
616tracepoint_name opt_event_config
617{
618 struct parse_events_state *parse_state = _parse_state;
619 struct parse_events_error *error = parse_state->error;
620 struct list_head *list;
621 int err;
622
623 list = alloc_list();
624 ABORT_ON(!list);
625 if (error)
626 error->idx = @1.first_column;
627
628 err = parse_events_add_tracepoint(list, &parse_state->idx, $1.sys, $1.event,
629 error, $2);
630
631 parse_events_terms__delete($2);
632 free($1.sys);
633 free($1.event);
634 if (err) {
635 free(list);
636 YYABORT;
637 }
638 $$ = list;
639}
640
641tracepoint_name:
642PE_NAME '-' PE_NAME ':' PE_NAME
643{
644 struct tracepoint_name tracepoint;
645
646 ABORT_ON(asprintf(&tracepoint.sys, "%s-%s", $1, $3) < 0);
647 tracepoint.event = $5;
648 free($1);
649 free($3);
650 $$ = tracepoint;
651}
652|
653PE_NAME ':' PE_NAME
654{
655 struct tracepoint_name tracepoint = {$1, $3};
656
657 $$ = tracepoint;
658}
659
660event_legacy_numeric:
661PE_VALUE ':' PE_VALUE opt_event_config
662{
663 struct list_head *list;
664 int err;
665
666 list = alloc_list();
667 ABORT_ON(!list);
668 err = parse_events_add_numeric(_parse_state, list, (u32)$1, $3, $4);
669 parse_events_terms__delete($4);
670 if (err) {
671 free(list);
672 YYABORT;
673 }
674 $$ = list;
675}
676
677event_legacy_raw:
678PE_RAW opt_event_config
679{
680 struct list_head *list;
681 int err;
682
683 list = alloc_list();
684 ABORT_ON(!list);
685 err = parse_events_add_numeric(_parse_state, list, PERF_TYPE_RAW, $1, $2);
686 parse_events_terms__delete($2);
687 if (err) {
688 free(list);
689 YYABORT;
690 }
691 $$ = list;
692}
693
694event_bpf_file:
695PE_BPF_OBJECT opt_event_config
696{
697 struct parse_events_state *parse_state = _parse_state;
698 struct list_head *list;
699 int err;
700
701 list = alloc_list();
702 ABORT_ON(!list);
703 err = parse_events_load_bpf(parse_state, list, $1, false, $2);
704 parse_events_terms__delete($2);
705 free($1);
706 if (err) {
707 free(list);
708 YYABORT;
709 }
710 $$ = list;
711}
712|
713PE_BPF_SOURCE opt_event_config
714{
715 struct list_head *list;
716 int err;
717
718 list = alloc_list();
719 ABORT_ON(!list);
720 err = parse_events_load_bpf(_parse_state, list, $1, true, $2);
721 parse_events_terms__delete($2);
722 if (err) {
723 free(list);
724 YYABORT;
725 }
726 $$ = list;
727}
728
729opt_event_config:
730'/' event_config '/'
731{
732 $$ = $2;
733}
734|
735'/' '/'
736{
737 $$ = NULL;
738}
739|
740{
741 $$ = NULL;
742}
743
744opt_pmu_config:
745'/' event_config '/'
746{
747 $$ = $2;
748}
749|
750'/' '/'
751{
752 $$ = NULL;
753}
754
755start_terms: event_config
756{
757 struct parse_events_state *parse_state = _parse_state;
758 if (parse_state->terms) {
759 parse_events_terms__delete ($1);
760 YYABORT;
761 }
762 parse_state->terms = $1;
763}
764
765event_config:
766event_config ',' event_term
767{
768 struct list_head *head = $1;
769 struct parse_events_term *term = $3;
770
771 if (!head) {
772 parse_events_term__delete(term);
773 YYABORT;
774 }
775 list_add_tail(&term->list, head);
776 $$ = $1;
777}
778|
779event_term
780{
781 struct list_head *head = malloc(sizeof(*head));
782 struct parse_events_term *term = $1;
783
784 ABORT_ON(!head);
785 INIT_LIST_HEAD(head);
786 list_add_tail(&term->list, head);
787 $$ = head;
788}
789
790event_term:
791PE_RAW
792{
793 struct parse_events_term *term;
794
795 ABORT_ON(parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_CONFIG,
796 NULL, $1, false, &@1, NULL));
797 $$ = term;
798}
799|
800PE_NAME '=' PE_NAME
801{
802 struct parse_events_term *term;
803
804 if (parse_events_term__str(&term, PARSE_EVENTS__TERM_TYPE_USER,
805 $1, $3, &@1, &@3)) {
806 free($1);
807 free($3);
808 YYABORT;
809 }
810 $$ = term;
811}
812|
813PE_NAME '=' PE_VALUE
814{
815 struct parse_events_term *term;
816
817 if (parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
818 $1, $3, false, &@1, &@3)) {
819 free($1);
820 YYABORT;
821 }
822 $$ = term;
823}
824|
825PE_NAME '=' PE_VALUE_SYM_HW
826{
827 struct parse_events_term *term;
828 int config = $3 & 255;
829
830 if (parse_events_term__sym_hw(&term, $1, config)) {
831 free($1);
832 YYABORT;
833 }
834 $$ = term;
835}
836|
837PE_NAME
838{
839 struct parse_events_term *term;
840
841 if (parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
842 $1, 1, true, &@1, NULL)) {
843 free($1);
844 YYABORT;
845 }
846 $$ = term;
847}
848|
849PE_VALUE_SYM_HW
850{
851 struct parse_events_term *term;
852 int config = $1 & 255;
853
854 ABORT_ON(parse_events_term__sym_hw(&term, NULL, config));
855 $$ = term;
856}
857|
858PE_TERM '=' PE_NAME
859{
860 struct parse_events_term *term;
861
862 if (parse_events_term__str(&term, (int)$1, NULL, $3, &@1, &@3)) {
863 free($3);
864 YYABORT;
865 }
866 $$ = term;
867}
868|
869PE_TERM '=' PE_VALUE
870{
871 struct parse_events_term *term;
872
873 ABORT_ON(parse_events_term__num(&term, (int)$1, NULL, $3, false, &@1, &@3));
874 $$ = term;
875}
876|
877PE_TERM
878{
879 struct parse_events_term *term;
880
881 ABORT_ON(parse_events_term__num(&term, (int)$1, NULL, 1, true, &@1, NULL));
882 $$ = term;
883}
884|
885PE_NAME array '=' PE_NAME
886{
887 struct parse_events_term *term;
888
889 if (parse_events_term__str(&term, PARSE_EVENTS__TERM_TYPE_USER,
890 $1, $4, &@1, &@4)) {
891 free($1);
892 free($4);
893 free($2.ranges);
894 YYABORT;
895 }
896 term->array = $2;
897 $$ = term;
898}
899|
900PE_NAME array '=' PE_VALUE
901{
902 struct parse_events_term *term;
903
904 if (parse_events_term__num(&term, PARSE_EVENTS__TERM_TYPE_USER,
905 $1, $4, false, &@1, &@4)) {
906 free($1);
907 free($2.ranges);
908 YYABORT;
909 }
910 term->array = $2;
911 $$ = term;
912}
913|
914PE_DRV_CFG_TERM
915{
916 struct parse_events_term *term;
917 char *config = strdup($1);
918
919 ABORT_ON(!config);
920 if (parse_events_term__str(&term, PARSE_EVENTS__TERM_TYPE_DRV_CFG,
921 config, $1, &@1, NULL)) {
922 free($1);
923 free(config);
924 YYABORT;
925 }
926 $$ = term;
927}
928
929array:
930'[' array_terms ']'
931{
932 $$ = $2;
933}
934|
935PE_ARRAY_ALL
936{
937 $$.nr_ranges = 0;
938 $$.ranges = NULL;
939}
940
941array_terms:
942array_terms ',' array_term
943{
944 struct parse_events_array new_array;
945
946 new_array.nr_ranges = $1.nr_ranges + $3.nr_ranges;
947 new_array.ranges = realloc($1.ranges,
948 sizeof(new_array.ranges[0]) *
949 new_array.nr_ranges);
950 ABORT_ON(!new_array.ranges);
951 memcpy(&new_array.ranges[$1.nr_ranges], $3.ranges,
952 $3.nr_ranges * sizeof(new_array.ranges[0]));
953 free($3.ranges);
954 $$ = new_array;
955}
956|
957array_term
958
959array_term:
960PE_VALUE
961{
962 struct parse_events_array array;
963
964 array.nr_ranges = 1;
965 array.ranges = malloc(sizeof(array.ranges[0]));
966 ABORT_ON(!array.ranges);
967 array.ranges[0].start = $1;
968 array.ranges[0].length = 1;
969 $$ = array;
970}
971|
972PE_VALUE PE_ARRAY_RANGE PE_VALUE
973{
974 struct parse_events_array array;
975
976 ABORT_ON($3 < $1);
977 array.nr_ranges = 1;
978 array.ranges = malloc(sizeof(array.ranges[0]));
979 ABORT_ON(!array.ranges);
980 array.ranges[0].start = $1;
981 array.ranges[0].length = $3 - $1 + 1;
982 $$ = array;
983}
984
985sep_dc: ':' |
986
987sep_slash_slash_dc: '/' '/' | ':' |
988
989%%
990
991void parse_events_error(YYLTYPE *loc, void *parse_state,
992 void *scanner __maybe_unused,
993 char const *msg __maybe_unused)
994{
995 parse_events_evlist_error(parse_state, loc->last_column, "parser error");
996}