Loading...
1#!/usr/bin/perl -w
2#
3# Copyright 2005-2009 - Steven Rostedt
4# Licensed under the terms of the GNU GPL License version 2
5#
6# It's simple enough to figure out how this works.
7# If not, then you can ask me at stripconfig@goodmis.org
8#
9# What it does?
10#
11# If you have installed a Linux kernel from a distribution
12# that turns on way too many modules than you need, and
13# you only want the modules you use, then this program
14# is perfect for you.
15#
16# It gives you the ability to turn off all the modules that are
17# not loaded on your system.
18#
19# Howto:
20#
21# 1. Boot up the kernel that you want to stream line the config on.
22# 2. Change directory to the directory holding the source of the
23# kernel that you just booted.
24# 3. Copy the configuraton file to this directory as .config
25# 4. Have all your devices that you need modules for connected and
26# operational (make sure that their corresponding modules are loaded)
27# 5. Run this script redirecting the output to some other file
28# like config_strip.
29# 6. Back up your old config (if you want too).
30# 7. copy the config_strip file to .config
31# 8. Run "make oldconfig"
32#
33# Now your kernel is ready to be built with only the modules that
34# are loaded.
35#
36# Here's what I did with my Debian distribution.
37#
38# cd /usr/src/linux-2.6.10
39# cp /boot/config-2.6.10-1-686-smp .config
40# ~/bin/streamline_config > config_strip
41# mv .config config_sav
42# mv config_strip .config
43# make oldconfig
44#
45use strict;
46use Getopt::Long;
47
48# set the environment variable LOCALMODCONFIG_DEBUG to get
49# debug output.
50my $debugprint = 0;
51$debugprint = 1 if (defined($ENV{LOCALMODCONFIG_DEBUG}));
52
53sub dprint {
54 return if (!$debugprint);
55 print STDERR @_;
56}
57
58my $config = ".config";
59
60my $uname = `uname -r`;
61chomp $uname;
62
63my @searchconfigs = (
64 {
65 "file" => ".config",
66 "exec" => "cat",
67 },
68 {
69 "file" => "/proc/config.gz",
70 "exec" => "zcat",
71 },
72 {
73 "file" => "/boot/config-$uname",
74 "exec" => "cat",
75 },
76 {
77 "file" => "/boot/vmlinuz-$uname",
78 "exec" => "scripts/extract-ikconfig",
79 "test" => "scripts/extract-ikconfig",
80 },
81 {
82 "file" => "vmlinux",
83 "exec" => "scripts/extract-ikconfig",
84 "test" => "scripts/extract-ikconfig",
85 },
86 {
87 "file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
88 "exec" => "scripts/extract-ikconfig",
89 "test" => "scripts/extract-ikconfig",
90 },
91 {
92 "file" => "kernel/configs.ko",
93 "exec" => "scripts/extract-ikconfig",
94 "test" => "scripts/extract-ikconfig",
95 },
96 {
97 "file" => "kernel/configs.o",
98 "exec" => "scripts/extract-ikconfig",
99 "test" => "scripts/extract-ikconfig",
100 },
101);
102
103sub read_config {
104 foreach my $conf (@searchconfigs) {
105 my $file = $conf->{"file"};
106
107 next if ( ! -f "$file");
108
109 if (defined($conf->{"test"})) {
110 `$conf->{"test"} $conf->{"file"} 2>/dev/null`;
111 next if ($?);
112 }
113
114 my $exec = $conf->{"exec"};
115
116 print STDERR "using config: '$file'\n";
117
118 open(my $infile, '-|', "$exec $file") || die "Failed to run $exec $file";
119 my @x = <$infile>;
120 close $infile;
121 return @x;
122 }
123 die "No config file found";
124}
125
126my @config_file = read_config;
127
128# Parse options
129my $localmodconfig = 0;
130my $localyesconfig = 0;
131
132GetOptions("localmodconfig" => \$localmodconfig,
133 "localyesconfig" => \$localyesconfig);
134
135# Get the build source and top level Kconfig file (passed in)
136my $ksource = ($ARGV[0] ? $ARGV[0] : '.');
137my $kconfig = $ARGV[1];
138my $lsmod_file = $ENV{'LSMOD'};
139
140my @makefiles = `find $ksource -name Makefile -or -name Kbuild 2>/dev/null`;
141chomp @makefiles;
142
143my %depends;
144my %selects;
145my %prompts;
146my %objects;
147my $var;
148my $iflevel = 0;
149my @ifdeps;
150
151# prevent recursion
152my %read_kconfigs;
153
154sub read_kconfig {
155 my ($kconfig) = @_;
156
157 my $state = "NONE";
158 my $config;
159
160 my $cont = 0;
161 my $line;
162
163 my $source = "$ksource/$kconfig";
164 my $last_source = "";
165
166 # Check for any environment variables used
167 while ($source =~ /\$(\w+)/ && $last_source ne $source) {
168 my $env = $1;
169 $last_source = $source;
170 $source =~ s/\$$env/$ENV{$env}/;
171 }
172
173 open(my $kinfile, '<', $source) || die "Can't open $kconfig";
174 while (<$kinfile>) {
175 chomp;
176
177 # Make sure that lines ending with \ continue
178 if ($cont) {
179 $_ = $line . " " . $_;
180 }
181
182 if (s/\\$//) {
183 $cont = 1;
184 $line = $_;
185 next;
186 }
187
188 $cont = 0;
189
190 # collect any Kconfig sources
191 if (/^source\s*"(.*)"/) {
192 my $kconfig = $1;
193 # prevent reading twice.
194 if (!defined($read_kconfigs{$kconfig})) {
195 $read_kconfigs{$kconfig} = 1;
196 read_kconfig($kconfig);
197 }
198 next;
199 }
200
201 # configs found
202 if (/^\s*(menu)?config\s+(\S+)\s*$/) {
203 $state = "NEW";
204 $config = $2;
205
206 # Add depends for 'if' nesting
207 for (my $i = 0; $i < $iflevel; $i++) {
208 if ($i) {
209 $depends{$config} .= " " . $ifdeps[$i];
210 } else {
211 $depends{$config} = $ifdeps[$i];
212 }
213 $state = "DEP";
214 }
215
216 # collect the depends for the config
217 } elsif ($state eq "NEW" && /^\s*depends\s+on\s+(.*)$/) {
218 $state = "DEP";
219 $depends{$config} = $1;
220 } elsif ($state eq "DEP" && /^\s*depends\s+on\s+(.*)$/) {
221 $depends{$config} .= " " . $1;
222 } elsif ($state eq "DEP" && /^\s*def(_(bool|tristate)|ault)\s+(\S.*)$/) {
223 my $dep = $3;
224 if ($dep !~ /^\s*(y|m|n)\s*$/) {
225 $dep =~ s/.*\sif\s+//;
226 $depends{$config} .= " " . $dep;
227 dprint "Added default depends $dep to $config\n";
228 }
229
230 # Get the configs that select this config
231 } elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
232 my $conf = $1;
233 if (defined($selects{$conf})) {
234 $selects{$conf} .= " " . $config;
235 } else {
236 $selects{$conf} = $config;
237 }
238
239 # configs without prompts must be selected
240 } elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
241 # note if the config has a prompt
242 $prompts{$config} = 1;
243
244 # Check for if statements
245 } elsif (/^if\s+(.*\S)\s*$/) {
246 my $deps = $1;
247 # remove beginning and ending non text
248 $deps =~ s/^[^a-zA-Z0-9_]*//;
249 $deps =~ s/[^a-zA-Z0-9_]*$//;
250
251 my @deps = split /[^a-zA-Z0-9_]+/, $deps;
252
253 $ifdeps[$iflevel++] = join ':', @deps;
254
255 } elsif (/^endif/) {
256
257 $iflevel-- if ($iflevel);
258
259 # stop on "help"
260 } elsif (/^\s*help\s*$/) {
261 $state = "NONE";
262 }
263 }
264 close($kinfile);
265}
266
267if ($kconfig) {
268 read_kconfig($kconfig);
269}
270
271# Makefiles can use variables to define their dependencies
272sub convert_vars {
273 my ($line, %vars) = @_;
274
275 my $process = "";
276
277 while ($line =~ s/^(.*?)(\$\((.*?)\))//) {
278 my $start = $1;
279 my $variable = $2;
280 my $var = $3;
281
282 if (defined($vars{$var})) {
283 $process .= $start . $vars{$var};
284 } else {
285 $process .= $start . $variable;
286 }
287 }
288
289 $process .= $line;
290
291 return $process;
292}
293
294# Read all Makefiles to map the configs to the objects
295foreach my $makefile (@makefiles) {
296
297 my $line = "";
298 my %make_vars;
299
300 open(my $infile, '<', $makefile) || die "Can't open $makefile";
301 while (<$infile>) {
302 # if this line ends with a backslash, continue
303 chomp;
304 if (/^(.*)\\$/) {
305 $line .= $1;
306 next;
307 }
308
309 $line .= $_;
310 $_ = $line;
311 $line = "";
312
313 my $objs;
314
315 # Convert variables in a line (could define configs)
316 $_ = convert_vars($_, %make_vars);
317
318 # collect objects after obj-$(CONFIG_FOO_BAR)
319 if (/obj-\$\((CONFIG_[^\)]*)\)\s*[+:]?=\s*(.*)/) {
320 $var = $1;
321 $objs = $2;
322
323 # check if variables are set
324 } elsif (/^\s*(\S+)\s*[:]?=\s*(.*\S)/) {
325 $make_vars{$1} = $2;
326 }
327 if (defined($objs)) {
328 foreach my $obj (split /\s+/,$objs) {
329 $obj =~ s/-/_/g;
330 if ($obj =~ /(.*)\.o$/) {
331 # Objects may be enabled by more than one config.
332 # Store configs in an array.
333 my @arr;
334
335 if (defined($objects{$1})) {
336 @arr = @{$objects{$1}};
337 }
338
339 $arr[$#arr+1] = $var;
340
341 # The objects have a hash mapping to a reference
342 # of an array of configs.
343 $objects{$1} = \@arr;
344 }
345 }
346 }
347 }
348 close($infile);
349}
350
351my %modules;
352my $linfile;
353
354if (defined($lsmod_file)) {
355 if ( ! -f $lsmod_file) {
356 if ( -f $ENV{'objtree'}."/".$lsmod_file) {
357 $lsmod_file = $ENV{'objtree'}."/".$lsmod_file;
358 } else {
359 die "$lsmod_file not found";
360 }
361 }
362
363 my $otype = ( -x $lsmod_file) ? '-|' : '<';
364 open($linfile, $otype, $lsmod_file);
365
366} else {
367
368 # see what modules are loaded on this system
369 my $lsmod;
370
371 foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
372 if ( -x "$dir/lsmod" ) {
373 $lsmod = "$dir/lsmod";
374 last;
375 }
376}
377 if (!defined($lsmod)) {
378 # try just the path
379 $lsmod = "lsmod";
380 }
381
382 open($linfile, '-|', $lsmod) || die "Can not call lsmod with $lsmod";
383}
384
385while (<$linfile>) {
386 next if (/^Module/); # Skip the first line.
387 if (/^(\S+)/) {
388 $modules{$1} = 1;
389 }
390}
391close ($linfile);
392
393# add to the configs hash all configs that are needed to enable
394# a loaded module. This is a direct obj-${CONFIG_FOO} += bar.o
395# where we know we need bar.o so we add FOO to the list.
396my %configs;
397foreach my $module (keys(%modules)) {
398 if (defined($objects{$module})) {
399 my @arr = @{$objects{$module}};
400 foreach my $conf (@arr) {
401 $configs{$conf} = $module;
402 dprint "$conf added by direct ($module)\n";
403 if ($debugprint) {
404 my $c=$conf;
405 $c =~ s/^CONFIG_//;
406 if (defined($depends{$c})) {
407 dprint " deps = $depends{$c}\n";
408 } else {
409 dprint " no deps\n";
410 }
411 }
412 }
413 } else {
414 # Most likely, someone has a custom (binary?) module loaded.
415 print STDERR "$module config not found!!\n";
416 }
417}
418
419# Read the current config, and see what is enabled. We want to
420# ignore configs that we would not enable anyway.
421
422my %orig_configs;
423my $valid = "A-Za-z_0-9";
424
425foreach my $line (@config_file) {
426 $_ = $line;
427
428 if (/(CONFIG_[$valid]*)=(m|y)/) {
429 $orig_configs{$1} = $2;
430 }
431}
432
433my $repeat = 1;
434
435my $depconfig;
436
437#
438# Note, we do not care about operands (like: &&, ||, !) we want to add any
439# config that is in the depend list of another config. This script does
440# not enable configs that are not already enabled. If we come across a
441# config A that depends on !B, we can still add B to the list of depends
442# to keep on. If A was on in the original config, B would not have been
443# and B would not be turned on by this script.
444#
445sub parse_config_depends
446{
447 my ($p) = @_;
448
449 while ($p =~ /[$valid]/) {
450
451 if ($p =~ /^[^$valid]*([$valid]+)/) {
452 my $conf = "CONFIG_" . $1;
453
454 $p =~ s/^[^$valid]*[$valid]+//;
455
456 # We only need to process if the depend config is a module
457 if (!defined($orig_configs{$conf}) || !$orig_configs{conf} eq "m") {
458 next;
459 }
460
461 if (!defined($configs{$conf})) {
462 # We must make sure that this config has its
463 # dependencies met.
464 $repeat = 1; # do again
465 dprint "$conf selected by depend $depconfig\n";
466 $configs{$conf} = 1;
467 }
468 } else {
469 die "this should never happen";
470 }
471 }
472}
473
474# Select is treated a bit differently than depends. We call this
475# when a config has no prompt and requires another config to be
476# selected. We use to just select all configs that selected this
477# config, but found that that can balloon into enabling hundreds
478# of configs that we do not care about.
479#
480# The idea is we look at all the configs that select it. If one
481# is already in our list of configs to enable, then there's nothing
482# else to do. If there isn't, we pick the first config that was
483# enabled in the orignal config and use that.
484sub parse_config_selects
485{
486 my ($config, $p) = @_;
487
488 my $next_config;
489
490 while ($p =~ /[$valid]/) {
491
492 if ($p =~ /^[^$valid]*([$valid]+)/) {
493 my $conf = "CONFIG_" . $1;
494
495 $p =~ s/^[^$valid]*[$valid]+//;
496
497 # Make sure that this config exists in the current .config file
498 if (!defined($orig_configs{$conf})) {
499 dprint "$conf not set for $config select\n";
500 next;
501 }
502
503 # Check if something other than a module selects this config
504 if (defined($orig_configs{$conf}) && $orig_configs{$conf} ne "m") {
505 dprint "$conf (non module) selects config, we are good\n";
506 # we are good with this
507 return;
508 }
509 if (defined($configs{$conf})) {
510 dprint "$conf selects $config so we are good\n";
511 # A set config selects this config, we are good
512 return;
513 }
514 # Set this config to be selected
515 if (!defined($next_config)) {
516 $next_config = $conf;
517 }
518 } else {
519 die "this should never happen";
520 }
521 }
522
523 # If no possible config selected this, then something happened.
524 if (!defined($next_config)) {
525 print STDERR "WARNING: $config is required, but nothing in the\n";
526 print STDERR " current config selects it.\n";
527 return;
528 }
529
530 # If we are here, then we found no config that is set and
531 # selects this config. Repeat.
532 $repeat = 1;
533 # Make this config need to be selected
534 $configs{$next_config} = 1;
535 dprint "$next_config selected by select $config\n";
536}
537
538my %process_selects;
539
540# loop through all configs, select their dependencies.
541sub loop_depend {
542 $repeat = 1;
543
544 while ($repeat) {
545 $repeat = 0;
546
547 forloop:
548 foreach my $config (keys %configs) {
549
550 # If this config is not a module, we do not need to process it
551 if (defined($orig_configs{$config}) && $orig_configs{$config} ne "m") {
552 next forloop;
553 }
554
555 $config =~ s/^CONFIG_//;
556 $depconfig = $config;
557
558 if (defined($depends{$config})) {
559 # This config has dependencies. Make sure they are also included
560 parse_config_depends $depends{$config};
561 }
562
563 # If the config has no prompt, then we need to check if a config
564 # that is enabled selected it. Or if we need to enable one.
565 if (!defined($prompts{$config}) && defined($selects{$config})) {
566 $process_selects{$config} = 1;
567 }
568 }
569 }
570}
571
572sub loop_select {
573
574 foreach my $config (keys %process_selects) {
575 $config =~ s/^CONFIG_//;
576
577 dprint "Process select $config\n";
578
579 # config has no prompt and must be selected.
580 parse_config_selects $config, $selects{$config};
581 }
582}
583
584while ($repeat) {
585 # Get the first set of configs and their dependencies.
586 loop_depend;
587
588 $repeat = 0;
589
590 # Now we need to see if we have to check selects;
591 loop_select;
592}
593
594my %setconfigs;
595
596# Finally, read the .config file and turn off any module enabled that
597# we could not find a reason to keep enabled.
598foreach my $line (@config_file) {
599 $_ = $line;
600
601 if (/CONFIG_IKCONFIG/) {
602 if (/# CONFIG_IKCONFIG is not set/) {
603 # enable IKCONFIG at least as a module
604 print "CONFIG_IKCONFIG=m\n";
605 # don't ask about PROC
606 print "# CONFIG_IKCONFIG_PROC is not set\n";
607 } else {
608 print;
609 }
610 next;
611 }
612
613 if (/^(CONFIG.*)=(m|y)/) {
614 if (defined($configs{$1})) {
615 if ($localyesconfig) {
616 $setconfigs{$1} = 'y';
617 print "$1=y\n";
618 next;
619 } else {
620 $setconfigs{$1} = $2;
621 }
622 } elsif ($2 eq "m") {
623 print "# $1 is not set\n";
624 next;
625 }
626 }
627 print;
628}
629
630# Integrity check, make sure all modules that we want enabled do
631# indeed have their configs set.
632loop:
633foreach my $module (keys(%modules)) {
634 if (defined($objects{$module})) {
635 my @arr = @{$objects{$module}};
636 foreach my $conf (@arr) {
637 if (defined($setconfigs{$conf})) {
638 next loop;
639 }
640 }
641 print STDERR "module $module did not have configs";
642 foreach my $conf (@arr) {
643 print STDERR " " , $conf;
644 }
645 print STDERR "\n";
646 }
647}
1#!/usr/bin/perl -w
2#
3# Copyright 2005-2009 - Steven Rostedt
4# Licensed under the terms of the GNU GPL License version 2
5#
6# It's simple enough to figure out how this works.
7# If not, then you can ask me at stripconfig@goodmis.org
8#
9# What it does?
10#
11# If you have installed a Linux kernel from a distribution
12# that turns on way too many modules than you need, and
13# you only want the modules you use, then this program
14# is perfect for you.
15#
16# It gives you the ability to turn off all the modules that are
17# not loaded on your system.
18#
19# Howto:
20#
21# 1. Boot up the kernel that you want to stream line the config on.
22# 2. Change directory to the directory holding the source of the
23# kernel that you just booted.
24# 3. Copy the configuraton file to this directory as .config
25# 4. Have all your devices that you need modules for connected and
26# operational (make sure that their corresponding modules are loaded)
27# 5. Run this script redirecting the output to some other file
28# like config_strip.
29# 6. Back up your old config (if you want too).
30# 7. copy the config_strip file to .config
31# 8. Run "make oldconfig"
32#
33# Now your kernel is ready to be built with only the modules that
34# are loaded.
35#
36# Here's what I did with my Debian distribution.
37#
38# cd /usr/src/linux-2.6.10
39# cp /boot/config-2.6.10-1-686-smp .config
40# ~/bin/streamline_config > config_strip
41# mv .config config_sav
42# mv config_strip .config
43# make oldconfig
44#
45use strict;
46
47my $config = ".config";
48
49my $uname = `uname -r`;
50chomp $uname;
51
52my @searchconfigs = (
53 {
54 "file" => ".config",
55 "exec" => "cat",
56 },
57 {
58 "file" => "/proc/config.gz",
59 "exec" => "zcat",
60 },
61 {
62 "file" => "/boot/config-$uname",
63 "exec" => "cat",
64 },
65 {
66 "file" => "/boot/vmlinuz-$uname",
67 "exec" => "scripts/extract-ikconfig",
68 "test" => "scripts/extract-ikconfig",
69 },
70 {
71 "file" => "vmlinux",
72 "exec" => "scripts/extract-ikconfig",
73 "test" => "scripts/extract-ikconfig",
74 },
75 {
76 "file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
77 "exec" => "scripts/extract-ikconfig",
78 "test" => "scripts/extract-ikconfig",
79 },
80 {
81 "file" => "kernel/configs.ko",
82 "exec" => "scripts/extract-ikconfig",
83 "test" => "scripts/extract-ikconfig",
84 },
85 {
86 "file" => "kernel/configs.o",
87 "exec" => "scripts/extract-ikconfig",
88 "test" => "scripts/extract-ikconfig",
89 },
90);
91
92sub find_config {
93 foreach my $conf (@searchconfigs) {
94 my $file = $conf->{"file"};
95
96 next if ( ! -f "$file");
97
98 if (defined($conf->{"test"})) {
99 `$conf->{"test"} $conf->{"file"} 2>/dev/null`;
100 next if ($?);
101 }
102
103 my $exec = $conf->{"exec"};
104
105 print STDERR "using config: '$file'\n";
106
107 open(CIN, "$exec $file |") || die "Failed to run $exec $file";
108 return;
109 }
110 die "No config file found";
111}
112
113find_config;
114
115# Get the build source and top level Kconfig file (passed in)
116my $ksource = $ARGV[0];
117my $kconfig = $ARGV[1];
118my $lsmod_file = $ARGV[2];
119
120my @makefiles = `find $ksource -name Makefile 2>/dev/null`;
121chomp @makefiles;
122
123my %depends;
124my %selects;
125my %prompts;
126my %objects;
127my $var;
128my $iflevel = 0;
129my @ifdeps;
130
131# prevent recursion
132my %read_kconfigs;
133
134sub read_kconfig {
135 my ($kconfig) = @_;
136
137 my $state = "NONE";
138 my $config;
139 my @kconfigs;
140
141 my $cont = 0;
142 my $line;
143
144 my $source = "$ksource/$kconfig";
145 my $last_source = "";
146
147 # Check for any environment variables used
148 while ($source =~ /\$(\w+)/ && $last_source ne $source) {
149 my $env = $1;
150 $last_source = $source;
151 $source =~ s/\$$env/$ENV{$env}/;
152 }
153
154 open(KIN, "$source") || die "Can't open $kconfig";
155 while (<KIN>) {
156 chomp;
157
158 # Make sure that lines ending with \ continue
159 if ($cont) {
160 $_ = $line . " " . $_;
161 }
162
163 if (s/\\$//) {
164 $cont = 1;
165 $line = $_;
166 next;
167 }
168
169 $cont = 0;
170
171 # collect any Kconfig sources
172 if (/^source\s*"(.*)"/) {
173 $kconfigs[$#kconfigs+1] = $1;
174 }
175
176 # configs found
177 if (/^\s*(menu)?config\s+(\S+)\s*$/) {
178 $state = "NEW";
179 $config = $2;
180
181 for (my $i = 0; $i < $iflevel; $i++) {
182 if ($i) {
183 $depends{$config} .= " " . $ifdeps[$i];
184 } else {
185 $depends{$config} = $ifdeps[$i];
186 }
187 $state = "DEP";
188 }
189
190 # collect the depends for the config
191 } elsif ($state eq "NEW" && /^\s*depends\s+on\s+(.*)$/) {
192 $state = "DEP";
193 $depends{$config} = $1;
194 } elsif ($state eq "DEP" && /^\s*depends\s+on\s+(.*)$/) {
195 $depends{$config} .= " " . $1;
196
197 # Get the configs that select this config
198 } elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
199 if (defined($selects{$1})) {
200 $selects{$1} .= " " . $config;
201 } else {
202 $selects{$1} = $config;
203 }
204
205 # configs without prompts must be selected
206 } elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
207 # note if the config has a prompt
208 $prompts{$config} = 1;
209
210 # Check for if statements
211 } elsif (/^if\s+(.*\S)\s*$/) {
212 my $deps = $1;
213 # remove beginning and ending non text
214 $deps =~ s/^[^a-zA-Z0-9_]*//;
215 $deps =~ s/[^a-zA-Z0-9_]*$//;
216
217 my @deps = split /[^a-zA-Z0-9_]+/, $deps;
218
219 $ifdeps[$iflevel++] = join ':', @deps;
220
221 } elsif (/^endif/) {
222
223 $iflevel-- if ($iflevel);
224
225 # stop on "help"
226 } elsif (/^\s*help\s*$/) {
227 $state = "NONE";
228 }
229 }
230 close(KIN);
231
232 # read in any configs that were found.
233 foreach $kconfig (@kconfigs) {
234 if (!defined($read_kconfigs{$kconfig})) {
235 $read_kconfigs{$kconfig} = 1;
236 read_kconfig($kconfig);
237 }
238 }
239}
240
241if ($kconfig) {
242 read_kconfig($kconfig);
243}
244
245# Read all Makefiles to map the configs to the objects
246foreach my $makefile (@makefiles) {
247
248 my $cont = 0;
249
250 open(MIN,$makefile) || die "Can't open $makefile";
251 while (<MIN>) {
252 my $objs;
253
254 # is this a line after a line with a backslash?
255 if ($cont && /(\S.*)$/) {
256 $objs = $1;
257 }
258 $cont = 0;
259
260 # collect objects after obj-$(CONFIG_FOO_BAR)
261 if (/obj-\$\((CONFIG_[^\)]*)\)\s*[+:]?=\s*(.*)/) {
262 $var = $1;
263 $objs = $2;
264 }
265 if (defined($objs)) {
266 # test if the line ends with a backslash
267 if ($objs =~ m,(.*)\\$,) {
268 $objs = $1;
269 $cont = 1;
270 }
271
272 foreach my $obj (split /\s+/,$objs) {
273 $obj =~ s/-/_/g;
274 if ($obj =~ /(.*)\.o$/) {
275 # Objects may be enabled by more than one config.
276 # Store configs in an array.
277 my @arr;
278
279 if (defined($objects{$1})) {
280 @arr = @{$objects{$1}};
281 }
282
283 $arr[$#arr+1] = $var;
284
285 # The objects have a hash mapping to a reference
286 # of an array of configs.
287 $objects{$1} = \@arr;
288 }
289 }
290 }
291 }
292 close(MIN);
293}
294
295my %modules;
296
297if (defined($lsmod_file)) {
298 if ( ! -f $lsmod_file) {
299 die "$lsmod_file not found";
300 }
301 if ( -x $lsmod_file) {
302 # the file is executable, run it
303 open(LIN, "$lsmod_file|");
304 } else {
305 # Just read the contents
306 open(LIN, "$lsmod_file");
307 }
308} else {
309
310 # see what modules are loaded on this system
311 my $lsmod;
312
313 foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
314 if ( -x "$dir/lsmod" ) {
315 $lsmod = "$dir/lsmod";
316 last;
317 }
318}
319 if (!defined($lsmod)) {
320 # try just the path
321 $lsmod = "lsmod";
322 }
323
324 open(LIN,"$lsmod|") || die "Can not call lsmod with $lsmod";
325}
326
327while (<LIN>) {
328 next if (/^Module/); # Skip the first line.
329 if (/^(\S+)/) {
330 $modules{$1} = 1;
331 }
332}
333close (LIN);
334
335# add to the configs hash all configs that are needed to enable
336# a loaded module.
337my %configs;
338foreach my $module (keys(%modules)) {
339 if (defined($objects{$module})) {
340 my @arr = @{$objects{$module}};
341 foreach my $conf (@arr) {
342 $configs{$conf} = $module;
343 }
344 } else {
345 # Most likely, someone has a custom (binary?) module loaded.
346 print STDERR "$module config not found!!\n";
347 }
348}
349
350my $valid = "A-Za-z_0-9";
351my $repeat = 1;
352
353#
354# Note, we do not care about operands (like: &&, ||, !) we want to add any
355# config that is in the depend list of another config. This script does
356# not enable configs that are not already enabled. If we come across a
357# config A that depends on !B, we can still add B to the list of depends
358# to keep on. If A was on in the original config, B would not have been
359# and B would not be turned on by this script.
360#
361sub parse_config_dep_select
362{
363 my ($p) = @_;
364
365 while ($p =~ /[$valid]/) {
366
367 if ($p =~ /^[^$valid]*([$valid]+)/) {
368 my $conf = "CONFIG_" . $1;
369
370 $p =~ s/^[^$valid]*[$valid]+//;
371
372 if (!defined($configs{$conf})) {
373 # We must make sure that this config has its
374 # dependencies met.
375 $repeat = 1; # do again
376 $configs{$conf} = 1;
377 }
378 } else {
379 die "this should never happen";
380 }
381 }
382}
383
384while ($repeat) {
385 $repeat = 0;
386
387 foreach my $config (keys %configs) {
388 $config =~ s/^CONFIG_//;
389
390 if (defined($depends{$config})) {
391 # This config has dependencies. Make sure they are also included
392 parse_config_dep_select $depends{$config};
393 }
394
395 if (defined($prompts{$config}) || !defined($selects{$config})) {
396 next;
397 }
398
399 # config has no prompt and must be selected.
400 parse_config_dep_select $selects{$config};
401 }
402}
403
404my %setconfigs;
405
406# Finally, read the .config file and turn off any module enabled that
407# we could not find a reason to keep enabled.
408while(<CIN>) {
409
410 if (/CONFIG_IKCONFIG/) {
411 if (/# CONFIG_IKCONFIG is not set/) {
412 # enable IKCONFIG at least as a module
413 print "CONFIG_IKCONFIG=m\n";
414 # don't ask about PROC
415 print "# CONFIG_IKCONFIG_PROC is not set\n";
416 } else {
417 print;
418 }
419 next;
420 }
421
422 if (/^(CONFIG.*)=(m|y)/) {
423 if (defined($configs{$1})) {
424 $setconfigs{$1} = $2;
425 } elsif ($2 eq "m") {
426 print "# $1 is not set\n";
427 next;
428 }
429 }
430 print;
431}
432close(CIN);
433
434# Integrity check, make sure all modules that we want enabled do
435# indeed have their configs set.
436loop:
437foreach my $module (keys(%modules)) {
438 if (defined($objects{$module})) {
439 my @arr = @{$objects{$module}};
440 foreach my $conf (@arr) {
441 if (defined($setconfigs{$conf})) {
442 next loop;
443 }
444 }
445 print STDERR "module $module did not have configs";
446 foreach my $conf (@arr) {
447 print STDERR " " , $conf;
448 }
449 print STDERR "\n";
450 }
451}