Loading...
1/*
2 * linux/arch/arm/lib/findbit.S
3 *
4 * Copyright (C) 1995-2000 Russell King
5 *
6 * This program is free software; you can redistribute it and/or modify
7 * it under the terms of the GNU General Public License version 2 as
8 * published by the Free Software Foundation.
9 *
10 * 16th March 2001 - John Ripley <jripley@sonicblue.com>
11 * Fixed so that "size" is an exclusive not an inclusive quantity.
12 * All users of these functions expect exclusive sizes, and may
13 * also call with zero size.
14 * Reworked by rmk.
15 */
16#include <linux/linkage.h>
17#include <asm/assembler.h>
18 .text
19
20/*
21 * Purpose : Find a 'zero' bit
22 * Prototype: int find_first_zero_bit(void *addr, unsigned int maxbit);
23 */
24ENTRY(_find_first_zero_bit_le)
25 teq r1, #0
26 beq 3f
27 mov r2, #0
281:
29 ARM( ldrb r3, [r0, r2, lsr #3] )
30 THUMB( lsr r3, r2, #3 )
31 THUMB( ldrb r3, [r0, r3] )
32 eors r3, r3, #0xff @ invert bits
33 bne .L_found @ any now set - found zero bit
34 add r2, r2, #8 @ next bit pointer
352: cmp r2, r1 @ any more?
36 blo 1b
373: mov r0, r1 @ no free bits
38 mov pc, lr
39ENDPROC(_find_first_zero_bit_le)
40
41/*
42 * Purpose : Find next 'zero' bit
43 * Prototype: int find_next_zero_bit(void *addr, unsigned int maxbit, int offset)
44 */
45ENTRY(_find_next_zero_bit_le)
46 teq r1, #0
47 beq 3b
48 ands ip, r2, #7
49 beq 1b @ If new byte, goto old routine
50 ARM( ldrb r3, [r0, r2, lsr #3] )
51 THUMB( lsr r3, r2, #3 )
52 THUMB( ldrb r3, [r0, r3] )
53 eor r3, r3, #0xff @ now looking for a 1 bit
54 movs r3, r3, lsr ip @ shift off unused bits
55 bne .L_found
56 orr r2, r2, #7 @ if zero, then no bits here
57 add r2, r2, #1 @ align bit pointer
58 b 2b @ loop for next bit
59ENDPROC(_find_next_zero_bit_le)
60
61/*
62 * Purpose : Find a 'one' bit
63 * Prototype: int find_first_bit(const unsigned long *addr, unsigned int maxbit);
64 */
65ENTRY(_find_first_bit_le)
66 teq r1, #0
67 beq 3f
68 mov r2, #0
691:
70 ARM( ldrb r3, [r0, r2, lsr #3] )
71 THUMB( lsr r3, r2, #3 )
72 THUMB( ldrb r3, [r0, r3] )
73 movs r3, r3
74 bne .L_found @ any now set - found zero bit
75 add r2, r2, #8 @ next bit pointer
762: cmp r2, r1 @ any more?
77 blo 1b
783: mov r0, r1 @ no free bits
79 mov pc, lr
80ENDPROC(_find_first_bit_le)
81
82/*
83 * Purpose : Find next 'one' bit
84 * Prototype: int find_next_zero_bit(void *addr, unsigned int maxbit, int offset)
85 */
86ENTRY(_find_next_bit_le)
87 teq r1, #0
88 beq 3b
89 ands ip, r2, #7
90 beq 1b @ If new byte, goto old routine
91 ARM( ldrb r3, [r0, r2, lsr #3] )
92 THUMB( lsr r3, r2, #3 )
93 THUMB( ldrb r3, [r0, r3] )
94 movs r3, r3, lsr ip @ shift off unused bits
95 bne .L_found
96 orr r2, r2, #7 @ if zero, then no bits here
97 add r2, r2, #1 @ align bit pointer
98 b 2b @ loop for next bit
99ENDPROC(_find_next_bit_le)
100
101#ifdef __ARMEB__
102
103ENTRY(_find_first_zero_bit_be)
104 teq r1, #0
105 beq 3f
106 mov r2, #0
1071: eor r3, r2, #0x18 @ big endian byte ordering
108 ARM( ldrb r3, [r0, r3, lsr #3] )
109 THUMB( lsr r3, #3 )
110 THUMB( ldrb r3, [r0, r3] )
111 eors r3, r3, #0xff @ invert bits
112 bne .L_found @ any now set - found zero bit
113 add r2, r2, #8 @ next bit pointer
1142: cmp r2, r1 @ any more?
115 blo 1b
1163: mov r0, r1 @ no free bits
117 mov pc, lr
118ENDPROC(_find_first_zero_bit_be)
119
120ENTRY(_find_next_zero_bit_be)
121 teq r1, #0
122 beq 3b
123 ands ip, r2, #7
124 beq 1b @ If new byte, goto old routine
125 eor r3, r2, #0x18 @ big endian byte ordering
126 ARM( ldrb r3, [r0, r3, lsr #3] )
127 THUMB( lsr r3, #3 )
128 THUMB( ldrb r3, [r0, r3] )
129 eor r3, r3, #0xff @ now looking for a 1 bit
130 movs r3, r3, lsr ip @ shift off unused bits
131 bne .L_found
132 orr r2, r2, #7 @ if zero, then no bits here
133 add r2, r2, #1 @ align bit pointer
134 b 2b @ loop for next bit
135ENDPROC(_find_next_zero_bit_be)
136
137ENTRY(_find_first_bit_be)
138 teq r1, #0
139 beq 3f
140 mov r2, #0
1411: eor r3, r2, #0x18 @ big endian byte ordering
142 ARM( ldrb r3, [r0, r3, lsr #3] )
143 THUMB( lsr r3, #3 )
144 THUMB( ldrb r3, [r0, r3] )
145 movs r3, r3
146 bne .L_found @ any now set - found zero bit
147 add r2, r2, #8 @ next bit pointer
1482: cmp r2, r1 @ any more?
149 blo 1b
1503: mov r0, r1 @ no free bits
151 mov pc, lr
152ENDPROC(_find_first_bit_be)
153
154ENTRY(_find_next_bit_be)
155 teq r1, #0
156 beq 3b
157 ands ip, r2, #7
158 beq 1b @ If new byte, goto old routine
159 eor r3, r2, #0x18 @ big endian byte ordering
160 ARM( ldrb r3, [r0, r3, lsr #3] )
161 THUMB( lsr r3, #3 )
162 THUMB( ldrb r3, [r0, r3] )
163 movs r3, r3, lsr ip @ shift off unused bits
164 bne .L_found
165 orr r2, r2, #7 @ if zero, then no bits here
166 add r2, r2, #1 @ align bit pointer
167 b 2b @ loop for next bit
168ENDPROC(_find_next_bit_be)
169
170#endif
171
172/*
173 * One or more bits in the LSB of r3 are assumed to be set.
174 */
175.L_found:
176#if __LINUX_ARM_ARCH__ >= 5
177 rsb r0, r3, #0
178 and r3, r3, r0
179 clz r3, r3
180 rsb r3, r3, #31
181 add r0, r2, r3
182#else
183 tst r3, #0x0f
184 addeq r2, r2, #4
185 movne r3, r3, lsl #4
186 tst r3, #0x30
187 addeq r2, r2, #2
188 movne r3, r3, lsl #2
189 tst r3, #0x40
190 addeq r2, r2, #1
191 mov r0, r2
192#endif
193 cmp r1, r0 @ Clamp to maxbit
194 movlo r0, r1
195 mov pc, lr
196
1/* SPDX-License-Identifier: GPL-2.0-only */
2/*
3 * linux/arch/arm/lib/findbit.S
4 *
5 * Copyright (C) 1995-2000 Russell King
6 *
7 * 16th March 2001 - John Ripley <jripley@sonicblue.com>
8 * Fixed so that "size" is an exclusive not an inclusive quantity.
9 * All users of these functions expect exclusive sizes, and may
10 * also call with zero size.
11 * Reworked by rmk.
12 */
13#include <linux/linkage.h>
14#include <asm/assembler.h>
15#include <asm/unwind.h>
16 .text
17
18#ifdef __ARMEB__
19#define SWAB_ENDIAN le
20#else
21#define SWAB_ENDIAN be
22#endif
23
24 .macro find_first, endian, set, name
25ENTRY(_find_first_\name\()bit_\endian)
26 UNWIND( .fnstart)
27 teq r1, #0
28 beq 3f
29 mov r2, #0
301: ldr r3, [r0], #4
31 .ifeq \set
32 mvns r3, r3 @ invert/test bits
33 .else
34 movs r3, r3 @ test bits
35 .endif
36 .ifc \endian, SWAB_ENDIAN
37 bne .L_found_swab
38 .else
39 bne .L_found @ found the bit?
40 .endif
41 add r2, r2, #32 @ next index
422: cmp r2, r1 @ any more?
43 blo 1b
443: mov r0, r1 @ no more bits
45 ret lr
46 UNWIND( .fnend)
47ENDPROC(_find_first_\name\()bit_\endian)
48 .endm
49
50 .macro find_next, endian, set, name
51ENTRY(_find_next_\name\()bit_\endian)
52 UNWIND( .fnstart)
53 cmp r2, r1
54 bhs 3b
55 mov ip, r2, lsr #5 @ word index
56 add r0, r0, ip, lsl #2
57 ands ip, r2, #31 @ bit position
58 beq 1b
59 ldr r3, [r0], #4
60 .ifeq \set
61 mvn r3, r3 @ invert bits
62 .endif
63 .ifc \endian, SWAB_ENDIAN
64 rev_l r3, ip
65 .if .Lrev_l_uses_tmp
66 @ we need to recompute ip because rev_l will have overwritten
67 @ it.
68 and ip, r2, #31 @ bit position
69 .endif
70 .endif
71 movs r3, r3, lsr ip @ shift off unused bits
72 bne .L_found
73 orr r2, r2, #31 @ no zero bits
74 add r2, r2, #1 @ align bit pointer
75 b 2b @ loop for next bit
76 UNWIND( .fnend)
77ENDPROC(_find_next_\name\()bit_\endian)
78 .endm
79
80 .macro find_bit, endian, set, name
81 find_first \endian, \set, \name
82 find_next \endian, \set, \name
83 .endm
84
85/* _find_first_zero_bit_le and _find_next_zero_bit_le */
86 find_bit le, 0, zero_
87
88/* _find_first_bit_le and _find_next_bit_le */
89 find_bit le, 1
90
91#ifdef __ARMEB__
92
93/* _find_first_zero_bit_be and _find_next_zero_bit_be */
94 find_bit be, 0, zero_
95
96/* _find_first_bit_be and _find_next_bit_be */
97 find_bit be, 1
98
99#endif
100
101/*
102 * One or more bits in the LSB of r3 are assumed to be set.
103 */
104.L_found_swab:
105 UNWIND( .fnstart)
106 rev_l r3, ip
107.L_found:
108#if __LINUX_ARM_ARCH__ >= 7
109 rbit r3, r3 @ reverse bits
110 clz r3, r3 @ count high zero bits
111 add r0, r2, r3 @ add offset of first set bit
112#elif __LINUX_ARM_ARCH__ >= 5
113 rsb r0, r3, #0
114 and r3, r3, r0 @ mask out lowest bit set
115 clz r3, r3 @ count high zero bits
116 rsb r3, r3, #31 @ offset of first set bit
117 add r0, r2, r3 @ add offset of first set bit
118#else
119 mov ip, #~0
120 tst r3, ip, lsr #16 @ test bits 0-15
121 addeq r2, r2, #16
122 moveq r3, r3, lsr #16
123 tst r3, #0x00ff
124 addeq r2, r2, #8
125 moveq r3, r3, lsr #8
126 tst r3, #0x000f
127 addeq r2, r2, #4
128 moveq r3, r3, lsr #4
129 tst r3, #0x0003
130 addeq r2, r2, #2
131 moveq r3, r3, lsr #2
132 tst r3, #0x0001
133 addeq r2, r2, #1
134 mov r0, r2
135#endif
136 cmp r1, r0 @ Clamp to maxbit
137 movlo r0, r1
138 ret lr
139 UNWIND( .fnend)