1/*
 2 * Common module linker script, always used when linking a module.
 3 * Archs are free to supply their own linker scripts.  ld will
 4 * combine them automatically.
 5 */
 6#ifdef CONFIG_UNWIND_TABLES
 7#define DISCARD_EH_FRAME
 8#else
 9#define DISCARD_EH_FRAME	*(.eh_frame)
10#endif
11
12#include <asm-generic/codetag.lds.h>
13
14SECTIONS {
15	/DISCARD/ : {
16		*(.discard)
17		*(.discard.*)
18		*(.export_symbol)
19	}
20
21	__ksymtab		0 : ALIGN(8) { *(SORT(___ksymtab+*)) }
22	__ksymtab_gpl		0 : ALIGN(8) { *(SORT(___ksymtab_gpl+*)) }
23	__kcrctab		0 : ALIGN(4) { *(SORT(___kcrctab+*)) }
24	__kcrctab_gpl		0 : ALIGN(4) { *(SORT(___kcrctab_gpl+*)) }
25
26	.ctors			0 : ALIGN(8) { *(SORT(.ctors.*)) *(.ctors) }
27	.init_array		0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) }
28
29	.altinstructions	0 : ALIGN(8) { KEEP(*(.altinstructions)) }
30	__bug_table		0 : ALIGN(8) { KEEP(*(__bug_table)) }
31	__jump_table		0 : ALIGN(8) { KEEP(*(__jump_table)) }
32	__ex_table		0 : ALIGN(4) { KEEP(*(__ex_table)) }
33
34	__patchable_function_entries : { *(__patchable_function_entries) }
35
36#ifdef CONFIG_ARCH_USES_CFI_TRAPS
37	__kcfi_traps 		: { KEEP(*(.kcfi_traps)) }
38#endif
39
40#ifdef CONFIG_LTO_CLANG
41	/*
42	 * With CONFIG_LTO_CLANG, LLD always enables -fdata-sections and
43	 * -ffunction-sections, which increases the size of the final module.
44	 * Merge the split sections in the final binary.
45	 */
46	.bss : {
47		*(.bss .bss.[0-9a-zA-Z_]*)
48		*(.bss..L*)
49	}
50
51	.data : {
52		*(.data .data.[0-9a-zA-Z_]*)
53		*(.data..L*)
54		MOD_CODETAG_SECTIONS()
55	}
56
57	.rodata : {
58		*(.rodata .rodata.[0-9a-zA-Z_]*)
59		*(.rodata..L*)
60	}
61#else
62	.data : {
63		MOD_CODETAG_SECTIONS()
64	}
65#endif
66	MOD_SEPARATE_CODETAG_SECTIONS()
67}
68
69/* bring in arch-specific sections */
70#include <asm/module.lds.h>