Loading...
1/*
2 * (C) Copyright David Gibson <dwg@au1.ibm.com>, IBM Corporation. 2005.
3 *
4 *
5 * This program is free software; you can redistribute it and/or
6 * modify it under the terms of the GNU General Public License as
7 * published by the Free Software Foundation; either version 2 of the
8 * License, or (at your option) any later version.
9 *
10 * This program is distributed in the hope that it will be useful,
11 * but WITHOUT ANY WARRANTY; without even the implied warranty of
12 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 * General Public License for more details.
14 *
15 * You should have received a copy of the GNU General Public License
16 * along with this program; if not, write to the Free Software
17 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
18 * USA
19 */
20
21%{
22#include <stdio.h>
23
24#include "dtc.h"
25#include "srcpos.h"
26
27YYLTYPE yylloc;
28
29extern int yylex(void);
30extern void print_error(char const *fmt, ...);
31extern void yyerror(char const *s);
32
33extern struct boot_info *the_boot_info;
34extern int treesource_error;
35
36static unsigned long long eval_literal(const char *s, int base, int bits);
37%}
38
39%union {
40 char *propnodename;
41 char *literal;
42 char *labelref;
43 unsigned int cbase;
44 uint8_t byte;
45 struct data data;
46
47 uint64_t addr;
48 cell_t cell;
49 struct property *prop;
50 struct property *proplist;
51 struct node *node;
52 struct node *nodelist;
53 struct reserve_info *re;
54}
55
56%token DT_V1
57%token DT_MEMRESERVE
58%token <propnodename> DT_PROPNODENAME
59%token <literal> DT_LITERAL
60%token <cbase> DT_BASE
61%token <byte> DT_BYTE
62%token <data> DT_STRING
63%token <labelref> DT_LABEL
64%token <labelref> DT_REF
65%token DT_INCBIN
66
67%type <data> propdata
68%type <data> propdataprefix
69%type <re> memreserve
70%type <re> memreserves
71%type <addr> addr
72%type <data> celllist
73%type <cell> cellval
74%type <data> bytestring
75%type <prop> propdef
76%type <proplist> proplist
77
78%type <node> devicetree
79%type <node> nodedef
80%type <node> subnode
81%type <nodelist> subnodes
82
83%%
84
85sourcefile:
86 DT_V1 ';' memreserves devicetree
87 {
88 the_boot_info = build_boot_info($3, $4,
89 guess_boot_cpuid($4));
90 }
91 ;
92
93memreserves:
94 /* empty */
95 {
96 $$ = NULL;
97 }
98 | memreserve memreserves
99 {
100 $$ = chain_reserve_entry($1, $2);
101 }
102 ;
103
104memreserve:
105 DT_MEMRESERVE addr addr ';'
106 {
107 $$ = build_reserve_entry($2, $3);
108 }
109 | DT_LABEL memreserve
110 {
111 add_label(&$2->labels, $1);
112 $$ = $2;
113 }
114 ;
115
116addr:
117 DT_LITERAL
118 {
119 $$ = eval_literal($1, 0, 64);
120 }
121 ;
122
123devicetree:
124 '/' nodedef
125 {
126 $$ = name_node($2, "");
127 }
128 | devicetree '/' nodedef
129 {
130 $$ = merge_nodes($1, $3);
131 }
132 | devicetree DT_REF nodedef
133 {
134 struct node *target = get_node_by_ref($1, $2);
135
136 if (target)
137 merge_nodes(target, $3);
138 else
139 print_error("label or path, '%s', not found", $2);
140 $$ = $1;
141 }
142 ;
143
144nodedef:
145 '{' proplist subnodes '}' ';'
146 {
147 $$ = build_node($2, $3);
148 }
149 ;
150
151proplist:
152 /* empty */
153 {
154 $$ = NULL;
155 }
156 | proplist propdef
157 {
158 $$ = chain_property($2, $1);
159 }
160 ;
161
162propdef:
163 DT_PROPNODENAME '=' propdata ';'
164 {
165 $$ = build_property($1, $3);
166 }
167 | DT_PROPNODENAME ';'
168 {
169 $$ = build_property($1, empty_data);
170 }
171 | DT_LABEL propdef
172 {
173 add_label(&$2->labels, $1);
174 $$ = $2;
175 }
176 ;
177
178propdata:
179 propdataprefix DT_STRING
180 {
181 $$ = data_merge($1, $2);
182 }
183 | propdataprefix '<' celllist '>'
184 {
185 $$ = data_merge($1, $3);
186 }
187 | propdataprefix '[' bytestring ']'
188 {
189 $$ = data_merge($1, $3);
190 }
191 | propdataprefix DT_REF
192 {
193 $$ = data_add_marker($1, REF_PATH, $2);
194 }
195 | propdataprefix DT_INCBIN '(' DT_STRING ',' addr ',' addr ')'
196 {
197 FILE *f = srcfile_relative_open($4.val, NULL);
198 struct data d;
199
200 if ($6 != 0)
201 if (fseek(f, $6, SEEK_SET) != 0)
202 print_error("Couldn't seek to offset %llu in \"%s\": %s",
203 (unsigned long long)$6,
204 $4.val,
205 strerror(errno));
206
207 d = data_copy_file(f, $8);
208
209 $$ = data_merge($1, d);
210 fclose(f);
211 }
212 | propdataprefix DT_INCBIN '(' DT_STRING ')'
213 {
214 FILE *f = srcfile_relative_open($4.val, NULL);
215 struct data d = empty_data;
216
217 d = data_copy_file(f, -1);
218
219 $$ = data_merge($1, d);
220 fclose(f);
221 }
222 | propdata DT_LABEL
223 {
224 $$ = data_add_marker($1, LABEL, $2);
225 }
226 ;
227
228propdataprefix:
229 /* empty */
230 {
231 $$ = empty_data;
232 }
233 | propdata ','
234 {
235 $$ = $1;
236 }
237 | propdataprefix DT_LABEL
238 {
239 $$ = data_add_marker($1, LABEL, $2);
240 }
241 ;
242
243celllist:
244 /* empty */
245 {
246 $$ = empty_data;
247 }
248 | celllist cellval
249 {
250 $$ = data_append_cell($1, $2);
251 }
252 | celllist DT_REF
253 {
254 $$ = data_append_cell(data_add_marker($1, REF_PHANDLE,
255 $2), -1);
256 }
257 | celllist DT_LABEL
258 {
259 $$ = data_add_marker($1, LABEL, $2);
260 }
261 ;
262
263cellval:
264 DT_LITERAL
265 {
266 $$ = eval_literal($1, 0, 32);
267 }
268 ;
269
270bytestring:
271 /* empty */
272 {
273 $$ = empty_data;
274 }
275 | bytestring DT_BYTE
276 {
277 $$ = data_append_byte($1, $2);
278 }
279 | bytestring DT_LABEL
280 {
281 $$ = data_add_marker($1, LABEL, $2);
282 }
283 ;
284
285subnodes:
286 /* empty */
287 {
288 $$ = NULL;
289 }
290 | subnode subnodes
291 {
292 $$ = chain_node($1, $2);
293 }
294 | subnode propdef
295 {
296 print_error("syntax error: properties must precede subnodes");
297 YYERROR;
298 }
299 ;
300
301subnode:
302 DT_PROPNODENAME nodedef
303 {
304 $$ = name_node($2, $1);
305 }
306 | DT_LABEL subnode
307 {
308 add_label(&$2->labels, $1);
309 $$ = $2;
310 }
311 ;
312
313%%
314
315void print_error(char const *fmt, ...)
316{
317 va_list va;
318
319 va_start(va, fmt);
320 srcpos_verror(&yylloc, fmt, va);
321 va_end(va);
322
323 treesource_error = 1;
324}
325
326void yyerror(char const *s) {
327 print_error("%s", s);
328}
329
330static unsigned long long eval_literal(const char *s, int base, int bits)
331{
332 unsigned long long val;
333 char *e;
334
335 errno = 0;
336 val = strtoull(s, &e, base);
337 if (*e)
338 print_error("bad characters in literal");
339 else if ((errno == ERANGE)
340 || ((bits < 64) && (val >= (1ULL << bits))))
341 print_error("literal out of range");
342 else if (errno != 0)
343 print_error("bad literal");
344 return val;
345}
1// SPDX-License-Identifier: GPL-2.0-or-later
2/*
3 * (C) Copyright David Gibson <dwg@au1.ibm.com>, IBM Corporation. 2005.
4 */
5%locations
6
7%{
8#include <stdio.h>
9#include <inttypes.h>
10
11#include "dtc.h"
12#include "srcpos.h"
13
14extern int yylex(void);
15extern void yyerror(char const *s);
16#define ERROR(loc, ...) \
17 do { \
18 srcpos_error((loc), "Error", __VA_ARGS__); \
19 treesource_error = true; \
20 } while (0)
21
22#define YYERROR_CALL(msg) yyerror(msg)
23
24extern struct dt_info *parser_output;
25extern bool treesource_error;
26
27static bool is_ref_relative(const char *ref)
28{
29 return ref[0] != '/' && strchr(&ref[1], '/');
30}
31
32%}
33
34%union {
35 char *propnodename;
36 char *labelref;
37 uint8_t byte;
38 struct data data;
39
40 struct {
41 struct data data;
42 int bits;
43 } array;
44
45 struct property *prop;
46 struct property *proplist;
47 struct node *node;
48 struct node *nodelist;
49 struct reserve_info *re;
50 uint64_t integer;
51 unsigned int flags;
52}
53
54%token DT_V1
55%token DT_PLUGIN
56%token DT_MEMRESERVE
57%token DT_LSHIFT DT_RSHIFT DT_LE DT_GE DT_EQ DT_NE DT_AND DT_OR
58%token DT_BITS
59%token DT_DEL_PROP
60%token DT_DEL_NODE
61%token DT_OMIT_NO_REF
62%token <propnodename> DT_PROPNODENAME
63%token <integer> DT_LITERAL
64%token <integer> DT_CHAR_LITERAL
65%token <byte> DT_BYTE
66%token <data> DT_STRING
67%token <labelref> DT_LABEL
68%token <labelref> DT_LABEL_REF
69%token <labelref> DT_PATH_REF
70%token DT_INCBIN
71
72%type <data> propdata
73%type <data> propdataprefix
74%type <flags> header
75%type <flags> headers
76%type <re> memreserve
77%type <re> memreserves
78%type <array> arrayprefix
79%type <data> bytestring
80%type <prop> propdef
81%type <proplist> proplist
82%type <labelref> dt_ref
83
84%type <node> devicetree
85%type <node> nodedef
86%type <node> subnode
87%type <nodelist> subnodes
88
89%type <integer> integer_prim
90%type <integer> integer_unary
91%type <integer> integer_mul
92%type <integer> integer_add
93%type <integer> integer_shift
94%type <integer> integer_rela
95%type <integer> integer_eq
96%type <integer> integer_bitand
97%type <integer> integer_bitxor
98%type <integer> integer_bitor
99%type <integer> integer_and
100%type <integer> integer_or
101%type <integer> integer_trinary
102%type <integer> integer_expr
103
104%%
105
106sourcefile:
107 headers memreserves devicetree
108 {
109 parser_output = build_dt_info($1, $2, $3,
110 guess_boot_cpuid($3));
111 }
112 ;
113
114header:
115 DT_V1 ';'
116 {
117 $$ = DTSF_V1;
118 }
119 | DT_V1 ';' DT_PLUGIN ';'
120 {
121 $$ = DTSF_V1 | DTSF_PLUGIN;
122 }
123 ;
124
125headers:
126 header
127 | header headers
128 {
129 if ($2 != $1)
130 ERROR(&@2, "Header flags don't match earlier ones");
131 $$ = $1;
132 }
133 ;
134
135memreserves:
136 /* empty */
137 {
138 $$ = NULL;
139 }
140 | memreserve memreserves
141 {
142 $$ = chain_reserve_entry($1, $2);
143 }
144 ;
145
146memreserve:
147 DT_MEMRESERVE integer_prim integer_prim ';'
148 {
149 $$ = build_reserve_entry($2, $3);
150 }
151 | DT_LABEL memreserve
152 {
153 add_label(&$2->labels, $1);
154 $$ = $2;
155 }
156 ;
157
158dt_ref: DT_LABEL_REF | DT_PATH_REF;
159
160devicetree:
161 '/' nodedef
162 {
163 $$ = name_node($2, "");
164 }
165 | devicetree '/' nodedef
166 {
167 $$ = merge_nodes($1, $3);
168 }
169 | dt_ref nodedef
170 {
171 /*
172 * We rely on the rule being always:
173 * versioninfo plugindecl memreserves devicetree
174 * so $-1 is what we want (plugindecl)
175 */
176 if (!($<flags>-1 & DTSF_PLUGIN))
177 ERROR(&@2, "Label or path %s not found", $1);
178 else if (is_ref_relative($1))
179 ERROR(&@2, "Label-relative reference %s not supported in plugin", $1);
180 $$ = add_orphan_node(
181 name_node(build_node(NULL, NULL, NULL),
182 ""),
183 $2, $1);
184 }
185 | devicetree DT_LABEL dt_ref nodedef
186 {
187 struct node *target = get_node_by_ref($1, $3);
188
189 if (($<flags>-1 & DTSF_PLUGIN) && is_ref_relative($3))
190 ERROR(&@2, "Label-relative reference %s not supported in plugin", $3);
191
192 if (target) {
193 add_label(&target->labels, $2);
194 merge_nodes(target, $4);
195 } else
196 ERROR(&@3, "Label or path %s not found", $3);
197 $$ = $1;
198 }
199 | devicetree DT_PATH_REF nodedef
200 {
201 /*
202 * We rely on the rule being always:
203 * versioninfo plugindecl memreserves devicetree
204 * so $-1 is what we want (plugindecl)
205 */
206 if ($<flags>-1 & DTSF_PLUGIN) {
207 if (is_ref_relative($2))
208 ERROR(&@2, "Label-relative reference %s not supported in plugin", $2);
209 add_orphan_node($1, $3, $2);
210 } else {
211 struct node *target = get_node_by_ref($1, $2);
212
213 if (target)
214 merge_nodes(target, $3);
215 else
216 ERROR(&@2, "Label or path %s not found", $2);
217 }
218 $$ = $1;
219 }
220 | devicetree DT_LABEL_REF nodedef
221 {
222 struct node *target = get_node_by_ref($1, $2);
223
224 if (target) {
225 merge_nodes(target, $3);
226 } else {
227 /*
228 * We rely on the rule being always:
229 * versioninfo plugindecl memreserves devicetree
230 * so $-1 is what we want (plugindecl)
231 */
232 if ($<flags>-1 & DTSF_PLUGIN)
233 add_orphan_node($1, $3, $2);
234 else
235 ERROR(&@2, "Label or path %s not found", $2);
236 }
237 $$ = $1;
238 }
239 | devicetree DT_DEL_NODE dt_ref ';'
240 {
241 struct node *target = get_node_by_ref($1, $3);
242
243 if (target)
244 delete_node(target);
245 else
246 ERROR(&@3, "Label or path %s not found", $3);
247
248
249 $$ = $1;
250 }
251 | devicetree DT_OMIT_NO_REF dt_ref ';'
252 {
253 struct node *target = get_node_by_ref($1, $3);
254
255 if (target)
256 omit_node_if_unused(target);
257 else
258 ERROR(&@3, "Label or path %s not found", $3);
259
260
261 $$ = $1;
262 }
263 ;
264
265nodedef:
266 '{' proplist subnodes '}' ';'
267 {
268 $$ = build_node($2, $3, &@$);
269 }
270 ;
271
272proplist:
273 /* empty */
274 {
275 $$ = NULL;
276 }
277 | proplist propdef
278 {
279 $$ = chain_property($2, $1);
280 }
281 ;
282
283propdef:
284 DT_PROPNODENAME '=' propdata ';'
285 {
286 $$ = build_property($1, $3, &@$);
287 }
288 | DT_PROPNODENAME ';'
289 {
290 $$ = build_property($1, empty_data, &@$);
291 }
292 | DT_DEL_PROP DT_PROPNODENAME ';'
293 {
294 $$ = build_property_delete($2);
295 }
296 | DT_LABEL propdef
297 {
298 add_label(&$2->labels, $1);
299 $$ = $2;
300 }
301 ;
302
303propdata:
304 propdataprefix DT_STRING
305 {
306 $$ = data_merge($1, $2);
307 }
308 | propdataprefix arrayprefix '>'
309 {
310 $$ = data_merge($1, $2.data);
311 }
312 | propdataprefix '[' bytestring ']'
313 {
314 $$ = data_merge($1, $3);
315 }
316 | propdataprefix dt_ref
317 {
318 $1 = data_add_marker($1, TYPE_STRING, $2);
319 $$ = data_add_marker($1, REF_PATH, $2);
320 }
321 | propdataprefix DT_INCBIN '(' DT_STRING ',' integer_prim ',' integer_prim ')'
322 {
323 FILE *f = srcfile_relative_open($4.val, NULL);
324 struct data d;
325
326 if ($6 != 0)
327 if (fseek(f, $6, SEEK_SET) != 0)
328 die("Couldn't seek to offset %llu in \"%s\": %s",
329 (unsigned long long)$6, $4.val,
330 strerror(errno));
331
332 d = data_copy_file(f, $8);
333
334 $$ = data_merge($1, d);
335 fclose(f);
336 }
337 | propdataprefix DT_INCBIN '(' DT_STRING ')'
338 {
339 FILE *f = srcfile_relative_open($4.val, NULL);
340 struct data d = empty_data;
341
342 d = data_copy_file(f, -1);
343
344 $$ = data_merge($1, d);
345 fclose(f);
346 }
347 | propdata DT_LABEL
348 {
349 $$ = data_add_marker($1, LABEL, $2);
350 }
351 ;
352
353propdataprefix:
354 /* empty */
355 {
356 $$ = empty_data;
357 }
358 | propdata ','
359 {
360 $$ = $1;
361 }
362 | propdataprefix DT_LABEL
363 {
364 $$ = data_add_marker($1, LABEL, $2);
365 }
366 ;
367
368arrayprefix:
369 DT_BITS DT_LITERAL '<'
370 {
371 unsigned long long bits;
372 enum markertype type = TYPE_UINT32;
373
374 bits = $2;
375
376 switch (bits) {
377 case 8: type = TYPE_UINT8; break;
378 case 16: type = TYPE_UINT16; break;
379 case 32: type = TYPE_UINT32; break;
380 case 64: type = TYPE_UINT64; break;
381 default:
382 ERROR(&@2, "Array elements must be"
383 " 8, 16, 32 or 64-bits");
384 bits = 32;
385 }
386
387 $$.data = data_add_marker(empty_data, type, NULL);
388 $$.bits = bits;
389 }
390 | '<'
391 {
392 $$.data = data_add_marker(empty_data, TYPE_UINT32, NULL);
393 $$.bits = 32;
394 }
395 | arrayprefix integer_prim
396 {
397 if ($1.bits < 64) {
398 uint64_t mask = (1ULL << $1.bits) - 1;
399 /*
400 * Bits above mask must either be all zero
401 * (positive within range of mask) or all one
402 * (negative and sign-extended). The second
403 * condition is true if when we set all bits
404 * within the mask to one (i.e. | in the
405 * mask), all bits are one.
406 */
407 if (($2 > mask) && (($2 | mask) != -1ULL))
408 ERROR(&@2, "Value out of range for"
409 " %d-bit array element", $1.bits);
410 }
411
412 $$.data = data_append_integer($1.data, $2, $1.bits);
413 }
414 | arrayprefix dt_ref
415 {
416 uint64_t val = ~0ULL >> (64 - $1.bits);
417
418 if ($1.bits == 32)
419 $1.data = data_add_marker($1.data,
420 REF_PHANDLE,
421 $2);
422 else
423 ERROR(&@2, "References are only allowed in "
424 "arrays with 32-bit elements.");
425
426 $$.data = data_append_integer($1.data, val, $1.bits);
427 }
428 | arrayprefix DT_LABEL
429 {
430 $$.data = data_add_marker($1.data, LABEL, $2);
431 }
432 ;
433
434integer_prim:
435 DT_LITERAL
436 | DT_CHAR_LITERAL
437 | '(' integer_expr ')'
438 {
439 $$ = $2;
440 }
441 ;
442
443integer_expr:
444 integer_trinary
445 ;
446
447integer_trinary:
448 integer_or
449 | integer_or '?' integer_expr ':' integer_trinary { $$ = $1 ? $3 : $5; }
450 ;
451
452integer_or:
453 integer_and
454 | integer_or DT_OR integer_and { $$ = $1 || $3; }
455 ;
456
457integer_and:
458 integer_bitor
459 | integer_and DT_AND integer_bitor { $$ = $1 && $3; }
460 ;
461
462integer_bitor:
463 integer_bitxor
464 | integer_bitor '|' integer_bitxor { $$ = $1 | $3; }
465 ;
466
467integer_bitxor:
468 integer_bitand
469 | integer_bitxor '^' integer_bitand { $$ = $1 ^ $3; }
470 ;
471
472integer_bitand:
473 integer_eq
474 | integer_bitand '&' integer_eq { $$ = $1 & $3; }
475 ;
476
477integer_eq:
478 integer_rela
479 | integer_eq DT_EQ integer_rela { $$ = $1 == $3; }
480 | integer_eq DT_NE integer_rela { $$ = $1 != $3; }
481 ;
482
483integer_rela:
484 integer_shift
485 | integer_rela '<' integer_shift { $$ = $1 < $3; }
486 | integer_rela '>' integer_shift { $$ = $1 > $3; }
487 | integer_rela DT_LE integer_shift { $$ = $1 <= $3; }
488 | integer_rela DT_GE integer_shift { $$ = $1 >= $3; }
489 ;
490
491integer_shift:
492 integer_shift DT_LSHIFT integer_add { $$ = ($3 < 64) ? ($1 << $3) : 0; }
493 | integer_shift DT_RSHIFT integer_add { $$ = ($3 < 64) ? ($1 >> $3) : 0; }
494 | integer_add
495 ;
496
497integer_add:
498 integer_add '+' integer_mul { $$ = $1 + $3; }
499 | integer_add '-' integer_mul { $$ = $1 - $3; }
500 | integer_mul
501 ;
502
503integer_mul:
504 integer_mul '*' integer_unary { $$ = $1 * $3; }
505 | integer_mul '/' integer_unary
506 {
507 if ($3 != 0) {
508 $$ = $1 / $3;
509 } else {
510 ERROR(&@$, "Division by zero");
511 $$ = 0;
512 }
513 }
514 | integer_mul '%' integer_unary
515 {
516 if ($3 != 0) {
517 $$ = $1 % $3;
518 } else {
519 ERROR(&@$, "Division by zero");
520 $$ = 0;
521 }
522 }
523 | integer_unary
524 ;
525
526integer_unary:
527 integer_prim
528 | '-' integer_unary { $$ = -$2; }
529 | '~' integer_unary { $$ = ~$2; }
530 | '!' integer_unary { $$ = !$2; }
531 ;
532
533bytestring:
534 /* empty */
535 {
536 $$ = data_add_marker(empty_data, TYPE_UINT8, NULL);
537 }
538 | bytestring DT_BYTE
539 {
540 $$ = data_append_byte($1, $2);
541 }
542 | bytestring DT_LABEL
543 {
544 $$ = data_add_marker($1, LABEL, $2);
545 }
546 ;
547
548subnodes:
549 /* empty */
550 {
551 $$ = NULL;
552 }
553 | subnode subnodes
554 {
555 $$ = chain_node($1, $2);
556 }
557 | subnode propdef
558 {
559 ERROR(&@2, "Properties must precede subnodes");
560 YYERROR;
561 }
562 ;
563
564subnode:
565 DT_PROPNODENAME nodedef
566 {
567 $$ = name_node($2, $1);
568 }
569 | DT_DEL_NODE DT_PROPNODENAME ';'
570 {
571 $$ = name_node(build_node_delete(&@$), $2);
572 }
573 | DT_OMIT_NO_REF subnode
574 {
575 $$ = omit_node_if_unused($2);
576 }
577 | DT_LABEL subnode
578 {
579 add_label(&$2->labels, $1);
580 $$ = $2;
581 }
582 ;
583
584%%
585
586void yyerror(char const *s)
587{
588 ERROR(&yylloc, "%s", s);
589}