Loading...
1/* SPDX-License-Identifier: GPL-2.0 */
2/* ld script to make s390 Linux kernel
3 * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
4 */
5
6#include <asm/thread_info.h>
7#include <asm/page.h>
8
9/*
10 * Put .bss..swapper_pg_dir as the first thing in .bss. This will
11 * make sure it has 16k alignment.
12 */
13#define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
14
15/* Handle ro_after_init data on our own. */
16#define RO_AFTER_INIT_DATA
17
18#include <asm-generic/vmlinux.lds.h>
19#include <asm/vmlinux.lds.h>
20
21OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
22OUTPUT_ARCH(s390:64-bit)
23ENTRY(startup_continue)
24jiffies = jiffies_64;
25
26PHDRS {
27 text PT_LOAD FLAGS(5); /* R_E */
28 data PT_LOAD FLAGS(7); /* RWE */
29 note PT_NOTE FLAGS(0); /* ___ */
30}
31
32SECTIONS
33{
34 . = 0x100000;
35 .text : {
36 _stext = .; /* Start of text section */
37 _text = .; /* Text and read-only data */
38 HEAD_TEXT
39 TEXT_TEXT
40 SCHED_TEXT
41 CPUIDLE_TEXT
42 LOCK_TEXT
43 KPROBES_TEXT
44 IRQENTRY_TEXT
45 SOFTIRQENTRY_TEXT
46 *(.text.*_indirect_*)
47 *(.fixup)
48 *(.gnu.warning)
49 . = ALIGN(PAGE_SIZE);
50 _etext = .; /* End of text section */
51 } :text = 0x0700
52
53 NOTES :text :note
54
55 .dummy : { *(.dummy) } :data
56
57 RO_DATA_SECTION(PAGE_SIZE)
58
59 . = ALIGN(PAGE_SIZE);
60 _sdata = .; /* Start of data section */
61
62 . = ALIGN(PAGE_SIZE);
63 __start_ro_after_init = .;
64 .data..ro_after_init : {
65 *(.data..ro_after_init)
66 JUMP_TABLE_DATA
67 }
68 EXCEPTION_TABLE(16)
69 . = ALIGN(PAGE_SIZE);
70 __end_ro_after_init = .;
71
72 RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
73 BOOT_DATA_PRESERVED
74
75 _edata = .; /* End of data section */
76
77 /* will be freed after init */
78 . = ALIGN(PAGE_SIZE); /* Init code and data */
79 __init_begin = .;
80
81 . = ALIGN(PAGE_SIZE);
82 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
83 _sinittext = .;
84 INIT_TEXT
85 . = ALIGN(PAGE_SIZE);
86 _einittext = .;
87 }
88
89 /*
90 * .exit.text is discarded at runtime, not link time,
91 * to deal with references from __bug_table
92 */
93 .exit.text : {
94 EXIT_TEXT
95 }
96
97 .exit.data : {
98 EXIT_DATA
99 }
100
101 /*
102 * struct alt_inst entries. From the header (alternative.h):
103 * "Alternative instructions for different CPU types or capabilities"
104 * Think locking instructions on spinlocks.
105 * Note, that it is a part of __init region.
106 */
107 . = ALIGN(8);
108 .altinstructions : {
109 __alt_instructions = .;
110 *(.altinstructions)
111 __alt_instructions_end = .;
112 }
113
114 /*
115 * And here are the replacement instructions. The linker sticks
116 * them as binary blobs. The .altinstructions has enough data to
117 * get the address and the length of them to patch the kernel safely.
118 * Note, that it is a part of __init region.
119 */
120 .altinstr_replacement : {
121 *(.altinstr_replacement)
122 }
123
124 /*
125 * Table with the patch locations to undo expolines
126 */
127 .nospec_call_table : {
128 __nospec_call_start = . ;
129 *(.s390_indirect*)
130 __nospec_call_end = . ;
131 }
132 .nospec_return_table : {
133 __nospec_return_start = . ;
134 *(.s390_return*)
135 __nospec_return_end = . ;
136 }
137
138 BOOT_DATA
139
140 /* early.c uses stsi, which requires page aligned data. */
141 . = ALIGN(PAGE_SIZE);
142 INIT_DATA_SECTION(0x100)
143
144 PERCPU_SECTION(0x100)
145
146 .dynsym ALIGN(8) : {
147 __dynsym_start = .;
148 *(.dynsym)
149 __dynsym_end = .;
150 }
151 .rela.dyn ALIGN(8) : {
152 __rela_dyn_start = .;
153 *(.rela*)
154 __rela_dyn_end = .;
155 }
156
157 . = ALIGN(PAGE_SIZE);
158 __init_end = .; /* freed after init ends here */
159
160 BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
161
162 _end = . ;
163
164 /*
165 * uncompressed image info used by the decompressor
166 * it should match struct vmlinux_info
167 */
168 .vmlinux.info 0 (INFO) : {
169 QUAD(_stext) /* default_lma */
170 QUAD(startup_continue) /* entry */
171 QUAD(__bss_start - _stext) /* image_size */
172 QUAD(__bss_stop - __bss_start) /* bss_size */
173 QUAD(__boot_data_start) /* bootdata_off */
174 QUAD(__boot_data_end - __boot_data_start) /* bootdata_size */
175 QUAD(__boot_data_preserved_start) /* bootdata_preserved_off */
176 QUAD(__boot_data_preserved_end -
177 __boot_data_preserved_start) /* bootdata_preserved_size */
178 QUAD(__dynsym_start) /* dynsym_start */
179 QUAD(__rela_dyn_start) /* rela_dyn_start */
180 QUAD(__rela_dyn_end) /* rela_dyn_end */
181 } :NONE
182
183 /* Debugging sections. */
184 STABS_DEBUG
185 DWARF_DEBUG
186
187 /* Sections to be discarded */
188 DISCARDS
189 /DISCARD/ : {
190 *(.eh_frame)
191 }
192}
1/* ld script to make s390 Linux kernel
2 * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
3 */
4
5#include <asm/thread_info.h>
6#include <asm/page.h>
7
8/*
9 * Put .bss..swapper_pg_dir as the first thing in .bss. This will
10 * make sure it has 16k alignment.
11 */
12#define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
13
14/* Handle ro_after_init data on our own. */
15#define RO_AFTER_INIT_DATA
16
17#include <asm-generic/vmlinux.lds.h>
18
19OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
20OUTPUT_ARCH(s390:64-bit)
21ENTRY(startup)
22jiffies = jiffies_64;
23
24PHDRS {
25 text PT_LOAD FLAGS(5); /* R_E */
26 data PT_LOAD FLAGS(7); /* RWE */
27 note PT_NOTE FLAGS(0); /* ___ */
28}
29
30SECTIONS
31{
32 . = 0x00000000;
33 .text : {
34 _text = .; /* Text and read-only data */
35 HEAD_TEXT
36 TEXT_TEXT
37 SCHED_TEXT
38 CPUIDLE_TEXT
39 LOCK_TEXT
40 KPROBES_TEXT
41 IRQENTRY_TEXT
42 SOFTIRQENTRY_TEXT
43 *(.fixup)
44 *(.gnu.warning)
45 } :text = 0x0700
46
47 _etext = .; /* End of text section */
48
49 NOTES :text :note
50
51 .dummy : { *(.dummy) } :data
52
53 RO_DATA_SECTION(PAGE_SIZE)
54
55#ifdef CONFIG_SHARED_KERNEL
56 . = ALIGN(0x100000); /* VM shared segments are 1MB aligned */
57#endif
58
59 . = ALIGN(PAGE_SIZE);
60 _eshared = .; /* End of shareable data */
61 _sdata = .; /* Start of data section */
62
63 . = ALIGN(PAGE_SIZE);
64 __start_ro_after_init = .;
65 __start_data_ro_after_init = .;
66 .data..ro_after_init : {
67 *(.data..ro_after_init)
68 }
69 __end_data_ro_after_init = .;
70 EXCEPTION_TABLE(16)
71 . = ALIGN(PAGE_SIZE);
72 __end_ro_after_init = .;
73
74 RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
75
76 _edata = .; /* End of data section */
77
78 /* will be freed after init */
79 . = ALIGN(PAGE_SIZE); /* Init code and data */
80 __init_begin = .;
81
82 INIT_TEXT_SECTION(PAGE_SIZE)
83
84 /*
85 * .exit.text is discarded at runtime, not link time,
86 * to deal with references from __bug_table
87 */
88 .exit.text : {
89 EXIT_TEXT
90 }
91
92 .exit.data : {
93 EXIT_DATA
94 }
95
96 /* early.c uses stsi, which requires page aligned data. */
97 . = ALIGN(PAGE_SIZE);
98 INIT_DATA_SECTION(0x100)
99
100 PERCPU_SECTION(0x100)
101 . = ALIGN(PAGE_SIZE);
102 __init_end = .; /* freed after init ends here */
103
104 BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
105
106 _end = . ;
107
108 /* Debugging sections. */
109 STABS_DEBUG
110 DWARF_DEBUG
111
112 /* Sections to be discarded */
113 DISCARDS
114}