Loading...
1
2%option reentrant
3%option bison-bridge
4%option prefix="parse_events_"
5%option stack
6%option bison-locations
7%option yylineno
8%option reject
9
10%{
11#include <errno.h>
12#include <sys/types.h>
13#include <sys/stat.h>
14#include <unistd.h>
15#include "../perf.h"
16#include "parse-events.h"
17#include "parse-events-bison.h"
18
19char *parse_events_get_text(yyscan_t yyscanner);
20YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
21
22static int __value(YYSTYPE *yylval, char *str, int base, int token)
23{
24 u64 num;
25
26 errno = 0;
27 num = strtoull(str, NULL, base);
28 if (errno)
29 return PE_ERROR;
30
31 yylval->num = num;
32 return token;
33}
34
35static int value(yyscan_t scanner, int base)
36{
37 YYSTYPE *yylval = parse_events_get_lval(scanner);
38 char *text = parse_events_get_text(scanner);
39
40 return __value(yylval, text, base, PE_VALUE);
41}
42
43static int raw(yyscan_t scanner)
44{
45 YYSTYPE *yylval = parse_events_get_lval(scanner);
46 char *text = parse_events_get_text(scanner);
47
48 return __value(yylval, text + 1, 16, PE_RAW);
49}
50
51static int str(yyscan_t scanner, int token)
52{
53 YYSTYPE *yylval = parse_events_get_lval(scanner);
54 char *text = parse_events_get_text(scanner);
55
56 yylval->str = strdup(text);
57 return token;
58}
59
60static bool isbpf_suffix(char *text)
61{
62 int len = strlen(text);
63
64 if (len < 2)
65 return false;
66 if ((text[len - 1] == 'c' || text[len - 1] == 'o') &&
67 text[len - 2] == '.')
68 return true;
69 if (len > 4 && !strcmp(text + len - 4, ".obj"))
70 return true;
71 return false;
72}
73
74static bool isbpf(yyscan_t scanner)
75{
76 char *text = parse_events_get_text(scanner);
77 struct stat st;
78
79 if (!isbpf_suffix(text))
80 return false;
81
82 return stat(text, &st) == 0;
83}
84
85/*
86 * This function is called when the parser gets two kind of input:
87 *
88 * @cfg1 or @cfg2=config
89 *
90 * The leading '@' is stripped off before 'cfg1' and 'cfg2=config' are given to
91 * bison. In the latter case it is necessary to keep the string intact so that
92 * the PMU kernel driver can determine what configurable is associated to
93 * 'config'.
94 */
95static int drv_str(yyscan_t scanner, int token)
96{
97 YYSTYPE *yylval = parse_events_get_lval(scanner);
98 char *text = parse_events_get_text(scanner);
99
100 /* Strip off the '@' */
101 yylval->str = strdup(text + 1);
102 return token;
103}
104
105#define REWIND(__alloc) \
106do { \
107 YYSTYPE *__yylval = parse_events_get_lval(yyscanner); \
108 char *text = parse_events_get_text(yyscanner); \
109 \
110 if (__alloc) \
111 __yylval->str = strdup(text); \
112 \
113 yycolumn -= strlen(text); \
114 yyless(0); \
115} while (0)
116
117static int pmu_str_check(yyscan_t scanner)
118{
119 YYSTYPE *yylval = parse_events_get_lval(scanner);
120 char *text = parse_events_get_text(scanner);
121
122 yylval->str = strdup(text);
123 switch (perf_pmu__parse_check(text)) {
124 case PMU_EVENT_SYMBOL_PREFIX:
125 return PE_PMU_EVENT_PRE;
126 case PMU_EVENT_SYMBOL_SUFFIX:
127 return PE_PMU_EVENT_SUF;
128 case PMU_EVENT_SYMBOL:
129 return PE_KERNEL_PMU_EVENT;
130 default:
131 return PE_NAME;
132 }
133}
134
135static int sym(yyscan_t scanner, int type, int config)
136{
137 YYSTYPE *yylval = parse_events_get_lval(scanner);
138
139 yylval->num = (type << 16) + config;
140 return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
141}
142
143static int term(yyscan_t scanner, int type)
144{
145 YYSTYPE *yylval = parse_events_get_lval(scanner);
146
147 yylval->num = type;
148 return PE_TERM;
149}
150
151#define YY_USER_ACTION \
152do { \
153 yylloc->last_column = yylloc->first_column; \
154 yylloc->first_column = yycolumn; \
155 yycolumn += yyleng; \
156} while (0);
157
158#define USER_REJECT \
159 yycolumn -= yyleng; \
160 REJECT
161
162%}
163
164%x mem
165%s config
166%x event
167%x array
168
169group [^,{}/]*[{][^}]*[}][^,{}/]*
170event_pmu [^,{}/]+[/][^/]*[/][^,{}/]*
171event [^,{}/]+
172bpf_object [^,{}]+\.(o|bpf)[a-zA-Z0-9._]*
173bpf_source [^,{}]+\.c[a-zA-Z0-9._]*
174
175num_dec [0-9]+
176num_hex 0x[a-fA-F0-9]+
177num_raw_hex [a-fA-F0-9]+
178name [a-zA-Z_*?\[\]][a-zA-Z0-9_*?.\[\]]*
179name_minus [a-zA-Z_*?][a-zA-Z0-9\-_*?.:]*
180drv_cfg_term [a-zA-Z0-9_\.]+(=[a-zA-Z0-9_*?\.:]+)?
181/* If you add a modifier you need to update check_modifier() */
182modifier_event [ukhpPGHSDIW]+
183modifier_bp [rwx]{1,3}
184
185%%
186
187%{
188 {
189 int start_token;
190
191 start_token = parse_events_get_extra(yyscanner);
192
193 if (start_token == PE_START_TERMS)
194 BEGIN(config);
195 else if (start_token == PE_START_EVENTS)
196 BEGIN(event);
197
198 if (start_token) {
199 parse_events_set_extra(NULL, yyscanner);
200 /*
201 * The flex parser does not init locations variable
202 * via the scan_string interface, so we need do the
203 * init in here.
204 */
205 yycolumn = 0;
206 return start_token;
207 }
208 }
209%}
210
211<event>{
212
213{group} {
214 BEGIN(INITIAL);
215 REWIND(0);
216 }
217
218{event_pmu} |
219{bpf_object} |
220{bpf_source} |
221{event} {
222 BEGIN(INITIAL);
223 REWIND(1);
224 return PE_EVENT_NAME;
225 }
226
227<<EOF>> {
228 BEGIN(INITIAL);
229 REWIND(0);
230 }
231
232}
233
234<array>{
235"]" { BEGIN(config); return ']'; }
236{num_dec} { return value(yyscanner, 10); }
237{num_hex} { return value(yyscanner, 16); }
238, { return ','; }
239"\.\.\." { return PE_ARRAY_RANGE; }
240}
241
242<config>{
243 /*
244 * Please update config_term_names when new static term is added.
245 */
246config { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
247config1 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
248config2 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
249name { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
250period { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
251freq { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
252branch_type { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
253time { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
254call-graph { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
255stack-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
256max-stack { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_MAX_STACK); }
257inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_INHERIT); }
258no-inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOINHERIT); }
259overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_OVERWRITE); }
260no-overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOOVERWRITE); }
261, { return ','; }
262"/" { BEGIN(INITIAL); return '/'; }
263{name_minus} { return str(yyscanner, PE_NAME); }
264\[all\] { return PE_ARRAY_ALL; }
265"[" { BEGIN(array); return '['; }
266@{drv_cfg_term} { return drv_str(yyscanner, PE_DRV_CFG_TERM); }
267}
268
269<mem>{
270{modifier_bp} { return str(yyscanner, PE_MODIFIER_BP); }
271: { return ':'; }
272"/" { return '/'; }
273{num_dec} { return value(yyscanner, 10); }
274{num_hex} { return value(yyscanner, 16); }
275 /*
276 * We need to separate 'mem:' scanner part, in order to get specific
277 * modifier bits parsed out. Otherwise we would need to handle PE_NAME
278 * and we'd need to parse it manually. During the escape from <mem>
279 * state we need to put the escaping char back, so we dont miss it.
280 */
281. { unput(*yytext); BEGIN(INITIAL); }
282 /*
283 * We destroy the scanner after reaching EOF,
284 * but anyway just to be sure get back to INIT state.
285 */
286<<EOF>> { BEGIN(INITIAL); }
287}
288
289cpu-cycles|cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
290stalled-cycles-frontend|idle-cycles-frontend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
291stalled-cycles-backend|idle-cycles-backend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
292instructions { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
293cache-references { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
294cache-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
295branch-instructions|branches { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
296branch-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
297bus-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
298ref-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
299cpu-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
300task-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
301page-faults|faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
302minor-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
303major-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
304context-switches|cs { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
305cpu-migrations|migrations { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
306alignment-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
307emulation-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
308dummy { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
309duration_time { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
310bpf-output { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_BPF_OUTPUT); }
311
312 /*
313 * We have to handle the kernel PMU event cycles-ct/cycles-t/mem-loads/mem-stores separately.
314 * Because the prefix cycles is mixed up with cpu-cycles.
315 * loads and stores are mixed up with cache event
316 */
317cycles-ct { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
318cycles-t { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
319mem-loads { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
320mem-stores { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
321topdown-[a-z-]+ { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
322
323L1-dcache|l1-d|l1d|L1-data |
324L1-icache|l1-i|l1i|L1-instruction |
325LLC|L2 |
326dTLB|d-tlb|Data-TLB |
327iTLB|i-tlb|Instruction-TLB |
328branch|branches|bpu|btb|bpc |
329node { return str(yyscanner, PE_NAME_CACHE_TYPE); }
330
331load|loads|read |
332store|stores|write |
333prefetch|prefetches |
334speculative-read|speculative-load |
335refs|Reference|ops|access |
336misses|miss { return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }
337
338mem: { BEGIN(mem); return PE_PREFIX_MEM; }
339r{num_raw_hex} { return raw(yyscanner); }
340{num_dec} { return value(yyscanner, 10); }
341{num_hex} { return value(yyscanner, 16); }
342
343{modifier_event} { return str(yyscanner, PE_MODIFIER_EVENT); }
344{bpf_object} { if (!isbpf(yyscanner)) { USER_REJECT }; return str(yyscanner, PE_BPF_OBJECT); }
345{bpf_source} { if (!isbpf(yyscanner)) { USER_REJECT }; return str(yyscanner, PE_BPF_SOURCE); }
346{name} { return pmu_str_check(yyscanner); }
347"/" { BEGIN(config); return '/'; }
348- { return '-'; }
349, { BEGIN(event); return ','; }
350: { return ':'; }
351"{" { BEGIN(event); return '{'; }
352"}" { return '}'; }
353= { return '='; }
354\n { }
355. { }
356
357%%
358
359int parse_events_wrap(void *scanner __maybe_unused)
360{
361 return 1;
362}
1
2%option reentrant
3%option bison-bridge
4%option prefix="parse_events_"
5%option stack
6%option bison-locations
7%option yylineno
8%option reject
9
10%{
11#include <errno.h>
12#include <sys/types.h>
13#include <sys/stat.h>
14#include <unistd.h>
15#include "parse-events.h"
16#include "parse-events-bison.h"
17#include "evsel.h"
18
19char *parse_events_get_text(yyscan_t yyscanner);
20YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
21
22static int __value(YYSTYPE *yylval, char *str, int base, int token)
23{
24 u64 num;
25
26 errno = 0;
27 num = strtoull(str, NULL, base);
28 if (errno)
29 return PE_ERROR;
30
31 yylval->num = num;
32 return token;
33}
34
35static int value(yyscan_t scanner, int base)
36{
37 YYSTYPE *yylval = parse_events_get_lval(scanner);
38 char *text = parse_events_get_text(scanner);
39
40 return __value(yylval, text, base, PE_VALUE);
41}
42
43static int str(yyscan_t scanner, int token)
44{
45 YYSTYPE *yylval = parse_events_get_lval(scanner);
46 char *text = parse_events_get_text(scanner);
47
48 if (text[0] != '\'') {
49 yylval->str = strdup(text);
50 } else {
51 /*
52 * If a text tag specified on the command line
53 * contains opening single quite ' then it is
54 * expected that the tag ends with single quote
55 * as well, like this:
56 * name=\'CPU_CLK_UNHALTED.THREAD:cmask=1\'
57 * quotes need to be escaped to bypass shell
58 * processing.
59 */
60 yylval->str = strndup(&text[1], strlen(text) - 2);
61 }
62
63 return token;
64}
65
66static int lc_str(yyscan_t scanner, const struct parse_events_state *state)
67{
68 return str(scanner, state->match_legacy_cache_terms ? PE_LEGACY_CACHE : PE_NAME);
69}
70
71/*
72 * This function is called when the parser gets two kind of input:
73 *
74 * @cfg1 or @cfg2=config
75 *
76 * The leading '@' is stripped off before 'cfg1' and 'cfg2=config' are given to
77 * bison. In the latter case it is necessary to keep the string intact so that
78 * the PMU kernel driver can determine what configurable is associated to
79 * 'config'.
80 */
81static int drv_str(yyscan_t scanner, int token)
82{
83 YYSTYPE *yylval = parse_events_get_lval(scanner);
84 char *text = parse_events_get_text(scanner);
85
86 /* Strip off the '@' */
87 yylval->str = strdup(text + 1);
88 return token;
89}
90
91#define REWIND(__alloc) \
92do { \
93 YYSTYPE *__yylval = parse_events_get_lval(yyscanner); \
94 char *text = parse_events_get_text(yyscanner); \
95 \
96 if (__alloc) \
97 __yylval->str = strdup(text); \
98 \
99 yycolumn -= strlen(text); \
100 yyless(0); \
101} while (0)
102
103static int sym(yyscan_t scanner, int type, int config)
104{
105 YYSTYPE *yylval = parse_events_get_lval(scanner);
106
107 yylval->num = (type << 16) + config;
108 return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
109}
110
111static int tool(yyscan_t scanner, enum perf_tool_event event)
112{
113 YYSTYPE *yylval = parse_events_get_lval(scanner);
114
115 yylval->num = event;
116 return PE_VALUE_SYM_TOOL;
117}
118
119static int term(yyscan_t scanner, enum parse_events__term_type type)
120{
121 YYSTYPE *yylval = parse_events_get_lval(scanner);
122
123 yylval->term_type = type;
124 return PE_TERM;
125}
126
127static int hw_term(yyscan_t scanner, int config)
128{
129 YYSTYPE *yylval = parse_events_get_lval(scanner);
130 char *text = parse_events_get_text(scanner);
131
132 yylval->hardware_term.str = strdup(text);
133 yylval->hardware_term.num = PERF_TYPE_HARDWARE + config;
134 return PE_TERM_HW;
135}
136
137#define YY_USER_ACTION \
138do { \
139 yylloc->last_column = yylloc->first_column; \
140 yylloc->first_column = yycolumn; \
141 yycolumn += yyleng; \
142} while (0);
143
144#define USER_REJECT \
145 yycolumn -= yyleng; \
146 REJECT
147
148%}
149
150%x mem
151%s config
152%x event
153
154group [^,{}/]*[{][^}]*[}][^,{}/]*
155event_pmu [^,{}/]+[/][^/]*[/][^,{}/]*
156event [^,{}/]+
157
158num_dec [0-9]+
159num_hex 0x[a-fA-F0-9]{1,16}
160num_raw_hex [a-fA-F0-9]{1,16}
161name [a-zA-Z_*?\[\]][a-zA-Z0-9_*?.\[\]!\-]*
162name_tag [\'][a-zA-Z_*?\[\]][a-zA-Z0-9_*?\-,\.\[\]:=]*[\']
163name_minus [a-zA-Z_*?][a-zA-Z0-9\-_*?.:]*
164drv_cfg_term [a-zA-Z0-9_\.]+(=[a-zA-Z0-9_*?\.:]+)?
165/*
166 * If you add a modifier you need to update check_modifier().
167 * Also, the letters in modifier_event must not be in modifier_bp.
168 */
169modifier_event [ukhpPGHSDIWeb]+
170modifier_bp [rwx]{1,3}
171lc_type (L1-dcache|l1-d|l1d|L1-data|L1-icache|l1-i|l1i|L1-instruction|LLC|L2|dTLB|d-tlb|Data-TLB|iTLB|i-tlb|Instruction-TLB|branch|branches|bpu|btb|bpc|node)
172lc_op_result (load|loads|read|store|stores|write|prefetch|prefetches|speculative-read|speculative-load|refs|Reference|ops|access|misses|miss)
173digit [0-9]
174non_digit [^0-9]
175
176%%
177
178%{
179 struct parse_events_state *_parse_state = parse_events_get_extra(yyscanner);
180 {
181 int start_token = _parse_state->stoken;
182
183 if (start_token == PE_START_TERMS)
184 BEGIN(config);
185 else if (start_token == PE_START_EVENTS)
186 BEGIN(event);
187
188 if (start_token) {
189 _parse_state->stoken = 0;
190 /*
191 * The flex parser does not init locations variable
192 * via the scan_string interface, so we need do the
193 * init in here.
194 */
195 yycolumn = 0;
196 return start_token;
197 }
198 }
199%}
200
201<event>{
202
203{group} {
204 BEGIN(INITIAL);
205 REWIND(0);
206 }
207
208{event_pmu} |
209{event} {
210 BEGIN(INITIAL);
211 REWIND(1);
212 return PE_EVENT_NAME;
213 }
214
215<<EOF>> {
216 BEGIN(INITIAL);
217 REWIND(0);
218 }
219, {
220 return ',';
221 }
222}
223
224<config>{
225 /*
226 * Please update config_term_names when new static term is added.
227 */
228config { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
229config1 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
230config2 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
231config3 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG3); }
232name { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
233period { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
234freq { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
235branch_type { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
236time { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
237call-graph { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
238stack-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
239max-stack { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_MAX_STACK); }
240nr { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_MAX_EVENTS); }
241inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_INHERIT); }
242no-inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOINHERIT); }
243overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_OVERWRITE); }
244no-overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOOVERWRITE); }
245percore { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_PERCORE); }
246aux-output { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_AUX_OUTPUT); }
247aux-sample-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_AUX_SAMPLE_SIZE); }
248metric-id { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_METRIC_ID); }
249cpu-cycles|cycles { return hw_term(yyscanner, PERF_COUNT_HW_CPU_CYCLES); }
250stalled-cycles-frontend|idle-cycles-frontend { return hw_term(yyscanner, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
251stalled-cycles-backend|idle-cycles-backend { return hw_term(yyscanner, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
252instructions { return hw_term(yyscanner, PERF_COUNT_HW_INSTRUCTIONS); }
253cache-references { return hw_term(yyscanner, PERF_COUNT_HW_CACHE_REFERENCES); }
254cache-misses { return hw_term(yyscanner, PERF_COUNT_HW_CACHE_MISSES); }
255branch-instructions|branches { return hw_term(yyscanner, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
256branch-misses { return hw_term(yyscanner, PERF_COUNT_HW_BRANCH_MISSES); }
257bus-cycles { return hw_term(yyscanner, PERF_COUNT_HW_BUS_CYCLES); }
258ref-cycles { return hw_term(yyscanner, PERF_COUNT_HW_REF_CPU_CYCLES); }
259r{num_raw_hex} { return str(yyscanner, PE_RAW); }
260r0x{num_raw_hex} { return str(yyscanner, PE_RAW); }
261, { return ','; }
262"/" { BEGIN(INITIAL); return '/'; }
263{lc_type} { return lc_str(yyscanner, _parse_state); }
264{lc_type}-{lc_op_result} { return lc_str(yyscanner, _parse_state); }
265{lc_type}-{lc_op_result}-{lc_op_result} { return lc_str(yyscanner, _parse_state); }
266{name_minus} { return str(yyscanner, PE_NAME); }
267@{drv_cfg_term} { return drv_str(yyscanner, PE_DRV_CFG_TERM); }
268}
269
270<mem>{
271{modifier_bp} { return str(yyscanner, PE_MODIFIER_BP); }
272 /*
273 * The colon before memory access modifiers can get mixed up with the
274 * colon before event modifiers. Fortunately none of the option letters
275 * are the same, so trailing context can be used disambiguate the two
276 * cases.
277 */
278":"/{modifier_bp} { return PE_BP_COLON; }
279 /*
280 * The slash before memory length can get mixed up with the slash before
281 * config terms. Fortunately config terms do not start with a numeric
282 * digit, so trailing context can be used disambiguate the two cases.
283 */
284"/"/{digit} { return PE_BP_SLASH; }
285"/"/{non_digit} { BEGIN(config); return '/'; }
286{num_dec} { return value(yyscanner, 10); }
287{num_hex} { return value(yyscanner, 16); }
288 /*
289 * We need to separate 'mem:' scanner part, in order to get specific
290 * modifier bits parsed out. Otherwise we would need to handle PE_NAME
291 * and we'd need to parse it manually. During the escape from <mem>
292 * state we need to put the escaping char back, so we dont miss it.
293 */
294. { unput(*yytext); BEGIN(INITIAL); }
295 /*
296 * We destroy the scanner after reaching EOF,
297 * but anyway just to be sure get back to INIT state.
298 */
299<<EOF>> { BEGIN(INITIAL); }
300}
301
302cpu-cycles|cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
303stalled-cycles-frontend|idle-cycles-frontend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
304stalled-cycles-backend|idle-cycles-backend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
305instructions { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
306cache-references { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
307cache-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
308branch-instructions|branches { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
309branch-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
310bus-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
311ref-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
312cpu-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
313task-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
314page-faults|faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
315minor-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
316major-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
317context-switches|cs { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
318cpu-migrations|migrations { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
319alignment-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
320emulation-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
321dummy { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
322duration_time { return tool(yyscanner, PERF_TOOL_DURATION_TIME); }
323user_time { return tool(yyscanner, PERF_TOOL_USER_TIME); }
324system_time { return tool(yyscanner, PERF_TOOL_SYSTEM_TIME); }
325bpf-output { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_BPF_OUTPUT); }
326cgroup-switches { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CGROUP_SWITCHES); }
327
328{lc_type} { return str(yyscanner, PE_LEGACY_CACHE); }
329{lc_type}-{lc_op_result} { return str(yyscanner, PE_LEGACY_CACHE); }
330{lc_type}-{lc_op_result}-{lc_op_result} { return str(yyscanner, PE_LEGACY_CACHE); }
331mem: { BEGIN(mem); return PE_PREFIX_MEM; }
332r{num_raw_hex} { return str(yyscanner, PE_RAW); }
333{num_dec} { return value(yyscanner, 10); }
334{num_hex} { return value(yyscanner, 16); }
335
336{modifier_event} { return str(yyscanner, PE_MODIFIER_EVENT); }
337{name} { return str(yyscanner, PE_NAME); }
338{name_tag} { return str(yyscanner, PE_NAME); }
339"/" { BEGIN(config); return '/'; }
340, { BEGIN(event); return ','; }
341: { return ':'; }
342"{" { BEGIN(event); return '{'; }
343"}" { return '}'; }
344= { return '='; }
345\n { }
346. { }
347
348%%
349
350int parse_events_wrap(void *scanner __maybe_unused)
351{
352 return 1;
353}