Loading...
1#!/bin/sh
2# Before running this script please ensure that your PATH is
3# typical as you use for compilation/installation. I use
4# /bin /sbin /usr/bin /usr/sbin /usr/local/bin, but it may
5# differ on your system.
6#
7echo 'If some fields are empty or look unusual you may have an old version.'
8echo 'Compare to the current minimal requirements in Documentation/Changes.'
9echo ' '
10
11uname -a
12echo ' '
13
14gcc -dumpversion 2>&1 |
15awk '/[0-9]+([.]?[0-9]+)+/ && !/not found$/{
16 match($0, /[0-9]+([.]?[0-9]+)+/)
17 printf("GNU C\t\t\t%s\n",
18 substr($0,RSTART,RLENGTH))
19}'
20
21make --version 2>&1 |
22awk '/GNU Make/{
23 match($0, /[0-9]+([.]?[0-9]+)+/)
24 printf("GNU Make\t\t%s\n",
25 substr($0,RSTART,RLENGTH))
26}'
27
28ld -v 2>&1 |
29awk '/[0-9]+([.]?[0-9]+)+/ && !/not found$/{
30 match($0, /[0-9]+([.]?[0-9]+)+/)
31 printf("Binutils\t\t%s\n",
32 substr($0,RSTART,RLENGTH))
33}'
34
35mount --version 2>&1 |
36awk '/[0-9]+([.]?[0-9]+)+/ && !/not found$/{
37 match($0, /[0-9]+([.]?[0-9]+)+/)
38 $0 = substr($0,RSTART,RLENGTH)
39 printf("Util-linux\t\t%s\nMount\t\t\t%s\n",$0,$0)
40}'
41
42depmod -V 2>&1 |
43awk '/[0-9]+([.]?[0-9]+)+/ && !/not found$/{
44 match($0, /[0-9]+([.]?[0-9]+)+/)
45 printf("Module-init-tools\t%s\n",
46 substr($0,RSTART,RLENGTH))
47}'
48
49tune2fs 2>&1 |
50awk '/^tune2fs/{
51 match($0, /[0-9]+([.]?[0-9]+)+/)
52 printf("E2fsprogs\t\t%s\n",
53 substr($0,RSTART,RLENGTH))
54}'
55
56fsck.jfs -V 2>&1 |
57awk '/version/{
58 match($0, /[0-9]+([.]?[0-9]+)+/)
59 printf("Jfsutils\t\t%s\n",
60 substr($0,RSTART,RLENGTH))
61}'
62
63reiserfsck -V 2>&1 |
64awk '/^reiserfsck/{
65 match($0, /[0-9]+([.]?[0-9]+)+/)
66 printf("Reiserfsprogs\t\t%s\n",
67 substr($0,RSTART,RLENGTH))
68}'
69
70fsck.reiser4 -V 2>&1 | grep ^fsck.reiser4 | awk \
71'NR==1{print "reiser4progs ", $2}'
72
73xfs_db -V 2>&1 |
74awk '/version/{
75 match($0, /[0-9]+([.]?[0-9]+)+/)
76 printf("Xfsprogs\t\t%s\n",
77 substr($0,RSTART,RLENGTH))
78}'
79
80pccardctl -V 2>&1 |
81awk '/pcmciautils/{
82 match($0, /[0-9]+([.]?[0-9]+)+/)
83 printf("Pcmciautils\t\t%s\n",
84 substr($0,RSTART,RLENGTH))
85}'
86
87cardmgr -V 2>&1| grep version | awk \
88'NR==1{print "pcmcia-cs ", $3}'
89
90quota -V 2>&1 |
91awk '/version/{
92 match($0, /[0-9]+([.]?[0-9]+)+/)
93 printf("Quota-tools\t\t%s\n",
94 substr($0,RSTART,RLENGTH))
95}'
96
97pppd --version 2>&1 |
98awk '/version/{
99 match($0, /[0-9]+([.]?[0-9]+)+/)
100 printf("PPP\t\t\t%s\n",
101 substr($0,RSTART,RLENGTH))
102}'
103
104isdnctrl 2>&1 | grep version | awk \
105'NR==1{print "isdn4k-utils ", $NF}'
106
107showmount --version 2>&1 | grep nfs-utils | awk \
108'NR==1{print "nfs-utils ", $NF}'
109
110test -r /proc/self/maps &&
111sed '
112 /.*libc-\(.*\)\.so$/!d
113 s//Linux C Library\t\t\1/
114 q
115' /proc/self/maps
116
117ldd --version 2>&1 |
118awk '/^ldd/{
119 match($0, /[0-9]+([.]?[0-9]+)+/)
120 printf("Dynamic linker (ldd)\t%s\n",
121 substr($0,RSTART,RLENGTH))
122}'
123
124libcpp=`ldconfig -p 2>/dev/null |
125 awk '/(libg|stdc)[+]+\.so/ {
126 print $NF
127 exit
128 }
129'`
130test -r "$libcpp" &&
131ls -l $libcpp |
132sed '
133 s!.*so\.!!
134 s!^!Linux C++ Library\t!
135'
136ps --version 2>&1 |
137awk '/version/{
138 match($0, /[0-9]+([.]?[0-9]+)+/)
139 printf("Procps\t\t\t%s\n",
140 substr($0,RSTART,RLENGTH))
141}'
142
143ifconfig --version 2>&1 |
144awk '/tools/{
145 match($0, /[0-9]+([.]?[0-9]+)+/)
146 printf("Net-tools\t\t%s\n",
147 substr($0,RSTART,RLENGTH))
148}'
149
150loadkeys -V 2>&1 |
151awk '/[0-9]+([.]?[0-9]+)+/ && !/not found$/{
152 match($0, /[0-9]+([.]?[0-9]+)+/)
153 $0 = substr($0,RSTART,RLENGTH)
154 printf("Kbd\t\t\t%s\nConsole-tools\t\t%s\n",$0,$0)
155}'
156
157oprofiled --version 2>&1 | awk \
158'(NR==1 && ($2 == "oprofile")) {print "oprofile ", $3}'
159
160expr --v 2>&1 |
161awk '/^expr/{
162 match($0, /[0-9]+([.]?[0-9]+)+/)
163 printf("Sh-utils\t\t%s\n",
164 substr($0,RSTART,RLENGTH))
165}'
166
167udevadm --version 2>&1 |
168awk '/[0-9]+([.]?[0-9]+)+/ && !/not found$/{
169 match($0, /[0-9]+([.]?[0-9]+)+/)
170 printf("Udev\t\t\t%s\n",
171 substr($0,RSTART,RLENGTH))
172}'
173
174iwconfig --version 2>&1 |
175awk '/version/{
176 match($0, /[0-9]+([.]?[0-9]+)+/)
177 printf("Wireless-tools\t\t%s\n",
178 substr($0,RSTART,RLENGTH))
179}'
180
181test -e /proc/modules &&
182sort /proc/modules |
183sed '
184 s/ .*//
185 H
186${
187 g
188 s/^\n/Modules Loaded\t\t/
189 y/\n/ /
190 q
191}
192 d
193'
1#!/usr/bin/awk -f
2# SPDX-License-Identifier: GPL-2.0
3# Before running this script please ensure that your PATH is
4# typical as you use for compilation/installation. I use
5# /bin /sbin /usr/bin /usr/sbin /usr/local/bin, but it may
6# differ on your system.
7
8BEGIN {
9 usage = "If some fields are empty or look unusual you may have an old version.\n"
10 usage = usage "Compare to the current minimal requirements in Documentation/Changes.\n"
11 print usage
12
13 system("uname -a")
14 printf("\n")
15
16 vernum = "[0-9]+([.]?[0-9]+)+"
17
18 printversion("GNU C", version("gcc -dumpversion"))
19 printversion("GNU Make", version("make --version"))
20 printversion("Binutils", version("ld -v"))
21 printversion("Util-linux", version("mount --version"))
22 printversion("Mount", version("mount --version"))
23 printversion("Module-init-tools", version("depmod -V"))
24 printversion("E2fsprogs", version("tune2fs"))
25 printversion("Jfsutils", version("fsck.jfs -V"))
26 printversion("Reiserfsprogs", version("reiserfsck -V"))
27 printversion("Reiser4fsprogs", version("fsck.reiser4 -V"))
28 printversion("Xfsprogs", version("xfs_db -V"))
29 printversion("Pcmciautils", version("pccardctl -V"))
30 printversion("Pcmcia-cs", version("cardmgr -V"))
31 printversion("Quota-tools", version("quota -V"))
32 printversion("PPP", version("pppd --version"))
33 printversion("Isdn4k-utils", version("isdnctrl"))
34 printversion("Nfs-utils", version("showmount --version"))
35
36 while (getline <"/proc/self/maps" > 0) {
37 if (/libc.*\.so$/) {
38 n = split($0, procmaps, "/")
39 if (match(procmaps[n], vernum)) {
40 ver = substr(procmaps[n], RSTART, RLENGTH)
41 printversion("Linux C Library", ver)
42 break
43 }
44 }
45 }
46
47 printversion("Dynamic linker (ldd)", version("ldd --version"))
48
49 while ("ldconfig -p 2>/dev/null" | getline > 0) {
50 if (/(libg|stdc)[+]+\.so/) {
51 libcpp = $NF
52 break
53 }
54 }
55 printversion("Linux C++ Library", version("readlink " libcpp))
56 printversion("Procps", version("ps --version"))
57 printversion("Net-tools", version("ifconfig --version"))
58 printversion("Kbd", version("loadkeys -V"))
59 printversion("Console-tools", version("loadkeys -V"))
60 printversion("Oprofile", version("oprofiled --version"))
61 printversion("Sh-utils", version("expr --v"))
62 printversion("Udev", version("udevadm --version"))
63 printversion("Wireless-tools", version("iwconfig --version"))
64
65 while ("sort /proc/modules" | getline > 0) {
66 mods = mods sep $1
67 sep = " "
68 }
69 printversion("Modules Loaded", mods)
70}
71
72function version(cmd, ver) {
73 cmd = cmd " 2>&1"
74 while (cmd | getline > 0) {
75 if (match($0, vernum)) {
76 ver = substr($0, RSTART, RLENGTH)
77 break
78 }
79 }
80 close(cmd)
81 return ver
82}
83
84function printversion(name, value, ofmt) {
85 if (value != "") {
86 ofmt = "%-20s\t%s\n"
87 printf(ofmt, name, value)
88 }
89}