Loading...
1/*
2 * (C) Copyright David Gibson <dwg@au1.ibm.com>, IBM Corporation. 2005.
3 *
4 *
5 * This program is free software; you can redistribute it and/or
6 * modify it under the terms of the GNU General Public License as
7 * published by the Free Software Foundation; either version 2 of the
8 * License, or (at your option) any later version.
9 *
10 * This program is distributed in the hope that it will be useful,
11 * but WITHOUT ANY WARRANTY; without even the implied warranty of
12 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 * General Public License for more details.
14 *
15 * You should have received a copy of the GNU General Public License
16 * along with this program; if not, write to the Free Software
17 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
18 * USA
19 */
20
21%option noyywrap nounput noinput never-interactive
22
23%x BYTESTRING
24%x PROPNODENAME
25%s V1
26
27PROPNODECHAR [a-zA-Z0-9,._+*#?@-]
28PATHCHAR ({PROPNODECHAR}|[/])
29LABEL [a-zA-Z_][a-zA-Z0-9_]*
30STRING \"([^\\"]|\\.)*\"
31CHAR_LITERAL '([^']|\\')*'
32WS [[:space:]]
33COMMENT "/*"([^*]|\*+[^*/])*\*+"/"
34LINECOMMENT "//".*\n
35
36%{
37#include "dtc.h"
38#include "srcpos.h"
39#include "dtc-parser.tab.h"
40
41YYLTYPE yylloc;
42extern bool treesource_error;
43
44/* CAUTION: this will stop working if we ever use yyless() or yyunput() */
45#define YY_USER_ACTION \
46 { \
47 srcpos_update(&yylloc, yytext, yyleng); \
48 }
49
50/*#define LEXDEBUG 1*/
51
52#ifdef LEXDEBUG
53#define DPRINT(fmt, ...) fprintf(stderr, fmt, ##__VA_ARGS__)
54#else
55#define DPRINT(fmt, ...) do { } while (0)
56#endif
57
58static int dts_version = 1;
59
60#define BEGIN_DEFAULT() DPRINT("<V1>\n"); \
61 BEGIN(V1); \
62
63static void push_input_file(const char *filename);
64static bool pop_input_file(void);
65static void PRINTF(1, 2) lexical_error(const char *fmt, ...);
66
67%}
68
69%%
70<*>"/include/"{WS}*{STRING} {
71 char *name = strchr(yytext, '\"') + 1;
72 yytext[yyleng-1] = '\0';
73 push_input_file(name);
74 }
75
76<*>^"#"(line)?[ \t]+[0-9]+[ \t]+{STRING}([ \t]+[0-9]+)? {
77 char *line, *fnstart, *fnend;
78 struct data fn;
79 /* skip text before line # */
80 line = yytext;
81 while (!isdigit((unsigned char)*line))
82 line++;
83
84 /* regexp ensures that first and list "
85 * in the whole yytext are those at
86 * beginning and end of the filename string */
87 fnstart = memchr(yytext, '"', yyleng);
88 for (fnend = yytext + yyleng - 1;
89 *fnend != '"'; fnend--)
90 ;
91 assert(fnstart && fnend && (fnend > fnstart));
92
93 fn = data_copy_escape_string(fnstart + 1,
94 fnend - fnstart - 1);
95
96 /* Don't allow nuls in filenames */
97 if (memchr(fn.val, '\0', fn.len - 1))
98 lexical_error("nul in line number directive");
99
100 /* -1 since #line is the number of the next line */
101 srcpos_set_line(xstrdup(fn.val), atoi(line) - 1);
102 data_free(fn);
103 }
104
105<*><<EOF>> {
106 if (!pop_input_file()) {
107 yyterminate();
108 }
109 }
110
111<*>{STRING} {
112 DPRINT("String: %s\n", yytext);
113 yylval.data = data_copy_escape_string(yytext+1,
114 yyleng-2);
115 return DT_STRING;
116 }
117
118<*>"/dts-v1/" {
119 DPRINT("Keyword: /dts-v1/\n");
120 dts_version = 1;
121 BEGIN_DEFAULT();
122 return DT_V1;
123 }
124
125<*>"/plugin/" {
126 DPRINT("Keyword: /plugin/\n");
127 return DT_PLUGIN;
128 }
129
130<*>"/memreserve/" {
131 DPRINT("Keyword: /memreserve/\n");
132 BEGIN_DEFAULT();
133 return DT_MEMRESERVE;
134 }
135
136<*>"/bits/" {
137 DPRINT("Keyword: /bits/\n");
138 BEGIN_DEFAULT();
139 return DT_BITS;
140 }
141
142<*>"/delete-property/" {
143 DPRINT("Keyword: /delete-property/\n");
144 DPRINT("<PROPNODENAME>\n");
145 BEGIN(PROPNODENAME);
146 return DT_DEL_PROP;
147 }
148
149<*>"/delete-node/" {
150 DPRINT("Keyword: /delete-node/\n");
151 DPRINT("<PROPNODENAME>\n");
152 BEGIN(PROPNODENAME);
153 return DT_DEL_NODE;
154 }
155
156<*>{LABEL}: {
157 DPRINT("Label: %s\n", yytext);
158 yylval.labelref = xstrdup(yytext);
159 yylval.labelref[yyleng-1] = '\0';
160 return DT_LABEL;
161 }
162
163<V1>([0-9]+|0[xX][0-9a-fA-F]+)(U|L|UL|LL|ULL)? {
164 char *e;
165 DPRINT("Integer Literal: '%s'\n", yytext);
166
167 errno = 0;
168 yylval.integer = strtoull(yytext, &e, 0);
169
170 if (*e && e[strspn(e, "UL")]) {
171 lexical_error("Bad integer literal '%s'",
172 yytext);
173 }
174
175 if (errno == ERANGE)
176 lexical_error("Integer literal '%s' out of range",
177 yytext);
178 else
179 /* ERANGE is the only strtoull error triggerable
180 * by strings matching the pattern */
181 assert(errno == 0);
182 return DT_LITERAL;
183 }
184
185<*>{CHAR_LITERAL} {
186 struct data d;
187 DPRINT("Character literal: %s\n", yytext);
188
189 d = data_copy_escape_string(yytext+1, yyleng-2);
190 if (d.len == 1) {
191 lexical_error("Empty character literal");
192 yylval.integer = 0;
193 } else {
194 yylval.integer = (unsigned char)d.val[0];
195
196 if (d.len > 2)
197 lexical_error("Character literal has %d"
198 " characters instead of 1",
199 d.len - 1);
200 }
201
202 data_free(d);
203 return DT_CHAR_LITERAL;
204 }
205
206<*>\&{LABEL} { /* label reference */
207 DPRINT("Ref: %s\n", yytext+1);
208 yylval.labelref = xstrdup(yytext+1);
209 return DT_REF;
210 }
211
212<*>"&{/"{PATHCHAR}*\} { /* new-style path reference */
213 yytext[yyleng-1] = '\0';
214 DPRINT("Ref: %s\n", yytext+2);
215 yylval.labelref = xstrdup(yytext+2);
216 return DT_REF;
217 }
218
219<BYTESTRING>[0-9a-fA-F]{2} {
220 yylval.byte = strtol(yytext, NULL, 16);
221 DPRINT("Byte: %02x\n", (int)yylval.byte);
222 return DT_BYTE;
223 }
224
225<BYTESTRING>"]" {
226 DPRINT("/BYTESTRING\n");
227 BEGIN_DEFAULT();
228 return ']';
229 }
230
231<PROPNODENAME>\\?{PROPNODECHAR}+ {
232 DPRINT("PropNodeName: %s\n", yytext);
233 yylval.propnodename = xstrdup((yytext[0] == '\\') ?
234 yytext + 1 : yytext);
235 BEGIN_DEFAULT();
236 return DT_PROPNODENAME;
237 }
238
239"/incbin/" {
240 DPRINT("Binary Include\n");
241 return DT_INCBIN;
242 }
243
244<*>{WS}+ /* eat whitespace */
245<*>{COMMENT}+ /* eat C-style comments */
246<*>{LINECOMMENT}+ /* eat C++-style comments */
247
248<*>"<<" { return DT_LSHIFT; };
249<*>">>" { return DT_RSHIFT; };
250<*>"<=" { return DT_LE; };
251<*>">=" { return DT_GE; };
252<*>"==" { return DT_EQ; };
253<*>"!=" { return DT_NE; };
254<*>"&&" { return DT_AND; };
255<*>"||" { return DT_OR; };
256
257<*>. {
258 DPRINT("Char: %c (\\x%02x)\n", yytext[0],
259 (unsigned)yytext[0]);
260 if (yytext[0] == '[') {
261 DPRINT("<BYTESTRING>\n");
262 BEGIN(BYTESTRING);
263 }
264 if ((yytext[0] == '{')
265 || (yytext[0] == ';')) {
266 DPRINT("<PROPNODENAME>\n");
267 BEGIN(PROPNODENAME);
268 }
269 return yytext[0];
270 }
271
272%%
273
274static void push_input_file(const char *filename)
275{
276 assert(filename);
277
278 srcfile_push(filename);
279
280 yyin = current_srcfile->f;
281
282 yypush_buffer_state(yy_create_buffer(yyin, YY_BUF_SIZE));
283}
284
285
286static bool pop_input_file(void)
287{
288 if (srcfile_pop() == 0)
289 return false;
290
291 yypop_buffer_state();
292 yyin = current_srcfile->f;
293
294 return true;
295}
296
297static void lexical_error(const char *fmt, ...)
298{
299 va_list ap;
300
301 va_start(ap, fmt);
302 srcpos_verror(&yylloc, "Lexical error", fmt, ap);
303 va_end(ap);
304
305 treesource_error = true;
306}
1/*
2 * (C) Copyright David Gibson <dwg@au1.ibm.com>, IBM Corporation. 2005.
3 *
4 *
5 * This program is free software; you can redistribute it and/or
6 * modify it under the terms of the GNU General Public License as
7 * published by the Free Software Foundation; either version 2 of the
8 * License, or (at your option) any later version.
9 *
10 * This program is distributed in the hope that it will be useful,
11 * but WITHOUT ANY WARRANTY; without even the implied warranty of
12 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 * General Public License for more details.
14 *
15 * You should have received a copy of the GNU General Public License
16 * along with this program; if not, write to the Free Software
17 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
18 * USA
19 */
20
21%option noyywrap nounput noinput never-interactive
22
23%x INCLUDE
24%x BYTESTRING
25%x PROPNODENAME
26%s V1
27
28PROPNODECHAR [a-zA-Z0-9,._+*#?@-]
29PATHCHAR ({PROPNODECHAR}|[/])
30LABEL [a-zA-Z_][a-zA-Z0-9_]*
31STRING \"([^\\"]|\\.)*\"
32CHAR_LITERAL '([^']|\\')*'
33WS [[:space:]]
34COMMENT "/*"([^*]|\*+[^*/])*\*+"/"
35LINECOMMENT "//".*\n
36
37%{
38#include "dtc.h"
39#include "srcpos.h"
40#include "dtc-parser.tab.h"
41
42YYLTYPE yylloc;
43
44/* CAUTION: this will stop working if we ever use yyless() or yyunput() */
45#define YY_USER_ACTION \
46 { \
47 srcpos_update(&yylloc, yytext, yyleng); \
48 }
49
50/*#define LEXDEBUG 1*/
51
52#ifdef LEXDEBUG
53#define DPRINT(fmt, ...) fprintf(stderr, fmt, ##__VA_ARGS__)
54#else
55#define DPRINT(fmt, ...) do { } while (0)
56#endif
57
58static int dts_version = 1;
59
60#define BEGIN_DEFAULT() DPRINT("<V1>\n"); \
61 BEGIN(V1); \
62
63static void push_input_file(const char *filename);
64static int pop_input_file(void);
65%}
66
67%%
68<*>"/include/"{WS}*{STRING} {
69 char *name = strchr(yytext, '\"') + 1;
70 yytext[yyleng-1] = '\0';
71 push_input_file(name);
72 }
73
74<*>^"#"(line)?[ \t]+[0-9]+[ \t]+{STRING}([ \t]+[0-9]+)? {
75 char *line, *tmp, *fn;
76 /* skip text before line # */
77 line = yytext;
78 while (!isdigit(*line))
79 line++;
80 /* skip digits in line # */
81 tmp = line;
82 while (!isspace(*tmp))
83 tmp++;
84 /* "NULL"-terminate line # */
85 *tmp = '\0';
86 /* start of filename */
87 fn = strchr(tmp + 1, '"') + 1;
88 /* strip trailing " from filename */
89 tmp = strchr(fn, '"');
90 *tmp = 0;
91 /* -1 since #line is the number of the next line */
92 srcpos_set_line(xstrdup(fn), atoi(line) - 1);
93 }
94
95<*><<EOF>> {
96 if (!pop_input_file()) {
97 yyterminate();
98 }
99 }
100
101<*>{STRING} {
102 DPRINT("String: %s\n", yytext);
103 yylval.data = data_copy_escape_string(yytext+1,
104 yyleng-2);
105 return DT_STRING;
106 }
107
108<*>"/dts-v1/" {
109 DPRINT("Keyword: /dts-v1/\n");
110 dts_version = 1;
111 BEGIN_DEFAULT();
112 return DT_V1;
113 }
114
115<*>"/memreserve/" {
116 DPRINT("Keyword: /memreserve/\n");
117 BEGIN_DEFAULT();
118 return DT_MEMRESERVE;
119 }
120
121<*>"/bits/" {
122 DPRINT("Keyword: /bits/\n");
123 BEGIN_DEFAULT();
124 return DT_BITS;
125 }
126
127<*>"/delete-property/" {
128 DPRINT("Keyword: /delete-property/\n");
129 DPRINT("<PROPNODENAME>\n");
130 BEGIN(PROPNODENAME);
131 return DT_DEL_PROP;
132 }
133
134<*>"/delete-node/" {
135 DPRINT("Keyword: /delete-node/\n");
136 DPRINT("<PROPNODENAME>\n");
137 BEGIN(PROPNODENAME);
138 return DT_DEL_NODE;
139 }
140
141<*>{LABEL}: {
142 DPRINT("Label: %s\n", yytext);
143 yylval.labelref = xstrdup(yytext);
144 yylval.labelref[yyleng-1] = '\0';
145 return DT_LABEL;
146 }
147
148<V1>([0-9]+|0[xX][0-9a-fA-F]+)(U|L|UL|LL|ULL)? {
149 yylval.literal = xstrdup(yytext);
150 DPRINT("Literal: '%s'\n", yylval.literal);
151 return DT_LITERAL;
152 }
153
154<*>{CHAR_LITERAL} {
155 yytext[yyleng-1] = '\0';
156 yylval.literal = xstrdup(yytext+1);
157 DPRINT("Character literal: %s\n", yylval.literal);
158 return DT_CHAR_LITERAL;
159 }
160
161<*>\&{LABEL} { /* label reference */
162 DPRINT("Ref: %s\n", yytext+1);
163 yylval.labelref = xstrdup(yytext+1);
164 return DT_REF;
165 }
166
167<*>"&{/"{PATHCHAR}+\} { /* new-style path reference */
168 yytext[yyleng-1] = '\0';
169 DPRINT("Ref: %s\n", yytext+2);
170 yylval.labelref = xstrdup(yytext+2);
171 return DT_REF;
172 }
173
174<BYTESTRING>[0-9a-fA-F]{2} {
175 yylval.byte = strtol(yytext, NULL, 16);
176 DPRINT("Byte: %02x\n", (int)yylval.byte);
177 return DT_BYTE;
178 }
179
180<BYTESTRING>"]" {
181 DPRINT("/BYTESTRING\n");
182 BEGIN_DEFAULT();
183 return ']';
184 }
185
186<PROPNODENAME>\\?{PROPNODECHAR}+ {
187 DPRINT("PropNodeName: %s\n", yytext);
188 yylval.propnodename = xstrdup((yytext[0] == '\\') ?
189 yytext + 1 : yytext);
190 BEGIN_DEFAULT();
191 return DT_PROPNODENAME;
192 }
193
194"/incbin/" {
195 DPRINT("Binary Include\n");
196 return DT_INCBIN;
197 }
198
199<*>{WS}+ /* eat whitespace */
200<*>{COMMENT}+ /* eat C-style comments */
201<*>{LINECOMMENT}+ /* eat C++-style comments */
202
203<*>"<<" { return DT_LSHIFT; };
204<*>">>" { return DT_RSHIFT; };
205<*>"<=" { return DT_LE; };
206<*>">=" { return DT_GE; };
207<*>"==" { return DT_EQ; };
208<*>"!=" { return DT_NE; };
209<*>"&&" { return DT_AND; };
210<*>"||" { return DT_OR; };
211
212<*>. {
213 DPRINT("Char: %c (\\x%02x)\n", yytext[0],
214 (unsigned)yytext[0]);
215 if (yytext[0] == '[') {
216 DPRINT("<BYTESTRING>\n");
217 BEGIN(BYTESTRING);
218 }
219 if ((yytext[0] == '{')
220 || (yytext[0] == ';')) {
221 DPRINT("<PROPNODENAME>\n");
222 BEGIN(PROPNODENAME);
223 }
224 return yytext[0];
225 }
226
227%%
228
229static void push_input_file(const char *filename)
230{
231 assert(filename);
232
233 srcfile_push(filename);
234
235 yyin = current_srcfile->f;
236
237 yypush_buffer_state(yy_create_buffer(yyin, YY_BUF_SIZE));
238}
239
240
241static int pop_input_file(void)
242{
243 if (srcfile_pop() == 0)
244 return 0;
245
246 yypop_buffer_state();
247 yyin = current_srcfile->f;
248
249 return 1;
250}