Loading...
1/* ld script to make ARM Linux kernel
2 * taken from the i386 version by Russell King
3 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
4 */
5
6#include <asm-generic/vmlinux.lds.h>
7#include <asm/cache.h>
8#include <asm/thread_info.h>
9#include <asm/memory.h>
10#include <asm/page.h>
11
12#define PROC_INFO \
13 . = ALIGN(4); \
14 VMLINUX_SYMBOL(__proc_info_begin) = .; \
15 *(.proc.info.init) \
16 VMLINUX_SYMBOL(__proc_info_end) = .;
17
18#define IDMAP_TEXT \
19 ALIGN_FUNCTION(); \
20 VMLINUX_SYMBOL(__idmap_text_start) = .; \
21 *(.idmap.text) \
22 VMLINUX_SYMBOL(__idmap_text_end) = .;
23
24#ifdef CONFIG_HOTPLUG_CPU
25#define ARM_CPU_DISCARD(x)
26#define ARM_CPU_KEEP(x) x
27#else
28#define ARM_CPU_DISCARD(x) x
29#define ARM_CPU_KEEP(x)
30#endif
31
32#if (defined(CONFIG_SMP_ON_UP) && !defined(CONFIG_DEBUG_SPINLOCK)) || \
33 defined(CONFIG_GENERIC_BUG)
34#define ARM_EXIT_KEEP(x) x
35#define ARM_EXIT_DISCARD(x)
36#else
37#define ARM_EXIT_KEEP(x)
38#define ARM_EXIT_DISCARD(x) x
39#endif
40
41OUTPUT_ARCH(arm)
42ENTRY(stext)
43
44#ifndef __ARMEB__
45jiffies = jiffies_64;
46#else
47jiffies = jiffies_64 + 4;
48#endif
49
50SECTIONS
51{
52 /*
53 * XXX: The linker does not define how output sections are
54 * assigned to input sections when there are multiple statements
55 * matching the same input section name. There is no documented
56 * order of matching.
57 *
58 * unwind exit sections must be discarded before the rest of the
59 * unwind sections get included.
60 */
61 /DISCARD/ : {
62 *(.ARM.exidx.exit.text)
63 *(.ARM.extab.exit.text)
64 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
65 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
66 ARM_EXIT_DISCARD(EXIT_TEXT)
67 ARM_EXIT_DISCARD(EXIT_DATA)
68 EXIT_CALL
69#ifndef CONFIG_HOTPLUG
70 *(.ARM.exidx.devexit.text)
71 *(.ARM.extab.devexit.text)
72#endif
73#ifndef CONFIG_MMU
74 *(.fixup)
75 *(__ex_table)
76#endif
77#ifndef CONFIG_SMP_ON_UP
78 *(.alt.smp.init)
79#endif
80 *(.discard)
81 *(.discard.*)
82 }
83
84#ifdef CONFIG_XIP_KERNEL
85 . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
86#else
87 . = PAGE_OFFSET + TEXT_OFFSET;
88#endif
89 .head.text : {
90 _text = .;
91 HEAD_TEXT
92 }
93 .text : { /* Real text segment */
94 _stext = .; /* Text and read-only data */
95 __exception_text_start = .;
96 *(.exception.text)
97 __exception_text_end = .;
98 IRQENTRY_TEXT
99 TEXT_TEXT
100 SCHED_TEXT
101 LOCK_TEXT
102 KPROBES_TEXT
103 IDMAP_TEXT
104#ifdef CONFIG_MMU
105 *(.fixup)
106#endif
107 *(.gnu.warning)
108 *(.glue_7)
109 *(.glue_7t)
110 . = ALIGN(4);
111 *(.got) /* Global offset table */
112 ARM_CPU_KEEP(PROC_INFO)
113 }
114
115 RO_DATA(PAGE_SIZE)
116
117#ifdef CONFIG_ARM_UNWIND
118 /*
119 * Stack unwinding tables
120 */
121 . = ALIGN(8);
122 .ARM.unwind_idx : {
123 __start_unwind_idx = .;
124 *(.ARM.exidx*)
125 __stop_unwind_idx = .;
126 }
127 .ARM.unwind_tab : {
128 __start_unwind_tab = .;
129 *(.ARM.extab*)
130 __stop_unwind_tab = .;
131 }
132#endif
133
134 _etext = .; /* End of text and rodata section */
135
136#ifndef CONFIG_XIP_KERNEL
137 . = ALIGN(PAGE_SIZE);
138 __init_begin = .;
139#endif
140
141 INIT_TEXT_SECTION(8)
142 .exit.text : {
143 ARM_EXIT_KEEP(EXIT_TEXT)
144 }
145 .init.proc.info : {
146 ARM_CPU_DISCARD(PROC_INFO)
147 }
148 .init.arch.info : {
149 __arch_info_begin = .;
150 *(.arch.info.init)
151 __arch_info_end = .;
152 }
153 .init.tagtable : {
154 __tagtable_begin = .;
155 *(.taglist.init)
156 __tagtable_end = .;
157 }
158#ifdef CONFIG_SMP_ON_UP
159 .init.smpalt : {
160 __smpalt_begin = .;
161 *(.alt.smp.init)
162 __smpalt_end = .;
163 }
164#endif
165 .init.pv_table : {
166 __pv_table_begin = .;
167 *(.pv_table)
168 __pv_table_end = .;
169 }
170 .init.data : {
171#ifndef CONFIG_XIP_KERNEL
172 INIT_DATA
173#endif
174 INIT_SETUP(16)
175 INIT_CALLS
176 CON_INITCALL
177 SECURITY_INITCALL
178 INIT_RAM_FS
179 }
180#ifndef CONFIG_XIP_KERNEL
181 .exit.data : {
182 ARM_EXIT_KEEP(EXIT_DATA)
183 }
184#endif
185
186#ifdef CONFIG_SMP
187 PERCPU_SECTION(L1_CACHE_BYTES)
188#endif
189
190#ifdef CONFIG_XIP_KERNEL
191 __data_loc = ALIGN(4); /* location in binary */
192 . = PAGE_OFFSET + TEXT_OFFSET;
193#else
194 __init_end = .;
195 . = ALIGN(THREAD_SIZE);
196 __data_loc = .;
197#endif
198
199 .data : AT(__data_loc) {
200 _data = .; /* address in memory */
201 _sdata = .;
202
203 /*
204 * first, the init task union, aligned
205 * to an 8192 byte boundary.
206 */
207 INIT_TASK_DATA(THREAD_SIZE)
208
209#ifdef CONFIG_XIP_KERNEL
210 . = ALIGN(PAGE_SIZE);
211 __init_begin = .;
212 INIT_DATA
213 ARM_EXIT_KEEP(EXIT_DATA)
214 . = ALIGN(PAGE_SIZE);
215 __init_end = .;
216#endif
217
218 NOSAVE_DATA
219 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
220 READ_MOSTLY_DATA(L1_CACHE_BYTES)
221
222 /*
223 * The exception fixup table (might need resorting at runtime)
224 */
225 . = ALIGN(4);
226 __start___ex_table = .;
227#ifdef CONFIG_MMU
228 *(__ex_table)
229#endif
230 __stop___ex_table = .;
231
232 /*
233 * and the usual data section
234 */
235 DATA_DATA
236 CONSTRUCTORS
237
238 _edata = .;
239 }
240 _edata_loc = __data_loc + SIZEOF(.data);
241
242#ifdef CONFIG_HAVE_TCM
243 /*
244 * We align everything to a page boundary so we can
245 * free it after init has commenced and TCM contents have
246 * been copied to its destination.
247 */
248 .tcm_start : {
249 . = ALIGN(PAGE_SIZE);
250 __tcm_start = .;
251 __itcm_start = .;
252 }
253
254 /*
255 * Link these to the ITCM RAM
256 * Put VMA to the TCM address and LMA to the common RAM
257 * and we'll upload the contents from RAM to TCM and free
258 * the used RAM after that.
259 */
260 .text_itcm ITCM_OFFSET : AT(__itcm_start)
261 {
262 __sitcm_text = .;
263 *(.tcm.text)
264 *(.tcm.rodata)
265 . = ALIGN(4);
266 __eitcm_text = .;
267 }
268
269 /*
270 * Reset the dot pointer, this is needed to create the
271 * relative __dtcm_start below (to be used as extern in code).
272 */
273 . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
274
275 .dtcm_start : {
276 __dtcm_start = .;
277 }
278
279 /* TODO: add remainder of ITCM as well, that can be used for data! */
280 .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
281 {
282 . = ALIGN(4);
283 __sdtcm_data = .;
284 *(.tcm.data)
285 . = ALIGN(4);
286 __edtcm_data = .;
287 }
288
289 /* Reset the dot pointer or the linker gets confused */
290 . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
291
292 /* End marker for freeing TCM copy in linked object */
293 .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
294 . = ALIGN(PAGE_SIZE);
295 __tcm_end = .;
296 }
297#endif
298
299 NOTES
300
301 BSS_SECTION(0, 0, 0)
302 _end = .;
303
304 STABS_DEBUG
305 .comment 0 : { *(.comment) }
306}
307
308/*
309 * These must never be empty
310 * If you have to comment these two assert statements out, your
311 * binutils is too old (for other reasons as well)
312 */
313ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
314ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
1/* SPDX-License-Identifier: GPL-2.0 */
2/* ld script to make ARM Linux kernel
3 * taken from the i386 version by Russell King
4 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
5 */
6
7#ifdef CONFIG_XIP_KERNEL
8#include "vmlinux-xip.lds.S"
9#else
10
11#include <asm-generic/vmlinux.lds.h>
12#include <asm/cache.h>
13#include <asm/thread_info.h>
14#include <asm/memory.h>
15#include <asm/page.h>
16#include <asm/pgtable.h>
17
18#include "vmlinux.lds.h"
19
20OUTPUT_ARCH(arm)
21ENTRY(stext)
22
23#ifndef __ARMEB__
24jiffies = jiffies_64;
25#else
26jiffies = jiffies_64 + 4;
27#endif
28
29SECTIONS
30{
31 /*
32 * XXX: The linker does not define how output sections are
33 * assigned to input sections when there are multiple statements
34 * matching the same input section name. There is no documented
35 * order of matching.
36 *
37 * unwind exit sections must be discarded before the rest of the
38 * unwind sections get included.
39 */
40 /DISCARD/ : {
41 ARM_DISCARD
42#ifndef CONFIG_SMP_ON_UP
43 *(.alt.smp.init)
44#endif
45 }
46
47 . = PAGE_OFFSET + TEXT_OFFSET;
48 .head.text : {
49 _text = .;
50 HEAD_TEXT
51 }
52
53#ifdef CONFIG_STRICT_KERNEL_RWX
54 . = ALIGN(1<<SECTION_SHIFT);
55#endif
56
57 .text : { /* Real text segment */
58 _stext = .; /* Text and read-only data */
59 ARM_TEXT
60 }
61
62#ifdef CONFIG_DEBUG_ALIGN_RODATA
63 . = ALIGN(1<<SECTION_SHIFT);
64#endif
65 _etext = .; /* End of text section */
66
67 RO_DATA(PAGE_SIZE)
68
69 . = ALIGN(4);
70 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
71 __start___ex_table = .;
72 ARM_MMU_KEEP(*(__ex_table))
73 __stop___ex_table = .;
74 }
75
76#ifdef CONFIG_ARM_UNWIND
77 ARM_UNWIND_SECTIONS
78#endif
79
80 NOTES
81
82#ifdef CONFIG_STRICT_KERNEL_RWX
83 . = ALIGN(1<<SECTION_SHIFT);
84#else
85 . = ALIGN(PAGE_SIZE);
86#endif
87 __init_begin = .;
88
89 ARM_VECTORS
90 INIT_TEXT_SECTION(8)
91 .exit.text : {
92 ARM_EXIT_KEEP(EXIT_TEXT)
93 }
94 .init.proc.info : {
95 ARM_CPU_DISCARD(PROC_INFO)
96 }
97 .init.arch.info : {
98 __arch_info_begin = .;
99 *(.arch.info.init)
100 __arch_info_end = .;
101 }
102 .init.tagtable : {
103 __tagtable_begin = .;
104 *(.taglist.init)
105 __tagtable_end = .;
106 }
107#ifdef CONFIG_SMP_ON_UP
108 .init.smpalt : {
109 __smpalt_begin = .;
110 *(.alt.smp.init)
111 __smpalt_end = .;
112 }
113#endif
114 .init.pv_table : {
115 __pv_table_begin = .;
116 *(.pv_table)
117 __pv_table_end = .;
118 }
119
120 INIT_DATA_SECTION(16)
121
122 .exit.data : {
123 ARM_EXIT_KEEP(EXIT_DATA)
124 }
125
126#ifdef CONFIG_SMP
127 PERCPU_SECTION(L1_CACHE_BYTES)
128#endif
129
130#ifdef CONFIG_HAVE_TCM
131 ARM_TCM
132#endif
133
134#ifdef CONFIG_STRICT_KERNEL_RWX
135 . = ALIGN(1<<SECTION_SHIFT);
136#else
137 . = ALIGN(THREAD_SIZE);
138#endif
139 __init_end = .;
140
141 _sdata = .;
142 RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
143 _edata = .;
144
145 BSS_SECTION(0, 0, 0)
146 _end = .;
147
148 STABS_DEBUG
149}
150
151#ifdef CONFIG_STRICT_KERNEL_RWX
152/*
153 * Without CONFIG_DEBUG_ALIGN_RODATA, __start_rodata_section_aligned will
154 * be the first section-aligned location after __start_rodata. Otherwise,
155 * it will be equal to __start_rodata.
156 */
157__start_rodata_section_aligned = ALIGN(__start_rodata, 1 << SECTION_SHIFT);
158#endif
159
160/*
161 * These must never be empty
162 * If you have to comment these two assert statements out, your
163 * binutils is too old (for other reasons as well)
164 */
165ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
166ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
167
168/*
169 * The HYP init code can't be more than a page long,
170 * and should not cross a page boundary.
171 * The above comment applies as well.
172 */
173ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & PAGE_MASK) <= PAGE_SIZE,
174 "HYP init code too big or misaligned")
175
176#endif /* CONFIG_XIP_KERNEL */