1/* ld script to make M32R Linux kernel
 2 */
 3
 4#include <asm-generic/vmlinux.lds.h>
 5#include <asm/addrspace.h>
 6#include <asm/page.h>
 7#include <asm/thread_info.h>
 8
 9OUTPUT_ARCH(m32r)
10#if defined(__LITTLE_ENDIAN__)
11       jiffies = jiffies_64;
12#else
13       jiffies = jiffies_64 + 4;
14#endif
15
16kernel_entry = boot - 0x80000000;
17ENTRY(kernel_entry)
18
19SECTIONS
20{
21  . = CONFIG_MEMORY_START + __PAGE_OFFSET;
22  eit_vector = .;
23
24  . = . + 0x1000;
25  .empty_zero_page : { *(.empty_zero_page) } = 0
26
27  /* read-only */
28  _text = .;			/* Text and read-only data */
29  .boot : { *(.boot) } = 0
30  .text : {
31	HEAD_TEXT
32	TEXT_TEXT
33	SCHED_TEXT
34	CPUIDLE_TEXT
35	LOCK_TEXT
36	*(.fixup)
37	*(.gnu.warning)
38	} = 0x9090
39#ifdef CONFIG_SMP
40  . = ALIGN(65536);
41  .eit_vector4 : { *(.eit_vector4) }
42#endif
43  _etext = .;			/* End of text section */
44
45  EXCEPTION_TABLE(16)
46  NOTES
47
48  _sdata = .;			/* Start of data section */
49  RODATA
50  RW_DATA_SECTION(32, PAGE_SIZE, THREAD_SIZE)
51  _edata = .;			/* End of data section */
52
53  /* will be freed after init */
54  . = ALIGN(PAGE_SIZE);		/* Init code and data */
55  __init_begin = .;
56  INIT_TEXT_SECTION(PAGE_SIZE)
57  INIT_DATA_SECTION(16)
58  PERCPU_SECTION(32)
59  . = ALIGN(PAGE_SIZE);
60  __init_end = .;
61  /* freed after init ends here */
62
63  BSS_SECTION(0, 0, 4)
64
65  _end = . ;
66
67  /* Stabs debugging sections.  */
68  .stab 0 : { *(.stab) }
69  .stabstr 0 : { *(.stabstr) }
70  .stab.excl 0 : { *(.stab.excl) }
71  .stab.exclstr 0 : { *(.stab.exclstr) }
72  .stab.index 0 : { *(.stab.index) }
73  .stab.indexstr 0 : { *(.stab.indexstr) }
74  .comment 0 : { *(.comment) }
75
76  /* Sections to be discarded */
77  DISCARDS
78}