Loading...
1/*
2 * arch/alpha/lib/divide.S
3 *
4 * (C) 1995 Linus Torvalds
5 *
6 * Alpha division..
7 */
8
9/*
10 * The alpha chip doesn't provide hardware division, so we have to do it
11 * by hand. The compiler expects the functions
12 *
13 * __divqu: 64-bit unsigned long divide
14 * __remqu: 64-bit unsigned long remainder
15 * __divqs/__remqs: signed 64-bit
16 * __divlu/__remlu: unsigned 32-bit
17 * __divls/__remls: signed 32-bit
18 *
19 * These are not normal C functions: instead of the normal
20 * calling sequence, these expect their arguments in registers
21 * $24 and $25, and return the result in $27. Register $28 may
22 * be clobbered (assembly temporary), anything else must be saved.
23 *
24 * In short: painful.
25 *
26 * This is a rather simple bit-at-a-time algorithm: it's very good
27 * at dividing random 64-bit numbers, but the more usual case where
28 * the divisor is small is handled better by the DEC algorithm
29 * using lookup tables. This uses much less memory, though, and is
30 * nicer on the cache.. Besides, I don't know the copyright status
31 * of the DEC code.
32 */
33
34/*
35 * My temporaries:
36 * $0 - current bit
37 * $1 - shifted divisor
38 * $2 - modulus/quotient
39 *
40 * $23 - return address
41 * $24 - dividend
42 * $25 - divisor
43 *
44 * $27 - quotient/modulus
45 * $28 - compare status
46 */
47
48#define halt .long 0
49
50/*
51 * Select function type and registers
52 */
53#define mask $0
54#define divisor $1
55#define compare $28
56#define tmp1 $3
57#define tmp2 $4
58
59#ifdef DIV
60#define DIV_ONLY(x,y...) x,##y
61#define MOD_ONLY(x,y...)
62#define func(x) __div##x
63#define modulus $2
64#define quotient $27
65#define GETSIGN(x) xor $24,$25,x
66#define STACK 48
67#else
68#define DIV_ONLY(x,y...)
69#define MOD_ONLY(x,y...) x,##y
70#define func(x) __rem##x
71#define modulus $27
72#define quotient $2
73#define GETSIGN(x) bis $24,$24,x
74#define STACK 32
75#endif
76
77/*
78 * For 32-bit operations, we need to extend to 64-bit
79 */
80#ifdef INTSIZE
81#define ufunction func(lu)
82#define sfunction func(l)
83#define LONGIFY(x) zapnot x,15,x
84#define SLONGIFY(x) addl x,0,x
85#else
86#define ufunction func(qu)
87#define sfunction func(q)
88#define LONGIFY(x)
89#define SLONGIFY(x)
90#endif
91
92.set noat
93.align 3
94.globl ufunction
95.ent ufunction
96ufunction:
97 subq $30,STACK,$30
98 .frame $30,STACK,$23
99 .prologue 0
100
1017: stq $1, 0($30)
102 bis $25,$25,divisor
103 stq $2, 8($30)
104 bis $24,$24,modulus
105 stq $0,16($30)
106 bis $31,$31,quotient
107 LONGIFY(divisor)
108 stq tmp1,24($30)
109 LONGIFY(modulus)
110 bis $31,1,mask
111 DIV_ONLY(stq tmp2,32($30))
112 beq divisor, 9f /* div by zero */
113
114#ifdef INTSIZE
115 /*
116 * shift divisor left, using 3-bit shifts for
117 * 32-bit divides as we can't overflow. Three-bit
118 * shifts will result in looping three times less
119 * here, but can result in two loops more later.
120 * Thus using a large shift isn't worth it (and
121 * s8add pairs better than a sll..)
122 */
1231: cmpult divisor,modulus,compare
124 s8addq divisor,$31,divisor
125 s8addq mask,$31,mask
126 bne compare,1b
127#else
1281: cmpult divisor,modulus,compare
129 blt divisor, 2f
130 addq divisor,divisor,divisor
131 addq mask,mask,mask
132 bne compare,1b
133 unop
134#endif
135
136 /* ok, start to go right again.. */
1372: DIV_ONLY(addq quotient,mask,tmp2)
138 srl mask,1,mask
139 cmpule divisor,modulus,compare
140 subq modulus,divisor,tmp1
141 DIV_ONLY(cmovne compare,tmp2,quotient)
142 srl divisor,1,divisor
143 cmovne compare,tmp1,modulus
144 bne mask,2b
145
1469: ldq $1, 0($30)
147 ldq $2, 8($30)
148 ldq $0,16($30)
149 ldq tmp1,24($30)
150 DIV_ONLY(ldq tmp2,32($30))
151 addq $30,STACK,$30
152 ret $31,($23),1
153 .end ufunction
154
155/*
156 * Uhh.. Ugly signed division. I'd rather not have it at all, but
157 * it's needed in some circumstances. There are different ways to
158 * handle this, really. This does:
159 * -a / b = a / -b = -(a / b)
160 * -a % b = -(a % b)
161 * a % -b = a % b
162 * which is probably not the best solution, but at least should
163 * have the property that (x/y)*y + (x%y) = x.
164 */
165.align 3
166.globl sfunction
167.ent sfunction
168sfunction:
169 subq $30,STACK,$30
170 .frame $30,STACK,$23
171 .prologue 0
172 bis $24,$25,$28
173 SLONGIFY($28)
174 bge $28,7b
175 stq $24,0($30)
176 subq $31,$24,$28
177 stq $25,8($30)
178 cmovlt $24,$28,$24 /* abs($24) */
179 stq $23,16($30)
180 subq $31,$25,$28
181 stq tmp1,24($30)
182 cmovlt $25,$28,$25 /* abs($25) */
183 unop
184 bsr $23,ufunction
185 ldq $24,0($30)
186 ldq $25,8($30)
187 GETSIGN($28)
188 subq $31,$27,tmp1
189 SLONGIFY($28)
190 ldq $23,16($30)
191 cmovlt $28,tmp1,$27
192 ldq tmp1,24($30)
193 addq $30,STACK,$30
194 ret $31,($23),1
195 .end sfunction
1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * arch/alpha/lib/divide.S
4 *
5 * (C) 1995 Linus Torvalds
6 *
7 * Alpha division..
8 */
9
10/*
11 * The alpha chip doesn't provide hardware division, so we have to do it
12 * by hand. The compiler expects the functions
13 *
14 * __divqu: 64-bit unsigned long divide
15 * __remqu: 64-bit unsigned long remainder
16 * __divqs/__remqs: signed 64-bit
17 * __divlu/__remlu: unsigned 32-bit
18 * __divls/__remls: signed 32-bit
19 *
20 * These are not normal C functions: instead of the normal
21 * calling sequence, these expect their arguments in registers
22 * $24 and $25, and return the result in $27. Register $28 may
23 * be clobbered (assembly temporary), anything else must be saved.
24 *
25 * In short: painful.
26 *
27 * This is a rather simple bit-at-a-time algorithm: it's very good
28 * at dividing random 64-bit numbers, but the more usual case where
29 * the divisor is small is handled better by the DEC algorithm
30 * using lookup tables. This uses much less memory, though, and is
31 * nicer on the cache.. Besides, I don't know the copyright status
32 * of the DEC code.
33 */
34
35/*
36 * My temporaries:
37 * $0 - current bit
38 * $1 - shifted divisor
39 * $2 - modulus/quotient
40 *
41 * $23 - return address
42 * $24 - dividend
43 * $25 - divisor
44 *
45 * $27 - quotient/modulus
46 * $28 - compare status
47 */
48
49#include <linux/export.h>
50#define halt .long 0
51
52/*
53 * Select function type and registers
54 */
55#define mask $0
56#define divisor $1
57#define compare $28
58#define tmp1 $3
59#define tmp2 $4
60
61#ifdef DIV
62#define DIV_ONLY(x,y...) x,##y
63#define MOD_ONLY(x,y...)
64#define func(x) __div##x
65#define modulus $2
66#define quotient $27
67#define GETSIGN(x) xor $24,$25,x
68#define STACK 48
69#else
70#define DIV_ONLY(x,y...)
71#define MOD_ONLY(x,y...) x,##y
72#define func(x) __rem##x
73#define modulus $27
74#define quotient $2
75#define GETSIGN(x) bis $24,$24,x
76#define STACK 32
77#endif
78
79/*
80 * For 32-bit operations, we need to extend to 64-bit
81 */
82#ifdef INTSIZE
83#define ufunction func(lu)
84#define sfunction func(l)
85#define LONGIFY(x) zapnot x,15,x
86#define SLONGIFY(x) addl x,0,x
87#else
88#define ufunction func(qu)
89#define sfunction func(q)
90#define LONGIFY(x)
91#define SLONGIFY(x)
92#endif
93
94.set noat
95.align 3
96.globl ufunction
97.ent ufunction
98ufunction:
99 subq $30,STACK,$30
100 .frame $30,STACK,$23
101 .prologue 0
102
1037: stq $1, 0($30)
104 bis $25,$25,divisor
105 stq $2, 8($30)
106 bis $24,$24,modulus
107 stq $0,16($30)
108 bis $31,$31,quotient
109 LONGIFY(divisor)
110 stq tmp1,24($30)
111 LONGIFY(modulus)
112 bis $31,1,mask
113 DIV_ONLY(stq tmp2,32($30))
114 beq divisor, 9f /* div by zero */
115
116#ifdef INTSIZE
117 /*
118 * shift divisor left, using 3-bit shifts for
119 * 32-bit divides as we can't overflow. Three-bit
120 * shifts will result in looping three times less
121 * here, but can result in two loops more later.
122 * Thus using a large shift isn't worth it (and
123 * s8add pairs better than a sll..)
124 */
1251: cmpult divisor,modulus,compare
126 s8addq divisor,$31,divisor
127 s8addq mask,$31,mask
128 bne compare,1b
129#else
1301: cmpult divisor,modulus,compare
131 blt divisor, 2f
132 addq divisor,divisor,divisor
133 addq mask,mask,mask
134 bne compare,1b
135 unop
136#endif
137
138 /* ok, start to go right again.. */
1392: DIV_ONLY(addq quotient,mask,tmp2)
140 srl mask,1,mask
141 cmpule divisor,modulus,compare
142 subq modulus,divisor,tmp1
143 DIV_ONLY(cmovne compare,tmp2,quotient)
144 srl divisor,1,divisor
145 cmovne compare,tmp1,modulus
146 bne mask,2b
147
1489: ldq $1, 0($30)
149 ldq $2, 8($30)
150 ldq $0,16($30)
151 ldq tmp1,24($30)
152 DIV_ONLY(ldq tmp2,32($30))
153 addq $30,STACK,$30
154 ret $31,($23),1
155 .end ufunction
156EXPORT_SYMBOL(ufunction)
157
158/*
159 * Uhh.. Ugly signed division. I'd rather not have it at all, but
160 * it's needed in some circumstances. There are different ways to
161 * handle this, really. This does:
162 * -a / b = a / -b = -(a / b)
163 * -a % b = -(a % b)
164 * a % -b = a % b
165 * which is probably not the best solution, but at least should
166 * have the property that (x/y)*y + (x%y) = x.
167 */
168.align 3
169.globl sfunction
170.ent sfunction
171sfunction:
172 subq $30,STACK,$30
173 .frame $30,STACK,$23
174 .prologue 0
175 bis $24,$25,$28
176 SLONGIFY($28)
177 bge $28,7b
178 stq $24,0($30)
179 subq $31,$24,$28
180 stq $25,8($30)
181 cmovlt $24,$28,$24 /* abs($24) */
182 stq $23,16($30)
183 subq $31,$25,$28
184 stq tmp1,24($30)
185 cmovlt $25,$28,$25 /* abs($25) */
186 unop
187 bsr $23,ufunction
188 ldq $24,0($30)
189 ldq $25,8($30)
190 GETSIGN($28)
191 subq $31,$27,tmp1
192 SLONGIFY($28)
193 ldq $23,16($30)
194 cmovlt $28,tmp1,$27
195 ldq tmp1,24($30)
196 addq $30,STACK,$30
197 ret $31,($23),1
198 .end sfunction
199EXPORT_SYMBOL(sfunction)