Loading...
1/*
2 * header.S
3 *
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 *
6 * Based on bootsect.S and setup.S
7 * modified by more people than can be counted
8 *
9 * Rewritten as a common file by H. Peter Anvin (Apr 2007)
10 *
11 * BIG FAT NOTE: We're in real mode using 64k segments. Therefore segment
12 * addresses must be multiplied by 16 to obtain their respective linear
13 * addresses. To avoid confusion, linear addresses are written using leading
14 * hex while segment addresses are written as segment:offset.
15 *
16 */
17
18#include <asm/segment.h>
19#include <generated/utsrelease.h>
20#include <asm/boot.h>
21#include <asm/e820.h>
22#include <asm/page_types.h>
23#include <asm/setup.h>
24#include "boot.h"
25#include "voffset.h"
26#include "zoffset.h"
27
28BOOTSEG = 0x07C0 /* original address of boot-sector */
29SYSSEG = 0x1000 /* historical load address >> 4 */
30
31#ifndef SVGA_MODE
32#define SVGA_MODE ASK_VGA
33#endif
34
35#ifndef RAMDISK
36#define RAMDISK 0
37#endif
38
39#ifndef ROOT_RDONLY
40#define ROOT_RDONLY 1
41#endif
42
43 .code16
44 .section ".bstext", "ax"
45
46 .global bootsect_start
47bootsect_start:
48#ifdef CONFIG_EFI_STUB
49 # "MZ", MS-DOS header
50 .byte 0x4d
51 .byte 0x5a
52#endif
53
54 # Normalize the start address
55 ljmp $BOOTSEG, $start2
56
57start2:
58 movw %cs, %ax
59 movw %ax, %ds
60 movw %ax, %es
61 movw %ax, %ss
62 xorw %sp, %sp
63 sti
64 cld
65
66 movw $bugger_off_msg, %si
67
68msg_loop:
69 lodsb
70 andb %al, %al
71 jz bs_die
72 movb $0xe, %ah
73 movw $7, %bx
74 int $0x10
75 jmp msg_loop
76
77bs_die:
78 # Allow the user to press a key, then reboot
79 xorw %ax, %ax
80 int $0x16
81 int $0x19
82
83 # int 0x19 should never return. In case it does anyway,
84 # invoke the BIOS reset code...
85 ljmp $0xf000,$0xfff0
86
87#ifdef CONFIG_EFI_STUB
88 .org 0x3c
89 #
90 # Offset to the PE header.
91 #
92 .long pe_header
93#endif /* CONFIG_EFI_STUB */
94
95 .section ".bsdata", "a"
96bugger_off_msg:
97 .ascii "Direct floppy boot is not supported. "
98 .ascii "Use a boot loader program instead.\r\n"
99 .ascii "\n"
100 .ascii "Remove disk and press any key to reboot ...\r\n"
101 .byte 0
102
103#ifdef CONFIG_EFI_STUB
104pe_header:
105 .ascii "PE"
106 .word 0
107
108coff_header:
109#ifdef CONFIG_X86_32
110 .word 0x14c # i386
111#else
112 .word 0x8664 # x86-64
113#endif
114 .word 3 # nr_sections
115 .long 0 # TimeDateStamp
116 .long 0 # PointerToSymbolTable
117 .long 1 # NumberOfSymbols
118 .word section_table - optional_header # SizeOfOptionalHeader
119#ifdef CONFIG_X86_32
120 .word 0x306 # Characteristics.
121 # IMAGE_FILE_32BIT_MACHINE |
122 # IMAGE_FILE_DEBUG_STRIPPED |
123 # IMAGE_FILE_EXECUTABLE_IMAGE |
124 # IMAGE_FILE_LINE_NUMS_STRIPPED
125#else
126 .word 0x206 # Characteristics
127 # IMAGE_FILE_DEBUG_STRIPPED |
128 # IMAGE_FILE_EXECUTABLE_IMAGE |
129 # IMAGE_FILE_LINE_NUMS_STRIPPED
130#endif
131
132optional_header:
133#ifdef CONFIG_X86_32
134 .word 0x10b # PE32 format
135#else
136 .word 0x20b # PE32+ format
137#endif
138 .byte 0x02 # MajorLinkerVersion
139 .byte 0x14 # MinorLinkerVersion
140
141 # Filled in by build.c
142 .long 0 # SizeOfCode
143
144 .long 0 # SizeOfInitializedData
145 .long 0 # SizeOfUninitializedData
146
147 # Filled in by build.c
148 .long 0x0000 # AddressOfEntryPoint
149
150 .long 0x0200 # BaseOfCode
151#ifdef CONFIG_X86_32
152 .long 0 # data
153#endif
154
155extra_header_fields:
156#ifdef CONFIG_X86_32
157 .long 0 # ImageBase
158#else
159 .quad 0 # ImageBase
160#endif
161 .long 0x20 # SectionAlignment
162 .long 0x20 # FileAlignment
163 .word 0 # MajorOperatingSystemVersion
164 .word 0 # MinorOperatingSystemVersion
165 .word 0 # MajorImageVersion
166 .word 0 # MinorImageVersion
167 .word 0 # MajorSubsystemVersion
168 .word 0 # MinorSubsystemVersion
169 .long 0 # Win32VersionValue
170
171 #
172 # The size of the bzImage is written in tools/build.c
173 #
174 .long 0 # SizeOfImage
175
176 .long 0x200 # SizeOfHeaders
177 .long 0 # CheckSum
178 .word 0xa # Subsystem (EFI application)
179 .word 0 # DllCharacteristics
180#ifdef CONFIG_X86_32
181 .long 0 # SizeOfStackReserve
182 .long 0 # SizeOfStackCommit
183 .long 0 # SizeOfHeapReserve
184 .long 0 # SizeOfHeapCommit
185#else
186 .quad 0 # SizeOfStackReserve
187 .quad 0 # SizeOfStackCommit
188 .quad 0 # SizeOfHeapReserve
189 .quad 0 # SizeOfHeapCommit
190#endif
191 .long 0 # LoaderFlags
192 .long 0x6 # NumberOfRvaAndSizes
193
194 .quad 0 # ExportTable
195 .quad 0 # ImportTable
196 .quad 0 # ResourceTable
197 .quad 0 # ExceptionTable
198 .quad 0 # CertificationTable
199 .quad 0 # BaseRelocationTable
200
201 # Section table
202section_table:
203 #
204 # The offset & size fields are filled in by build.c.
205 #
206 .ascii ".setup"
207 .byte 0
208 .byte 0
209 .long 0
210 .long 0x0 # startup_{32,64}
211 .long 0 # Size of initialized data
212 # on disk
213 .long 0x0 # startup_{32,64}
214 .long 0 # PointerToRelocations
215 .long 0 # PointerToLineNumbers
216 .word 0 # NumberOfRelocations
217 .word 0 # NumberOfLineNumbers
218 .long 0x60500020 # Characteristics (section flags)
219
220 #
221 # The EFI application loader requires a relocation section
222 # because EFI applications must be relocatable. The .reloc
223 # offset & size fields are filled in by build.c.
224 #
225 .ascii ".reloc"
226 .byte 0
227 .byte 0
228 .long 0
229 .long 0
230 .long 0 # SizeOfRawData
231 .long 0 # PointerToRawData
232 .long 0 # PointerToRelocations
233 .long 0 # PointerToLineNumbers
234 .word 0 # NumberOfRelocations
235 .word 0 # NumberOfLineNumbers
236 .long 0x42100040 # Characteristics (section flags)
237
238 #
239 # The offset & size fields are filled in by build.c.
240 #
241 .ascii ".text"
242 .byte 0
243 .byte 0
244 .byte 0
245 .long 0
246 .long 0x0 # startup_{32,64}
247 .long 0 # Size of initialized data
248 # on disk
249 .long 0x0 # startup_{32,64}
250 .long 0 # PointerToRelocations
251 .long 0 # PointerToLineNumbers
252 .word 0 # NumberOfRelocations
253 .word 0 # NumberOfLineNumbers
254 .long 0x60500020 # Characteristics (section flags)
255
256#endif /* CONFIG_EFI_STUB */
257
258 # Kernel attributes; used by setup. This is part 1 of the
259 # header, from the old boot sector.
260
261 .section ".header", "a"
262 .globl hdr
263hdr:
264setup_sects: .byte 0 /* Filled in by build.c */
265root_flags: .word ROOT_RDONLY
266syssize: .long 0 /* Filled in by build.c */
267ram_size: .word 0 /* Obsolete */
268vid_mode: .word SVGA_MODE
269root_dev: .word 0 /* Filled in by build.c */
270boot_flag: .word 0xAA55
271
272 # offset 512, entry point
273
274 .globl _start
275_start:
276 # Explicitly enter this as bytes, or the assembler
277 # tries to generate a 3-byte jump here, which causes
278 # everything else to push off to the wrong offset.
279 .byte 0xeb # short (2-byte) jump
280 .byte start_of_setup-1f
2811:
282
283 # Part 2 of the header, from the old setup.S
284
285 .ascii "HdrS" # header signature
286 .word 0x020a # header version number (>= 0x0105)
287 # or else old loadlin-1.5 will fail)
288 .globl realmode_swtch
289realmode_swtch: .word 0, 0 # default_switch, SETUPSEG
290start_sys_seg: .word SYSSEG # obsolete and meaningless, but just
291 # in case something decided to "use" it
292 .word kernel_version-512 # pointing to kernel version string
293 # above section of header is compatible
294 # with loadlin-1.5 (header v1.5). Don't
295 # change it.
296
297type_of_loader: .byte 0 # 0 means ancient bootloader, newer
298 # bootloaders know to change this.
299 # See Documentation/x86/boot.txt for
300 # assigned ids
301
302# flags, unused bits must be zero (RFU) bit within loadflags
303loadflags:
304LOADED_HIGH = 1 # If set, the kernel is loaded high
305CAN_USE_HEAP = 0x80 # If set, the loader also has set
306 # heap_end_ptr to tell how much
307 # space behind setup.S can be used for
308 # heap purposes.
309 # Only the loader knows what is free
310 .byte LOADED_HIGH
311
312setup_move_size: .word 0x8000 # size to move, when setup is not
313 # loaded at 0x90000. We will move setup
314 # to 0x90000 then just before jumping
315 # into the kernel. However, only the
316 # loader knows how much data behind
317 # us also needs to be loaded.
318
319code32_start: # here loaders can put a different
320 # start address for 32-bit code.
321 .long 0x100000 # 0x100000 = default for big kernel
322
323ramdisk_image: .long 0 # address of loaded ramdisk image
324 # Here the loader puts the 32-bit
325 # address where it loaded the image.
326 # This only will be read by the kernel.
327
328ramdisk_size: .long 0 # its size in bytes
329
330bootsect_kludge:
331 .long 0 # obsolete
332
333heap_end_ptr: .word _end+STACK_SIZE-512
334 # (Header version 0x0201 or later)
335 # space from here (exclusive) down to
336 # end of setup code can be used by setup
337 # for local heap purposes.
338
339ext_loader_ver:
340 .byte 0 # Extended boot loader version
341ext_loader_type:
342 .byte 0 # Extended boot loader type
343
344cmd_line_ptr: .long 0 # (Header version 0x0202 or later)
345 # If nonzero, a 32-bit pointer
346 # to the kernel command line.
347 # The command line should be
348 # located between the start of
349 # setup and the end of low
350 # memory (0xa0000), or it may
351 # get overwritten before it
352 # gets read. If this field is
353 # used, there is no longer
354 # anything magical about the
355 # 0x90000 segment; the setup
356 # can be located anywhere in
357 # low memory 0x10000 or higher.
358
359ramdisk_max: .long 0x7fffffff
360 # (Header version 0x0203 or later)
361 # The highest safe address for
362 # the contents of an initrd
363 # The current kernel allows up to 4 GB,
364 # but leave it at 2 GB to avoid
365 # possible bootloader bugs.
366
367kernel_alignment: .long CONFIG_PHYSICAL_ALIGN #physical addr alignment
368 #required for protected mode
369 #kernel
370#ifdef CONFIG_RELOCATABLE
371relocatable_kernel: .byte 1
372#else
373relocatable_kernel: .byte 0
374#endif
375min_alignment: .byte MIN_KERNEL_ALIGN_LG2 # minimum alignment
376pad3: .word 0
377
378cmdline_size: .long COMMAND_LINE_SIZE-1 #length of the command line,
379 #added with boot protocol
380 #version 2.06
381
382hardware_subarch: .long 0 # subarchitecture, added with 2.07
383 # default to 0 for normal x86 PC
384
385hardware_subarch_data: .quad 0
386
387payload_offset: .long ZO_input_data
388payload_length: .long ZO_z_input_len
389
390setup_data: .quad 0 # 64-bit physical pointer to
391 # single linked list of
392 # struct setup_data
393
394pref_address: .quad LOAD_PHYSICAL_ADDR # preferred load addr
395
396#define ZO_INIT_SIZE (ZO__end - ZO_startup_32 + ZO_z_extract_offset)
397#define VO_INIT_SIZE (VO__end - VO__text)
398#if ZO_INIT_SIZE > VO_INIT_SIZE
399#define INIT_SIZE ZO_INIT_SIZE
400#else
401#define INIT_SIZE VO_INIT_SIZE
402#endif
403init_size: .long INIT_SIZE # kernel initialization size
404
405# End of setup header #####################################################
406
407 .section ".entrytext", "ax"
408start_of_setup:
409#ifdef SAFE_RESET_DISK_CONTROLLER
410# Reset the disk controller.
411 movw $0x0000, %ax # Reset disk controller
412 movb $0x80, %dl # All disks
413 int $0x13
414#endif
415
416# Force %es = %ds
417 movw %ds, %ax
418 movw %ax, %es
419 cld
420
421# Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
422# which happened to work by accident for the old code. Recalculate the stack
423# pointer if %ss is invalid. Otherwise leave it alone, LOADLIN sets up the
424# stack behind its own code, so we can't blindly put it directly past the heap.
425
426 movw %ss, %dx
427 cmpw %ax, %dx # %ds == %ss?
428 movw %sp, %dx
429 je 2f # -> assume %sp is reasonably set
430
431 # Invalid %ss, make up a new stack
432 movw $_end, %dx
433 testb $CAN_USE_HEAP, loadflags
434 jz 1f
435 movw heap_end_ptr, %dx
4361: addw $STACK_SIZE, %dx
437 jnc 2f
438 xorw %dx, %dx # Prevent wraparound
439
4402: # Now %dx should point to the end of our stack space
441 andw $~3, %dx # dword align (might as well...)
442 jnz 3f
443 movw $0xfffc, %dx # Make sure we're not zero
4443: movw %ax, %ss
445 movzwl %dx, %esp # Clear upper half of %esp
446 sti # Now we should have a working stack
447
448# We will have entered with %cs = %ds+0x20, normalize %cs so
449# it is on par with the other segments.
450 pushw %ds
451 pushw $6f
452 lretw
4536:
454
455# Check signature at end of setup
456 cmpl $0x5a5aaa55, setup_sig
457 jne setup_bad
458
459# Zero the bss
460 movw $__bss_start, %di
461 movw $_end+3, %cx
462 xorl %eax, %eax
463 subw %di, %cx
464 shrw $2, %cx
465 rep; stosl
466
467# Jump to C code (should not return)
468 calll main
469
470# Setup corrupt somehow...
471setup_bad:
472 movl $setup_corrupt, %eax
473 calll puts
474 # Fall through...
475
476 .globl die
477 .type die, @function
478die:
479 hlt
480 jmp die
481
482 .size die, .-die
483
484 .section ".initdata", "a"
485setup_corrupt:
486 .byte 7
487 .string "No setup signature found...\n"
488
489 .data
490dummy: .long 0
1/*
2 * header.S
3 *
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 *
6 * Based on bootsect.S and setup.S
7 * modified by more people than can be counted
8 *
9 * Rewritten as a common file by H. Peter Anvin (Apr 2007)
10 *
11 * BIG FAT NOTE: We're in real mode using 64k segments. Therefore segment
12 * addresses must be multiplied by 16 to obtain their respective linear
13 * addresses. To avoid confusion, linear addresses are written using leading
14 * hex while segment addresses are written as segment:offset.
15 *
16 */
17
18#include <asm/segment.h>
19#include <generated/utsrelease.h>
20#include <asm/boot.h>
21#include <asm/e820.h>
22#include <asm/page_types.h>
23#include <asm/setup.h>
24#include <asm/bootparam.h>
25#include "boot.h"
26#include "voffset.h"
27#include "zoffset.h"
28
29BOOTSEG = 0x07C0 /* original address of boot-sector */
30SYSSEG = 0x1000 /* historical load address >> 4 */
31
32#ifndef SVGA_MODE
33#define SVGA_MODE ASK_VGA
34#endif
35
36#ifndef ROOT_RDONLY
37#define ROOT_RDONLY 1
38#endif
39
40 .code16
41 .section ".bstext", "ax"
42
43 .global bootsect_start
44bootsect_start:
45#ifdef CONFIG_EFI_STUB
46 # "MZ", MS-DOS header
47 .byte 0x4d
48 .byte 0x5a
49#endif
50
51 # Normalize the start address
52 ljmp $BOOTSEG, $start2
53
54start2:
55 movw %cs, %ax
56 movw %ax, %ds
57 movw %ax, %es
58 movw %ax, %ss
59 xorw %sp, %sp
60 sti
61 cld
62
63 movw $bugger_off_msg, %si
64
65msg_loop:
66 lodsb
67 andb %al, %al
68 jz bs_die
69 movb $0xe, %ah
70 movw $7, %bx
71 int $0x10
72 jmp msg_loop
73
74bs_die:
75 # Allow the user to press a key, then reboot
76 xorw %ax, %ax
77 int $0x16
78 int $0x19
79
80 # int 0x19 should never return. In case it does anyway,
81 # invoke the BIOS reset code...
82 ljmp $0xf000,$0xfff0
83
84#ifdef CONFIG_EFI_STUB
85 .org 0x3c
86 #
87 # Offset to the PE header.
88 #
89 .long pe_header
90#endif /* CONFIG_EFI_STUB */
91
92 .section ".bsdata", "a"
93bugger_off_msg:
94 .ascii "Direct floppy boot is not supported. "
95 .ascii "Use a boot loader program instead.\r\n"
96 .ascii "\n"
97 .ascii "Remove disk and press any key to reboot ...\r\n"
98 .byte 0
99
100#ifdef CONFIG_EFI_STUB
101pe_header:
102 .ascii "PE"
103 .word 0
104
105coff_header:
106#ifdef CONFIG_X86_32
107 .word 0x14c # i386
108#else
109 .word 0x8664 # x86-64
110#endif
111 .word 3 # nr_sections
112 .long 0 # TimeDateStamp
113 .long 0 # PointerToSymbolTable
114 .long 1 # NumberOfSymbols
115 .word section_table - optional_header # SizeOfOptionalHeader
116#ifdef CONFIG_X86_32
117 .word 0x306 # Characteristics.
118 # IMAGE_FILE_32BIT_MACHINE |
119 # IMAGE_FILE_DEBUG_STRIPPED |
120 # IMAGE_FILE_EXECUTABLE_IMAGE |
121 # IMAGE_FILE_LINE_NUMS_STRIPPED
122#else
123 .word 0x206 # Characteristics
124 # IMAGE_FILE_DEBUG_STRIPPED |
125 # IMAGE_FILE_EXECUTABLE_IMAGE |
126 # IMAGE_FILE_LINE_NUMS_STRIPPED
127#endif
128
129optional_header:
130#ifdef CONFIG_X86_32
131 .word 0x10b # PE32 format
132#else
133 .word 0x20b # PE32+ format
134#endif
135 .byte 0x02 # MajorLinkerVersion
136 .byte 0x14 # MinorLinkerVersion
137
138 # Filled in by build.c
139 .long 0 # SizeOfCode
140
141 .long 0 # SizeOfInitializedData
142 .long 0 # SizeOfUninitializedData
143
144 # Filled in by build.c
145 .long 0x0000 # AddressOfEntryPoint
146
147 .long 0x0200 # BaseOfCode
148#ifdef CONFIG_X86_32
149 .long 0 # data
150#endif
151
152extra_header_fields:
153#ifdef CONFIG_X86_32
154 .long 0 # ImageBase
155#else
156 .quad 0 # ImageBase
157#endif
158 .long 0x20 # SectionAlignment
159 .long 0x20 # FileAlignment
160 .word 0 # MajorOperatingSystemVersion
161 .word 0 # MinorOperatingSystemVersion
162 .word 0 # MajorImageVersion
163 .word 0 # MinorImageVersion
164 .word 0 # MajorSubsystemVersion
165 .word 0 # MinorSubsystemVersion
166 .long 0 # Win32VersionValue
167
168 #
169 # The size of the bzImage is written in tools/build.c
170 #
171 .long 0 # SizeOfImage
172
173 .long 0x200 # SizeOfHeaders
174 .long 0 # CheckSum
175 .word 0xa # Subsystem (EFI application)
176 .word 0 # DllCharacteristics
177#ifdef CONFIG_X86_32
178 .long 0 # SizeOfStackReserve
179 .long 0 # SizeOfStackCommit
180 .long 0 # SizeOfHeapReserve
181 .long 0 # SizeOfHeapCommit
182#else
183 .quad 0 # SizeOfStackReserve
184 .quad 0 # SizeOfStackCommit
185 .quad 0 # SizeOfHeapReserve
186 .quad 0 # SizeOfHeapCommit
187#endif
188 .long 0 # LoaderFlags
189 .long 0x6 # NumberOfRvaAndSizes
190
191 .quad 0 # ExportTable
192 .quad 0 # ImportTable
193 .quad 0 # ResourceTable
194 .quad 0 # ExceptionTable
195 .quad 0 # CertificationTable
196 .quad 0 # BaseRelocationTable
197
198 # Section table
199section_table:
200 #
201 # The offset & size fields are filled in by build.c.
202 #
203 .ascii ".setup"
204 .byte 0
205 .byte 0
206 .long 0
207 .long 0x0 # startup_{32,64}
208 .long 0 # Size of initialized data
209 # on disk
210 .long 0x0 # startup_{32,64}
211 .long 0 # PointerToRelocations
212 .long 0 # PointerToLineNumbers
213 .word 0 # NumberOfRelocations
214 .word 0 # NumberOfLineNumbers
215 .long 0x60500020 # Characteristics (section flags)
216
217 #
218 # The EFI application loader requires a relocation section
219 # because EFI applications must be relocatable. The .reloc
220 # offset & size fields are filled in by build.c.
221 #
222 .ascii ".reloc"
223 .byte 0
224 .byte 0
225 .long 0
226 .long 0
227 .long 0 # SizeOfRawData
228 .long 0 # PointerToRawData
229 .long 0 # PointerToRelocations
230 .long 0 # PointerToLineNumbers
231 .word 0 # NumberOfRelocations
232 .word 0 # NumberOfLineNumbers
233 .long 0x42100040 # Characteristics (section flags)
234
235 #
236 # The offset & size fields are filled in by build.c.
237 #
238 .ascii ".text"
239 .byte 0
240 .byte 0
241 .byte 0
242 .long 0
243 .long 0x0 # startup_{32,64}
244 .long 0 # Size of initialized data
245 # on disk
246 .long 0x0 # startup_{32,64}
247 .long 0 # PointerToRelocations
248 .long 0 # PointerToLineNumbers
249 .word 0 # NumberOfRelocations
250 .word 0 # NumberOfLineNumbers
251 .long 0x60500020 # Characteristics (section flags)
252
253#endif /* CONFIG_EFI_STUB */
254
255 # Kernel attributes; used by setup. This is part 1 of the
256 # header, from the old boot sector.
257
258 .section ".header", "a"
259 .globl sentinel
260sentinel: .byte 0xff, 0xff /* Used to detect broken loaders */
261
262 .globl hdr
263hdr:
264setup_sects: .byte 0 /* Filled in by build.c */
265root_flags: .word ROOT_RDONLY
266syssize: .long 0 /* Filled in by build.c */
267ram_size: .word 0 /* Obsolete */
268vid_mode: .word SVGA_MODE
269root_dev: .word 0 /* Filled in by build.c */
270boot_flag: .word 0xAA55
271
272 # offset 512, entry point
273
274 .globl _start
275_start:
276 # Explicitly enter this as bytes, or the assembler
277 # tries to generate a 3-byte jump here, which causes
278 # everything else to push off to the wrong offset.
279 .byte 0xeb # short (2-byte) jump
280 .byte start_of_setup-1f
2811:
282
283 # Part 2 of the header, from the old setup.S
284
285 .ascii "HdrS" # header signature
286 .word 0x020d # header version number (>= 0x0105)
287 # or else old loadlin-1.5 will fail)
288 .globl realmode_swtch
289realmode_swtch: .word 0, 0 # default_switch, SETUPSEG
290start_sys_seg: .word SYSSEG # obsolete and meaningless, but just
291 # in case something decided to "use" it
292 .word kernel_version-512 # pointing to kernel version string
293 # above section of header is compatible
294 # with loadlin-1.5 (header v1.5). Don't
295 # change it.
296
297type_of_loader: .byte 0 # 0 means ancient bootloader, newer
298 # bootloaders know to change this.
299 # See Documentation/x86/boot.txt for
300 # assigned ids
301
302# flags, unused bits must be zero (RFU) bit within loadflags
303loadflags:
304 .byte LOADED_HIGH # The kernel is to be loaded high
305
306setup_move_size: .word 0x8000 # size to move, when setup is not
307 # loaded at 0x90000. We will move setup
308 # to 0x90000 then just before jumping
309 # into the kernel. However, only the
310 # loader knows how much data behind
311 # us also needs to be loaded.
312
313code32_start: # here loaders can put a different
314 # start address for 32-bit code.
315 .long 0x100000 # 0x100000 = default for big kernel
316
317ramdisk_image: .long 0 # address of loaded ramdisk image
318 # Here the loader puts the 32-bit
319 # address where it loaded the image.
320 # This only will be read by the kernel.
321
322ramdisk_size: .long 0 # its size in bytes
323
324bootsect_kludge:
325 .long 0 # obsolete
326
327heap_end_ptr: .word _end+STACK_SIZE-512
328 # (Header version 0x0201 or later)
329 # space from here (exclusive) down to
330 # end of setup code can be used by setup
331 # for local heap purposes.
332
333ext_loader_ver:
334 .byte 0 # Extended boot loader version
335ext_loader_type:
336 .byte 0 # Extended boot loader type
337
338cmd_line_ptr: .long 0 # (Header version 0x0202 or later)
339 # If nonzero, a 32-bit pointer
340 # to the kernel command line.
341 # The command line should be
342 # located between the start of
343 # setup and the end of low
344 # memory (0xa0000), or it may
345 # get overwritten before it
346 # gets read. If this field is
347 # used, there is no longer
348 # anything magical about the
349 # 0x90000 segment; the setup
350 # can be located anywhere in
351 # low memory 0x10000 or higher.
352
353initrd_addr_max: .long 0x7fffffff
354 # (Header version 0x0203 or later)
355 # The highest safe address for
356 # the contents of an initrd
357 # The current kernel allows up to 4 GB,
358 # but leave it at 2 GB to avoid
359 # possible bootloader bugs.
360
361kernel_alignment: .long CONFIG_PHYSICAL_ALIGN #physical addr alignment
362 #required for protected mode
363 #kernel
364#ifdef CONFIG_RELOCATABLE
365relocatable_kernel: .byte 1
366#else
367relocatable_kernel: .byte 0
368#endif
369min_alignment: .byte MIN_KERNEL_ALIGN_LG2 # minimum alignment
370
371xloadflags:
372#ifdef CONFIG_X86_64
373# define XLF0 XLF_KERNEL_64 /* 64-bit kernel */
374#else
375# define XLF0 0
376#endif
377
378#if defined(CONFIG_RELOCATABLE) && defined(CONFIG_X86_64)
379 /* kernel/boot_param/ramdisk could be loaded above 4g */
380# define XLF1 XLF_CAN_BE_LOADED_ABOVE_4G
381#else
382# define XLF1 0
383#endif
384
385#ifdef CONFIG_EFI_STUB
386# ifdef CONFIG_EFI_MIXED
387# define XLF23 (XLF_EFI_HANDOVER_32|XLF_EFI_HANDOVER_64)
388# else
389# ifdef CONFIG_X86_64
390# define XLF23 XLF_EFI_HANDOVER_64 /* 64-bit EFI handover ok */
391# else
392# define XLF23 XLF_EFI_HANDOVER_32 /* 32-bit EFI handover ok */
393# endif
394# endif
395#else
396# define XLF23 0
397#endif
398
399#if defined(CONFIG_X86_64) && defined(CONFIG_EFI) && defined(CONFIG_KEXEC)
400# define XLF4 XLF_EFI_KEXEC
401#else
402# define XLF4 0
403#endif
404
405 .word XLF0 | XLF1 | XLF23 | XLF4
406
407cmdline_size: .long COMMAND_LINE_SIZE-1 #length of the command line,
408 #added with boot protocol
409 #version 2.06
410
411hardware_subarch: .long 0 # subarchitecture, added with 2.07
412 # default to 0 for normal x86 PC
413
414hardware_subarch_data: .quad 0
415
416payload_offset: .long ZO_input_data
417payload_length: .long ZO_z_input_len
418
419setup_data: .quad 0 # 64-bit physical pointer to
420 # single linked list of
421 # struct setup_data
422
423pref_address: .quad LOAD_PHYSICAL_ADDR # preferred load addr
424
425#define ZO_INIT_SIZE (ZO__end - ZO_startup_32 + ZO_z_extract_offset)
426#define VO_INIT_SIZE (VO__end - VO__text)
427#if ZO_INIT_SIZE > VO_INIT_SIZE
428#define INIT_SIZE ZO_INIT_SIZE
429#else
430#define INIT_SIZE VO_INIT_SIZE
431#endif
432init_size: .long INIT_SIZE # kernel initialization size
433handover_offset: .long 0 # Filled in by build.c
434
435# End of setup header #####################################################
436
437 .section ".entrytext", "ax"
438start_of_setup:
439# Force %es = %ds
440 movw %ds, %ax
441 movw %ax, %es
442 cld
443
444# Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
445# which happened to work by accident for the old code. Recalculate the stack
446# pointer if %ss is invalid. Otherwise leave it alone, LOADLIN sets up the
447# stack behind its own code, so we can't blindly put it directly past the heap.
448
449 movw %ss, %dx
450 cmpw %ax, %dx # %ds == %ss?
451 movw %sp, %dx
452 je 2f # -> assume %sp is reasonably set
453
454 # Invalid %ss, make up a new stack
455 movw $_end, %dx
456 testb $CAN_USE_HEAP, loadflags
457 jz 1f
458 movw heap_end_ptr, %dx
4591: addw $STACK_SIZE, %dx
460 jnc 2f
461 xorw %dx, %dx # Prevent wraparound
462
4632: # Now %dx should point to the end of our stack space
464 andw $~3, %dx # dword align (might as well...)
465 jnz 3f
466 movw $0xfffc, %dx # Make sure we're not zero
4673: movw %ax, %ss
468 movzwl %dx, %esp # Clear upper half of %esp
469 sti # Now we should have a working stack
470
471# We will have entered with %cs = %ds+0x20, normalize %cs so
472# it is on par with the other segments.
473 pushw %ds
474 pushw $6f
475 lretw
4766:
477
478# Check signature at end of setup
479 cmpl $0x5a5aaa55, setup_sig
480 jne setup_bad
481
482# Zero the bss
483 movw $__bss_start, %di
484 movw $_end+3, %cx
485 xorl %eax, %eax
486 subw %di, %cx
487 shrw $2, %cx
488 rep; stosl
489
490# Jump to C code (should not return)
491 calll main
492
493# Setup corrupt somehow...
494setup_bad:
495 movl $setup_corrupt, %eax
496 calll puts
497 # Fall through...
498
499 .globl die
500 .type die, @function
501die:
502 hlt
503 jmp die
504
505 .size die, .-die
506
507 .section ".initdata", "a"
508setup_corrupt:
509 .byte 7
510 .string "No setup signature found...\n"