Loading...
1/* ld script to make ARM Linux kernel
2 * taken from the i386 version by Russell King
3 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
4 */
5
6#include <asm-generic/vmlinux.lds.h>
7#include <asm/cache.h>
8#include <asm/thread_info.h>
9#include <asm/memory.h>
10#include <asm/page.h>
11
12#define PROC_INFO \
13 . = ALIGN(4); \
14 VMLINUX_SYMBOL(__proc_info_begin) = .; \
15 *(.proc.info.init) \
16 VMLINUX_SYMBOL(__proc_info_end) = .;
17
18#define IDMAP_TEXT \
19 ALIGN_FUNCTION(); \
20 VMLINUX_SYMBOL(__idmap_text_start) = .; \
21 *(.idmap.text) \
22 VMLINUX_SYMBOL(__idmap_text_end) = .; \
23 . = ALIGN(PAGE_SIZE); \
24 VMLINUX_SYMBOL(__hyp_idmap_text_start) = .; \
25 *(.hyp.idmap.text) \
26 VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;
27
28#ifdef CONFIG_HOTPLUG_CPU
29#define ARM_CPU_DISCARD(x)
30#define ARM_CPU_KEEP(x) x
31#else
32#define ARM_CPU_DISCARD(x) x
33#define ARM_CPU_KEEP(x)
34#endif
35
36#if (defined(CONFIG_SMP_ON_UP) && !defined(CONFIG_DEBUG_SPINLOCK)) || \
37 defined(CONFIG_GENERIC_BUG)
38#define ARM_EXIT_KEEP(x) x
39#define ARM_EXIT_DISCARD(x)
40#else
41#define ARM_EXIT_KEEP(x)
42#define ARM_EXIT_DISCARD(x) x
43#endif
44
45OUTPUT_ARCH(arm)
46ENTRY(stext)
47
48#ifndef __ARMEB__
49jiffies = jiffies_64;
50#else
51jiffies = jiffies_64 + 4;
52#endif
53
54SECTIONS
55{
56 /*
57 * XXX: The linker does not define how output sections are
58 * assigned to input sections when there are multiple statements
59 * matching the same input section name. There is no documented
60 * order of matching.
61 *
62 * unwind exit sections must be discarded before the rest of the
63 * unwind sections get included.
64 */
65 /DISCARD/ : {
66 *(.ARM.exidx.exit.text)
67 *(.ARM.extab.exit.text)
68 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
69 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
70 ARM_EXIT_DISCARD(EXIT_TEXT)
71 ARM_EXIT_DISCARD(EXIT_DATA)
72 EXIT_CALL
73#ifndef CONFIG_MMU
74 *(.text.fixup)
75 *(__ex_table)
76#endif
77#ifndef CONFIG_SMP_ON_UP
78 *(.alt.smp.init)
79#endif
80 *(.discard)
81 *(.discard.*)
82 }
83
84 . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
85 _xiprom = .; /* XIP ROM area to be mapped */
86
87 .head.text : {
88 _text = .;
89 HEAD_TEXT
90 }
91
92 .text : { /* Real text segment */
93 _stext = .; /* Text and read-only data */
94 IDMAP_TEXT
95 __exception_text_start = .;
96 *(.exception.text)
97 __exception_text_end = .;
98 IRQENTRY_TEXT
99 TEXT_TEXT
100 SCHED_TEXT
101 LOCK_TEXT
102 KPROBES_TEXT
103 *(.gnu.warning)
104 *(.glue_7)
105 *(.glue_7t)
106 . = ALIGN(4);
107 *(.got) /* Global offset table */
108 ARM_CPU_KEEP(PROC_INFO)
109 }
110
111 RO_DATA(PAGE_SIZE)
112
113 . = ALIGN(4);
114 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
115 __start___ex_table = .;
116#ifdef CONFIG_MMU
117 *(__ex_table)
118#endif
119 __stop___ex_table = .;
120 }
121
122#ifdef CONFIG_ARM_UNWIND
123 /*
124 * Stack unwinding tables
125 */
126 . = ALIGN(8);
127 .ARM.unwind_idx : {
128 __start_unwind_idx = .;
129 *(.ARM.exidx*)
130 __stop_unwind_idx = .;
131 }
132 .ARM.unwind_tab : {
133 __start_unwind_tab = .;
134 *(.ARM.extab*)
135 __stop_unwind_tab = .;
136 }
137#endif
138
139 NOTES
140
141 _etext = .; /* End of text and rodata section */
142
143 /*
144 * The vectors and stubs are relocatable code, and the
145 * only thing that matters is their relative offsets
146 */
147 __vectors_start = .;
148 .vectors 0xffff0000 : AT(__vectors_start) {
149 *(.vectors)
150 }
151 . = __vectors_start + SIZEOF(.vectors);
152 __vectors_end = .;
153
154 __stubs_start = .;
155 .stubs ADDR(.vectors) + 0x1000 : AT(__stubs_start) {
156 *(.stubs)
157 }
158 . = __stubs_start + SIZEOF(.stubs);
159 __stubs_end = .;
160
161 PROVIDE(vector_fiq_offset = vector_fiq - ADDR(.vectors));
162
163 INIT_TEXT_SECTION(8)
164 .exit.text : {
165 ARM_EXIT_KEEP(EXIT_TEXT)
166 }
167 .init.proc.info : {
168 ARM_CPU_DISCARD(PROC_INFO)
169 }
170 .init.arch.info : {
171 __arch_info_begin = .;
172 *(.arch.info.init)
173 __arch_info_end = .;
174 }
175 .init.tagtable : {
176 __tagtable_begin = .;
177 *(.taglist.init)
178 __tagtable_end = .;
179 }
180#ifdef CONFIG_SMP_ON_UP
181 .init.smpalt : {
182 __smpalt_begin = .;
183 *(.alt.smp.init)
184 __smpalt_end = .;
185 }
186#endif
187 .init.pv_table : {
188 __pv_table_begin = .;
189 *(.pv_table)
190 __pv_table_end = .;
191 }
192 .init.data : {
193 INIT_SETUP(16)
194 INIT_CALLS
195 CON_INITCALL
196 SECURITY_INITCALL
197 INIT_RAM_FS
198 }
199
200#ifdef CONFIG_SMP
201 PERCPU_SECTION(L1_CACHE_BYTES)
202#endif
203
204 _exiprom = .; /* End of XIP ROM area */
205 __data_loc = ALIGN(4); /* location in binary */
206 . = PAGE_OFFSET + TEXT_OFFSET;
207
208 .data : AT(__data_loc) {
209 _data = .; /* address in memory */
210 _sdata = .;
211
212 /*
213 * first, the init task union, aligned
214 * to an 8192 byte boundary.
215 */
216 INIT_TASK_DATA(THREAD_SIZE)
217
218 . = ALIGN(PAGE_SIZE);
219 __init_begin = .;
220 INIT_DATA
221 ARM_EXIT_KEEP(EXIT_DATA)
222 . = ALIGN(PAGE_SIZE);
223 __init_end = .;
224
225 NOSAVE_DATA
226 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
227 READ_MOSTLY_DATA(L1_CACHE_BYTES)
228
229 /*
230 * and the usual data section
231 */
232 DATA_DATA
233 CONSTRUCTORS
234
235 _edata = .;
236 }
237 _edata_loc = __data_loc + SIZEOF(.data);
238
239#ifdef CONFIG_HAVE_TCM
240 /*
241 * We align everything to a page boundary so we can
242 * free it after init has commenced and TCM contents have
243 * been copied to its destination.
244 */
245 .tcm_start : {
246 . = ALIGN(PAGE_SIZE);
247 __tcm_start = .;
248 __itcm_start = .;
249 }
250
251 /*
252 * Link these to the ITCM RAM
253 * Put VMA to the TCM address and LMA to the common RAM
254 * and we'll upload the contents from RAM to TCM and free
255 * the used RAM after that.
256 */
257 .text_itcm ITCM_OFFSET : AT(__itcm_start)
258 {
259 __sitcm_text = .;
260 *(.tcm.text)
261 *(.tcm.rodata)
262 . = ALIGN(4);
263 __eitcm_text = .;
264 }
265
266 /*
267 * Reset the dot pointer, this is needed to create the
268 * relative __dtcm_start below (to be used as extern in code).
269 */
270 . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
271
272 .dtcm_start : {
273 __dtcm_start = .;
274 }
275
276 /* TODO: add remainder of ITCM as well, that can be used for data! */
277 .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
278 {
279 . = ALIGN(4);
280 __sdtcm_data = .;
281 *(.tcm.data)
282 . = ALIGN(4);
283 __edtcm_data = .;
284 }
285
286 /* Reset the dot pointer or the linker gets confused */
287 . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
288
289 /* End marker for freeing TCM copy in linked object */
290 .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
291 . = ALIGN(PAGE_SIZE);
292 __tcm_end = .;
293 }
294#endif
295
296 BSS_SECTION(0, 0, 0)
297 _end = .;
298
299 STABS_DEBUG
300}
301
302/*
303 * These must never be empty
304 * If you have to comment these two assert statements out, your
305 * binutils is too old (for other reasons as well)
306 */
307ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
308ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
309
310/*
311 * The HYP init code can't be more than a page long,
312 * and should not cross a page boundary.
313 * The above comment applies as well.
314 */
315ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & PAGE_MASK) <= PAGE_SIZE,
316 "HYP init code too big or misaligned")
1/* SPDX-License-Identifier: GPL-2.0 */
2/* ld script to make ARM Linux kernel
3 * taken from the i386 version by Russell King
4 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
5 */
6
7/* No __ro_after_init data in the .rodata section - which will always be ro */
8#define RO_AFTER_INIT_DATA
9
10#include <linux/sizes.h>
11
12#include <asm/vmlinux.lds.h>
13#include <asm/cache.h>
14#include <asm/thread_info.h>
15#include <asm/memory.h>
16#include <asm/mpu.h>
17#include <asm/page.h>
18
19OUTPUT_ARCH(arm)
20ENTRY(stext)
21
22#ifndef __ARMEB__
23jiffies = jiffies_64;
24#else
25jiffies = jiffies_64 + 4;
26#endif
27
28SECTIONS
29{
30 /*
31 * XXX: The linker does not define how output sections are
32 * assigned to input sections when there are multiple statements
33 * matching the same input section name. There is no documented
34 * order of matching.
35 *
36 * unwind exit sections must be discarded before the rest of the
37 * unwind sections get included.
38 */
39 /DISCARD/ : {
40 ARM_DISCARD
41 *(.alt.smp.init)
42 *(.pv_table)
43 }
44
45 . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
46 _xiprom = .; /* XIP ROM area to be mapped */
47
48 .head.text : {
49 _text = .;
50 HEAD_TEXT
51 }
52
53 .text : { /* Real text segment */
54 _stext = .; /* Text and read-only data */
55 ARM_TEXT
56 }
57
58 RO_DATA(PAGE_SIZE)
59
60 . = ALIGN(4);
61 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
62 __start___ex_table = .;
63 ARM_MMU_KEEP(*(__ex_table))
64 __stop___ex_table = .;
65 }
66
67#ifdef CONFIG_ARM_UNWIND
68 ARM_UNWIND_SECTIONS
69#endif
70
71 _etext = .; /* End of text and rodata section */
72
73 ARM_VECTORS
74 INIT_TEXT_SECTION(8)
75 .exit.text : {
76 ARM_EXIT_KEEP(EXIT_TEXT)
77 }
78 .init.proc.info : {
79 ARM_CPU_DISCARD(PROC_INFO)
80 }
81 .init.arch.info : {
82 __arch_info_begin = .;
83 *(.arch.info.init)
84 __arch_info_end = .;
85 }
86 .init.tagtable : {
87 __tagtable_begin = .;
88 *(.taglist.init)
89 __tagtable_end = .;
90 }
91 .init.rodata : {
92 INIT_SETUP(16)
93 INIT_CALLS
94 CON_INITCALL
95 INIT_RAM_FS
96 }
97
98#ifdef CONFIG_ARM_MPU
99 . = ALIGN(SZ_128K);
100#endif
101 _exiprom = .; /* End of XIP ROM area */
102
103/*
104 * From this point, stuff is considered writable and will be copied to RAM
105 */
106 __data_loc = ALIGN(4); /* location in file */
107 . = PAGE_OFFSET + TEXT_OFFSET; /* location in memory */
108#undef LOAD_OFFSET
109#define LOAD_OFFSET (PAGE_OFFSET + TEXT_OFFSET - __data_loc)
110
111 . = ALIGN(THREAD_SIZE);
112 _sdata = .;
113 RW_DATA(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
114 .data.ro_after_init : AT(ADDR(.data.ro_after_init) - LOAD_OFFSET) {
115 *(.data..ro_after_init)
116 }
117 _edata = .;
118
119 . = ALIGN(PAGE_SIZE);
120 __init_begin = .;
121 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
122 INIT_DATA
123 }
124 .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
125 ARM_EXIT_KEEP(EXIT_DATA)
126 }
127#ifdef CONFIG_SMP
128 PERCPU_SECTION(L1_CACHE_BYTES)
129#endif
130
131#ifdef CONFIG_HAVE_TCM
132 ARM_TCM
133#endif
134
135 /*
136 * End of copied data. We need a dummy section to get its LMA.
137 * Also located before final ALIGN() as trailing padding is not stored
138 * in the resulting binary file and useless to copy.
139 */
140 .data.endmark : AT(ADDR(.data.endmark) - LOAD_OFFSET) { }
141 _edata_loc = LOADADDR(.data.endmark);
142
143 . = ALIGN(PAGE_SIZE);
144 __init_end = .;
145
146 BSS_SECTION(0, 0, 8)
147#ifdef CONFIG_ARM_MPU
148 . = ALIGN(PMSAv8_MINALIGN);
149#endif
150 _end = .;
151
152 STABS_DEBUG
153 DWARF_DEBUG
154 ARM_DETAILS
155
156 ARM_ASSERTS
157}
158
159/*
160 * These must never be empty
161 * If you have to comment these two assert statements out, your
162 * binutils is too old (for other reasons as well)
163 */
164ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
165ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
166
167#ifdef CONFIG_XIP_DEFLATED_DATA
168/*
169 * The .bss is used as a stack area for __inflate_kernel_data() whose stack
170 * frame is 9568 bytes. Make sure it has extra room left.
171 */
172ASSERT((_end - __bss_start) >= 12288, ".bss too small for CONFIG_XIP_DEFLATED_DATA")
173#endif
174
175#ifdef CONFIG_ARM_MPU
176/*
177 * Due to PMSAv7 restriction on base address and size we have to
178 * enforce minimal alignment restrictions. It was seen that weaker
179 * alignment restriction on _xiprom will likely force XIP address
180 * space spawns multiple MPU regions thus it is likely we run in
181 * situation when we are reprogramming MPU region we run on with
182 * something which doesn't cover reprogramming code itself, so as soon
183 * as we update MPU settings we'd immediately try to execute straight
184 * from background region which is XN.
185 * It seem that alignment in 1M should suit most users.
186 * _exiprom is aligned as 1/8 of 1M so can be covered by subregion
187 * disable
188 */
189ASSERT(!(_xiprom & (SZ_1M - 1)), "XIP start address may cause MPU programming issues")
190ASSERT(!(_exiprom & (SZ_128K - 1)), "XIP end address may cause MPU programming issues")
191#endif