Loading...
1#!/bin/sh
2# Before running this script please ensure that your PATH is
3# typical as you use for compilation/istallation. I use
4# /bin /sbin /usr/bin /usr/sbin /usr/local/bin, but it may
5# differ on your system.
6#
7echo 'If some fields are empty or look unusual you may have an old version.'
8echo 'Compare to the current minimal requirements in Documentation/Changes.'
9echo ' '
10
11uname -a
12echo ' '
13
14gcc -dumpversion 2>&1| awk \
15'NR==1{print "Gnu C ", $1}'
16
17make --version 2>&1 | awk -F, '{print $1}' | awk \
18 '/GNU Make/{print "Gnu make ",$NF}'
19
20echo "binutils $(ld -v | egrep -o '[0-9]+\.[0-9\.]+')"
21
22echo -n "util-linux "
23fdformat --version | awk '{print $NF}' | sed -e s/^util-linux-// -e s/\)$//
24
25echo -n "mount "
26mount --version | awk '{print $NF}' | sed -e s/^mount-// -e s/\)$//
27
28depmod -V 2>&1 | awk 'NR==1 {print "module-init-tools ",$NF}'
29
30tune2fs 2>&1 | grep "^tune2fs" | sed 's/,//' | awk \
31'NR==1 {print "e2fsprogs ", $2}'
32
33fsck.jfs -V 2>&1 | grep version | sed 's/,//' | awk \
34'NR==1 {print "jfsutils ", $3}'
35
36reiserfsck -V 2>&1 | grep ^reiserfsck | awk \
37'NR==1{print "reiserfsprogs ", $2}'
38
39fsck.reiser4 -V 2>&1 | grep ^fsck.reiser4 | awk \
40'NR==1{print "reiser4progs ", $2}'
41
42xfs_db -V 2>&1 | grep version | awk \
43'NR==1{print "xfsprogs ", $3}'
44
45pccardctl -V 2>&1| grep pcmciautils | awk '{print "pcmciautils ", $2}'
46
47cardmgr -V 2>&1| grep version | awk \
48'NR==1{print "pcmcia-cs ", $3}'
49
50quota -V 2>&1 | grep version | awk \
51'NR==1{print "quota-tools ", $NF}'
52
53pppd --version 2>&1| grep version | awk \
54'NR==1{print "PPP ", $3}'
55
56isdnctrl 2>&1 | grep version | awk \
57'NR==1{print "isdn4k-utils ", $NF}'
58
59showmount --version 2>&1 | grep nfs-utils | awk \
60'NR==1{print "nfs-utils ", $NF}'
61
62echo -n "Linux C Library "
63sed -n -e '/^.*\/libc-\([^/]*\)\.so$/{s//\1/;p;q}' < /proc/self/maps
64
65ldd -v > /dev/null 2>&1 && ldd -v || ldd --version |head -n 1 | awk \
66'NR==1{print "Dynamic linker (ldd) ", $NF}'
67
68ls -l /usr/lib/libg++.so /usr/lib/libstdc++.so 2>/dev/null | awk -F. \
69 '{print "Linux C++ Library " $4"."$5"."$6}'
70
71ps --version 2>&1 | grep version | awk \
72'NR==1{print "Procps ", $NF}'
73
74ifconfig --version 2>&1 | grep tools | awk \
75'NR==1{print "Net-tools ", $NF}'
76
77# Kbd needs 'loadkeys -h',
78loadkeys -h 2>&1 | awk \
79'(NR==1 && ($3 !~ /option/)) {print "Kbd ", $3}'
80
81# while console-tools needs 'loadkeys -V'.
82loadkeys -V 2>&1 | awk \
83'(NR==1 && ($2 ~ /console-tools/)) {print "Console-tools ", $3}'
84
85oprofiled --version 2>&1 | awk \
86'(NR==1 && ($2 == "oprofile")) {print "oprofile ", $3}'
87
88expr --v 2>&1 | awk 'NR==1{print "Sh-utils ", $NF}'
89
90udevinfo -V 2>&1 | grep version | awk '{print "udev ", $3}'
91
92iwconfig --version 2>&1 | awk \
93'(NR==1 && ($3 == "version")) {print "wireless-tools ",$4}'
94
95if [ -e /proc/modules ]; then
96 X=`cat /proc/modules | sed -e "s/ .*$//"`
97 echo "Modules Loaded "$X
98fi
1#!/bin/awk -f
2# Before running this script please ensure that your PATH is
3# typical as you use for compilation/installation. I use
4# /bin /sbin /usr/bin /usr/sbin /usr/local/bin, but it may
5# differ on your system.
6
7BEGIN {
8 usage = "If some fields are empty or look unusual you may have an old version.\n"
9 usage = usage "Compare to the current minimal requirements in Documentation/Changes.\n"
10 print usage
11
12 system("uname -a")
13 printf("\n")
14
15 printversion("GNU C", version("gcc -dumpversion 2>&1"))
16 printversion("GNU Make", version("make --version 2>&1"))
17 printversion("Binutils", version("ld -v 2>&1"))
18 printversion("Util-linux", version("mount --version 2>&1"))
19 printversion("Mount", version("mount --version 2>&1"))
20 printversion("Module-init-tools", version("depmod -V 2>&1"))
21 printversion("E2fsprogs", version("tune2fs 2>&1"))
22 printversion("Jfsutils", version("fsck.jfs -V 2>&1"))
23 printversion("Reiserfsprogs", version("reiserfsck -V 2>&1"))
24 printversion("Reiser4fsprogs", version("fsck.reiser4 -V 2>&1"))
25 printversion("Xfsprogs", version("xfs_db -V 2>&1"))
26 printversion("Pcmciautils", version("pccardctl -V 2>&1"))
27 printversion("Pcmcia-cs", version("cardmgr -V 2>&1"))
28 printversion("Quota-tools", version("quota -V 2>&1"))
29 printversion("PPP", version("pppd --version 2>&1"))
30 printversion("Isdn4k-utils", version("isdnctrl 2>&1"))
31 printversion("Nfs-utils", version("showmount --version 2>&1"))
32
33 if (system("test -r /proc/self/maps") == 0) {
34 while (getline <"/proc/self/maps" > 0) {
35 n = split($0, procmaps, "/")
36 if (/libc.*so$/ && match(procmaps[n], /[0-9]+([.]?[0-9]+)+/)) {
37 ver = substr(procmaps[n], RSTART, RLENGTH)
38 printversion("Linux C Library", ver)
39 break
40 }
41 }
42 }
43
44 printversion("Dynamic linker (ldd)", version("ldd --version 2>&1"))
45
46 while ("ldconfig -p 2>/dev/null" | getline > 0) {
47 if (/(libg|stdc)[+]+\.so/) {
48 libcpp = $NF
49 break
50 }
51 }
52 if (system("test -r " libcpp) == 0)
53 printversion("Linux C++ Library", version("readlink " libcpp))
54
55 printversion("Procps", version("ps --version 2>&1"))
56 printversion("Net-tools", version("ifconfig --version 2>&1"))
57 printversion("Kbd", version("loadkeys -V 2>&1"))
58 printversion("Console-tools", version("loadkeys -V 2>&1"))
59 printversion("Oprofile", version("oprofiled --version 2>&1"))
60 printversion("Sh-utils", version("expr --v 2>&1"))
61 printversion("Udev", version("udevadm --version 2>&1"))
62 printversion("Wireless-tools", version("iwconfig --version 2>&1"))
63
64 if (system("test -r /proc/modules") == 0) {
65 while ("sort /proc/modules" | getline > 0) {
66 mods = mods sep $1
67 sep = " "
68 }
69 printversion("Modules Loaded", mods)
70 }
71}
72
73function version(cmd, ver) {
74 while (cmd | getline > 0) {
75 if (!/ver_linux/ && match($0, /[0-9]+([.]?[0-9]+)+/)) {
76 ver = substr($0, RSTART, RLENGTH)
77 break
78 }
79 }
80 close(cmd)
81 return ver
82}
83
84function printversion(name, value, ofmt) {
85 if (value != "") {
86 ofmt = "%-20s\t%s\n"
87 printf(ofmt, name, value)
88 }
89}