Loading...
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#ifndef LOAD_OFFSET
54#define LOAD_OFFSET 0
55#endif
56
57#include <linux/export.h>
58
59/* Align . to a 8 byte boundary equals to maximum function alignment. */
60#define ALIGN_FUNCTION() . = ALIGN(8)
61
62/*
63 * Align to a 32 byte boundary equal to the
64 * alignment gcc 4.5 uses for a struct
65 */
66#define STRUCT_ALIGNMENT 32
67#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
68
69/* The actual configuration determine if the init/exit sections
70 * are handled as text/data or they can be discarded (which
71 * often happens at runtime)
72 */
73#ifdef CONFIG_HOTPLUG_CPU
74#define CPU_KEEP(sec) *(.cpu##sec)
75#define CPU_DISCARD(sec)
76#else
77#define CPU_KEEP(sec)
78#define CPU_DISCARD(sec) *(.cpu##sec)
79#endif
80
81#if defined(CONFIG_MEMORY_HOTPLUG)
82#define MEM_KEEP(sec) *(.mem##sec)
83#define MEM_DISCARD(sec)
84#else
85#define MEM_KEEP(sec)
86#define MEM_DISCARD(sec) *(.mem##sec)
87#endif
88
89#ifdef CONFIG_FTRACE_MCOUNT_RECORD
90#define MCOUNT_REC() . = ALIGN(8); \
91 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
92 *(__mcount_loc) \
93 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
94#else
95#define MCOUNT_REC()
96#endif
97
98#ifdef CONFIG_TRACE_BRANCH_PROFILING
99#define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
100 *(_ftrace_annotated_branch) \
101 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
102#else
103#define LIKELY_PROFILE()
104#endif
105
106#ifdef CONFIG_PROFILE_ALL_BRANCHES
107#define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
108 *(_ftrace_branch) \
109 VMLINUX_SYMBOL(__stop_branch_profile) = .;
110#else
111#define BRANCH_PROFILE()
112#endif
113
114#ifdef CONFIG_KPROBES
115#define KPROBE_BLACKLIST() . = ALIGN(8); \
116 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
117 KEEP(*(_kprobe_blacklist)) \
118 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
119#else
120#define KPROBE_BLACKLIST()
121#endif
122
123#ifdef CONFIG_EVENT_TRACING
124#define FTRACE_EVENTS() . = ALIGN(8); \
125 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
126 KEEP(*(_ftrace_events)) \
127 VMLINUX_SYMBOL(__stop_ftrace_events) = .; \
128 VMLINUX_SYMBOL(__start_ftrace_enum_maps) = .; \
129 KEEP(*(_ftrace_enum_map)) \
130 VMLINUX_SYMBOL(__stop_ftrace_enum_maps) = .;
131#else
132#define FTRACE_EVENTS()
133#endif
134
135#ifdef CONFIG_TRACING
136#define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
137 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
138 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
139#define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
140 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
141 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
142#else
143#define TRACE_PRINTKS()
144#define TRACEPOINT_STR()
145#endif
146
147#ifdef CONFIG_FTRACE_SYSCALLS
148#define TRACE_SYSCALLS() . = ALIGN(8); \
149 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
150 KEEP(*(__syscalls_metadata)) \
151 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
152#else
153#define TRACE_SYSCALLS()
154#endif
155
156#ifdef CONFIG_SERIAL_EARLYCON
157#define EARLYCON_TABLE() STRUCT_ALIGN(); \
158 VMLINUX_SYMBOL(__earlycon_table) = .; \
159 KEEP(*(__earlycon_table)) \
160 VMLINUX_SYMBOL(__earlycon_table_end) = .;
161#else
162#define EARLYCON_TABLE()
163#endif
164
165#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
166#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
167#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
168#define _OF_TABLE_0(name)
169#define _OF_TABLE_1(name) \
170 . = ALIGN(8); \
171 VMLINUX_SYMBOL(__##name##_of_table) = .; \
172 KEEP(*(__##name##_of_table)) \
173 KEEP(*(__##name##_of_table_end))
174
175#define CLKSRC_OF_TABLES() OF_TABLE(CONFIG_CLKSRC_OF, clksrc)
176#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
177#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
178#define IOMMU_OF_TABLES() OF_TABLE(CONFIG_OF_IOMMU, iommu)
179#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
180#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
181#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
182
183#ifdef CONFIG_ACPI
184#define ACPI_PROBE_TABLE(name) \
185 . = ALIGN(8); \
186 VMLINUX_SYMBOL(__##name##_acpi_probe_table) = .; \
187 KEEP(*(__##name##_acpi_probe_table)) \
188 VMLINUX_SYMBOL(__##name##_acpi_probe_table_end) = .;
189#else
190#define ACPI_PROBE_TABLE(name)
191#endif
192
193#define KERNEL_DTB() \
194 STRUCT_ALIGN(); \
195 VMLINUX_SYMBOL(__dtb_start) = .; \
196 KEEP(*(.dtb.init.rodata)) \
197 VMLINUX_SYMBOL(__dtb_end) = .;
198
199/*
200 * .data section
201 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections generates
202 * .data.identifier which needs to be pulled in with .data, but don't want to
203 * pull in .data..stuff which has its own requirements. Same for bss.
204 */
205#define DATA_DATA \
206 *(.data .data.[0-9a-zA-Z_]*) \
207 *(.ref.data) \
208 *(.data..shared_aligned) /* percpu related */ \
209 MEM_KEEP(init.data) \
210 MEM_KEEP(exit.data) \
211 *(.data.unlikely) \
212 STRUCT_ALIGN(); \
213 *(__tracepoints) \
214 /* implement dynamic printk debug */ \
215 . = ALIGN(8); \
216 VMLINUX_SYMBOL(__start___jump_table) = .; \
217 KEEP(*(__jump_table)) \
218 VMLINUX_SYMBOL(__stop___jump_table) = .; \
219 . = ALIGN(8); \
220 VMLINUX_SYMBOL(__start___verbose) = .; \
221 KEEP(*(__verbose)) \
222 VMLINUX_SYMBOL(__stop___verbose) = .; \
223 LIKELY_PROFILE() \
224 BRANCH_PROFILE() \
225 TRACE_PRINTKS() \
226 TRACEPOINT_STR()
227
228/*
229 * Data section helpers
230 */
231#define NOSAVE_DATA \
232 . = ALIGN(PAGE_SIZE); \
233 VMLINUX_SYMBOL(__nosave_begin) = .; \
234 *(.data..nosave) \
235 . = ALIGN(PAGE_SIZE); \
236 VMLINUX_SYMBOL(__nosave_end) = .;
237
238#define PAGE_ALIGNED_DATA(page_align) \
239 . = ALIGN(page_align); \
240 *(.data..page_aligned)
241
242#define READ_MOSTLY_DATA(align) \
243 . = ALIGN(align); \
244 *(.data..read_mostly) \
245 . = ALIGN(align);
246
247#define CACHELINE_ALIGNED_DATA(align) \
248 . = ALIGN(align); \
249 *(.data..cacheline_aligned)
250
251#define INIT_TASK_DATA(align) \
252 . = ALIGN(align); \
253 VMLINUX_SYMBOL(__start_init_task) = .; \
254 *(.data..init_task) \
255 VMLINUX_SYMBOL(__end_init_task) = .;
256
257/*
258 * Allow architectures to handle ro_after_init data on their
259 * own by defining an empty RO_AFTER_INIT_DATA.
260 */
261#ifndef RO_AFTER_INIT_DATA
262#define RO_AFTER_INIT_DATA \
263 __start_data_ro_after_init = .; \
264 *(.data..ro_after_init) \
265 __end_data_ro_after_init = .;
266#endif
267
268/*
269 * Read only Data
270 */
271#define RO_DATA_SECTION(align) \
272 . = ALIGN((align)); \
273 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
274 VMLINUX_SYMBOL(__start_rodata) = .; \
275 *(.rodata) *(.rodata.*) \
276 RO_AFTER_INIT_DATA /* Read only after init */ \
277 KEEP(*(__vermagic)) /* Kernel version magic */ \
278 . = ALIGN(8); \
279 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
280 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
281 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
282 *(__tracepoints_strings)/* Tracepoints: strings */ \
283 } \
284 \
285 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
286 *(.rodata1) \
287 } \
288 \
289 BUG_TABLE \
290 \
291 /* PCI quirks */ \
292 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
293 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
294 KEEP(*(.pci_fixup_early)) \
295 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
296 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
297 KEEP(*(.pci_fixup_header)) \
298 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
299 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
300 KEEP(*(.pci_fixup_final)) \
301 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
302 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
303 KEEP(*(.pci_fixup_enable)) \
304 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
305 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
306 KEEP(*(.pci_fixup_resume)) \
307 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
308 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
309 KEEP(*(.pci_fixup_resume_early)) \
310 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
311 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
312 KEEP(*(.pci_fixup_suspend)) \
313 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
314 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .; \
315 KEEP(*(.pci_fixup_suspend_late)) \
316 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .; \
317 } \
318 \
319 /* Built-in firmware blobs */ \
320 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
321 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
322 KEEP(*(.builtin_fw)) \
323 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
324 } \
325 \
326 TRACEDATA \
327 \
328 /* Kernel symbol table: Normal symbols */ \
329 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
330 VMLINUX_SYMBOL(__start___ksymtab) = .; \
331 KEEP(*(SORT(___ksymtab+*))) \
332 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
333 } \
334 \
335 /* Kernel symbol table: GPL-only symbols */ \
336 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
337 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
338 KEEP(*(SORT(___ksymtab_gpl+*))) \
339 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
340 } \
341 \
342 /* Kernel symbol table: Normal unused symbols */ \
343 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
344 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
345 KEEP(*(SORT(___ksymtab_unused+*))) \
346 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
347 } \
348 \
349 /* Kernel symbol table: GPL-only unused symbols */ \
350 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
351 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
352 KEEP(*(SORT(___ksymtab_unused_gpl+*))) \
353 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
354 } \
355 \
356 /* Kernel symbol table: GPL-future-only symbols */ \
357 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
358 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
359 KEEP(*(SORT(___ksymtab_gpl_future+*))) \
360 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
361 } \
362 \
363 /* Kernel symbol table: Normal symbols */ \
364 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
365 VMLINUX_SYMBOL(__start___kcrctab) = .; \
366 KEEP(*(SORT(___kcrctab+*))) \
367 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
368 } \
369 \
370 /* Kernel symbol table: GPL-only symbols */ \
371 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
372 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
373 KEEP(*(SORT(___kcrctab_gpl+*))) \
374 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
375 } \
376 \
377 /* Kernel symbol table: Normal unused symbols */ \
378 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
379 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
380 KEEP(*(SORT(___kcrctab_unused+*))) \
381 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
382 } \
383 \
384 /* Kernel symbol table: GPL-only unused symbols */ \
385 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
386 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
387 KEEP(*(SORT(___kcrctab_unused_gpl+*))) \
388 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
389 } \
390 \
391 /* Kernel symbol table: GPL-future-only symbols */ \
392 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
393 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
394 KEEP(*(SORT(___kcrctab_gpl_future+*))) \
395 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
396 } \
397 \
398 /* Kernel symbol table: strings */ \
399 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
400 *(__ksymtab_strings) \
401 } \
402 \
403 /* __*init sections */ \
404 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
405 *(.ref.rodata) \
406 MEM_KEEP(init.rodata) \
407 MEM_KEEP(exit.rodata) \
408 } \
409 \
410 /* Built-in module parameters. */ \
411 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
412 VMLINUX_SYMBOL(__start___param) = .; \
413 KEEP(*(__param)) \
414 VMLINUX_SYMBOL(__stop___param) = .; \
415 } \
416 \
417 /* Built-in module versions. */ \
418 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
419 VMLINUX_SYMBOL(__start___modver) = .; \
420 KEEP(*(__modver)) \
421 VMLINUX_SYMBOL(__stop___modver) = .; \
422 . = ALIGN((align)); \
423 VMLINUX_SYMBOL(__end_rodata) = .; \
424 } \
425 . = ALIGN((align));
426
427/* RODATA & RO_DATA provided for backward compatibility.
428 * All archs are supposed to use RO_DATA() */
429#define RODATA RO_DATA_SECTION(4096)
430#define RO_DATA(align) RO_DATA_SECTION(align)
431
432#define SECURITY_INIT \
433 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
434 VMLINUX_SYMBOL(__security_initcall_start) = .; \
435 KEEP(*(.security_initcall.init)) \
436 VMLINUX_SYMBOL(__security_initcall_end) = .; \
437 }
438
439/* .text section. Map to function alignment to avoid address changes
440 * during second ld run in second ld pass when generating System.map
441 * LD_DEAD_CODE_DATA_ELIMINATION option enables -ffunction-sections generates
442 * .text.identifier which needs to be pulled in with .text , but some
443 * architectures define .text.foo which is not intended to be pulled in here.
444 * Those enabling LD_DEAD_CODE_DATA_ELIMINATION must ensure they don't have
445 * conflicting section names, and must pull in .text.[0-9a-zA-Z_]* */
446#define TEXT_TEXT \
447 ALIGN_FUNCTION(); \
448 *(.text.hot .text .text.fixup .text.unlikely) \
449 *(.ref.text) \
450 MEM_KEEP(init.text) \
451 MEM_KEEP(exit.text) \
452
453
454/* sched.text is aling to function alignment to secure we have same
455 * address even at second ld pass when generating System.map */
456#define SCHED_TEXT \
457 ALIGN_FUNCTION(); \
458 VMLINUX_SYMBOL(__sched_text_start) = .; \
459 *(.sched.text) \
460 VMLINUX_SYMBOL(__sched_text_end) = .;
461
462/* spinlock.text is aling to function alignment to secure we have same
463 * address even at second ld pass when generating System.map */
464#define LOCK_TEXT \
465 ALIGN_FUNCTION(); \
466 VMLINUX_SYMBOL(__lock_text_start) = .; \
467 *(.spinlock.text) \
468 VMLINUX_SYMBOL(__lock_text_end) = .;
469
470#define CPUIDLE_TEXT \
471 ALIGN_FUNCTION(); \
472 VMLINUX_SYMBOL(__cpuidle_text_start) = .; \
473 *(.cpuidle.text) \
474 VMLINUX_SYMBOL(__cpuidle_text_end) = .;
475
476#define KPROBES_TEXT \
477 ALIGN_FUNCTION(); \
478 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
479 *(.kprobes.text) \
480 VMLINUX_SYMBOL(__kprobes_text_end) = .;
481
482#define ENTRY_TEXT \
483 ALIGN_FUNCTION(); \
484 VMLINUX_SYMBOL(__entry_text_start) = .; \
485 *(.entry.text) \
486 VMLINUX_SYMBOL(__entry_text_end) = .;
487
488#if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
489#define IRQENTRY_TEXT \
490 ALIGN_FUNCTION(); \
491 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
492 *(.irqentry.text) \
493 VMLINUX_SYMBOL(__irqentry_text_end) = .;
494#else
495#define IRQENTRY_TEXT
496#endif
497
498#if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
499#define SOFTIRQENTRY_TEXT \
500 ALIGN_FUNCTION(); \
501 VMLINUX_SYMBOL(__softirqentry_text_start) = .; \
502 *(.softirqentry.text) \
503 VMLINUX_SYMBOL(__softirqentry_text_end) = .;
504#else
505#define SOFTIRQENTRY_TEXT
506#endif
507
508/* Section used for early init (in .S files) */
509#define HEAD_TEXT *(.head.text)
510
511#define HEAD_TEXT_SECTION \
512 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
513 HEAD_TEXT \
514 }
515
516/*
517 * Exception table
518 */
519#define EXCEPTION_TABLE(align) \
520 . = ALIGN(align); \
521 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
522 VMLINUX_SYMBOL(__start___ex_table) = .; \
523 KEEP(*(__ex_table)) \
524 VMLINUX_SYMBOL(__stop___ex_table) = .; \
525 }
526
527/*
528 * Init task
529 */
530#define INIT_TASK_DATA_SECTION(align) \
531 . = ALIGN(align); \
532 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
533 INIT_TASK_DATA(align) \
534 }
535
536#ifdef CONFIG_CONSTRUCTORS
537#define KERNEL_CTORS() . = ALIGN(8); \
538 VMLINUX_SYMBOL(__ctors_start) = .; \
539 KEEP(*(.ctors)) \
540 KEEP(*(SORT(.init_array.*))) \
541 KEEP(*(.init_array)) \
542 VMLINUX_SYMBOL(__ctors_end) = .;
543#else
544#define KERNEL_CTORS()
545#endif
546
547/* init and exit section handling */
548#define INIT_DATA \
549 KEEP(*(SORT(___kentry+*))) \
550 *(.init.data) \
551 MEM_DISCARD(init.data) \
552 KERNEL_CTORS() \
553 MCOUNT_REC() \
554 *(.init.rodata) \
555 FTRACE_EVENTS() \
556 TRACE_SYSCALLS() \
557 KPROBE_BLACKLIST() \
558 MEM_DISCARD(init.rodata) \
559 CLK_OF_TABLES() \
560 RESERVEDMEM_OF_TABLES() \
561 CLKSRC_OF_TABLES() \
562 IOMMU_OF_TABLES() \
563 CPU_METHOD_OF_TABLES() \
564 CPUIDLE_METHOD_OF_TABLES() \
565 KERNEL_DTB() \
566 IRQCHIP_OF_MATCH_TABLE() \
567 ACPI_PROBE_TABLE(irqchip) \
568 ACPI_PROBE_TABLE(clksrc) \
569 ACPI_PROBE_TABLE(iort) \
570 EARLYCON_TABLE()
571
572#define INIT_TEXT \
573 *(.init.text) \
574 *(.text.startup) \
575 MEM_DISCARD(init.text)
576
577#define EXIT_DATA \
578 *(.exit.data) \
579 *(.fini_array) \
580 *(.dtors) \
581 MEM_DISCARD(exit.data) \
582 MEM_DISCARD(exit.rodata)
583
584#define EXIT_TEXT \
585 *(.exit.text) \
586 *(.text.exit) \
587 MEM_DISCARD(exit.text)
588
589#define EXIT_CALL \
590 *(.exitcall.exit)
591
592/*
593 * bss (Block Started by Symbol) - uninitialized data
594 * zeroed during startup
595 */
596#define SBSS(sbss_align) \
597 . = ALIGN(sbss_align); \
598 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
599 *(.sbss) \
600 *(.scommon) \
601 }
602
603/*
604 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
605 * sections to the front of bss.
606 */
607#ifndef BSS_FIRST_SECTIONS
608#define BSS_FIRST_SECTIONS
609#endif
610
611#define BSS(bss_align) \
612 . = ALIGN(bss_align); \
613 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
614 BSS_FIRST_SECTIONS \
615 *(.bss..page_aligned) \
616 *(.dynbss) \
617 *(.bss .bss.[0-9a-zA-Z_]*) \
618 *(COMMON) \
619 }
620
621/*
622 * DWARF debug sections.
623 * Symbols in the DWARF debugging sections are relative to
624 * the beginning of the section so we begin them at 0.
625 */
626#define DWARF_DEBUG \
627 /* DWARF 1 */ \
628 .debug 0 : { *(.debug) } \
629 .line 0 : { *(.line) } \
630 /* GNU DWARF 1 extensions */ \
631 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
632 .debug_sfnames 0 : { *(.debug_sfnames) } \
633 /* DWARF 1.1 and DWARF 2 */ \
634 .debug_aranges 0 : { *(.debug_aranges) } \
635 .debug_pubnames 0 : { *(.debug_pubnames) } \
636 /* DWARF 2 */ \
637 .debug_info 0 : { *(.debug_info \
638 .gnu.linkonce.wi.*) } \
639 .debug_abbrev 0 : { *(.debug_abbrev) } \
640 .debug_line 0 : { *(.debug_line) } \
641 .debug_frame 0 : { *(.debug_frame) } \
642 .debug_str 0 : { *(.debug_str) } \
643 .debug_loc 0 : { *(.debug_loc) } \
644 .debug_macinfo 0 : { *(.debug_macinfo) } \
645 /* SGI/MIPS DWARF 2 extensions */ \
646 .debug_weaknames 0 : { *(.debug_weaknames) } \
647 .debug_funcnames 0 : { *(.debug_funcnames) } \
648 .debug_typenames 0 : { *(.debug_typenames) } \
649 .debug_varnames 0 : { *(.debug_varnames) } \
650
651 /* Stabs debugging sections. */
652#define STABS_DEBUG \
653 .stab 0 : { *(.stab) } \
654 .stabstr 0 : { *(.stabstr) } \
655 .stab.excl 0 : { *(.stab.excl) } \
656 .stab.exclstr 0 : { *(.stab.exclstr) } \
657 .stab.index 0 : { *(.stab.index) } \
658 .stab.indexstr 0 : { *(.stab.indexstr) } \
659 .comment 0 : { *(.comment) }
660
661#ifdef CONFIG_GENERIC_BUG
662#define BUG_TABLE \
663 . = ALIGN(8); \
664 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
665 VMLINUX_SYMBOL(__start___bug_table) = .; \
666 KEEP(*(__bug_table)) \
667 VMLINUX_SYMBOL(__stop___bug_table) = .; \
668 }
669#else
670#define BUG_TABLE
671#endif
672
673#ifdef CONFIG_PM_TRACE
674#define TRACEDATA \
675 . = ALIGN(4); \
676 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
677 VMLINUX_SYMBOL(__tracedata_start) = .; \
678 KEEP(*(.tracedata)) \
679 VMLINUX_SYMBOL(__tracedata_end) = .; \
680 }
681#else
682#define TRACEDATA
683#endif
684
685#define NOTES \
686 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
687 VMLINUX_SYMBOL(__start_notes) = .; \
688 *(.note.*) \
689 VMLINUX_SYMBOL(__stop_notes) = .; \
690 }
691
692#define INIT_SETUP(initsetup_align) \
693 . = ALIGN(initsetup_align); \
694 VMLINUX_SYMBOL(__setup_start) = .; \
695 KEEP(*(.init.setup)) \
696 VMLINUX_SYMBOL(__setup_end) = .;
697
698#define INIT_CALLS_LEVEL(level) \
699 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
700 KEEP(*(.initcall##level##.init)) \
701 KEEP(*(.initcall##level##s.init)) \
702
703#define INIT_CALLS \
704 VMLINUX_SYMBOL(__initcall_start) = .; \
705 KEEP(*(.initcallearly.init)) \
706 INIT_CALLS_LEVEL(0) \
707 INIT_CALLS_LEVEL(1) \
708 INIT_CALLS_LEVEL(2) \
709 INIT_CALLS_LEVEL(3) \
710 INIT_CALLS_LEVEL(4) \
711 INIT_CALLS_LEVEL(5) \
712 INIT_CALLS_LEVEL(rootfs) \
713 INIT_CALLS_LEVEL(6) \
714 INIT_CALLS_LEVEL(7) \
715 VMLINUX_SYMBOL(__initcall_end) = .;
716
717#define CON_INITCALL \
718 VMLINUX_SYMBOL(__con_initcall_start) = .; \
719 KEEP(*(.con_initcall.init)) \
720 VMLINUX_SYMBOL(__con_initcall_end) = .;
721
722#define SECURITY_INITCALL \
723 VMLINUX_SYMBOL(__security_initcall_start) = .; \
724 KEEP(*(.security_initcall.init)) \
725 VMLINUX_SYMBOL(__security_initcall_end) = .;
726
727#ifdef CONFIG_BLK_DEV_INITRD
728#define INIT_RAM_FS \
729 . = ALIGN(4); \
730 VMLINUX_SYMBOL(__initramfs_start) = .; \
731 KEEP(*(.init.ramfs)) \
732 . = ALIGN(8); \
733 KEEP(*(.init.ramfs.info))
734#else
735#define INIT_RAM_FS
736#endif
737
738/*
739 * Default discarded sections.
740 *
741 * Some archs want to discard exit text/data at runtime rather than
742 * link time due to cross-section references such as alt instructions,
743 * bug table, eh_frame, etc. DISCARDS must be the last of output
744 * section definitions so that such archs put those in earlier section
745 * definitions.
746 */
747#define DISCARDS \
748 /DISCARD/ : { \
749 EXIT_TEXT \
750 EXIT_DATA \
751 EXIT_CALL \
752 *(.discard) \
753 *(.discard.*) \
754 }
755
756/**
757 * PERCPU_INPUT - the percpu input sections
758 * @cacheline: cacheline size
759 *
760 * The core percpu section names and core symbols which do not rely
761 * directly upon load addresses.
762 *
763 * @cacheline is used to align subsections to avoid false cacheline
764 * sharing between subsections for different purposes.
765 */
766#define PERCPU_INPUT(cacheline) \
767 VMLINUX_SYMBOL(__per_cpu_start) = .; \
768 *(.data..percpu..first) \
769 . = ALIGN(PAGE_SIZE); \
770 *(.data..percpu..page_aligned) \
771 . = ALIGN(cacheline); \
772 *(.data..percpu..read_mostly) \
773 . = ALIGN(cacheline); \
774 *(.data..percpu) \
775 *(.data..percpu..shared_aligned) \
776 VMLINUX_SYMBOL(__per_cpu_end) = .;
777
778/**
779 * PERCPU_VADDR - define output section for percpu area
780 * @cacheline: cacheline size
781 * @vaddr: explicit base address (optional)
782 * @phdr: destination PHDR (optional)
783 *
784 * Macro which expands to output section for percpu area.
785 *
786 * @cacheline is used to align subsections to avoid false cacheline
787 * sharing between subsections for different purposes.
788 *
789 * If @vaddr is not blank, it specifies explicit base address and all
790 * percpu symbols will be offset from the given address. If blank,
791 * @vaddr always equals @laddr + LOAD_OFFSET.
792 *
793 * @phdr defines the output PHDR to use if not blank. Be warned that
794 * output PHDR is sticky. If @phdr is specified, the next output
795 * section in the linker script will go there too. @phdr should have
796 * a leading colon.
797 *
798 * Note that this macros defines __per_cpu_load as an absolute symbol.
799 * If there is no need to put the percpu section at a predetermined
800 * address, use PERCPU_SECTION.
801 */
802#define PERCPU_VADDR(cacheline, vaddr, phdr) \
803 VMLINUX_SYMBOL(__per_cpu_load) = .; \
804 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
805 - LOAD_OFFSET) { \
806 PERCPU_INPUT(cacheline) \
807 } phdr \
808 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
809
810/**
811 * PERCPU_SECTION - define output section for percpu area, simple version
812 * @cacheline: cacheline size
813 *
814 * Align to PAGE_SIZE and outputs output section for percpu area. This
815 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
816 * __per_cpu_start will be identical.
817 *
818 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
819 * except that __per_cpu_load is defined as a relative symbol against
820 * .data..percpu which is required for relocatable x86_32 configuration.
821 */
822#define PERCPU_SECTION(cacheline) \
823 . = ALIGN(PAGE_SIZE); \
824 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
825 VMLINUX_SYMBOL(__per_cpu_load) = .; \
826 PERCPU_INPUT(cacheline) \
827 }
828
829
830/*
831 * Definition of the high level *_SECTION macros
832 * They will fit only a subset of the architectures
833 */
834
835
836/*
837 * Writeable data.
838 * All sections are combined in a single .data section.
839 * The sections following CONSTRUCTORS are arranged so their
840 * typical alignment matches.
841 * A cacheline is typical/always less than a PAGE_SIZE so
842 * the sections that has this restriction (or similar)
843 * is located before the ones requiring PAGE_SIZE alignment.
844 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
845 * matches the requirement of PAGE_ALIGNED_DATA.
846 *
847 * use 0 as page_align if page_aligned data is not used */
848#define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
849 . = ALIGN(PAGE_SIZE); \
850 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
851 INIT_TASK_DATA(inittask) \
852 NOSAVE_DATA \
853 PAGE_ALIGNED_DATA(pagealigned) \
854 CACHELINE_ALIGNED_DATA(cacheline) \
855 READ_MOSTLY_DATA(cacheline) \
856 DATA_DATA \
857 CONSTRUCTORS \
858 }
859
860#define INIT_TEXT_SECTION(inittext_align) \
861 . = ALIGN(inittext_align); \
862 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
863 VMLINUX_SYMBOL(_sinittext) = .; \
864 INIT_TEXT \
865 VMLINUX_SYMBOL(_einittext) = .; \
866 }
867
868#define INIT_DATA_SECTION(initsetup_align) \
869 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
870 INIT_DATA \
871 INIT_SETUP(initsetup_align) \
872 INIT_CALLS \
873 CON_INITCALL \
874 SECURITY_INITCALL \
875 INIT_RAM_FS \
876 }
877
878#define BSS_SECTION(sbss_align, bss_align, stop_align) \
879 . = ALIGN(sbss_align); \
880 VMLINUX_SYMBOL(__bss_start) = .; \
881 SBSS(sbss_align) \
882 BSS(bss_align) \
883 . = ALIGN(stop_align); \
884 VMLINUX_SYMBOL(__bss_stop) = .;
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requirements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#include <asm-generic/codetag.lds.h>
54
55#ifndef LOAD_OFFSET
56#define LOAD_OFFSET 0
57#endif
58
59/*
60 * Only some architectures want to have the .notes segment visible in
61 * a separate PT_NOTE ELF Program Header. When this happens, it needs
62 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
63 * Program Headers. In this case, though, the PT_LOAD needs to be made
64 * the default again so that all the following sections don't also end
65 * up in the PT_NOTE Program Header.
66 */
67#ifdef EMITS_PT_NOTE
68#define NOTES_HEADERS :text :note
69#define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
70#else
71#define NOTES_HEADERS
72#define NOTES_HEADERS_RESTORE
73#endif
74
75/*
76 * Some architectures have non-executable read-only exception tables.
77 * They can be added to the RO_DATA segment by specifying their desired
78 * alignment.
79 */
80#ifdef RO_EXCEPTION_TABLE_ALIGN
81#define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
82#else
83#define RO_EXCEPTION_TABLE
84#endif
85
86/* Align . function alignment. */
87#define ALIGN_FUNCTION() . = ALIGN(CONFIG_FUNCTION_ALIGNMENT)
88
89/*
90 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
91 * generates .data.identifier sections, which need to be pulled in with
92 * .data. We don't want to pull in .data..other sections, which Linux
93 * has defined. Same for text and bss.
94 *
95 * With LTO_CLANG, the linker also splits sections by default, so we need
96 * these macros to combine the sections during the final link.
97 *
98 * With AUTOFDO_CLANG and PROPELLER_CLANG, by default, the linker splits
99 * text sections and regroups functions into subsections.
100 *
101 * RODATA_MAIN is not used because existing code already defines .rodata.x
102 * sections to be brought in with rodata.
103 */
104#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG) || \
105defined(CONFIG_AUTOFDO_CLANG) || defined(CONFIG_PROPELLER_CLANG)
106#define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
107#else
108#define TEXT_MAIN .text
109#endif
110#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG)
111#define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..L* .data..compoundliteral* .data.$__unnamed_* .data.$L*
112#define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
113#define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]* .rodata..L*
114#define BSS_MAIN .bss .bss.[0-9a-zA-Z_]* .bss..L* .bss..compoundliteral*
115#define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
116#else
117#define DATA_MAIN .data
118#define SDATA_MAIN .sdata
119#define RODATA_MAIN .rodata
120#define BSS_MAIN .bss
121#define SBSS_MAIN .sbss
122#endif
123
124/*
125 * GCC 4.5 and later have a 32 bytes section alignment for structures.
126 * Except GCC 4.9, that feels the need to align on 64 bytes.
127 */
128#define STRUCT_ALIGNMENT 32
129#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
130
131/*
132 * The order of the sched class addresses are important, as they are
133 * used to determine the order of the priority of each sched class in
134 * relation to each other.
135 */
136#define SCHED_DATA \
137 STRUCT_ALIGN(); \
138 __sched_class_highest = .; \
139 *(__stop_sched_class) \
140 *(__dl_sched_class) \
141 *(__rt_sched_class) \
142 *(__fair_sched_class) \
143 *(__ext_sched_class) \
144 *(__idle_sched_class) \
145 __sched_class_lowest = .;
146
147/* The actual configuration determine if the init/exit sections
148 * are handled as text/data or they can be discarded (which
149 * often happens at runtime)
150 */
151
152#ifndef CONFIG_HAVE_DYNAMIC_FTRACE_NO_PATCHABLE
153#define KEEP_PATCHABLE KEEP(*(__patchable_function_entries))
154#define PATCHABLE_DISCARDS
155#else
156#define KEEP_PATCHABLE
157#define PATCHABLE_DISCARDS *(__patchable_function_entries)
158#endif
159
160#ifndef CONFIG_ARCH_SUPPORTS_CFI_CLANG
161/*
162 * Simply points to ftrace_stub, but with the proper protocol.
163 * Defined by the linker script in linux/vmlinux.lds.h
164 */
165#define FTRACE_STUB_HACK ftrace_stub_graph = ftrace_stub;
166#else
167#define FTRACE_STUB_HACK
168#endif
169
170#ifdef CONFIG_FTRACE_MCOUNT_RECORD
171/*
172 * The ftrace call sites are logged to a section whose name depends on the
173 * compiler option used. A given kernel image will only use one, AKA
174 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
175 * dependencies for FTRACE_CALLSITE_SECTION's definition.
176 *
177 * ftrace_ops_list_func will be defined as arch_ftrace_ops_list_func
178 * as some archs will have a different prototype for that function
179 * but ftrace_ops_list_func() will have a single prototype.
180 */
181#define MCOUNT_REC() . = ALIGN(8); \
182 __start_mcount_loc = .; \
183 KEEP(*(__mcount_loc)) \
184 KEEP_PATCHABLE \
185 __stop_mcount_loc = .; \
186 FTRACE_STUB_HACK \
187 ftrace_ops_list_func = arch_ftrace_ops_list_func;
188#else
189# ifdef CONFIG_FUNCTION_TRACER
190# define MCOUNT_REC() FTRACE_STUB_HACK \
191 ftrace_ops_list_func = arch_ftrace_ops_list_func;
192# else
193# define MCOUNT_REC()
194# endif
195#endif
196
197#define BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_) \
198 _BEGIN_##_label_ = .; \
199 KEEP(*(_sec_)) \
200 _END_##_label_ = .;
201
202#define BOUNDED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_) \
203 _label_##_BEGIN_ = .; \
204 KEEP(*(_sec_)) \
205 _label_##_END_ = .;
206
207#define BOUNDED_SECTION_BY(_sec_, _label_) \
208 BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, __start, __stop)
209
210#define BOUNDED_SECTION(_sec) BOUNDED_SECTION_BY(_sec, _sec)
211
212#define HEADERED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_, _HDR_) \
213 _HDR_##_label_ = .; \
214 KEEP(*(.gnu.linkonce.##_sec_)) \
215 BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_)
216
217#define HEADERED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_, _HDR_) \
218 _label_##_HDR_ = .; \
219 KEEP(*(.gnu.linkonce.##_sec_)) \
220 BOUNDED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_)
221
222#define HEADERED_SECTION_BY(_sec_, _label_) \
223 HEADERED_SECTION_PRE_LABEL(_sec_, _label_, __start, __stop)
224
225#define HEADERED_SECTION(_sec) HEADERED_SECTION_BY(_sec, _sec)
226
227#ifdef CONFIG_TRACE_BRANCH_PROFILING
228#define LIKELY_PROFILE() \
229 BOUNDED_SECTION_BY(_ftrace_annotated_branch, _annotated_branch_profile)
230#else
231#define LIKELY_PROFILE()
232#endif
233
234#ifdef CONFIG_PROFILE_ALL_BRANCHES
235#define BRANCH_PROFILE() \
236 BOUNDED_SECTION_BY(_ftrace_branch, _branch_profile)
237#else
238#define BRANCH_PROFILE()
239#endif
240
241#ifdef CONFIG_KPROBES
242#define KPROBE_BLACKLIST() \
243 . = ALIGN(8); \
244 BOUNDED_SECTION(_kprobe_blacklist)
245#else
246#define KPROBE_BLACKLIST()
247#endif
248
249#ifdef CONFIG_FUNCTION_ERROR_INJECTION
250#define ERROR_INJECT_WHITELIST() \
251 STRUCT_ALIGN(); \
252 BOUNDED_SECTION(_error_injection_whitelist)
253#else
254#define ERROR_INJECT_WHITELIST()
255#endif
256
257#ifdef CONFIG_EVENT_TRACING
258#define FTRACE_EVENTS() \
259 . = ALIGN(8); \
260 BOUNDED_SECTION(_ftrace_events) \
261 BOUNDED_SECTION_BY(_ftrace_eval_map, _ftrace_eval_maps)
262#else
263#define FTRACE_EVENTS()
264#endif
265
266#ifdef CONFIG_TRACING
267#define TRACE_PRINTKS() BOUNDED_SECTION_BY(__trace_printk_fmt, ___trace_bprintk_fmt)
268#define TRACEPOINT_STR() BOUNDED_SECTION_BY(__tracepoint_str, ___tracepoint_str)
269#else
270#define TRACE_PRINTKS()
271#define TRACEPOINT_STR()
272#endif
273
274#ifdef CONFIG_FTRACE_SYSCALLS
275#define TRACE_SYSCALLS() \
276 . = ALIGN(8); \
277 BOUNDED_SECTION_BY(__syscalls_metadata, _syscalls_metadata)
278#else
279#define TRACE_SYSCALLS()
280#endif
281
282#ifdef CONFIG_BPF_EVENTS
283#define BPF_RAW_TP() STRUCT_ALIGN(); \
284 BOUNDED_SECTION_BY(__bpf_raw_tp_map, __bpf_raw_tp)
285#else
286#define BPF_RAW_TP()
287#endif
288
289#ifdef CONFIG_SERIAL_EARLYCON
290#define EARLYCON_TABLE() \
291 . = ALIGN(8); \
292 BOUNDED_SECTION_POST_LABEL(__earlycon_table, __earlycon_table, , _end)
293#else
294#define EARLYCON_TABLE()
295#endif
296
297#ifdef CONFIG_SECURITY
298#define LSM_TABLE() \
299 . = ALIGN(8); \
300 BOUNDED_SECTION_PRE_LABEL(.lsm_info.init, _lsm_info, __start, __end)
301
302#define EARLY_LSM_TABLE() \
303 . = ALIGN(8); \
304 BOUNDED_SECTION_PRE_LABEL(.early_lsm_info.init, _early_lsm_info, __start, __end)
305#else
306#define LSM_TABLE()
307#define EARLY_LSM_TABLE()
308#endif
309
310#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
311#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
312#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
313#define _OF_TABLE_0(name)
314#define _OF_TABLE_1(name) \
315 . = ALIGN(8); \
316 __##name##_of_table = .; \
317 KEEP(*(__##name##_of_table)) \
318 KEEP(*(__##name##_of_table_end))
319
320#define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
321#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
322#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
323#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
324#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
325#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
326
327#ifdef CONFIG_ACPI
328#define ACPI_PROBE_TABLE(name) \
329 . = ALIGN(8); \
330 BOUNDED_SECTION_POST_LABEL(__##name##_acpi_probe_table, \
331 __##name##_acpi_probe_table,, _end)
332#else
333#define ACPI_PROBE_TABLE(name)
334#endif
335
336#ifdef CONFIG_THERMAL
337#define THERMAL_TABLE(name) \
338 . = ALIGN(8); \
339 BOUNDED_SECTION_POST_LABEL(__##name##_thermal_table, \
340 __##name##_thermal_table,, _end)
341#else
342#define THERMAL_TABLE(name)
343#endif
344
345#define KERNEL_DTB() \
346 STRUCT_ALIGN(); \
347 __dtb_start = .; \
348 KEEP(*(.dtb.init.rodata)) \
349 __dtb_end = .;
350
351/*
352 * .data section
353 */
354#define DATA_DATA \
355 *(.xiptext) \
356 *(DATA_MAIN) \
357 *(.data..decrypted) \
358 *(.ref.data) \
359 *(.data..shared_aligned) /* percpu related */ \
360 *(.data..unlikely) \
361 __start_once = .; \
362 *(.data..once) \
363 __end_once = .; \
364 STRUCT_ALIGN(); \
365 *(__tracepoints) \
366 /* implement dynamic printk debug */ \
367 . = ALIGN(8); \
368 BOUNDED_SECTION_BY(__dyndbg_classes, ___dyndbg_classes) \
369 BOUNDED_SECTION_BY(__dyndbg, ___dyndbg) \
370 CODETAG_SECTIONS() \
371 LIKELY_PROFILE() \
372 BRANCH_PROFILE() \
373 TRACE_PRINTKS() \
374 BPF_RAW_TP() \
375 TRACEPOINT_STR() \
376 KUNIT_TABLE()
377
378/*
379 * Data section helpers
380 */
381#define NOSAVE_DATA \
382 . = ALIGN(PAGE_SIZE); \
383 __nosave_begin = .; \
384 *(.data..nosave) \
385 . = ALIGN(PAGE_SIZE); \
386 __nosave_end = .;
387
388#define PAGE_ALIGNED_DATA(page_align) \
389 . = ALIGN(page_align); \
390 *(.data..page_aligned) \
391 . = ALIGN(page_align);
392
393#define READ_MOSTLY_DATA(align) \
394 . = ALIGN(align); \
395 *(.data..read_mostly) \
396 . = ALIGN(align);
397
398#define CACHELINE_ALIGNED_DATA(align) \
399 . = ALIGN(align); \
400 *(.data..cacheline_aligned)
401
402#define INIT_TASK_DATA(align) \
403 . = ALIGN(align); \
404 __start_init_stack = .; \
405 init_thread_union = .; \
406 init_stack = .; \
407 KEEP(*(.data..init_task)) \
408 KEEP(*(.data..init_thread_info)) \
409 . = __start_init_stack + THREAD_SIZE; \
410 __end_init_stack = .;
411
412#define JUMP_TABLE_DATA \
413 . = ALIGN(8); \
414 BOUNDED_SECTION_BY(__jump_table, ___jump_table)
415
416#ifdef CONFIG_HAVE_STATIC_CALL_INLINE
417#define STATIC_CALL_DATA \
418 . = ALIGN(8); \
419 BOUNDED_SECTION_BY(.static_call_sites, _static_call_sites) \
420 BOUNDED_SECTION_BY(.static_call_tramp_key, _static_call_tramp_key)
421#else
422#define STATIC_CALL_DATA
423#endif
424
425/*
426 * Allow architectures to handle ro_after_init data on their
427 * own by defining an empty RO_AFTER_INIT_DATA.
428 */
429#ifndef RO_AFTER_INIT_DATA
430#define RO_AFTER_INIT_DATA \
431 . = ALIGN(8); \
432 __start_ro_after_init = .; \
433 *(.data..ro_after_init) \
434 JUMP_TABLE_DATA \
435 STATIC_CALL_DATA \
436 __end_ro_after_init = .;
437#endif
438
439/*
440 * .kcfi_traps contains a list KCFI trap locations.
441 */
442#ifndef KCFI_TRAPS
443#ifdef CONFIG_ARCH_USES_CFI_TRAPS
444#define KCFI_TRAPS \
445 __kcfi_traps : AT(ADDR(__kcfi_traps) - LOAD_OFFSET) { \
446 BOUNDED_SECTION_BY(.kcfi_traps, ___kcfi_traps) \
447 }
448#else
449#define KCFI_TRAPS
450#endif
451#endif
452
453/*
454 * Read only Data
455 */
456#define RO_DATA(align) \
457 . = ALIGN((align)); \
458 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
459 __start_rodata = .; \
460 *(.rodata) *(.rodata.*) *(.data.rel.ro*) \
461 SCHED_DATA \
462 RO_AFTER_INIT_DATA /* Read only after init */ \
463 . = ALIGN(8); \
464 BOUNDED_SECTION_BY(__tracepoints_ptrs, ___tracepoints_ptrs) \
465 *(__tracepoints_strings)/* Tracepoints: strings */ \
466 } \
467 \
468 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
469 *(.rodata1) \
470 } \
471 \
472 /* PCI quirks */ \
473 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
474 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_early, _pci_fixups_early, __start, __end) \
475 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_header, _pci_fixups_header, __start, __end) \
476 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_final, _pci_fixups_final, __start, __end) \
477 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_enable, _pci_fixups_enable, __start, __end) \
478 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_resume, _pci_fixups_resume, __start, __end) \
479 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_suspend, _pci_fixups_suspend, __start, __end) \
480 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_resume_early, _pci_fixups_resume_early, __start, __end) \
481 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_suspend_late, _pci_fixups_suspend_late, __start, __end) \
482 } \
483 \
484 FW_LOADER_BUILT_IN_DATA \
485 TRACEDATA \
486 \
487 PRINTK_INDEX \
488 \
489 /* Kernel symbol table: Normal symbols */ \
490 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
491 __start___ksymtab = .; \
492 KEEP(*(SORT(___ksymtab+*))) \
493 __stop___ksymtab = .; \
494 } \
495 \
496 /* Kernel symbol table: GPL-only symbols */ \
497 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
498 __start___ksymtab_gpl = .; \
499 KEEP(*(SORT(___ksymtab_gpl+*))) \
500 __stop___ksymtab_gpl = .; \
501 } \
502 \
503 /* Kernel symbol table: Normal symbols */ \
504 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
505 __start___kcrctab = .; \
506 KEEP(*(SORT(___kcrctab+*))) \
507 __stop___kcrctab = .; \
508 } \
509 \
510 /* Kernel symbol table: GPL-only symbols */ \
511 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
512 __start___kcrctab_gpl = .; \
513 KEEP(*(SORT(___kcrctab_gpl+*))) \
514 __stop___kcrctab_gpl = .; \
515 } \
516 \
517 /* Kernel symbol table: strings */ \
518 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
519 *(__ksymtab_strings) \
520 } \
521 \
522 /* __*init sections */ \
523 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
524 *(.ref.rodata) \
525 } \
526 \
527 /* Built-in module parameters. */ \
528 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
529 BOUNDED_SECTION_BY(__param, ___param) \
530 } \
531 \
532 /* Built-in module versions. */ \
533 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
534 BOUNDED_SECTION_BY(__modver, ___modver) \
535 } \
536 \
537 KCFI_TRAPS \
538 \
539 RO_EXCEPTION_TABLE \
540 NOTES \
541 BTF \
542 \
543 . = ALIGN((align)); \
544 __end_rodata = .;
545
546
547/*
548 * Non-instrumentable text section
549 */
550#define NOINSTR_TEXT \
551 ALIGN_FUNCTION(); \
552 __noinstr_text_start = .; \
553 *(.noinstr.text) \
554 __cpuidle_text_start = .; \
555 *(.cpuidle.text) \
556 __cpuidle_text_end = .; \
557 __noinstr_text_end = .;
558
559#define TEXT_SPLIT \
560 __split_text_start = .; \
561 *(.text.split .text.split.[0-9a-zA-Z_]*) \
562 __split_text_end = .;
563
564#define TEXT_UNLIKELY \
565 __unlikely_text_start = .; \
566 *(.text.unlikely .text.unlikely.*) \
567 __unlikely_text_end = .;
568
569#define TEXT_HOT \
570 __hot_text_start = .; \
571 *(.text.hot .text.hot.*) \
572 __hot_text_end = .;
573
574/*
575 * .text section. Map to function alignment to avoid address changes
576 * during second ld run in second ld pass when generating System.map
577 *
578 * TEXT_MAIN here will match symbols with a fixed pattern (for example,
579 * .text.hot or .text.unlikely) if dead code elimination or
580 * function-section is enabled. Match these symbols first before
581 * TEXT_MAIN to ensure they are grouped together.
582 *
583 * Also placing .text.hot section at the beginning of a page, this
584 * would help the TLB performance.
585 */
586#define TEXT_TEXT \
587 ALIGN_FUNCTION(); \
588 *(.text.asan.* .text.tsan.*) \
589 *(.text.unknown .text.unknown.*) \
590 TEXT_SPLIT \
591 TEXT_UNLIKELY \
592 . = ALIGN(PAGE_SIZE); \
593 TEXT_HOT \
594 *(TEXT_MAIN .text.fixup) \
595 NOINSTR_TEXT \
596 *(.ref.text)
597
598/* sched.text is aling to function alignment to secure we have same
599 * address even at second ld pass when generating System.map */
600#define SCHED_TEXT \
601 ALIGN_FUNCTION(); \
602 __sched_text_start = .; \
603 *(.sched.text) \
604 __sched_text_end = .;
605
606/* spinlock.text is aling to function alignment to secure we have same
607 * address even at second ld pass when generating System.map */
608#define LOCK_TEXT \
609 ALIGN_FUNCTION(); \
610 __lock_text_start = .; \
611 *(.spinlock.text) \
612 __lock_text_end = .;
613
614#define KPROBES_TEXT \
615 ALIGN_FUNCTION(); \
616 __kprobes_text_start = .; \
617 *(.kprobes.text) \
618 __kprobes_text_end = .;
619
620#define ENTRY_TEXT \
621 ALIGN_FUNCTION(); \
622 __entry_text_start = .; \
623 *(.entry.text) \
624 __entry_text_end = .;
625
626#define IRQENTRY_TEXT \
627 ALIGN_FUNCTION(); \
628 __irqentry_text_start = .; \
629 *(.irqentry.text) \
630 __irqentry_text_end = .;
631
632#define SOFTIRQENTRY_TEXT \
633 ALIGN_FUNCTION(); \
634 __softirqentry_text_start = .; \
635 *(.softirqentry.text) \
636 __softirqentry_text_end = .;
637
638#define STATIC_CALL_TEXT \
639 ALIGN_FUNCTION(); \
640 __static_call_text_start = .; \
641 *(.static_call.text) \
642 __static_call_text_end = .;
643
644/* Section used for early init (in .S files) */
645#define HEAD_TEXT KEEP(*(.head.text))
646
647#define HEAD_TEXT_SECTION \
648 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
649 HEAD_TEXT \
650 }
651
652/*
653 * Exception table
654 */
655#define EXCEPTION_TABLE(align) \
656 . = ALIGN(align); \
657 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
658 BOUNDED_SECTION_BY(__ex_table, ___ex_table) \
659 }
660
661/*
662 * .BTF
663 */
664#ifdef CONFIG_DEBUG_INFO_BTF
665#define BTF \
666 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
667 BOUNDED_SECTION_BY(.BTF, _BTF) \
668 } \
669 . = ALIGN(4); \
670 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
671 *(.BTF_ids) \
672 }
673#else
674#define BTF
675#endif
676
677/*
678 * Init task
679 */
680#define INIT_TASK_DATA_SECTION(align) \
681 . = ALIGN(align); \
682 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
683 INIT_TASK_DATA(align) \
684 }
685
686#ifdef CONFIG_CONSTRUCTORS
687#define KERNEL_CTORS() . = ALIGN(8); \
688 __ctors_start = .; \
689 KEEP(*(SORT(.ctors.*))) \
690 KEEP(*(.ctors)) \
691 KEEP(*(SORT(.init_array.*))) \
692 KEEP(*(.init_array)) \
693 __ctors_end = .;
694#else
695#define KERNEL_CTORS()
696#endif
697
698/* init and exit section handling */
699#define INIT_DATA \
700 KEEP(*(SORT(___kentry+*))) \
701 *(.init.data .init.data.*) \
702 KERNEL_CTORS() \
703 MCOUNT_REC() \
704 *(.init.rodata .init.rodata.*) \
705 FTRACE_EVENTS() \
706 TRACE_SYSCALLS() \
707 KPROBE_BLACKLIST() \
708 ERROR_INJECT_WHITELIST() \
709 CLK_OF_TABLES() \
710 RESERVEDMEM_OF_TABLES() \
711 TIMER_OF_TABLES() \
712 CPU_METHOD_OF_TABLES() \
713 CPUIDLE_METHOD_OF_TABLES() \
714 KERNEL_DTB() \
715 IRQCHIP_OF_MATCH_TABLE() \
716 ACPI_PROBE_TABLE(irqchip) \
717 ACPI_PROBE_TABLE(timer) \
718 THERMAL_TABLE(governor) \
719 EARLYCON_TABLE() \
720 LSM_TABLE() \
721 EARLY_LSM_TABLE() \
722 KUNIT_INIT_TABLE()
723
724#define INIT_TEXT \
725 *(.init.text .init.text.*) \
726 *(.text.startup)
727
728#define EXIT_DATA \
729 *(.exit.data .exit.data.*) \
730 *(.fini_array .fini_array.*) \
731 *(.dtors .dtors.*) \
732
733#define EXIT_TEXT \
734 *(.exit.text) \
735 *(.text.exit) \
736
737#define EXIT_CALL \
738 *(.exitcall.exit)
739
740/*
741 * bss (Block Started by Symbol) - uninitialized data
742 * zeroed during startup
743 */
744#define SBSS(sbss_align) \
745 . = ALIGN(sbss_align); \
746 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
747 *(.dynsbss) \
748 *(SBSS_MAIN) \
749 *(.scommon) \
750 }
751
752/*
753 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
754 * sections to the front of bss.
755 */
756#ifndef BSS_FIRST_SECTIONS
757#define BSS_FIRST_SECTIONS
758#endif
759
760#define BSS(bss_align) \
761 . = ALIGN(bss_align); \
762 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
763 BSS_FIRST_SECTIONS \
764 . = ALIGN(PAGE_SIZE); \
765 *(.bss..page_aligned) \
766 . = ALIGN(PAGE_SIZE); \
767 *(.dynbss) \
768 *(BSS_MAIN) \
769 *(COMMON) \
770 }
771
772/*
773 * DWARF debug sections.
774 * Symbols in the DWARF debugging sections are relative to
775 * the beginning of the section so we begin them at 0.
776 */
777#define DWARF_DEBUG \
778 /* DWARF 1 */ \
779 .debug 0 : { *(.debug) } \
780 .line 0 : { *(.line) } \
781 /* GNU DWARF 1 extensions */ \
782 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
783 .debug_sfnames 0 : { *(.debug_sfnames) } \
784 /* DWARF 1.1 and DWARF 2 */ \
785 .debug_aranges 0 : { *(.debug_aranges) } \
786 .debug_pubnames 0 : { *(.debug_pubnames) } \
787 /* DWARF 2 */ \
788 .debug_info 0 : { *(.debug_info \
789 .gnu.linkonce.wi.*) } \
790 .debug_abbrev 0 : { *(.debug_abbrev) } \
791 .debug_line 0 : { *(.debug_line) } \
792 .debug_frame 0 : { *(.debug_frame) } \
793 .debug_str 0 : { *(.debug_str) } \
794 .debug_loc 0 : { *(.debug_loc) } \
795 .debug_macinfo 0 : { *(.debug_macinfo) } \
796 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
797 /* DWARF 3 */ \
798 .debug_ranges 0 : { *(.debug_ranges) } \
799 /* SGI/MIPS DWARF 2 extensions */ \
800 .debug_weaknames 0 : { *(.debug_weaknames) } \
801 .debug_funcnames 0 : { *(.debug_funcnames) } \
802 .debug_typenames 0 : { *(.debug_typenames) } \
803 .debug_varnames 0 : { *(.debug_varnames) } \
804 /* GNU DWARF 2 extensions */ \
805 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
806 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
807 /* DWARF 4 */ \
808 .debug_types 0 : { *(.debug_types) } \
809 /* DWARF 5 */ \
810 .debug_addr 0 : { *(.debug_addr) } \
811 .debug_line_str 0 : { *(.debug_line_str) } \
812 .debug_loclists 0 : { *(.debug_loclists) } \
813 .debug_macro 0 : { *(.debug_macro) } \
814 .debug_names 0 : { *(.debug_names) } \
815 .debug_rnglists 0 : { *(.debug_rnglists) } \
816 .debug_str_offsets 0 : { *(.debug_str_offsets) }
817
818/* Stabs debugging sections. */
819#define STABS_DEBUG \
820 .stab 0 : { *(.stab) } \
821 .stabstr 0 : { *(.stabstr) } \
822 .stab.excl 0 : { *(.stab.excl) } \
823 .stab.exclstr 0 : { *(.stab.exclstr) } \
824 .stab.index 0 : { *(.stab.index) } \
825 .stab.indexstr 0 : { *(.stab.indexstr) }
826
827/* Required sections not related to debugging. */
828#define ELF_DETAILS \
829 .comment 0 : { *(.comment) } \
830 .symtab 0 : { *(.symtab) } \
831 .strtab 0 : { *(.strtab) } \
832 .shstrtab 0 : { *(.shstrtab) }
833
834#ifdef CONFIG_GENERIC_BUG
835#define BUG_TABLE \
836 . = ALIGN(8); \
837 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
838 BOUNDED_SECTION_BY(__bug_table, ___bug_table) \
839 }
840#else
841#define BUG_TABLE
842#endif
843
844#ifdef CONFIG_UNWINDER_ORC
845#define ORC_UNWIND_TABLE \
846 .orc_header : AT(ADDR(.orc_header) - LOAD_OFFSET) { \
847 BOUNDED_SECTION_BY(.orc_header, _orc_header) \
848 } \
849 . = ALIGN(4); \
850 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
851 BOUNDED_SECTION_BY(.orc_unwind_ip, _orc_unwind_ip) \
852 } \
853 . = ALIGN(2); \
854 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
855 BOUNDED_SECTION_BY(.orc_unwind, _orc_unwind) \
856 } \
857 text_size = _etext - _stext; \
858 . = ALIGN(4); \
859 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
860 orc_lookup = .; \
861 . += (((text_size + LOOKUP_BLOCK_SIZE - 1) / \
862 LOOKUP_BLOCK_SIZE) + 1) * 4; \
863 orc_lookup_end = .; \
864 }
865#else
866#define ORC_UNWIND_TABLE
867#endif
868
869/* Built-in firmware blobs */
870#ifdef CONFIG_FW_LOADER
871#define FW_LOADER_BUILT_IN_DATA \
872 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
873 BOUNDED_SECTION_PRE_LABEL(.builtin_fw, _builtin_fw, __start, __end) \
874 }
875#else
876#define FW_LOADER_BUILT_IN_DATA
877#endif
878
879#ifdef CONFIG_PM_TRACE
880#define TRACEDATA \
881 . = ALIGN(4); \
882 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
883 BOUNDED_SECTION_POST_LABEL(.tracedata, __tracedata, _start, _end) \
884 }
885#else
886#define TRACEDATA
887#endif
888
889#ifdef CONFIG_PRINTK_INDEX
890#define PRINTK_INDEX \
891 .printk_index : AT(ADDR(.printk_index) - LOAD_OFFSET) { \
892 BOUNDED_SECTION_BY(.printk_index, _printk_index) \
893 }
894#else
895#define PRINTK_INDEX
896#endif
897
898/*
899 * Discard .note.GNU-stack, which is emitted as PROGBITS by the compiler.
900 * Otherwise, the type of .notes section would become PROGBITS instead of NOTES.
901 *
902 * Also, discard .note.gnu.property, otherwise it forces the notes section to
903 * be 8-byte aligned which causes alignment mismatches with the kernel's custom
904 * 4-byte aligned notes.
905 */
906#define NOTES \
907 /DISCARD/ : { \
908 *(.note.GNU-stack) \
909 *(.note.gnu.property) \
910 } \
911 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
912 BOUNDED_SECTION_BY(.note.*, _notes) \
913 } NOTES_HEADERS \
914 NOTES_HEADERS_RESTORE
915
916#define INIT_SETUP(initsetup_align) \
917 . = ALIGN(initsetup_align); \
918 BOUNDED_SECTION_POST_LABEL(.init.setup, __setup, _start, _end)
919
920#define INIT_CALLS_LEVEL(level) \
921 __initcall##level##_start = .; \
922 KEEP(*(.initcall##level##.init)) \
923 KEEP(*(.initcall##level##s.init)) \
924
925#define INIT_CALLS \
926 __initcall_start = .; \
927 KEEP(*(.initcallearly.init)) \
928 INIT_CALLS_LEVEL(0) \
929 INIT_CALLS_LEVEL(1) \
930 INIT_CALLS_LEVEL(2) \
931 INIT_CALLS_LEVEL(3) \
932 INIT_CALLS_LEVEL(4) \
933 INIT_CALLS_LEVEL(5) \
934 INIT_CALLS_LEVEL(rootfs) \
935 INIT_CALLS_LEVEL(6) \
936 INIT_CALLS_LEVEL(7) \
937 __initcall_end = .;
938
939#define CON_INITCALL \
940 BOUNDED_SECTION_POST_LABEL(.con_initcall.init, __con_initcall, _start, _end)
941
942#define NAMED_SECTION(name) \
943 . = ALIGN(8); \
944 name : AT(ADDR(name) - LOAD_OFFSET) \
945 { BOUNDED_SECTION_PRE_LABEL(name, name, __start_, __stop_) }
946
947#define RUNTIME_CONST(t,x) NAMED_SECTION(runtime_##t##_##x)
948
949#define RUNTIME_CONST_VARIABLES \
950 RUNTIME_CONST(shift, d_hash_shift) \
951 RUNTIME_CONST(ptr, dentry_hashtable)
952
953/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
954#define KUNIT_TABLE() \
955 . = ALIGN(8); \
956 BOUNDED_SECTION_POST_LABEL(.kunit_test_suites, __kunit_suites, _start, _end)
957
958/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
959#define KUNIT_INIT_TABLE() \
960 . = ALIGN(8); \
961 BOUNDED_SECTION_POST_LABEL(.kunit_init_test_suites, \
962 __kunit_init_suites, _start, _end)
963
964#ifdef CONFIG_BLK_DEV_INITRD
965#define INIT_RAM_FS \
966 . = ALIGN(4); \
967 __initramfs_start = .; \
968 KEEP(*(.init.ramfs)) \
969 . = ALIGN(8); \
970 KEEP(*(.init.ramfs.info))
971#else
972#define INIT_RAM_FS
973#endif
974
975/*
976 * Memory encryption operates on a page basis. Since we need to clear
977 * the memory encryption mask for this section, it needs to be aligned
978 * on a page boundary and be a page-size multiple in length.
979 *
980 * Note: We use a separate section so that only this section gets
981 * decrypted to avoid exposing more than we wish.
982 */
983#ifdef CONFIG_AMD_MEM_ENCRYPT
984#define PERCPU_DECRYPTED_SECTION \
985 . = ALIGN(PAGE_SIZE); \
986 *(.data..percpu..decrypted) \
987 . = ALIGN(PAGE_SIZE);
988#else
989#define PERCPU_DECRYPTED_SECTION
990#endif
991
992
993/*
994 * Default discarded sections.
995 *
996 * Some archs want to discard exit text/data at runtime rather than
997 * link time due to cross-section references such as alt instructions,
998 * bug table, eh_frame, etc. DISCARDS must be the last of output
999 * section definitions so that such archs put those in earlier section
1000 * definitions.
1001 */
1002#ifdef RUNTIME_DISCARD_EXIT
1003#define EXIT_DISCARDS
1004#else
1005#define EXIT_DISCARDS \
1006 EXIT_TEXT \
1007 EXIT_DATA
1008#endif
1009
1010/*
1011 * Clang's -fprofile-arcs, -fsanitize=kernel-address, and
1012 * -fsanitize=thread produce unwanted sections (.eh_frame
1013 * and .init_array.*), but CONFIG_CONSTRUCTORS wants to
1014 * keep any .init_array.* sections.
1015 * https://llvm.org/pr46478
1016 */
1017#ifdef CONFIG_UNWIND_TABLES
1018#define DISCARD_EH_FRAME
1019#else
1020#define DISCARD_EH_FRAME *(.eh_frame)
1021#endif
1022#if defined(CONFIG_GCOV_KERNEL) || defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN)
1023# ifdef CONFIG_CONSTRUCTORS
1024# define SANITIZER_DISCARDS \
1025 DISCARD_EH_FRAME
1026# else
1027# define SANITIZER_DISCARDS \
1028 *(.init_array) *(.init_array.*) \
1029 DISCARD_EH_FRAME
1030# endif
1031#else
1032# define SANITIZER_DISCARDS
1033#endif
1034
1035#define COMMON_DISCARDS \
1036 SANITIZER_DISCARDS \
1037 PATCHABLE_DISCARDS \
1038 *(.discard) \
1039 *(.discard.*) \
1040 *(.export_symbol) \
1041 *(.modinfo) \
1042 /* ld.bfd warns about .gnu.version* even when not emitted */ \
1043 *(.gnu.version*) \
1044
1045#define DISCARDS \
1046 /DISCARD/ : { \
1047 EXIT_DISCARDS \
1048 EXIT_CALL \
1049 COMMON_DISCARDS \
1050 }
1051
1052/**
1053 * PERCPU_INPUT - the percpu input sections
1054 * @cacheline: cacheline size
1055 *
1056 * The core percpu section names and core symbols which do not rely
1057 * directly upon load addresses.
1058 *
1059 * @cacheline is used to align subsections to avoid false cacheline
1060 * sharing between subsections for different purposes.
1061 */
1062#define PERCPU_INPUT(cacheline) \
1063 __per_cpu_start = .; \
1064 *(.data..percpu..first) \
1065 . = ALIGN(PAGE_SIZE); \
1066 *(.data..percpu..page_aligned) \
1067 . = ALIGN(cacheline); \
1068 *(.data..percpu..read_mostly) \
1069 . = ALIGN(cacheline); \
1070 *(.data..percpu) \
1071 *(.data..percpu..shared_aligned) \
1072 PERCPU_DECRYPTED_SECTION \
1073 __per_cpu_end = .;
1074
1075/**
1076 * PERCPU_VADDR - define output section for percpu area
1077 * @cacheline: cacheline size
1078 * @vaddr: explicit base address (optional)
1079 * @phdr: destination PHDR (optional)
1080 *
1081 * Macro which expands to output section for percpu area.
1082 *
1083 * @cacheline is used to align subsections to avoid false cacheline
1084 * sharing between subsections for different purposes.
1085 *
1086 * If @vaddr is not blank, it specifies explicit base address and all
1087 * percpu symbols will be offset from the given address. If blank,
1088 * @vaddr always equals @laddr + LOAD_OFFSET.
1089 *
1090 * @phdr defines the output PHDR to use if not blank. Be warned that
1091 * output PHDR is sticky. If @phdr is specified, the next output
1092 * section in the linker script will go there too. @phdr should have
1093 * a leading colon.
1094 *
1095 * Note that this macros defines __per_cpu_load as an absolute symbol.
1096 * If there is no need to put the percpu section at a predetermined
1097 * address, use PERCPU_SECTION.
1098 */
1099#define PERCPU_VADDR(cacheline, vaddr, phdr) \
1100 __per_cpu_load = .; \
1101 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1102 PERCPU_INPUT(cacheline) \
1103 } phdr \
1104 . = __per_cpu_load + SIZEOF(.data..percpu);
1105
1106/**
1107 * PERCPU_SECTION - define output section for percpu area, simple version
1108 * @cacheline: cacheline size
1109 *
1110 * Align to PAGE_SIZE and outputs output section for percpu area. This
1111 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1112 * __per_cpu_start will be identical.
1113 *
1114 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1115 * except that __per_cpu_load is defined as a relative symbol against
1116 * .data..percpu which is required for relocatable x86_32 configuration.
1117 */
1118#define PERCPU_SECTION(cacheline) \
1119 . = ALIGN(PAGE_SIZE); \
1120 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1121 __per_cpu_load = .; \
1122 PERCPU_INPUT(cacheline) \
1123 }
1124
1125
1126/*
1127 * Definition of the high level *_SECTION macros
1128 * They will fit only a subset of the architectures
1129 */
1130
1131
1132/*
1133 * Writeable data.
1134 * All sections are combined in a single .data section.
1135 * The sections following CONSTRUCTORS are arranged so their
1136 * typical alignment matches.
1137 * A cacheline is typical/always less than a PAGE_SIZE so
1138 * the sections that has this restriction (or similar)
1139 * is located before the ones requiring PAGE_SIZE alignment.
1140 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1141 * matches the requirement of PAGE_ALIGNED_DATA.
1142 *
1143 * use 0 as page_align if page_aligned data is not used */
1144#define RW_DATA(cacheline, pagealigned, inittask) \
1145 . = ALIGN(PAGE_SIZE); \
1146 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1147 INIT_TASK_DATA(inittask) \
1148 NOSAVE_DATA \
1149 PAGE_ALIGNED_DATA(pagealigned) \
1150 CACHELINE_ALIGNED_DATA(cacheline) \
1151 READ_MOSTLY_DATA(cacheline) \
1152 DATA_DATA \
1153 CONSTRUCTORS \
1154 } \
1155 BUG_TABLE \
1156
1157#define INIT_TEXT_SECTION(inittext_align) \
1158 . = ALIGN(inittext_align); \
1159 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1160 _sinittext = .; \
1161 INIT_TEXT \
1162 _einittext = .; \
1163 }
1164
1165#define INIT_DATA_SECTION(initsetup_align) \
1166 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1167 INIT_DATA \
1168 INIT_SETUP(initsetup_align) \
1169 INIT_CALLS \
1170 CON_INITCALL \
1171 INIT_RAM_FS \
1172 }
1173
1174#define BSS_SECTION(sbss_align, bss_align, stop_align) \
1175 . = ALIGN(sbss_align); \
1176 __bss_start = .; \
1177 SBSS(sbss_align) \
1178 BSS(bss_align) \
1179 . = ALIGN(stop_align); \
1180 __bss_stop = .;